src/msvcbuild.bat

   1 @rem Script to build LuaJIT with MSVC.\r
   2 @rem Copyright (C) 2005-2023 Mike Pall. See Copyright Notice in luajit.h\r
   3 @rem\r
   4 @rem Open a "Visual Studio Command Prompt" (either x86 or x64).\r
   5 @rem Then cd to this directory and run this script. Use the following\r
   6 @rem options (in order), if needed. The default is a dynamic release build.\r
   7 @rem\r
   8 @rem   nogc64   disable LJ_GC64 mode for x64\r
   9 @rem   debug    emit debug symbols\r
  10 @rem   amalg    amalgamated build\r
  11 @rem   static   static linkage\r
  12 \r
  13 @if not defined INCLUDE goto :FAIL\r
  14 \r
  15 @setlocal\r
  16 @rem Add more debug flags here, e.g. DEBUGCFLAGS=/DLUA_USE_APICHECK\r
  17 @set DEBUGCFLAGS=\r
  18 @set LJCOMPILE=cl /nologo /c /O2 /W3 /D_CRT_SECURE_NO_DEPRECATE /D_CRT_STDIO_INLINE=__declspec(dllexport)__inline\r
  19 @set LJDYNBUILD=/MD /DLUA_BUILD_AS_DLL\r
  20 @set LJLINK=link /nologo\r
  21 @set LJMT=mt /nologo\r
  22 @set LJLIB=lib /nologo /nodefaultlib\r
  23 @set DASMDIR=..\dynasm\r
  24 @set DASM=%DASMDIR%\dynasm.lua\r
  25 @set DASC=vm_x64.dasc\r
  26 @set LJDLLNAME=lua51.dll\r
  27 @set LJLIBNAME=lua51.lib\r
  28 @set BUILDTYPE=release\r
  29 @set ALL_LIB=lib_base.c lib_math.c lib_bit.c lib_string.c lib_table.c lib_io.c lib_os.c lib_package.c lib_debug.c lib_jit.c lib_ffi.c lib_buffer.c\r
  30 \r
  31 @setlocal\r
  32 @call :SETHOSTVARS\r
  33 %LJCOMPILE% host\minilua.c\r
  34 @if errorlevel 1 goto :BAD\r
  35 %LJLINK% /out:minilua.exe minilua.obj\r
  36 @if errorlevel 1 goto :BAD\r
  37 if exist minilua.exe.manifest^\r
  38   %LJMT% -manifest minilua.exe.manifest -outputresource:minilua.exe\r
  39 @endlocal\r
  40 \r
  41 @set DASMFLAGS=-D WIN -D JIT -D FFI -D ENDIAN_LE -D FPU -D P64\r
  42 @set LJARCH=x64\r
  43 @minilua\r
  44 @if errorlevel 8 goto :NO32\r
  45 @set DASC=vm_x86.dasc\r
  46 @set DASMFLAGS=-D WIN -D JIT -D FFI -D ENDIAN_LE -D FPU\r
  47 @set LJARCH=x86\r
  48 @set LJCOMPILE=%LJCOMPILE% /arch:SSE2\r
  49 @goto :DA\r
  50 :NO32\r
  51 @if "%VSCMD_ARG_TGT_ARCH%" neq "arm64" goto :X64\r
  52 @set DASC=vm_arm64.dasc\r
  53 @set DASMTARGET=-D LUAJIT_TARGET=LUAJIT_ARCH_ARM64\r
  54 @set LJARCH=arm64\r
  55 @goto :DA\r
  56 :X64\r
  57 @if "%1" neq "nogc64" goto :DA\r
  58 @shift\r
  59 @set DASC=vm_x86.dasc\r
  60 @set LJCOMPILE=%LJCOMPILE% /DLUAJIT_DISABLE_GC64\r
  61 :DA\r
  62 minilua %DASM% -LN %DASMFLAGS% -o host\buildvm_arch.h %DASC%\r
  63 @if errorlevel 1 goto :BAD\r
  64 \r
  65 if exist ..\.git ( git show -s --format=%%ct >luajit_relver.txt ) else ( type ..\.relver >luajit_relver.txt )\r
  66 minilua host\genversion.lua\r
  67 \r
  68 @setlocal\r
  69 @call :SETHOSTVARS\r
  70 %LJCOMPILE% /I "." /I %DASMDIR% %DASMTARGET% host\buildvm*.c\r
  71 @if errorlevel 1 goto :BAD\r
  72 %LJLINK% /out:buildvm.exe buildvm*.obj\r
  73 @if errorlevel 1 goto :BAD\r
  74 if exist buildvm.exe.manifest^\r
  75   %LJMT% -manifest buildvm.exe.manifest -outputresource:buildvm.exe\r
  76 @endlocal\r
  77 \r
  78 buildvm -m peobj -o lj_vm.obj\r
  79 @if errorlevel 1 goto :BAD\r
  80 buildvm -m bcdef -o lj_bcdef.h %ALL_LIB%\r
  81 @if errorlevel 1 goto :BAD\r
  82 buildvm -m ffdef -o lj_ffdef.h %ALL_LIB%\r
  83 @if errorlevel 1 goto :BAD\r
  84 buildvm -m libdef -o lj_libdef.h %ALL_LIB%\r
  85 @if errorlevel 1 goto :BAD\r
  86 buildvm -m recdef -o lj_recdef.h %ALL_LIB%\r
  87 @if errorlevel 1 goto :BAD\r
  88 buildvm -m vmdef -o jit\vmdef.lua %ALL_LIB%\r
  89 @if errorlevel 1 goto :BAD\r
  90 buildvm -m folddef -o lj_folddef.h lj_opt_fold.c\r
  91 @if errorlevel 1 goto :BAD\r
  92 \r
  93 @if "%1" neq "debug" goto :NODEBUG\r
  94 @shift\r
  95 @set BUILDTYPE=debug\r
  96 @set LJCOMPILE=%LJCOMPILE% /Zi %DEBUGCFLAGS%\r
  97 @set LJDYNBUILD=/MDd /DLUA_BUILD_AS_DLL\r
  98 @set LJLINK=%LJLINK% /opt:ref /opt:icf /incremental:no\r
  99 :NODEBUG\r
 100 @set LJLINK=%LJLINK% /%BUILDTYPE%\r
 101 @if "%1"=="amalg" goto :AMALGDLL\r
 102 @if "%1"=="static" goto :STATIC\r
 103 %LJCOMPILE% %LJDYNBUILD% lj_*.c lib_*.c\r
 104 @if errorlevel 1 goto :BAD\r
 105 %LJLINK% /DLL /out:%LJDLLNAME% lj_*.obj lib_*.obj\r
 106 @if errorlevel 1 goto :BAD\r
 107 @goto :MTDLL\r
 108 :STATIC\r
 109 %LJCOMPILE% lj_*.c lib_*.c\r
 110 @if errorlevel 1 goto :BAD\r
 111 %LJLIB% /OUT:%LJLIBNAME% lj_*.obj lib_*.obj\r
 112 @if errorlevel 1 goto :BAD\r
 113 @goto :MTDLL\r
 114 :AMALGDLL\r
 115 %LJCOMPILE% %LJDYNBUILD% ljamalg.c\r
 116 @if errorlevel 1 goto :BAD\r
 117 %LJLINK% /DLL /out:%LJDLLNAME% ljamalg.obj lj_vm.obj\r
 118 @if errorlevel 1 goto :BAD\r
 119 :MTDLL\r
 120 if exist %LJDLLNAME%.manifest^\r
 121   %LJMT% -manifest %LJDLLNAME%.manifest -outputresource:%LJDLLNAME%;2\r
 122 \r
 123 %LJCOMPILE% luajit.c\r
 124 @if errorlevel 1 goto :BAD\r
 125 %LJLINK% /out:luajit.exe luajit.obj %LJLIBNAME%\r
 126 @if errorlevel 1 goto :BAD\r
 127 if exist luajit.exe.manifest^\r
 128   %LJMT% -manifest luajit.exe.manifest -outputresource:luajit.exe\r
 129 \r
 130 @del *.obj *.manifest minilua.exe buildvm.exe\r
 131 @del host\buildvm_arch.h\r
 132 @del lj_bcdef.h lj_ffdef.h lj_libdef.h lj_recdef.h lj_folddef.h\r
 133 @echo.\r
 134 @echo === Successfully built LuaJIT for Windows/%LJARCH% ===\r
 135 \r
 136 @goto :END\r
 137 :SETHOSTVARS\r
 138 @if "%VSCMD_ARG_HOST_ARCH%_%VSCMD_ARG_TGT_ARCH%" equ "x64_arm64" (\r
 139   call "%VSINSTALLDIR%Common7\Tools\VsDevCmd.bat" -arch=%VSCMD_ARG_HOST_ARCH% -no_logo\r
 140   echo on\r
 141 )\r
 142 @goto :END\r
 143 :BAD\r
 144 @echo.\r
 145 @echo *******************************************************\r
 146 @echo *** Build FAILED -- Please check the error messages ***\r
 147 @echo *******************************************************\a\r
 148 @goto :END\r
 149 :FAIL\r
 150 @echo You must open a "Visual Studio Command Prompt" to run this script\r
 151 :END\r