| blob | abcc03e5b3ea4b6c43bba37e69b147a6ad4970cb |
1 |// Low-level VM code for PowerPC 32 bit or 32on64 bit mode.
2 |// Bytecode interpreter, fast functions and helper functions.
3 |// Copyright (C) 2005-2023 Mike Pall. See Copyright Notice in luajit.h
4 |
5 |.arch ppc
6 |.section code_op, code_sub
7 |
8 |.actionlist build_actionlist
9 |.globals GLOB_
10 |.globalnames globnames
11 |.externnames extnames
12 |
13 |// Note: The ragged indentation of the instructions is intentional.
14 |// The starting columns indicate data dependencies.
15 |
16 |//-----------------------------------------------------------------------
17 |
18 |// DynASM defines used by the PPC port:
19 |//
20 |// P64 64 bit pointers (only for GPR64 testing).
21 |// GPR64 64 bit registers (but possibly 32 bit pointers, e.g. PS3).
22 |// Affects reg saves, stack layout, carry/overflow/dot flags etc.
23 |// FRAME32 Use 32 bit frame layout, even with GPR64 (Xbox 360).
24 |// TOC Need table of contents (64 bit or 32 bit variant, e.g. PS3).
25 |// Function pointers are really a struct: code, TOC, env (optional).
26 |// TOCENV Function pointers have an environment pointer, too (not on PS3).
27 |// PPE Power Processor Element of Cell (PS3) or Xenon (Xbox 360).
28 |// Must avoid (slow) micro-coded instructions.
29 |
30 |.if P64
31 |.define TOC, 1
32 |.define TOCENV, 1
33 |.macro lpx, a, b, c; ldx a, b, c; .endmacro
34 |.macro lp, a, b; ld a, b; .endmacro
35 |.macro stp, a, b; std a, b; .endmacro
36 |.define decode_OPP, decode_OP8
37 |.if FFI
38 |// Missing: Calling conventions, 64 bit regs, TOC.
39 |.error lib_ffi not yet implemented for PPC64
40 |.endif
41 |.else
42 |.macro lpx, a, b, c; lwzx a, b, c; .endmacro
43 |.macro lp, a, b; lwz a, b; .endmacro
44 |.macro stp, a, b; stw a, b; .endmacro
45 |.define decode_OPP, decode_OP4
46 |.endif
47 |
48 |// Convenience macros for TOC handling.
49 |.if TOC
50 |// Linker needs a TOC patch area for every external call relocation.
51 |.macro blex, target; bl extern target@plt; nop; .endmacro
52 |.macro .toc, a, b; a, b; .endmacro
53 |.if P64
54 |.define TOC_OFS, 8
55 |.define ENV_OFS, 16
56 |.else
57 |.define TOC_OFS, 4
58 |.define ENV_OFS, 8
59 |.endif
60 |.else // No TOC.
61 |.macro blex, target; bl extern target@plt; .endmacro
62 |.macro .toc, a, b; .endmacro
63 |.endif
64 |.macro .tocenv, a, b; .if TOCENV; a, b; .endif; .endmacro
65 |
66 |.macro .gpr64, a, b; .if GPR64; a, b; .endif; .endmacro
67 |
68 |.macro andix., y, a, i
69 |.if PPE
70 | rlwinm y, a, 0, 31-lj_fls(i), 31-lj_ffs(i)
71 | cmpwi y, 0
72 |.else
73 | andi. y, a, i
74 |.endif
75 |.endmacro
76 |
77 |.macro clrso, reg
78 |.if PPE
79 | li reg, 0
80 | mtxer reg
81 |.else
82 | mcrxr cr0
83 |.endif
84 |.endmacro
85 |
86 |.macro checkov, reg, noov
87 |.if PPE
88 | mfxer reg
89 | add reg, reg, reg
90 | cmpwi reg, 0
91 | li reg, 0
92 | mtxer reg
93 | bgey noov
94 |.else
95 | mcrxr cr0
96 | bley noov
97 |.endif
98 |.endmacro
99 |
100 |//-----------------------------------------------------------------------
101 |
102 |// Fixed register assignments for the interpreter.
103 |// Don't use: r1 = sp, r2 and r13 = reserved (TOC, TLS or SDATA)
104 |
105 |.macro .FPU, a, b
106 |.if FPU
107 | a, b
108 |.endif
109 |.endmacro
110 |
111 |.macro .FPU, a, b, c
112 |.if FPU
113 | a, b, c
114 |.endif
115 |.endmacro
116 |
117 |// The following must be C callee-save (but BASE is often refetched).
118 |.define BASE, r14 // Base of current Lua stack frame.
119 |.define KBASE, r15 // Constants of current Lua function.
120 |.define PC, r16 // Next PC.
121 |.define DISPATCH, r17 // Opcode dispatch table.
122 |.define LREG, r18 // Register holding lua_State (also in SAVE_L).
123 |.define MULTRES, r19 // Size of multi-result: (nresults+1)*8.
124 |.define JGL, r31 // On-trace: global_State + 32768.
125 |
126 |// Constants for type-comparisons, stores and conversions. C callee-save.
127 |.define TISNUM, r22
128 |.define TISNIL, r23
129 |.define ZERO, r24
130 |.if FPU
131 |.define TOBIT, f30 // 2^52 + 2^51.
132 |.define TONUM, f31 // 2^52 + 2^51 + 2^31.
133 |.endif
134 |
135 |// The following temporaries are not saved across C calls, except for RA.
136 |.define RA, r20 // Callee-save.
137 |.define RB, r10
138 |.define RC, r11
139 |.define RD, r12
140 |.define INS, r7 // Overlaps CARG5.
141 |
142 |.define TMP0, r0
143 |.define TMP1, r8
144 |.define TMP2, r9
145 |.define TMP3, r6 // Overlaps CARG4.
146 |
147 |// Saved temporaries.
148 |.define SAVE0, r21
149 |.define SAVE1, r25
150 |
151 |// Calling conventions.
152 |.define CARG1, r3
153 |.define CARG2, r4
154 |.define CARG3, r5
155 |.define CARG4, r6 // Overlaps TMP3.
156 |.define CARG5, r7 // Overlaps INS.
157 |
158 |.if FPU
159 |.define FARG1, f1
160 |.define FARG2, f2
161 |.endif
162 |
163 |.define CRET1, r3
164 |.define CRET2, r4
165 |
166 |.define TOCREG, r2 // TOC register (only used by C code).
167 |.define ENVREG, r11 // Environment pointer (nested C functions).
168 |
169 |// Stack layout while in interpreter. Must match with lj_frame.h.
170 |.if GPR64
171 |.if FRAME32
172 |
173 |// 456(sp) // \ 32/64 bit C frame info
174 |.define TONUM_LO, 452(sp) // |
175 |.define TONUM_HI, 448(sp) // |
176 |.define TMPD_LO, 444(sp) // |
177 |.define TMPD_HI, 440(sp) // |
178 |.define SAVE_CR, 432(sp) // | 64 bit CR save.
179 |.define SAVE_ERRF, 424(sp) // > Parameter save area.
180 |.define SAVE_NRES, 420(sp) // |
181 |.define SAVE_L, 416(sp) // |
182 |.define SAVE_PC, 412(sp) // |
183 |.define SAVE_MULTRES, 408(sp) // |
184 |.define SAVE_CFRAME, 400(sp) // / 64 bit C frame chain.
185 |// 392(sp) // Reserved.
186 |.define CFRAME_SPACE, 384 // Delta for sp.
187 |// Back chain for sp: 384(sp) <-- sp entering interpreter
188 |.define SAVE_LR, 376(sp) // 32 bit LR stored in hi-part.
189 |.define SAVE_GPR_, 232 // .. 232+18*8: 64 bit GPR saves.
190 |.define SAVE_FPR_, 88 // .. 88+18*8: 64 bit FPR saves.
191 |// 80(sp) // Needed for 16 byte stack frame alignment.
192 |// 16(sp) // Callee parameter save area (ABI mandated).
193 |// 8(sp) // Reserved
194 |// Back chain for sp: 0(sp) <-- sp while in interpreter
195 |// 32 bit sp stored in hi-part of 0(sp).
196 |
197 |.define TMPD_BLO, 447(sp)
198 |.define TMPD, TMPD_HI
199 |.define TONUM_D, TONUM_HI
200 |
201 |.else
202 |
203 |// 508(sp) // \ 32 bit C frame info.
204 |.define SAVE_ERRF, 472(sp) // |
205 |.define SAVE_NRES, 468(sp) // |
206 |.define SAVE_L, 464(sp) // > Parameter save area.
207 |.define SAVE_PC, 460(sp) // |
208 |.define SAVE_MULTRES, 456(sp) // |
209 |.define SAVE_CFRAME, 448(sp) // / 64 bit C frame chain.
210 |.define SAVE_LR, 416(sp)
211 |.define CFRAME_SPACE, 400 // Delta for sp.
212 |// Back chain for sp: 400(sp) <-- sp entering interpreter
213 |.define SAVE_FPR_, 256 // .. 256+18*8: 64 bit FPR saves.
214 |.define SAVE_GPR_, 112 // .. 112+18*8: 64 bit GPR saves.
215 |// 48(sp) // Callee parameter save area (ABI mandated).
216 |.define SAVE_TOC, 40(sp) // TOC save area.
217 |.define TMPD_LO, 36(sp) // \ Link editor temp (ABI mandated).
218 |.define TMPD_HI, 32(sp) // /
219 |.define TONUM_LO, 28(sp) // \ Compiler temp (ABI mandated).
220 |.define TONUM_HI, 24(sp) // /
221 |// Next frame lr: 16(sp)
222 |.define SAVE_CR, 8(sp) // 64 bit CR save.
223 |// Back chain for sp: 0(sp) <-- sp while in interpreter
224 |
225 |.define TMPD_BLO, 39(sp)
226 |.define TMPD, TMPD_HI
227 |.define TONUM_D, TONUM_HI
228 |
229 |.endif
230 |.else
231 |
232 |.if FPU
233 |.define SAVE_LR, 276(sp)
234 |.define CFRAME_SPACE, 272 // Delta for sp.
235 |// Back chain for sp: 272(sp) <-- sp entering interpreter
236 |.define SAVE_FPR_, 128 // .. 128+18*8: 64 bit FPR saves.
237 |.else
238 |.define SAVE_LR, 132(sp)
239 |.define CFRAME_SPACE, 128 // Delta for sp.
240 |// Back chain for sp: 128(sp) <-- sp entering interpreter
241 |.endif
242 |.define SAVE_GPR_, 56 // .. 56+18*4: 32 bit GPR saves.
243 |.define SAVE_CR, 52(sp) // 32 bit CR save.
244 |.define SAVE_ERRF, 48(sp) // 32 bit C frame info.
245 |.define SAVE_NRES, 44(sp)
246 |.define SAVE_CFRAME, 40(sp)
247 |.define SAVE_L, 36(sp)
248 |.define SAVE_PC, 32(sp)
249 |.define SAVE_MULTRES, 28(sp)
250 |.define UNUSED1, 24(sp)
251 |.if FPU
252 |.define TMPD_LO, 20(sp)
253 |.define TMPD_HI, 16(sp)
254 |.define TONUM_LO, 12(sp)
255 |.define TONUM_HI, 8(sp)
256 |.else
257 |.define SFSAVE_4, 20(sp)
258 |.define SFSAVE_3, 16(sp)
259 |.define SFSAVE_2, 12(sp)
260 |.define SFSAVE_1, 8(sp)
261 |.endif
262 |// Next frame lr: 4(sp)
263 |// Back chain for sp: 0(sp) <-- sp while in interpreter
264 |
265 |.if FPU
266 |.define TMPD_BLO, 23(sp)
267 |.define TMPD, TMPD_HI
268 |.define TONUM_D, TONUM_HI
269 |.endif
270 |
271 |.endif
272 |
273 |.macro save_, reg
274 |.if GPR64
275 | std r..reg, SAVE_GPR_+(reg-14)*8(sp)
276 |.else
277 | stw r..reg, SAVE_GPR_+(reg-14)*4(sp)
278 |.endif
279 | .FPU stfd f..reg, SAVE_FPR_+(reg-14)*8(sp)
280 |.endmacro
281 |.macro rest_, reg
282 |.if GPR64
283 | ld r..reg, SAVE_GPR_+(reg-14)*8(sp)
284 |.else
285 | lwz r..reg, SAVE_GPR_+(reg-14)*4(sp)
286 |.endif
287 | .FPU lfd f..reg, SAVE_FPR_+(reg-14)*8(sp)
288 |.endmacro
289 |
290 |.macro saveregs
291 |.if GPR64 and not FRAME32
292 | stdu sp, -CFRAME_SPACE(sp)
293 |.else
294 | stwu sp, -CFRAME_SPACE(sp)
295 |.endif
296 | save_ 14; save_ 15; save_ 16
297 | mflr r0
298 | save_ 17; save_ 18; save_ 19; save_ 20; save_ 21; save_ 22
299 |.if GPR64 and not FRAME32
300 | std r0, SAVE_LR
301 |.else
302 | stw r0, SAVE_LR
303 |.endif
304 | save_ 23; save_ 24; save_ 25
305 | mfcr r0
306 | save_ 26; save_ 27; save_ 28; save_ 29; save_ 30; save_ 31
307 |.if GPR64
308 | std r0, SAVE_CR
309 |.else
310 | stw r0, SAVE_CR
311 |.endif
312 | .toc std TOCREG, SAVE_TOC
313 |.endmacro
314 |
315 |.macro restoreregs
316 |.if GPR64 and not FRAME32
317 | ld r0, SAVE_LR
318 |.else
319 | lwz r0, SAVE_LR
320 |.endif
321 |.if GPR64
322 | ld r12, SAVE_CR
323 |.else
324 | lwz r12, SAVE_CR
325 |.endif
326 | rest_ 14; rest_ 15; rest_ 16; rest_ 17; rest_ 18; rest_ 19
327 | mtlr r0;
328 |.if PPE; mtocrf 0x20, r12; .else; mtcrf 0x38, r12; .endif
329 | rest_ 20; rest_ 21; rest_ 22; rest_ 23; rest_ 24; rest_ 25
330 |.if PPE; mtocrf 0x10, r12; .endif
331 | rest_ 26; rest_ 27; rest_ 28; rest_ 29; rest_ 30; rest_ 31
332 |.if PPE; mtocrf 0x08, r12; .endif
333 | addi sp, sp, CFRAME_SPACE
334 |.endmacro
335 |
336 |// Type definitions. Some of these are only used for documentation.
337 |.type L, lua_State, LREG
338 |.type GL, global_State
339 |.type TVALUE, TValue
340 |.type GCOBJ, GCobj
341 |.type STR, GCstr
342 |.type TAB, GCtab
343 |.type LFUNC, GCfuncL
344 |.type CFUNC, GCfuncC
345 |.type PROTO, GCproto
346 |.type UPVAL, GCupval
347 |.type NODE, Node
348 |.type NARGS8, int
349 |.type TRACE, GCtrace
350 |.type SBUF, SBuf
351 |
352 |//-----------------------------------------------------------------------
353 |
354 |// Trap for not-yet-implemented parts.
355 |.macro NYI; tw 4, sp, sp; .endmacro
356 |
357 |.if FPU
358 |// int/FP conversions.
359 |.macro tonum_i, freg, reg
360 | xoris reg, reg, 0x8000
361 | stw reg, TONUM_LO
362 | lfd freg, TONUM_D
363 | fsub freg, freg, TONUM
364 |.endmacro
365 |
366 |.macro tonum_u, freg, reg
367 | stw reg, TONUM_LO
368 | lfd freg, TONUM_D
369 | fsub freg, freg, TOBIT
370 |.endmacro
371 |
372 |.macro toint, reg, freg, tmpfreg
373 | fctiwz tmpfreg, freg
374 | stfd tmpfreg, TMPD
375 | lwz reg, TMPD_LO
376 |.endmacro
377 |
378 |.macro toint, reg, freg
379 | toint reg, freg, freg
380 |.endmacro
381 |.endif
382 |
383 |//-----------------------------------------------------------------------
384 |
385 |// Access to frame relative to BASE.
386 |.define FRAME_PC, -8
387 |.define FRAME_FUNC, -4
388 |
389 |// Instruction decode.
390 |.macro decode_OP4, dst, ins; rlwinm dst, ins, 2, 22, 29; .endmacro
391 |.macro decode_OP8, dst, ins; rlwinm dst, ins, 3, 21, 28; .endmacro
392 |.macro decode_RA8, dst, ins; rlwinm dst, ins, 27, 21, 28; .endmacro
393 |.macro decode_RB8, dst, ins; rlwinm dst, ins, 11, 21, 28; .endmacro
394 |.macro decode_RC8, dst, ins; rlwinm dst, ins, 19, 21, 28; .endmacro
395 |.macro decode_RD8, dst, ins; rlwinm dst, ins, 19, 13, 28; .endmacro
396 |
397 |.macro decode_OP1, dst, ins; rlwinm dst, ins, 0, 24, 31; .endmacro
398 |.macro decode_RD4, dst, ins; rlwinm dst, ins, 18, 14, 29; .endmacro
399 |
400 |// Instruction fetch.
401 |.macro ins_NEXT1
402 | lwz INS, 0(PC)
403 | addi PC, PC, 4
404 |.endmacro
405 |// Instruction decode+dispatch. Note: optimized for e300!
406 |.macro ins_NEXT2
407 | decode_OPP TMP1, INS
408 | lpx TMP0, DISPATCH, TMP1
409 | mtctr TMP0
410 | decode_RB8 RB, INS
411 | decode_RD8 RD, INS
412 | decode_RA8 RA, INS
413 | decode_RC8 RC, INS
414 | bctr
415 |.endmacro
416 |.macro ins_NEXT
417 | ins_NEXT1
418 | ins_NEXT2
419 |.endmacro
420 |
421 |// Instruction footer.
422 |.if 1
423 | // Replicated dispatch. Less unpredictable branches, but higher I-Cache use.
424 | .define ins_next, ins_NEXT
425 | .define ins_next_, ins_NEXT
426 | .define ins_next1, ins_NEXT1
427 | .define ins_next2, ins_NEXT2
428 |.else
429 | // Common dispatch. Lower I-Cache use, only one (very) unpredictable branch.
430 | // Affects only certain kinds of benchmarks (and only with -j off).
431 | .macro ins_next
432 | b ->ins_next
433 | .endmacro
434 | .macro ins_next1
435 | .endmacro
436 | .macro ins_next2
437 | b ->ins_next
438 | .endmacro
439 | .macro ins_next_
440 | ->ins_next:
441 | ins_NEXT
442 | .endmacro
443 |.endif
444 |
445 |// Call decode and dispatch.
446 |.macro ins_callt
447 | // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
448 | lwz PC, LFUNC:RB->pc
449 | lwz INS, 0(PC)
450 | addi PC, PC, 4
451 | decode_OPP TMP1, INS
452 | decode_RA8 RA, INS
453 | lpx TMP0, DISPATCH, TMP1
454 | add RA, RA, BASE
455 | mtctr TMP0
456 | bctr
457 |.endmacro
458 |
459 |.macro ins_call
460 | // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, PC = caller PC
461 | stw PC, FRAME_PC(BASE)
462 | ins_callt
463 |.endmacro
464 |
465 |//-----------------------------------------------------------------------
466 |
467 |// Macros to test operand types.
468 |.macro checknum, reg; cmplw reg, TISNUM; .endmacro
469 |.macro checknum, cr, reg; cmplw cr, reg, TISNUM; .endmacro
470 |.macro checkstr, reg; cmpwi reg, LJ_TSTR; .endmacro
471 |.macro checktab, reg; cmpwi reg, LJ_TTAB; .endmacro
472 |.macro checkfunc, reg; cmpwi reg, LJ_TFUNC; .endmacro
473 |.macro checknil, reg; cmpwi reg, LJ_TNIL; .endmacro
474 |
475 |.macro branch_RD
476 | srwi TMP0, RD, 1
477 | addis PC, PC, -(BCBIAS_J*4 >> 16)
478 | add PC, PC, TMP0
479 |.endmacro
480 |
481 |// Assumes DISPATCH is relative to GL.
482 #define DISPATCH_GL(field) (GG_DISP2G + (int)offsetof(global_State, field))
483 #define DISPATCH_J(field) (GG_DISP2J + (int)offsetof(jit_State, field))
484 |
485 #define PC2PROTO(field) ((int)offsetof(GCproto, field)-(int)sizeof(GCproto))
486 |
487 |.macro hotcheck, delta, target
488 | rlwinm TMP1, PC, 31, 25, 30
489 | addi TMP1, TMP1, GG_DISP2HOT
490 | lhzx TMP2, DISPATCH, TMP1
491 | addic. TMP2, TMP2, -delta
492 | sthx TMP2, DISPATCH, TMP1
493 | blt target
494 |.endmacro
495 |
496 |.macro hotloop
497 | hotcheck HOTCOUNT_LOOP, ->vm_hotloop
498 |.endmacro
499 |
500 |.macro hotcall
501 | hotcheck HOTCOUNT_CALL, ->vm_hotcall
502 |.endmacro
503 |
504 |// Set current VM state. Uses TMP0.
505 |.macro li_vmstate, st; li TMP0, ~LJ_VMST_..st; .endmacro
506 |.macro st_vmstate; stw TMP0, DISPATCH_GL(vmstate)(DISPATCH); .endmacro
507 |
508 |// Move table write barrier back. Overwrites mark and tmp.
509 |.macro barrierback, tab, mark, tmp
510 | lwz tmp, DISPATCH_GL(gc.grayagain)(DISPATCH)
511 | // Assumes LJ_GC_BLACK is 0x04.
512 | rlwinm mark, mark, 0, 30, 28 // black2gray(tab)
513 | stw tab, DISPATCH_GL(gc.grayagain)(DISPATCH)
514 | stb mark, tab->marked
515 | stw tmp, tab->gclist
516 |.endmacro
517 |
518 |//-----------------------------------------------------------------------
520 /* Generate subroutines used by opcodes and other parts of the VM. */
521 /* The .code_sub section should be last to help static branch prediction. */
522 static void build_subroutines(BuildCtx *ctx)
523 {
524 |.code_sub
525 |
526 |//-----------------------------------------------------------------------
527 |//-- Return handling ----------------------------------------------------
528 |//-----------------------------------------------------------------------
529 |
530 |->vm_returnp:
531 | // See vm_return. Also: TMP2 = previous base.
532 | andix. TMP0, PC, FRAME_P
533 | li TMP1, LJ_TTRUE
534 | beq ->cont_dispatch
535 |
536 | // Return from pcall or xpcall fast func.
537 | lwz PC, FRAME_PC(TMP2) // Fetch PC of previous frame.
538 | mr BASE, TMP2 // Restore caller base.
539 | // Prepending may overwrite the pcall frame, so do it at the end.
540 | stwu TMP1, FRAME_PC(RA) // Prepend true to results.
541 |
542 |->vm_returnc:
543 | addi RD, RD, 8 // RD = (nresults+1)*8.
544 | andix. TMP0, PC, FRAME_TYPE
545 | cmpwi cr1, RD, 0
546 | li CRET1, LUA_YIELD
547 | beq cr1, ->vm_unwind_c_eh
548 | mr MULTRES, RD
549 | beq ->BC_RET_Z // Handle regular return to Lua.
550 |
551 |->vm_return:
552 | // BASE = base, RA = resultptr, RD/MULTRES = (nresults+1)*8, PC = return
553 | // TMP0 = PC & FRAME_TYPE
554 | cmpwi TMP0, FRAME_C
555 | rlwinm TMP2, PC, 0, 0, 28
556 | li_vmstate C
557 | sub TMP2, BASE, TMP2 // TMP2 = previous base.
558 | bney ->vm_returnp
559 |
560 | addic. TMP1, RD, -8
561 | stp TMP2, L->base
562 | lwz TMP2, SAVE_NRES
563 | subi BASE, BASE, 8
564 | st_vmstate
565 | slwi TMP2, TMP2, 3
566 | beq >2
567 |1:
568 | addic. TMP1, TMP1, -8
569 |.if FPU
570 | lfd f0, 0(RA)
571 |.else
572 | lwz CARG1, 0(RA)
573 | lwz CARG2, 4(RA)
574 |.endif
575 | addi RA, RA, 8
576 |.if FPU
577 | stfd f0, 0(BASE)
578 |.else
579 | stw CARG1, 0(BASE)
580 | stw CARG2, 4(BASE)
581 |.endif
582 | addi BASE, BASE, 8
583 | bney <1
584 |
585 |2:
586 | cmpw TMP2, RD // More/less results wanted?
587 | bne >6
588 |3:
589 | stp BASE, L->top // Store new top.
590 |
591 |->vm_leave_cp:
592 | lp TMP0, SAVE_CFRAME // Restore previous C frame.
593 | li CRET1, 0 // Ok return status for vm_pcall.
594 | stp TMP0, L->cframe
595 |
596 |->vm_leave_unw:
597 | restoreregs
598 | blr
599 |
600 |6:
601 | ble >7 // Less results wanted?
602 | // More results wanted. Check stack size and fill up results with nil.
603 | lwz TMP1, L->maxstack
604 | cmplw BASE, TMP1
605 | bge >8
606 | stw TISNIL, 0(BASE)
607 | addi RD, RD, 8
608 | addi BASE, BASE, 8
609 | b <2
610 |
611 |7: // Less results wanted.
612 | subfic TMP3, TMP2, 0 // LUA_MULTRET+1 case?
613 | sub TMP0, RD, TMP2
614 | subfe TMP1, TMP1, TMP1 // TMP1 = TMP2 == 0 ? 0 : -1
615 | and TMP0, TMP0, TMP1
616 | sub BASE, BASE, TMP0 // Either keep top or shrink it.
617 | b <3
618 |
619 |8: // Corner case: need to grow stack for filling up results.
620 | // This can happen if:
621 | // - A C function grows the stack (a lot).
622 | // - The GC shrinks the stack in between.
623 | // - A return back from a lua_call() with (high) nresults adjustment.
624 | stp BASE, L->top // Save current top held in BASE (yes).
625 | mr SAVE0, RD
626 | srwi CARG2, TMP2, 3
627 | mr CARG1, L
628 | bl extern lj_state_growstack // (lua_State *L, int n)
629 | lwz TMP2, SAVE_NRES
630 | mr RD, SAVE0
631 | slwi TMP2, TMP2, 3
632 | lp BASE, L->top // Need the (realloced) L->top in BASE.
633 | b <2
634 |
635 |->vm_unwind_c: // Unwind C stack, return from vm_pcall.
636 | // (void *cframe, int errcode)
637 | mr sp, CARG1
638 | mr CRET1, CARG2
639 |->vm_unwind_c_eh: // Landing pad for external unwinder.
640 | lwz L, SAVE_L
641 | .toc ld TOCREG, SAVE_TOC
642 | li TMP0, ~LJ_VMST_C
643 | lwz GL:TMP1, L->glref
644 | stw TMP0, GL:TMP1->vmstate
645 | b ->vm_leave_unw
646 |
647 |->vm_unwind_ff: // Unwind C stack, return from ff pcall.
648 | // (void *cframe)
649 |.if GPR64
650 | rldicr sp, CARG1, 0, 61
651 |.else
652 | rlwinm sp, CARG1, 0, 0, 29
653 |.endif
654 |->vm_unwind_ff_eh: // Landing pad for external unwinder.
655 | lwz L, SAVE_L
656 | .toc ld TOCREG, SAVE_TOC
657 | li TISNUM, LJ_TISNUM // Setup type comparison constants.
658 | lp BASE, L->base
659 | .FPU lus TMP3, 0x59c0 // TOBIT = 2^52 + 2^51 (float).
660 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
661 | li ZERO, 0
662 | .FPU stw TMP3, TMPD
663 | li TMP1, LJ_TFALSE
664 | .FPU ori TMP3, TMP3, 0x0004 // TONUM = 2^52 + 2^51 + 2^31 (float).
665 | li TISNIL, LJ_TNIL
666 | li_vmstate INTERP
667 | .FPU lfs TOBIT, TMPD
668 | lwz PC, FRAME_PC(BASE) // Fetch PC of previous frame.
669 | la RA, -8(BASE) // Results start at BASE-8.
670 | .FPU stw TMP3, TMPD
671 | addi DISPATCH, DISPATCH, GG_G2DISP
672 | stw TMP1, 0(RA) // Prepend false to error message.
673 | li RD, 16 // 2 results: false + error message.
674 | st_vmstate
675 | .FPU lfs TONUM, TMPD
676 | b ->vm_returnc
677 |
678 |//-----------------------------------------------------------------------
679 |//-- Grow stack for calls -----------------------------------------------
680 |//-----------------------------------------------------------------------
681 |
682 |->vm_growstack_c: // Grow stack for C function.
683 | li CARG2, LUA_MINSTACK
684 | b >2
685 |
686 |->vm_growstack_l: // Grow stack for Lua function.
687 | // BASE = new base, RA = BASE+framesize*8, RC = nargs*8, PC = first PC
688 | add RC, BASE, RC
689 | sub RA, RA, BASE
690 | stp BASE, L->base
691 | addi PC, PC, 4 // Must point after first instruction.
692 | stp RC, L->top
693 | srwi CARG2, RA, 3
694 |2:
695 | // L->base = new base, L->top = top
696 | stw PC, SAVE_PC
697 | mr CARG1, L
698 | bl extern lj_state_growstack // (lua_State *L, int n)
699 | lp BASE, L->base
700 | lp RC, L->top
701 | lwz LFUNC:RB, FRAME_FUNC(BASE)
702 | sub RC, RC, BASE
703 | // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
704 | ins_callt // Just retry the call.
705 |
706 |//-----------------------------------------------------------------------
707 |//-- Entry points into the assembler VM ---------------------------------
708 |//-----------------------------------------------------------------------
709 |
710 |->vm_resume: // Setup C frame and resume thread.
711 | // (lua_State *L, TValue *base, int nres1 = 0, ptrdiff_t ef = 0)
712 | saveregs
713 | mr L, CARG1
714 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
715 | mr BASE, CARG2
716 | lbz TMP1, L->status
717 | stw L, SAVE_L
718 | li PC, FRAME_CP
719 | addi TMP0, sp, CFRAME_RESUME
720 | addi DISPATCH, DISPATCH, GG_G2DISP
721 | stw CARG3, SAVE_NRES
722 | cmplwi TMP1, 0
723 | stw CARG3, SAVE_ERRF
724 | stp CARG3, SAVE_CFRAME
725 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
726 | stp TMP0, L->cframe
727 | beq >3
728 |
729 | // Resume after yield (like a return).
730 | stw L, DISPATCH_GL(cur_L)(DISPATCH)
731 | mr RA, BASE
732 | lp BASE, L->base
733 | li TISNUM, LJ_TISNUM // Setup type comparison constants.
734 | lp TMP1, L->top
735 | lwz PC, FRAME_PC(BASE)
736 | .FPU lus TMP3, 0x59c0 // TOBIT = 2^52 + 2^51 (float).
737 | stb CARG3, L->status
738 | .FPU stw TMP3, TMPD
739 | .FPU ori TMP3, TMP3, 0x0004 // TONUM = 2^52 + 2^51 + 2^31 (float).
740 | .FPU lfs TOBIT, TMPD
741 | sub RD, TMP1, BASE
742 | .FPU stw TMP3, TMPD
743 | .FPU lus TMP0, 0x4338 // Hiword of 2^52 + 2^51 (double)
744 | addi RD, RD, 8
745 | .FPU stw TMP0, TONUM_HI
746 | li_vmstate INTERP
747 | li ZERO, 0
748 | st_vmstate
749 | andix. TMP0, PC, FRAME_TYPE
750 | mr MULTRES, RD
751 | .FPU lfs TONUM, TMPD
752 | li TISNIL, LJ_TNIL
753 | beq ->BC_RET_Z
754 | b ->vm_return
755 |
756 |->vm_pcall: // Setup protected C frame and enter VM.
757 | // (lua_State *L, TValue *base, int nres1, ptrdiff_t ef)
758 | saveregs
759 | li PC, FRAME_CP
760 | stw CARG4, SAVE_ERRF
761 | b >1
762 |
763 |->vm_call: // Setup C frame and enter VM.
764 | // (lua_State *L, TValue *base, int nres1)
765 | saveregs
766 | li PC, FRAME_C
767 |
768 |1: // Entry point for vm_pcall above (PC = ftype).
769 | lp TMP1, L:CARG1->cframe
770 | mr L, CARG1
771 | stw CARG3, SAVE_NRES
772 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
773 | stw CARG1, SAVE_L
774 | mr BASE, CARG2
775 | addi DISPATCH, DISPATCH, GG_G2DISP
776 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
777 | stp TMP1, SAVE_CFRAME
778 | stp sp, L->cframe // Add our C frame to cframe chain.
779 |
780 |3: // Entry point for vm_cpcall/vm_resume (BASE = base, PC = ftype).
781 | stw L, DISPATCH_GL(cur_L)(DISPATCH)
782 | lp TMP2, L->base // TMP2 = old base (used in vmeta_call).
783 | li TISNUM, LJ_TISNUM // Setup type comparison constants.
784 | lp TMP1, L->top
785 | .FPU lus TMP3, 0x59c0 // TOBIT = 2^52 + 2^51 (float).
786 | add PC, PC, BASE
787 | .FPU stw TMP3, TMPD
788 | li ZERO, 0
789 | .FPU ori TMP3, TMP3, 0x0004 // TONUM = 2^52 + 2^51 + 2^31 (float).
790 | .FPU lfs TOBIT, TMPD
791 | sub PC, PC, TMP2 // PC = frame delta + frame type
792 | .FPU stw TMP3, TMPD
793 | .FPU lus TMP0, 0x4338 // Hiword of 2^52 + 2^51 (double)
794 | sub NARGS8:RC, TMP1, BASE
795 | .FPU stw TMP0, TONUM_HI
796 | li_vmstate INTERP
797 | .FPU lfs TONUM, TMPD
798 | li TISNIL, LJ_TNIL
799 | st_vmstate
800 |
801 |->vm_call_dispatch:
802 | // TMP2 = old base, BASE = new base, RC = nargs*8, PC = caller PC
803 | lwz TMP0, FRAME_PC(BASE)
804 | lwz LFUNC:RB, FRAME_FUNC(BASE)
805 | checkfunc TMP0; bne ->vmeta_call
806 |
807 |->vm_call_dispatch_f:
808 | ins_call
809 | // BASE = new base, RB = func, RC = nargs*8, PC = caller PC
810 |
811 |->vm_cpcall: // Setup protected C frame, call C.
812 | // (lua_State *L, lua_CFunction func, void *ud, lua_CPFunction cp)
813 | saveregs
814 | mr L, CARG1
815 | lwz TMP0, L:CARG1->stack
816 | stw CARG1, SAVE_L
817 | lp TMP1, L->top
818 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
819 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
820 | sub TMP0, TMP0, TMP1 // Compute -savestack(L, L->top).
821 | lp TMP1, L->cframe
822 | addi DISPATCH, DISPATCH, GG_G2DISP
823 | .toc lp CARG4, 0(CARG4)
824 | li TMP2, 0
825 | stw TMP0, SAVE_NRES // Neg. delta means cframe w/o frame.
826 | stw TMP2, SAVE_ERRF // No error function.
827 | stp TMP1, SAVE_CFRAME
828 | stp sp, L->cframe // Add our C frame to cframe chain.
829 | stw L, DISPATCH_GL(cur_L)(DISPATCH)
830 | mtctr CARG4
831 | bctrl // (lua_State *L, lua_CFunction func, void *ud)
832 |.if PPE
833 | mr BASE, CRET1
834 | cmpwi CRET1, 0
835 |.else
836 | mr. BASE, CRET1
837 |.endif
838 | li PC, FRAME_CP
839 | bne <3 // Else continue with the call.
840 | b ->vm_leave_cp // No base? Just remove C frame.
841 |
842 |//-----------------------------------------------------------------------
843 |//-- Metamethod handling ------------------------------------------------
844 |//-----------------------------------------------------------------------
845 |
846 |// The lj_meta_* functions (except for lj_meta_cat) don't reallocate the
847 |// stack, so BASE doesn't need to be reloaded across these calls.
848 |
849 |//-- Continuation dispatch ----------------------------------------------
850 |
851 |->cont_dispatch:
852 | // BASE = meta base, RA = resultptr, RD = (nresults+1)*8
853 | lwz TMP0, -12(BASE) // Continuation.
854 | mr RB, BASE
855 | mr BASE, TMP2 // Restore caller BASE.
856 | lwz LFUNC:TMP1, FRAME_FUNC(TMP2)
857 |.if FFI
858 | cmplwi TMP0, 1
859 |.endif
860 | lwz PC, -16(RB) // Restore PC from [cont|PC].
861 | subi TMP2, RD, 8
862 | stwx TISNIL, RA, TMP2 // Ensure one valid arg.
863 |.if FFI
864 | ble >1
865 |.endif
866 | lwz TMP1, LFUNC:TMP1->pc
867 | lwz KBASE, PC2PROTO(k)(TMP1)
868 | // BASE = base, RA = resultptr, RB = meta base
869 | mtctr TMP0
870 | bctr // Jump to continuation.
871 |
872 |.if FFI
873 |1:
874 | beq ->cont_ffi_callback // cont = 1: return from FFI callback.
875 | // cont = 0: tailcall from C function.
876 | subi TMP1, RB, 16
877 | sub RC, TMP1, BASE
878 | b ->vm_call_tail
879 |.endif
880 |
881 |->cont_cat: // RA = resultptr, RB = meta base
882 | lwz INS, -4(PC)
883 | subi CARG2, RB, 16
884 | decode_RB8 SAVE0, INS
885 |.if FPU
886 | lfd f0, 0(RA)
887 |.else
888 | lwz TMP2, 0(RA)
889 | lwz TMP3, 4(RA)
890 |.endif
891 | add TMP1, BASE, SAVE0
892 | stp BASE, L->base
893 | cmplw TMP1, CARG2
894 | sub CARG3, CARG2, TMP1
895 | decode_RA8 RA, INS
896 |.if FPU
897 | stfd f0, 0(CARG2)
898 |.else
899 | stw TMP2, 0(CARG2)
900 | stw TMP3, 4(CARG2)
901 |.endif
902 | bney ->BC_CAT_Z
903 |.if FPU
904 | stfdx f0, BASE, RA
905 |.else
906 | stwux TMP2, RA, BASE
907 | stw TMP3, 4(RA)
908 |.endif
909 | b ->cont_nop
910 |
911 |//-- Table indexing metamethods -----------------------------------------
912 |
913 |->vmeta_tgets1:
914 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
915 | li TMP0, LJ_TSTR
916 | decode_RB8 RB, INS
917 | stw STR:RC, 4(CARG3)
918 | add CARG2, BASE, RB
919 | stw TMP0, 0(CARG3)
920 | b >1
921 |
922 |->vmeta_tgets:
923 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
924 | li TMP0, LJ_TTAB
925 | stw TAB:RB, 4(CARG2)
926 | la CARG3, DISPATCH_GL(tmptv2)(DISPATCH)
927 | stw TMP0, 0(CARG2)
928 | li TMP1, LJ_TSTR
929 | stw STR:RC, 4(CARG3)
930 | stw TMP1, 0(CARG3)
931 | b >1
932 |
933 |->vmeta_tgetb: // TMP0 = index
934 |.if not DUALNUM
935 | tonum_u f0, TMP0
936 |.endif
937 | decode_RB8 RB, INS
938 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
939 | add CARG2, BASE, RB
940 |.if DUALNUM
941 | stw TISNUM, 0(CARG3)
942 | stw TMP0, 4(CARG3)
943 |.else
944 | stfd f0, 0(CARG3)
945 |.endif
946 | b >1
947 |
948 |->vmeta_tgetv:
949 | decode_RB8 RB, INS
950 | decode_RC8 RC, INS
951 | add CARG2, BASE, RB
952 | add CARG3, BASE, RC
953 |1:
954 | stp BASE, L->base
955 | mr CARG1, L
956 | stw PC, SAVE_PC
957 | bl extern lj_meta_tget // (lua_State *L, TValue *o, TValue *k)
958 | // Returns TValue * (finished) or NULL (metamethod).
959 | cmplwi CRET1, 0
960 | beq >3
961 |.if FPU
962 | lfd f0, 0(CRET1)
963 |.else
964 | lwz TMP0, 0(CRET1)
965 | lwz TMP1, 4(CRET1)
966 |.endif
967 | ins_next1
968 |.if FPU
969 | stfdx f0, BASE, RA
970 |.else
971 | stwux TMP0, RA, BASE
972 | stw TMP1, 4(RA)
973 |.endif
974 | ins_next2
975 |
976 |3: // Call __index metamethod.
977 | // BASE = base, L->top = new base, stack = cont/func/t/k
978 | subfic TMP1, BASE, FRAME_CONT
979 | lp BASE, L->top
980 | stw PC, -16(BASE) // [cont|PC]
981 | add PC, TMP1, BASE
982 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
983 | li NARGS8:RC, 16 // 2 args for func(t, k).
984 | b ->vm_call_dispatch_f
985 |
986 |->vmeta_tgetr:
987 | bl extern lj_tab_getinth // (GCtab *t, int32_t key)
988 | // Returns cTValue * or NULL.
989 | cmplwi CRET1, 0
990 | beq >1
991 |.if FPU
992 | lfd f14, 0(CRET1)
993 |.else
994 | lwz SAVE0, 0(CRET1)
995 | lwz SAVE1, 4(CRET1)
996 |.endif
997 | b ->BC_TGETR_Z
998 |1:
999 | stwx TISNIL, BASE, RA
1000 | b ->cont_nop
1001 |
1002 |//-----------------------------------------------------------------------
1003 |
1004 |->vmeta_tsets1:
1005 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
1006 | li TMP0, LJ_TSTR
1007 | decode_RB8 RB, INS
1008 | stw STR:RC, 4(CARG3)
1009 | add CARG2, BASE, RB
1010 | stw TMP0, 0(CARG3)
1011 | b >1
1012 |
1013 |->vmeta_tsets:
1014 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
1015 | li TMP0, LJ_TTAB
1016 | stw TAB:RB, 4(CARG2)
1017 | la CARG3, DISPATCH_GL(tmptv2)(DISPATCH)
1018 | stw TMP0, 0(CARG2)
1019 | li TMP1, LJ_TSTR
1020 | stw STR:RC, 4(CARG3)
1021 | stw TMP1, 0(CARG3)
1022 | b >1
1023 |
1024 |->vmeta_tsetb: // TMP0 = index
1025 |.if not DUALNUM
1026 | tonum_u f0, TMP0
1027 |.endif
1028 | decode_RB8 RB, INS
1029 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
1030 | add CARG2, BASE, RB
1031 |.if DUALNUM
1032 | stw TISNUM, 0(CARG3)
1033 | stw TMP0, 4(CARG3)
1034 |.else
1035 | stfd f0, 0(CARG3)
1036 |.endif
1037 | b >1
1038 |
1039 |->vmeta_tsetv:
1040 | decode_RB8 RB, INS
1041 | decode_RC8 RC, INS
1042 | add CARG2, BASE, RB
1043 | add CARG3, BASE, RC
1044 |1:
1045 | stp BASE, L->base
1046 | mr CARG1, L
1047 | stw PC, SAVE_PC
1048 | bl extern lj_meta_tset // (lua_State *L, TValue *o, TValue *k)
1049 | // Returns TValue * (finished) or NULL (metamethod).
1050 | cmplwi CRET1, 0
1051 |.if FPU
1052 | lfdx f0, BASE, RA
1053 |.else
1054 | lwzux TMP2, RA, BASE
1055 | lwz TMP3, 4(RA)
1056 |.endif
1057 | beq >3
1058 | // NOBARRIER: lj_meta_tset ensures the table is not black.
1059 | ins_next1
1060 |.if FPU
1061 | stfd f0, 0(CRET1)
1062 |.else
1063 | stw TMP2, 0(CRET1)
1064 | stw TMP3, 4(CRET1)
1065 |.endif
1066 | ins_next2
1067 |
1068 |3: // Call __newindex metamethod.
1069 | // BASE = base, L->top = new base, stack = cont/func/t/k/(v)
1070 | subfic TMP1, BASE, FRAME_CONT
1071 | lp BASE, L->top
1072 | stw PC, -16(BASE) // [cont|PC]
1073 | add PC, TMP1, BASE
1074 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
1075 | li NARGS8:RC, 24 // 3 args for func(t, k, v)
1076 |.if FPU
1077 | stfd f0, 16(BASE) // Copy value to third argument.
1078 |.else
1079 | stw TMP2, 16(BASE)
1080 | stw TMP3, 20(BASE)
1081 |.endif
1082 | b ->vm_call_dispatch_f
1083 |
1084 |->vmeta_tsetr:
1085 | stp BASE, L->base
1086 | mr CARG1, L
1087 | stw PC, SAVE_PC
1088 | bl extern lj_tab_setinth // (lua_State *L, GCtab *t, int32_t key)
1089 | // Returns TValue *.
1090 |.if FPU
1091 | stfd f14, 0(CRET1)
1092 |.else
1093 | stw SAVE0, 0(CRET1)
1094 | stw SAVE1, 4(CRET1)
1095 |.endif
1096 | b ->cont_nop
1097 |
1098 |//-- Comparison metamethods ---------------------------------------------
1099 |
1100 |->vmeta_comp:
1101 | mr CARG1, L
1102 | subi PC, PC, 4
1103 |.if DUALNUM
1104 | mr CARG2, RA
1105 |.else
1106 | add CARG2, BASE, RA
1107 |.endif
1108 | stw PC, SAVE_PC
1109 |.if DUALNUM
1110 | mr CARG3, RD
1111 |.else
1112 | add CARG3, BASE, RD
1113 |.endif
1114 | stp BASE, L->base
1115 | decode_OP1 CARG4, INS
1116 | bl extern lj_meta_comp // (lua_State *L, TValue *o1, *o2, int op)
1117 | // Returns 0/1 or TValue * (metamethod).
1118 |3:
1119 | cmplwi CRET1, 1
1120 | bgt ->vmeta_binop
1121 | subfic CRET1, CRET1, 0
1122 |4:
1123 | lwz INS, 0(PC)
1124 | addi PC, PC, 4
1125 | decode_RD4 TMP2, INS
1126 | addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
1127 | and TMP2, TMP2, CRET1
1128 | add PC, PC, TMP2
1129 |->cont_nop:
1130 | ins_next
1131 |
1132 |->cont_ra: // RA = resultptr
1133 | lwz INS, -4(PC)
1134 |.if FPU
1135 | lfd f0, 0(RA)
1136 |.else
1137 | lwz CARG1, 0(RA)
1138 | lwz CARG2, 4(RA)
1139 |.endif
1140 | decode_RA8 TMP1, INS
1141 |.if FPU
1142 | stfdx f0, BASE, TMP1
1143 |.else
1144 | stwux CARG1, TMP1, BASE
1145 | stw CARG2, 4(TMP1)
1146 |.endif
1147 | b ->cont_nop
1148 |
1149 |->cont_condt: // RA = resultptr
1150 | lwz TMP0, 0(RA)
1151 | .gpr64 extsw TMP0, TMP0
1152 | subfic TMP0, TMP0, LJ_TTRUE // Branch if result is true.
1153 | subfe CRET1, CRET1, CRET1
1154 | not CRET1, CRET1
1155 | b <4
1156 |
1157 |->cont_condf: // RA = resultptr
1158 | lwz TMP0, 0(RA)
1159 | .gpr64 extsw TMP0, TMP0
1160 | subfic TMP0, TMP0, LJ_TTRUE // Branch if result is false.
1161 | subfe CRET1, CRET1, CRET1
1162 | b <4
1163 |
1164 |->vmeta_equal:
1165 | // CARG2, CARG3, CARG4 are already set by BC_ISEQV/BC_ISNEV.
1166 | subi PC, PC, 4
1167 | stp BASE, L->base
1168 | mr CARG1, L
1169 | stw PC, SAVE_PC
1170 | bl extern lj_meta_equal // (lua_State *L, GCobj *o1, *o2, int ne)
1171 | // Returns 0/1 or TValue * (metamethod).
1172 | b <3
1173 |
1174 |->vmeta_equal_cd:
1175 |.if FFI
1176 | mr CARG2, INS
1177 | subi PC, PC, 4
1178 | stp BASE, L->base
1179 | mr CARG1, L
1180 | stw PC, SAVE_PC
1181 | bl extern lj_meta_equal_cd // (lua_State *L, BCIns op)
1182 | // Returns 0/1 or TValue * (metamethod).
1183 | b <3
1184 |.endif
1185 |
1186 |->vmeta_istype:
1187 | subi PC, PC, 4
1188 | stp BASE, L->base
1189 | srwi CARG2, RA, 3
1190 | mr CARG1, L
1191 | srwi CARG3, RD, 3
1192 | stw PC, SAVE_PC
1193 | bl extern lj_meta_istype // (lua_State *L, BCReg ra, BCReg tp)
1194 | b ->cont_nop
1195 |
1196 |//-- Arithmetic metamethods ---------------------------------------------
1197 |
1198 |->vmeta_arith_nv:
1199 | add CARG3, KBASE, RC
1200 | add CARG4, BASE, RB
1201 | b >1
1202 |->vmeta_arith_nv2:
1203 |.if DUALNUM
1204 | mr CARG3, RC
1205 | mr CARG4, RB
1206 | b >1
1207 |.endif
1208 |
1209 |->vmeta_unm:
1210 | mr CARG3, RD
1211 | mr CARG4, RD
1212 | b >1
1213 |
1214 |->vmeta_arith_vn:
1215 | add CARG3, BASE, RB
1216 | add CARG4, KBASE, RC
1217 | b >1
1218 |
1219 |->vmeta_arith_vv:
1220 | add CARG3, BASE, RB
1221 | add CARG4, BASE, RC
1222 |.if DUALNUM
1223 | b >1
1224 |.endif
1225 |->vmeta_arith_vn2:
1226 |->vmeta_arith_vv2:
1227 |.if DUALNUM
1228 | mr CARG3, RB
1229 | mr CARG4, RC
1230 |.endif
1231 |1:
1232 | add CARG2, BASE, RA
1233 | stp BASE, L->base
1234 | mr CARG1, L
1235 | stw PC, SAVE_PC
1236 | decode_OP1 CARG5, INS // Caveat: CARG5 overlaps INS.
1237 | bl extern lj_meta_arith // (lua_State *L, TValue *ra,*rb,*rc, BCReg op)
1238 | // Returns NULL (finished) or TValue * (metamethod).
1239 | cmplwi CRET1, 0
1240 | beq ->cont_nop
1241 |
1242 | // Call metamethod for binary op.
1243 |->vmeta_binop:
1244 | // BASE = old base, CRET1 = new base, stack = cont/func/o1/o2
1245 | sub TMP1, CRET1, BASE
1246 | stw PC, -16(CRET1) // [cont|PC]
1247 | mr TMP2, BASE
1248 | addi PC, TMP1, FRAME_CONT
1249 | mr BASE, CRET1
1250 | li NARGS8:RC, 16 // 2 args for func(o1, o2).
1251 | b ->vm_call_dispatch
1252 |
1253 |->vmeta_len:
1254 #if LJ_52
1255 | mr SAVE0, CARG1
1256 #endif
1257 | mr CARG2, RD
1258 | stp BASE, L->base
1259 | mr CARG1, L
1260 | stw PC, SAVE_PC
1261 | bl extern lj_meta_len // (lua_State *L, TValue *o)
1262 | // Returns NULL (retry) or TValue * (metamethod base).
1263 #if LJ_52
1264 | cmplwi CRET1, 0
1265 | bne ->vmeta_binop // Binop call for compatibility.
1266 | mr CARG1, SAVE0
1267 | b ->BC_LEN_Z
1268 #else
1269 | b ->vmeta_binop // Binop call for compatibility.
1270 #endif
1271 |
1272 |//-- Call metamethod ----------------------------------------------------
1273 |
1274 |->vmeta_call: // Resolve and call __call metamethod.
1275 | // TMP2 = old base, BASE = new base, RC = nargs*8
1276 | mr CARG1, L
1277 | stp TMP2, L->base // This is the callers base!
1278 | subi CARG2, BASE, 8
1279 | stw PC, SAVE_PC
1280 | add CARG3, BASE, RC
1281 | mr SAVE0, NARGS8:RC
1282 | bl extern lj_meta_call // (lua_State *L, TValue *func, TValue *top)
1283 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
1284 | addi NARGS8:RC, SAVE0, 8 // Got one more argument now.
1285 | ins_call
1286 |
1287 |->vmeta_callt: // Resolve __call for BC_CALLT.
1288 | // BASE = old base, RA = new base, RC = nargs*8
1289 | mr CARG1, L
1290 | stp BASE, L->base
1291 | subi CARG2, RA, 8
1292 | stw PC, SAVE_PC
1293 | add CARG3, RA, RC
1294 | mr SAVE0, NARGS8:RC
1295 | bl extern lj_meta_call // (lua_State *L, TValue *func, TValue *top)
1296 | lwz TMP1, FRAME_PC(BASE)
1297 | addi NARGS8:RC, SAVE0, 8 // Got one more argument now.
1298 | lwz LFUNC:RB, FRAME_FUNC(RA) // Guaranteed to be a function here.
1299 | b ->BC_CALLT_Z
1300 |
1301 |//-- Argument coercion for 'for' statement ------------------------------
1302 |
1303 |->vmeta_for:
1304 | mr CARG1, L
1305 | stp BASE, L->base
1306 | mr CARG2, RA
1307 | stw PC, SAVE_PC
1308 | mr SAVE0, INS
1309 | bl extern lj_meta_for // (lua_State *L, TValue *base)
1310 |.if JIT
1311 | decode_OP1 TMP0, SAVE0
1312 |.endif
1313 | decode_RA8 RA, SAVE0
1314 |.if JIT
1315 | cmpwi TMP0, BC_JFORI
1316 |.endif
1317 | decode_RD8 RD, SAVE0
1318 |.if JIT
1319 | beqy =>BC_JFORI
1320 |.endif
1321 | b =>BC_FORI
1322 |
1323 |//-----------------------------------------------------------------------
1324 |//-- Fast functions -----------------------------------------------------
1325 |//-----------------------------------------------------------------------
1326 |
1327 |.macro .ffunc, name
1328 |->ff_ .. name:
1329 |.endmacro
1330 |
1331 |.macro .ffunc_1, name
1332 |->ff_ .. name:
1333 | cmplwi NARGS8:RC, 8
1334 | lwz CARG3, 0(BASE)
1335 | lwz CARG1, 4(BASE)
1336 | blt ->fff_fallback
1337 |.endmacro
1338 |
1339 |.macro .ffunc_2, name
1340 |->ff_ .. name:
1341 | cmplwi NARGS8:RC, 16
1342 | lwz CARG3, 0(BASE)
1343 | lwz CARG4, 8(BASE)
1344 | lwz CARG1, 4(BASE)
1345 | lwz CARG2, 12(BASE)
1346 | blt ->fff_fallback
1347 |.endmacro
1348 |
1349 |.macro .ffunc_n, name
1350 |->ff_ .. name:
1351 | cmplwi NARGS8:RC, 8
1352 | lwz CARG1, 0(BASE)
1353 |.if FPU
1354 | lfd FARG1, 0(BASE)
1355 |.else
1356 | lwz CARG2, 4(BASE)
1357 |.endif
1358 | blt ->fff_fallback
1359 | checknum CARG1; bge ->fff_fallback
1360 |.endmacro
1361 |
1362 |.macro .ffunc_nn, name
1363 |->ff_ .. name:
1364 | cmplwi NARGS8:RC, 16
1365 | lwz CARG1, 0(BASE)
1366 |.if FPU
1367 | lfd FARG1, 0(BASE)
1368 | lwz CARG3, 8(BASE)
1369 | lfd FARG2, 8(BASE)
1370 |.else
1371 | lwz CARG2, 4(BASE)
1372 | lwz CARG3, 8(BASE)
1373 | lwz CARG4, 12(BASE)
1374 |.endif
1375 | blt ->fff_fallback
1376 | checknum CARG1; bge ->fff_fallback
1377 | checknum CARG3; bge ->fff_fallback
1378 |.endmacro
1379 |
1380 |// Inlined GC threshold check. Caveat: uses TMP0 and TMP1.
1381 |.macro ffgccheck
1382 | lwz TMP0, DISPATCH_GL(gc.total)(DISPATCH)
1383 | lwz TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
1384 | cmplw TMP0, TMP1
1385 | bgel ->fff_gcstep
1386 |.endmacro
1387 |
1388 |//-- Base library: checks -----------------------------------------------
1389 |
1390 |.ffunc_1 assert
1391 | li TMP1, LJ_TFALSE
1392 | la RA, -8(BASE)
1393 | cmplw cr1, CARG3, TMP1
1394 | lwz PC, FRAME_PC(BASE)
1395 | bge cr1, ->fff_fallback
1396 | stw CARG3, 0(RA)
1397 | addi RD, NARGS8:RC, 8 // Compute (nresults+1)*8.
1398 | addi TMP1, BASE, 8
1399 | add TMP2, RA, NARGS8:RC
1400 | stw CARG1, 4(RA)
1401 | beq ->fff_res // Done if exactly 1 argument.
1402 |1:
1403 | cmplw TMP1, TMP2
1404 |.if FPU
1405 | lfd f0, 0(TMP1)
1406 | stfd f0, 0(TMP1)
1407 |.else
1408 | lwz CARG1, 0(TMP1)
1409 | lwz CARG2, 4(TMP1)
1410 | stw CARG1, -8(TMP1)
1411 | stw CARG2, -4(TMP1)
1412 |.endif
1413 | addi TMP1, TMP1, 8
1414 | bney <1
1415 | b ->fff_res
1416 |
1417 |.ffunc type
1418 | cmplwi NARGS8:RC, 8
1419 | lwz CARG1, 0(BASE)
1420 | blt ->fff_fallback
1421 | .gpr64 extsw CARG1, CARG1
1422 | subfc TMP0, TISNUM, CARG1
1423 | subfe TMP2, CARG1, CARG1
1424 | orc TMP1, TMP2, TMP0
1425 | addi TMP1, TMP1, ~LJ_TISNUM+1
1426 | slwi TMP1, TMP1, 3
1427 |.if FPU
1428 | la TMP2, CFUNC:RB->upvalue
1429 | lfdx FARG1, TMP2, TMP1
1430 |.else
1431 | add TMP1, CFUNC:RB, TMP1
1432 | lwz CARG1, CFUNC:TMP1->upvalue[0].u32.hi
1433 | lwz CARG2, CFUNC:TMP1->upvalue[0].u32.lo
1434 |.endif
1435 | b ->fff_resn
1436 |
1437 |//-- Base library: getters and setters ---------------------------------
1438 |
1439 |.ffunc_1 getmetatable
1440 | checktab CARG3; bne >6
1441 |1: // Field metatable must be at same offset for GCtab and GCudata!
1442 | lwz TAB:CARG1, TAB:CARG1->metatable
1443 |2:
1444 | li CARG3, LJ_TNIL
1445 | cmplwi TAB:CARG1, 0
1446 | lwz STR:RC, DISPATCH_GL(gcroot[GCROOT_MMNAME+MM_metatable])(DISPATCH)
1447 | beq ->fff_restv
1448 | lwz TMP0, TAB:CARG1->hmask
1449 | li CARG3, LJ_TTAB // Use metatable as default result.
1450 | lwz TMP1, STR:RC->sid
1451 | lwz NODE:TMP2, TAB:CARG1->node
1452 | and TMP1, TMP1, TMP0 // idx = str->sid & tab->hmask
1453 | slwi TMP0, TMP1, 5
1454 | slwi TMP1, TMP1, 3
1455 | sub TMP1, TMP0, TMP1
1456 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
1457 |3: // Rearranged logic, because we expect _not_ to find the key.
1458 | lwz CARG4, NODE:TMP2->key
1459 | lwz TMP0, 4+offsetof(Node, key)(NODE:TMP2)
1460 | lwz CARG2, NODE:TMP2->val
1461 | lwz TMP1, 4+offsetof(Node, val)(NODE:TMP2)
1462 | checkstr CARG4; bne >4
1463 | cmpw TMP0, STR:RC; beq >5
1464 |4:
1465 | lwz NODE:TMP2, NODE:TMP2->next
1466 | cmplwi NODE:TMP2, 0
1467 | beq ->fff_restv // Not found, keep default result.
1468 | b <3
1469 |5:
1470 | checknil CARG2
1471 | beq ->fff_restv // Ditto for nil value.
1472 | mr CARG3, CARG2 // Return value of mt.__metatable.
1473 | mr CARG1, TMP1
1474 | b ->fff_restv
1475 |
1476 |6:
1477 | cmpwi CARG3, LJ_TUDATA; beq <1
1478 | .gpr64 extsw CARG3, CARG3
1479 | subfc TMP0, TISNUM, CARG3
1480 | subfe TMP2, CARG3, CARG3
1481 | orc TMP1, TMP2, TMP0
1482 | addi TMP1, TMP1, ~LJ_TISNUM+1
1483 | slwi TMP1, TMP1, 2
1484 | la TMP2, DISPATCH_GL(gcroot[GCROOT_BASEMT])(DISPATCH)
1485 | lwzx TAB:CARG1, TMP2, TMP1
1486 | b <2
1487 |
1488 |.ffunc_2 setmetatable
1489 | // Fast path: no mt for table yet and not clearing the mt.
1490 | checktab CARG3; bne ->fff_fallback
1491 | lwz TAB:TMP1, TAB:CARG1->metatable
1492 | checktab CARG4; bne ->fff_fallback
1493 | cmplwi TAB:TMP1, 0
1494 | lbz TMP3, TAB:CARG1->marked
1495 | bne ->fff_fallback
1496 | andix. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
1497 | stw TAB:CARG2, TAB:CARG1->metatable
1498 | beq ->fff_restv
1499 | barrierback TAB:CARG1, TMP3, TMP0
1500 | b ->fff_restv
1501 |
1502 |.ffunc rawget
1503 | cmplwi NARGS8:RC, 16
1504 | lwz CARG4, 0(BASE)
1505 | lwz TAB:CARG2, 4(BASE)
1506 | blt ->fff_fallback
1507 | checktab CARG4; bne ->fff_fallback
1508 | la CARG3, 8(BASE)
1509 | mr CARG1, L
1510 | bl extern lj_tab_get // (lua_State *L, GCtab *t, cTValue *key)
1511 | // Returns cTValue *.
1512 |.if FPU
1513 | lfd FARG1, 0(CRET1)
1514 |.else
1515 | lwz CARG2, 4(CRET1)
1516 | lwz CARG1, 0(CRET1) // Caveat: CARG1 == CRET1.
1517 |.endif
1518 | b ->fff_resn
1519 |
1520 |//-- Base library: conversions ------------------------------------------
1521 |
1522 |.ffunc tonumber
1523 | // Only handles the number case inline (without a base argument).
1524 | cmplwi NARGS8:RC, 8
1525 | lwz CARG1, 0(BASE)
1526 |.if FPU
1527 | lfd FARG1, 0(BASE)
1528 |.else
1529 | lwz CARG2, 4(BASE)
1530 |.endif
1531 | bne ->fff_fallback // Exactly one argument.
1532 | checknum CARG1; bgt ->fff_fallback
1533 | b ->fff_resn
1534 |
1535 |.ffunc_1 tostring
1536 | // Only handles the string or number case inline.
1537 | checkstr CARG3
1538 | // A __tostring method in the string base metatable is ignored.
1539 | beq ->fff_restv // String key?
1540 | // Handle numbers inline, unless a number base metatable is present.
1541 | lwz TMP0, DISPATCH_GL(gcroot[GCROOT_BASEMT_NUM])(DISPATCH)
1542 | checknum CARG3
1543 | cmplwi cr1, TMP0, 0
1544 | stp BASE, L->base // Add frame since C call can throw.
1545 | crorc 4*cr0+eq, 4*cr0+gt, 4*cr1+eq
1546 | stw PC, SAVE_PC // Redundant (but a defined value).
1547 | beq ->fff_fallback
1548 | ffgccheck
1549 | mr CARG1, L
1550 | mr CARG2, BASE
1551 |.if DUALNUM
1552 | bl extern lj_strfmt_number // (lua_State *L, cTValue *o)
1553 |.else
1554 | bl extern lj_strfmt_num // (lua_State *L, lua_Number *np)
1555 |.endif
1556 | // Returns GCstr *.
1557 | li CARG3, LJ_TSTR
1558 | b ->fff_restv
1559 |
1560 |//-- Base library: iterators -------------------------------------------
1561 |
1562 |.ffunc_1 next
1563 | stwx TISNIL, BASE, NARGS8:RC // Set missing 2nd arg to nil.
1564 | checktab CARG3
1565 | lwz PC, FRAME_PC(BASE)
1566 | bne ->fff_fallback
1567 | la CARG2, 8(BASE)
1568 | la CARG3, -8(BASE)
1569 | bl extern lj_tab_next // (GCtab *t, cTValue *key, TValue *o)
1570 | // Returns 1=found, 0=end, -1=error.
1571 | cmpwi CRET1, 0
1572 | la RA, -8(BASE)
1573 | li RD, (2+1)*8
1574 | bgt ->fff_res // Found key/value.
1575 | li CARG3, LJ_TNIL
1576 | beq ->fff_restv // End of traversal: return nil.
1577 | lwz CFUNC:RB, FRAME_FUNC(BASE)
1578 | li NARGS8:RC, 2*8
1579 | b ->fff_fallback // Invalid key.
1580 |
1581 |.ffunc_1 pairs
1582 | checktab CARG3
1583 | lwz PC, FRAME_PC(BASE)
1584 | bne ->fff_fallback
1585 #if LJ_52
1586 | lwz TAB:TMP2, TAB:CARG1->metatable
1587 |.if FPU
1588 | lfd f0, CFUNC:RB->upvalue[0]
1589 |.else
1590 | lwz TMP0, CFUNC:RB->upvalue[0].u32.hi
1591 | lwz TMP1, CFUNC:RB->upvalue[0].u32.lo
1592 |.endif
1593 | cmplwi TAB:TMP2, 0
1594 | la RA, -8(BASE)
1595 | bne ->fff_fallback
1596 #else
1597 |.if FPU
1598 | lfd f0, CFUNC:RB->upvalue[0]
1599 |.else
1600 | lwz TMP0, CFUNC:RB->upvalue[0].u32.hi
1601 | lwz TMP1, CFUNC:RB->upvalue[0].u32.lo
1602 |.endif
1603 | la RA, -8(BASE)
1604 #endif
1605 | stw TISNIL, 8(BASE)
1606 | li RD, (3+1)*8
1607 |.if FPU
1608 | stfd f0, 0(RA)
1609 |.else
1610 | stw TMP0, 0(RA)
1611 | stw TMP1, 4(RA)
1612 |.endif
1613 | b ->fff_res
1614 |
1615 |.ffunc ipairs_aux
1616 | cmplwi NARGS8:RC, 16
1617 | lwz CARG3, 0(BASE)
1618 | lwz TAB:CARG1, 4(BASE)
1619 | lwz CARG4, 8(BASE)
1620 |.if DUALNUM
1621 | lwz TMP2, 12(BASE)
1622 |.else
1623 | lfd FARG2, 8(BASE)
1624 |.endif
1625 | blt ->fff_fallback
1626 | checktab CARG3
1627 | checknum cr1, CARG4
1628 | lwz PC, FRAME_PC(BASE)
1629 |.if DUALNUM
1630 | bne ->fff_fallback
1631 | bne cr1, ->fff_fallback
1632 |.else
1633 | lus TMP0, 0x3ff0
1634 | stw ZERO, TMPD_LO
1635 | bne ->fff_fallback
1636 | stw TMP0, TMPD_HI
1637 | bge cr1, ->fff_fallback
1638 | lfd FARG1, TMPD
1639 | toint TMP2, FARG2, f0
1640 |.endif
1641 | lwz TMP0, TAB:CARG1->asize
1642 | lwz TMP1, TAB:CARG1->array
1643 |.if not DUALNUM
1644 | fadd FARG2, FARG2, FARG1
1645 |.endif
1646 | addi TMP2, TMP2, 1
1647 | la RA, -8(BASE)
1648 | cmplw TMP0, TMP2
1649 |.if DUALNUM
1650 | stw TISNUM, 0(RA)
1651 | slwi TMP3, TMP2, 3
1652 | stw TMP2, 4(RA)
1653 |.else
1654 | slwi TMP3, TMP2, 3
1655 | stfd FARG2, 0(RA)
1656 |.endif
1657 | ble >2 // Not in array part?
1658 |.if FPU
1659 | lwzx TMP2, TMP1, TMP3
1660 | lfdx f0, TMP1, TMP3
1661 |.else
1662 | lwzux TMP2, TMP1, TMP3
1663 | lwz TMP3, 4(TMP1)
1664 |.endif
1665 |1:
1666 | checknil TMP2
1667 | li RD, (0+1)*8
1668 | beq ->fff_res // End of iteration, return 0 results.
1669 | li RD, (2+1)*8
1670 |.if FPU
1671 | stfd f0, 8(RA)
1672 |.else
1673 | stw TMP2, 8(RA)
1674 | stw TMP3, 12(RA)
1675 |.endif
1676 | b ->fff_res
1677 |2: // Check for empty hash part first. Otherwise call C function.
1678 | lwz TMP0, TAB:CARG1->hmask
1679 | cmplwi TMP0, 0
1680 | li RD, (0+1)*8
1681 | beq ->fff_res
1682 | mr CARG2, TMP2
1683 | bl extern lj_tab_getinth // (GCtab *t, int32_t key)
1684 | // Returns cTValue * or NULL.
1685 | cmplwi CRET1, 0
1686 | li RD, (0+1)*8
1687 | beq ->fff_res
1688 | lwz TMP2, 0(CRET1)
1689 |.if FPU
1690 | lfd f0, 0(CRET1)
1691 |.else
1692 | lwz TMP3, 4(CRET1)
1693 |.endif
1694 | b <1
1695 |
1696 |.ffunc_1 ipairs
1697 | checktab CARG3
1698 | lwz PC, FRAME_PC(BASE)
1699 | bne ->fff_fallback
1700 #if LJ_52
1701 | lwz TAB:TMP2, TAB:CARG1->metatable
1702 |.if FPU
1703 | lfd f0, CFUNC:RB->upvalue[0]
1704 |.else
1705 | lwz TMP0, CFUNC:RB->upvalue[0].u32.hi
1706 | lwz TMP1, CFUNC:RB->upvalue[0].u32.lo
1707 |.endif
1708 | cmplwi TAB:TMP2, 0
1709 | la RA, -8(BASE)
1710 | bne ->fff_fallback
1711 #else
1712 |.if FPU
1713 | lfd f0, CFUNC:RB->upvalue[0]
1714 |.else
1715 | lwz TMP0, CFUNC:RB->upvalue[0].u32.hi
1716 | lwz TMP1, CFUNC:RB->upvalue[0].u32.lo
1717 |.endif
1718 | la RA, -8(BASE)
1719 #endif
1720 |.if DUALNUM
1721 | stw TISNUM, 8(BASE)
1722 |.else
1723 | stw ZERO, 8(BASE)
1724 |.endif
1725 | stw ZERO, 12(BASE)
1726 | li RD, (3+1)*8
1727 |.if FPU
1728 | stfd f0, 0(RA)
1729 |.else
1730 | stw TMP0, 0(RA)
1731 | stw TMP1, 4(RA)
1732 |.endif
1733 | b ->fff_res
1734 |
1735 |//-- Base library: catch errors ----------------------------------------
1736 |
1737 |.ffunc pcall
1738 | lwz TMP1, L->maxstack
1739 | add TMP2, BASE, NARGS8:RC
1740 | cmplwi NARGS8:RC, 8
1741 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1742 | cmplw cr1, TMP1, TMP2
1743 | cror 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
1744 | blt ->fff_fallback
1745 | mr TMP2, BASE
1746 | la BASE, 8(BASE)
1747 | // Remember active hook before pcall.
1748 | rlwinm TMP3, TMP3, 32-HOOK_ACTIVE_SHIFT, 31, 31
1749 | subi NARGS8:RC, NARGS8:RC, 8
1750 | addi PC, TMP3, 8+FRAME_PCALL
1751 | b ->vm_call_dispatch
1752 |
1753 |.ffunc xpcall
1754 | lwz TMP1, L->maxstack
1755 | add TMP2, BASE, NARGS8:RC
1756 | cmplwi NARGS8:RC, 16
1757 | lwz CARG3, 8(BASE)
1758 | cmplw cr1, TMP1, TMP2
1759 |.if FPU
1760 | lfd FARG2, 8(BASE)
1761 | cror 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
1762 | lfd FARG1, 0(BASE)
1763 |.else
1764 | lwz CARG1, 0(BASE)
1765 | lwz CARG2, 4(BASE)
1766 | cror 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
1767 | lwz CARG4, 12(BASE)
1768 |.endif
1769 | blt ->fff_fallback
1770 | lbz TMP1, DISPATCH_GL(hookmask)(DISPATCH)
1771 | mr TMP2, BASE
1772 | checkfunc CARG3; bne ->fff_fallback // Traceback must be a function.
1773 | la BASE, 16(BASE)
1774 | // Remember active hook before pcall.
1775 | rlwinm TMP1, TMP1, 32-HOOK_ACTIVE_SHIFT, 31, 31
1776 |.if FPU
1777 | stfd FARG2, 0(TMP2) // Swap function and traceback.
1778 | stfd FARG1, 8(TMP2)
1779 |.else
1780 | stw CARG3, 0(TMP2)
1781 | stw CARG4, 4(TMP2)
1782 | stw CARG1, 8(TMP2)
1783 | stw CARG2, 12(TMP2)
1784 |.endif
1785 | subi NARGS8:RC, NARGS8:RC, 16
1786 | addi PC, TMP1, 16+FRAME_PCALL
1787 | b ->vm_call_dispatch
1788 |
1789 |//-- Coroutine library --------------------------------------------------
1790 |
1791 |.macro coroutine_resume_wrap, resume
1792 |.if resume
1793 |.ffunc_1 coroutine_resume
1794 | cmpwi CARG3, LJ_TTHREAD; bne ->fff_fallback
1795 |.else
1796 |.ffunc coroutine_wrap_aux
1797 | lwz L:CARG1, CFUNC:RB->upvalue[0].gcr
1798 |.endif
1799 | lbz TMP0, L:CARG1->status
1800 | lp TMP1, L:CARG1->cframe
1801 | lp CARG2, L:CARG1->top
1802 | cmplwi cr0, TMP0, LUA_YIELD
1803 | lp TMP2, L:CARG1->base
1804 | cmplwi cr1, TMP1, 0
1805 | lwz TMP0, L:CARG1->maxstack
1806 | cmplw cr7, CARG2, TMP2
1807 | lwz PC, FRAME_PC(BASE)
1808 | crorc 4*cr6+lt, 4*cr0+gt, 4*cr1+eq // st>LUA_YIELD || cframe!=0
1809 | add TMP2, CARG2, NARGS8:RC
1810 | crandc 4*cr6+gt, 4*cr7+eq, 4*cr0+eq // base==top && st!=LUA_YIELD
1811 | cmplw cr1, TMP2, TMP0
1812 | cror 4*cr6+lt, 4*cr6+lt, 4*cr6+gt
1813 | stw PC, SAVE_PC
1814 | cror 4*cr6+lt, 4*cr6+lt, 4*cr1+gt // cond1 || cond2 || stackov
1815 | stp BASE, L->base
1816 | blt cr6, ->fff_fallback
1817 |1:
1818 |.if resume
1819 | addi BASE, BASE, 8 // Keep resumed thread in stack for GC.
1820 | subi NARGS8:RC, NARGS8:RC, 8
1821 | subi TMP2, TMP2, 8
1822 |.endif
1823 | stp TMP2, L:CARG1->top
1824 | li TMP1, 0
1825 | stp BASE, L->top
1826 |2: // Move args to coroutine.
1827 | cmpw TMP1, NARGS8:RC
1828 |.if FPU
1829 | lfdx f0, BASE, TMP1
1830 |.else
1831 | add CARG3, BASE, TMP1
1832 | lwz TMP2, 0(CARG3)
1833 | lwz TMP3, 4(CARG3)
1834 |.endif
1835 | beq >3
1836 |.if FPU
1837 | stfdx f0, CARG2, TMP1
1838 |.else
1839 | add CARG3, CARG2, TMP1
1840 | stw TMP2, 0(CARG3)
1841 | stw TMP3, 4(CARG3)
1842 |.endif
1843 | addi TMP1, TMP1, 8
1844 | b <2
1845 |3:
1846 | li CARG3, 0
1847 | mr L:SAVE0, L:CARG1
1848 | li CARG4, 0
1849 | bl ->vm_resume // (lua_State *L, TValue *base, 0, 0)
1850 | // Returns thread status.
1851 |4:
1852 | lp TMP2, L:SAVE0->base
1853 | cmplwi CRET1, LUA_YIELD
1854 | lp TMP3, L:SAVE0->top
1855 | li_vmstate INTERP
1856 | lp BASE, L->base
1857 | stw L, DISPATCH_GL(cur_L)(DISPATCH)
1858 | st_vmstate
1859 | bgt >8
1860 | sub RD, TMP3, TMP2
1861 | lwz TMP0, L->maxstack
1862 | cmplwi RD, 0
1863 | add TMP1, BASE, RD
1864 | beq >6 // No results?
1865 | cmplw TMP1, TMP0
1866 | li TMP1, 0
1867 | bgt >9 // Need to grow stack?
1868 |
1869 | subi TMP3, RD, 8
1870 | stp TMP2, L:SAVE0->top // Clear coroutine stack.
1871 |5: // Move results from coroutine.
1872 | cmplw TMP1, TMP3
1873 |.if FPU
1874 | lfdx f0, TMP2, TMP1
1875 | stfdx f0, BASE, TMP1
1876 |.else
1877 | add CARG3, TMP2, TMP1
1878 | lwz CARG1, 0(CARG3)
1879 | lwz CARG2, 4(CARG3)
1880 | add CARG3, BASE, TMP1
1881 | stw CARG1, 0(CARG3)
1882 | stw CARG2, 4(CARG3)
1883 |.endif
1884 | addi TMP1, TMP1, 8
1885 | bne <5
1886 |6:
1887 | andix. TMP0, PC, FRAME_TYPE
1888 |.if resume
1889 | li TMP1, LJ_TTRUE
1890 | la RA, -8(BASE)
1891 | stw TMP1, -8(BASE) // Prepend true to results.
1892 | addi RD, RD, 16
1893 |.else
1894 | mr RA, BASE
1895 | addi RD, RD, 8
1896 |.endif
1897 |7:
1898 | stw PC, SAVE_PC
1899 | mr MULTRES, RD
1900 | beq ->BC_RET_Z
1901 | b ->vm_return
1902 |
1903 |8: // Coroutine returned with error (at co->top-1).
1904 |.if resume
1905 | andix. TMP0, PC, FRAME_TYPE
1906 | la TMP3, -8(TMP3)
1907 | li TMP1, LJ_TFALSE
1908 |.if FPU
1909 | lfd f0, 0(TMP3)
1910 |.else
1911 | lwz CARG1, 0(TMP3)
1912 | lwz CARG2, 4(TMP3)
1913 |.endif
1914 | stp TMP3, L:SAVE0->top // Remove error from coroutine stack.
1915 | li RD, (2+1)*8
1916 | stw TMP1, -8(BASE) // Prepend false to results.
1917 | la RA, -8(BASE)
1918 |.if FPU
1919 | stfd f0, 0(BASE) // Copy error message.
1920 |.else
1921 | stw CARG1, 0(BASE) // Copy error message.
1922 | stw CARG2, 4(BASE)
1923 |.endif
1924 | b <7
1925 |.else
1926 | mr CARG1, L
1927 | mr CARG2, L:SAVE0
1928 | bl extern lj_ffh_coroutine_wrap_err // (lua_State *L, lua_State *co)
1929 |.endif
1930 |
1931 |9: // Handle stack expansion on return from yield.
1932 | mr CARG1, L
1933 | srwi CARG2, RD, 3
1934 | bl extern lj_state_growstack // (lua_State *L, int n)
1935 | li CRET1, 0
1936 | b <4
1937 |.endmacro
1938 |
1939 | coroutine_resume_wrap 1 // coroutine.resume
1940 | coroutine_resume_wrap 0 // coroutine.wrap
1941 |
1942 |.ffunc coroutine_yield
1943 | lp TMP0, L->cframe
1944 | add TMP1, BASE, NARGS8:RC
1945 | stp BASE, L->base
1946 | andix. TMP0, TMP0, CFRAME_RESUME
1947 | stp TMP1, L->top
1948 | li CRET1, LUA_YIELD
1949 | beq ->fff_fallback
1950 | stp ZERO, L->cframe
1951 | stb CRET1, L->status
1952 | b ->vm_leave_unw
1953 |
1954 |//-- Math library -------------------------------------------------------
1955 |
1956 |.ffunc_1 math_abs
1957 | checknum CARG3
1958 |.if DUALNUM
1959 | bne >2
1960 | srawi TMP1, CARG1, 31
1961 | xor TMP2, TMP1, CARG1
1962 |.if GPR64
1963 | lus TMP0, 0x8000
1964 | sub CARG1, TMP2, TMP1
1965 | cmplw CARG1, TMP0
1966 | beq >1
1967 |.else
1968 | sub. CARG1, TMP2, TMP1
1969 | blt >1
1970 |.endif
1971 |->fff_resi:
1972 | lwz PC, FRAME_PC(BASE)
1973 | la RA, -8(BASE)
1974 | stw TISNUM, -8(BASE)
1975 | stw CRET1, -4(BASE)
1976 | b ->fff_res1
1977 |1:
1978 | lus CARG3, 0x41e0 // 2^31.
1979 | li CARG1, 0
1980 | b ->fff_restv
1981 |2:
1982 |.endif
1983 | bge ->fff_fallback
1984 | rlwinm CARG3, CARG3, 0, 1, 31
1985 | // Fallthrough.
1986 |
1987 |->fff_restv:
1988 | // CARG3/CARG1 = TValue result.
1989 | lwz PC, FRAME_PC(BASE)
1990 | stw CARG3, -8(BASE)
1991 | la RA, -8(BASE)
1992 | stw CARG1, -4(BASE)
1993 |->fff_res1:
1994 | // RA = results, PC = return.
1995 | li RD, (1+1)*8
1996 |->fff_res:
1997 | // RA = results, RD = (nresults+1)*8, PC = return.
1998 | andix. TMP0, PC, FRAME_TYPE
1999 | mr MULTRES, RD
2000 | bney ->vm_return
2001 | lwz INS, -4(PC)
2002 | decode_RB8 RB, INS
2003 |5:
2004 | cmplw RB, RD // More results expected?
2005 | decode_RA8 TMP0, INS
2006 | bgt >6
2007 | ins_next1
2008 | // Adjust BASE. KBASE is assumed to be set for the calling frame.
2009 | sub BASE, RA, TMP0
2010 | ins_next2
2011 |
2012 |6: // Fill up results with nil.
2013 | subi TMP1, RD, 8
2014 | addi RD, RD, 8
2015 | stwx TISNIL, RA, TMP1
2016 | b <5
2017 |
2018 |.macro math_extern, func
2019 | .ffunc_n math_ .. func
2020 | blex func
2021 | b ->fff_resn
2022 |.endmacro
2023 |
2024 |.macro math_extern2, func
2025 | .ffunc_nn math_ .. func
2026 | blex func
2027 | b ->fff_resn
2028 |.endmacro
2029 |
2030 |.macro math_round, func
2031 | .ffunc_1 math_ .. func
2032 | checknum CARG3; beqy ->fff_restv
2033 | rlwinm TMP2, CARG3, 12, 21, 31
2034 | bge ->fff_fallback
2035 | addic. TMP2, TMP2, -1023 // exp = exponent(x) - 1023
2036 | cmplwi cr1, TMP2, 31 // 0 <= exp < 31?
2037 | subfic TMP0, TMP2, 31
2038 | blt >3
2039 | slwi TMP1, CARG3, 11
2040 | srwi TMP3, CARG1, 21
2041 | oris TMP1, TMP1, 0x8000
2042 | addi TMP2, TMP2, 1
2043 | or TMP1, TMP1, TMP3
2044 | slwi CARG2, CARG1, 11
2045 | bge cr1, >4
2046 | slw TMP3, TMP1, TMP2
2047 | srw RD, TMP1, TMP0
2048 | or TMP3, TMP3, CARG2
2049 | srawi TMP2, CARG3, 31
2050 |.if "func" == "floor"
2051 | and TMP1, TMP3, TMP2
2052 | addic TMP0, TMP1, -1
2053 | subfe TMP1, TMP0, TMP1
2054 | add CARG1, RD, TMP1
2055 | xor CARG1, CARG1, TMP2
2056 | sub CARG1, CARG1, TMP2
2057 | b ->fff_resi
2058 |.else
2059 | andc TMP1, TMP3, TMP2
2060 | addic TMP0, TMP1, -1
2061 | subfe TMP1, TMP0, TMP1
2062 | add CARG1, RD, TMP1
2063 | cmpw CARG1, RD
2064 | xor CARG1, CARG1, TMP2
2065 | sub CARG1, CARG1, TMP2
2066 | bge ->fff_resi
2067 | // Overflow to 2^31.
2068 | lus CARG3, 0x41e0 // 2^31.
2069 | li CARG1, 0
2070 | b ->fff_restv
2071 |.endif
2072 |3: // |x| < 1
2073 | slwi TMP2, CARG3, 1
2074 | srawi TMP1, CARG3, 31
2075 | or TMP2, CARG1, TMP2 // ztest = (hi+hi) | lo
2076 |.if "func" == "floor"
2077 | and TMP1, TMP2, TMP1 // (ztest & sign) == 0 ? 0 : -1
2078 | subfic TMP2, TMP1, 0
2079 | subfe CARG1, CARG1, CARG1
2080 |.else
2081 | andc TMP1, TMP2, TMP1 // (ztest & ~sign) == 0 ? 0 : 1
2082 | addic TMP2, TMP1, -1
2083 | subfe CARG1, TMP2, TMP1
2084 |.endif
2085 | b ->fff_resi
2086 |4: // exp >= 31. Check for -(2^31).
2087 | xoris TMP1, TMP1, 0x8000
2088 | srawi TMP2, CARG3, 31
2089 |.if "func" == "floor"
2090 | or TMP1, TMP1, CARG2
2091 |.endif
2092 |.if PPE
2093 | orc TMP1, TMP1, TMP2
2094 | cmpwi TMP1, 0
2095 |.else
2096 | orc. TMP1, TMP1, TMP2
2097 |.endif
2098 | crand 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
2099 | lus CARG1, 0x8000 // -(2^31).
2100 | beqy ->fff_resi
2101 |5:
2102 |.if FPU
2103 | lfd FARG1, 0(BASE)
2104 |.else
2105 | lwz CARG1, 0(BASE)
2106 | lwz CARG2, 4(BASE)
2107 |.endif
2108 | blex func
2109 | b ->fff_resn
2110 |.endmacro
2111 |
2112 |.if DUALNUM
2113 | math_round floor
2114 | math_round ceil
2115 |.else
2116 | // NYI: use internal implementation.
2117 | math_extern floor
2118 | math_extern ceil
2119 |.endif
2120 |
2121 |.if SQRT
2122 |.ffunc_n math_sqrt
2123 | fsqrt FARG1, FARG1
2124 | b ->fff_resn
2125 |.else
2126 | math_extern sqrt
2127 |.endif
2128 |
2129 |.ffunc math_log
2130 | cmplwi NARGS8:RC, 8
2131 | lwz CARG1, 0(BASE)
2132 | bne ->fff_fallback // Need exactly 1 argument.
2133 | checknum CARG1; bge ->fff_fallback
2134 |.if FPU
2135 | lfd FARG1, 0(BASE)
2136 |.else
2137 | lwz CARG2, 4(BASE)
2138 |.endif
2139 | blex log
2140 | b ->fff_resn
2141 |
2142 | math_extern log10
2143 | math_extern exp
2144 | math_extern sin
2145 | math_extern cos
2146 | math_extern tan
2147 | math_extern asin
2148 | math_extern acos
2149 | math_extern atan
2150 | math_extern sinh
2151 | math_extern cosh
2152 | math_extern tanh
2153 | math_extern2 pow
2154 | math_extern2 atan2
2155 | math_extern2 fmod
2156 |
2157 |.if DUALNUM
2158 |.ffunc math_ldexp
2159 | cmplwi NARGS8:RC, 16
2160 | lwz TMP0, 0(BASE)
2161 |.if FPU
2162 | lfd FARG1, 0(BASE)
2163 |.else
2164 | lwz CARG1, 0(BASE)
2165 | lwz CARG2, 4(BASE)
2166 |.endif
2167 | lwz TMP1, 8(BASE)
2168 |.if GPR64
2169 | lwz CARG2, 12(BASE)
2170 |.elif FPU
2171 | lwz CARG1, 12(BASE)
2172 |.else
2173 | lwz CARG3, 12(BASE)
2174 |.endif
2175 | blt ->fff_fallback
2176 | checknum TMP0; bge ->fff_fallback
2177 | checknum TMP1; bne ->fff_fallback
2178 |.else
2179 |.ffunc_nn math_ldexp
2180 |.if GPR64
2181 | toint CARG2, FARG2
2182 |.else
2183 | toint CARG1, FARG2
2184 |.endif
2185 |.endif
2186 | blex ldexp
2187 | b ->fff_resn
2188 |
2189 |.ffunc_n math_frexp
2190 |.if GPR64
2191 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
2192 |.elif FPU
2193 | la CARG1, DISPATCH_GL(tmptv)(DISPATCH)
2194 |.else
2195 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
2196 |.endif
2197 | lwz PC, FRAME_PC(BASE)
2198 | blex frexp
2199 | lwz TMP1, DISPATCH_GL(tmptv)(DISPATCH)
2200 | la RA, -8(BASE)
2201 |.if not DUALNUM
2202 | tonum_i FARG2, TMP1
2203 |.endif
2204 |.if FPU
2205 | stfd FARG1, 0(RA)
2206 |.else
2207 | stw CRET1, 0(RA)
2208 | stw CRET2, 4(RA)
2209 |.endif
2210 | li RD, (2+1)*8
2211 |.if DUALNUM
2212 | stw TISNUM, 8(RA)
2213 | stw TMP1, 12(RA)
2214 |.else
2215 | stfd FARG2, 8(RA)
2216 |.endif
2217 | b ->fff_res
2218 |
2219 |.ffunc_n math_modf
2220 |.if GPR64
2221 | la CARG2, -8(BASE)
2222 |.elif FPU
2223 | la CARG1, -8(BASE)
2224 |.else
2225 | la CARG3, -8(BASE)
2226 |.endif
2227 | lwz PC, FRAME_PC(BASE)
2228 | blex modf
2229 | la RA, -8(BASE)
2230 |.if FPU
2231 | stfd FARG1, 0(BASE)
2232 |.else
2233 | stw CRET1, 0(BASE)
2234 | stw CRET2, 4(BASE)
2235 |.endif
2236 | li RD, (2+1)*8
2237 | b ->fff_res
2238 |
2239 |.macro math_minmax, name, ismax
2240 |.if DUALNUM
2241 | .ffunc_1 name
2242 | checknum CARG3
2243 | addi SAVE0, BASE, 8
2244 | add SAVE1, BASE, NARGS8:RC
2245 | bne >4
2246 |1: // Handle integers.
2247 | lwz CARG4, 0(SAVE0)
2248 | cmplw cr1, SAVE0, SAVE1
2249 | lwz CARG2, 4(SAVE0)
2250 | bge cr1, ->fff_resi
2251 | checknum CARG4
2252 | xoris TMP0, CARG1, 0x8000
2253 | xoris TMP3, CARG2, 0x8000
2254 | bne >3
2255 | subfc TMP3, TMP3, TMP0
2256 | subfe TMP0, TMP0, TMP0
2257 |.if ismax
2258 | andc TMP3, TMP3, TMP0
2259 |.else
2260 | and TMP3, TMP3, TMP0
2261 |.endif
2262 | add CARG1, TMP3, CARG2
2263 |.if GPR64
2264 | rldicl CARG1, CARG1, 0, 32
2265 |.endif
2266 | addi SAVE0, SAVE0, 8
2267 | b <1
2268 |3:
2269 | bge ->fff_fallback
2270 | // Convert intermediate result to number and continue below.
2271 |.if FPU
2272 | tonum_i FARG1, CARG1
2273 | lfd FARG2, 0(SAVE0)
2274 |.else
2275 | mr CARG2, CARG1
2276 | bl ->vm_sfi2d_1
2277 | lwz CARG3, 0(SAVE0)
2278 | lwz CARG4, 4(SAVE0)
2279 |.endif
2280 | b >6
2281 |4:
2282 |.if FPU
2283 | lfd FARG1, 0(BASE)
2284 |.else
2285 | lwz CARG1, 0(BASE)
2286 | lwz CARG2, 4(BASE)
2287 |.endif
2288 | bge ->fff_fallback
2289 |5: // Handle numbers.
2290 | lwz CARG3, 0(SAVE0)
2291 | cmplw cr1, SAVE0, SAVE1
2292 |.if FPU
2293 | lfd FARG2, 0(SAVE0)
2294 |.else
2295 | lwz CARG4, 4(SAVE0)
2296 |.endif
2297 | bge cr1, ->fff_resn
2298 | checknum CARG3; bge >7
2299 |6:
2300 | addi SAVE0, SAVE0, 8
2301 |.if FPU
2302 |.if ismax
2303 | fsub f0, FARG1, FARG2
2304 |.else
2305 | fsub f0, FARG2, FARG1
2306 |.endif
2307 | fsel FARG1, f0, FARG1, FARG2
2308 |.else
2309 | stw CARG1, SFSAVE_1
2310 | stw CARG2, SFSAVE_2
2311 | stw CARG3, SFSAVE_3
2312 | stw CARG4, SFSAVE_4
2313 | blex __ledf2
2314 | cmpwi CRET1, 0
2315 |.if ismax
2316 | blt >8
2317 |.else
2318 | bge >8
2319 |.endif
2320 | lwz CARG1, SFSAVE_1
2321 | lwz CARG2, SFSAVE_2
2322 | b <5
2323 |8:
2324 | lwz CARG1, SFSAVE_3
2325 | lwz CARG2, SFSAVE_4
2326 |.endif
2327 | b <5
2328 |7: // Convert integer to number and continue above.
2329 | lwz CARG3, 4(SAVE0)
2330 | bne ->fff_fallback
2331 |.if FPU
2332 | tonum_i FARG2, CARG3
2333 |.else
2334 | bl ->vm_sfi2d_2
2335 |.endif
2336 | b <6
2337 |.else
2338 | .ffunc_n name
2339 | li TMP1, 8
2340 |1:
2341 | lwzx CARG2, BASE, TMP1
2342 | lfdx FARG2, BASE, TMP1
2343 | cmplw cr1, TMP1, NARGS8:RC
2344 | checknum CARG2
2345 | bge cr1, ->fff_resn
2346 | bge ->fff_fallback
2347 |.if ismax
2348 | fsub f0, FARG1, FARG2
2349 |.else
2350 | fsub f0, FARG2, FARG1
2351 |.endif
2352 | addi TMP1, TMP1, 8
2353 | fsel FARG1, f0, FARG1, FARG2
2354 | b <1
2355 |.endif
2356 |.endmacro
2357 |
2358 | math_minmax math_min, 0
2359 | math_minmax math_max, 1
2360 |
2361 |//-- String library -----------------------------------------------------
2362 |
2363 |.ffunc string_byte // Only handle the 1-arg case here.
2364 | cmplwi NARGS8:RC, 8
2365 | lwz CARG3, 0(BASE)
2366 | lwz STR:CARG1, 4(BASE)
2367 | bne ->fff_fallback // Need exactly 1 argument.
2368 | checkstr CARG3
2369 | bne ->fff_fallback
2370 | lwz TMP0, STR:CARG1->len
2371 |.if DUALNUM
2372 | lbz CARG1, STR:CARG1[1] // Access is always ok (NUL at end).
2373 | li RD, (0+1)*8
2374 | lwz PC, FRAME_PC(BASE)
2375 | cmplwi TMP0, 0
2376 | la RA, -8(BASE)
2377 | beqy ->fff_res
2378 | b ->fff_resi
2379 |.else
2380 | lbz TMP1, STR:CARG1[1] // Access is always ok (NUL at end).
2381 | addic TMP3, TMP0, -1 // RD = ((str->len != 0)+1)*8
2382 | subfe RD, TMP3, TMP0
2383 | stw TMP1, TONUM_LO // Inlined tonum_u f0, TMP1.
2384 | addi RD, RD, 1
2385 | lfd f0, TONUM_D
2386 | la RA, -8(BASE)
2387 | lwz PC, FRAME_PC(BASE)
2388 | fsub f0, f0, TOBIT
2389 | slwi RD, RD, 3
2390 | stfd f0, 0(RA)
2391 | b ->fff_res
2392 |.endif
2393 |
2394 |.ffunc string_char // Only handle the 1-arg case here.
2395 | ffgccheck
2396 | cmplwi NARGS8:RC, 8
2397 | lwz CARG3, 0(BASE)
2398 |.if DUALNUM
2399 | lwz TMP0, 4(BASE)
2400 | bne ->fff_fallback // Exactly 1 argument.
2401 | checknum CARG3; bne ->fff_fallback
2402 | la CARG2, 7(BASE)
2403 |.else
2404 | lfd FARG1, 0(BASE)
2405 | bne ->fff_fallback // Exactly 1 argument.
2406 | checknum CARG3; bge ->fff_fallback
2407 | toint TMP0, FARG1
2408 | la CARG2, TMPD_BLO
2409 |.endif
2410 | li CARG3, 1
2411 | cmplwi TMP0, 255; bgt ->fff_fallback
2412 |->fff_newstr:
2413 | mr CARG1, L
2414 | stp BASE, L->base
2415 | stw PC, SAVE_PC
2416 | bl extern lj_str_new // (lua_State *L, char *str, size_t l)
2417 |->fff_resstr:
2418 | // Returns GCstr *.
2419 | lp BASE, L->base
2420 | li CARG3, LJ_TSTR
2421 | b ->fff_restv
2422 |
2423 |.ffunc string_sub
2424 | ffgccheck
2425 | cmplwi NARGS8:RC, 16
2426 | lwz CARG3, 16(BASE)
2427 |.if not DUALNUM
2428 | lfd f0, 16(BASE)
2429 |.endif
2430 | lwz TMP0, 0(BASE)
2431 | lwz STR:CARG1, 4(BASE)
2432 | blt ->fff_fallback
2433 | lwz CARG2, 8(BASE)
2434 |.if DUALNUM
2435 | lwz TMP1, 12(BASE)
2436 |.else
2437 | lfd f1, 8(BASE)
2438 |.endif
2439 | li TMP2, -1
2440 | beq >1
2441 |.if DUALNUM
2442 | checknum CARG3
2443 | lwz TMP2, 20(BASE)
2444 | bne ->fff_fallback
2445 |1:
2446 | checknum CARG2; bne ->fff_fallback
2447 |.else
2448 | checknum CARG3; bge ->fff_fallback
2449 | toint TMP2, f0
2450 |1:
2451 | checknum CARG2; bge ->fff_fallback
2452 |.endif
2453 | checkstr TMP0; bne ->fff_fallback
2454 |.if not DUALNUM
2455 | toint TMP1, f1
2456 |.endif
2457 | lwz TMP0, STR:CARG1->len
2458 | cmplw TMP0, TMP2 // len < end? (unsigned compare)
2459 | addi TMP3, TMP2, 1
2460 | blt >5
2461 |2:
2462 | cmpwi TMP1, 0 // start <= 0?
2463 | add TMP3, TMP1, TMP0
2464 | ble >7
2465 |3:
2466 | sub CARG3, TMP2, TMP1
2467 | addi CARG2, STR:CARG1, #STR-1
2468 | srawi TMP0, CARG3, 31
2469 | addi CARG3, CARG3, 1
2470 | add CARG2, CARG2, TMP1
2471 | andc CARG3, CARG3, TMP0
2472 |.if GPR64
2473 | rldicl CARG2, CARG2, 0, 32
2474 | rldicl CARG3, CARG3, 0, 32
2475 |.endif
2476 | b ->fff_newstr
2477 |
2478 |5: // Negative end or overflow.
2479 | cmpw TMP0, TMP2 // len >= end? (signed compare)
2480 | add TMP2, TMP0, TMP3 // Negative end: end = end+len+1.
2481 | bge <2
2482 | mr TMP2, TMP0 // Overflow: end = len.
2483 | b <2
2484 |
2485 |7: // Negative start or underflow.
2486 | .gpr64 extsw TMP1, TMP1
2487 | addic CARG3, TMP1, -1
2488 | subfe CARG3, CARG3, CARG3
2489 | srawi CARG2, TMP3, 31 // Note: modifies carry.
2490 | andc TMP3, TMP3, CARG3
2491 | andc TMP1, TMP3, CARG2
2492 | addi TMP1, TMP1, 1 // start = 1 + (start ? start+len : 0)
2493 | b <3
2494 |
2495 |.macro ffstring_op, name
2496 | .ffunc string_ .. name
2497 | ffgccheck
2498 | cmplwi NARGS8:RC, 8
2499 | lwz CARG3, 0(BASE)
2500 | lwz STR:CARG2, 4(BASE)
2501 | blt ->fff_fallback
2502 | checkstr CARG3
2503 | la SBUF:CARG1, DISPATCH_GL(tmpbuf)(DISPATCH)
2504 | bne ->fff_fallback
2505 | lwz TMP0, SBUF:CARG1->b
2506 | stw L, SBUF:CARG1->L
2507 | stp BASE, L->base
2508 | stw PC, SAVE_PC
2509 | stw TMP0, SBUF:CARG1->w
2510 | bl extern lj_buf_putstr_ .. name
2511 | bl extern lj_buf_tostr
2512 | b ->fff_resstr
2513 |.endmacro
2514 |
2515 |ffstring_op reverse
2516 |ffstring_op lower
2517 |ffstring_op upper
2518 |
2519 |//-- Bit library --------------------------------------------------------
2520 |
2521 |.macro .ffunc_bit, name
2522 |.if DUALNUM
2523 | .ffunc_1 bit_..name
2524 | checknum CARG3; bnel ->fff_tobit_fb
2525 |.else
2526 | .ffunc_n bit_..name
2527 | fadd FARG1, FARG1, TOBIT
2528 | stfd FARG1, TMPD
2529 | lwz CARG1, TMPD_LO
2530 |.endif
2531 |.endmacro
2532 |
2533 |.macro .ffunc_bit_op, name, ins
2534 | .ffunc_bit name
2535 | addi SAVE0, BASE, 8
2536 | add SAVE1, BASE, NARGS8:RC
2537 |1:
2538 | lwz CARG4, 0(SAVE0)
2539 | cmplw cr1, SAVE0, SAVE1
2540 |.if DUALNUM
2541 | lwz CARG2, 4(SAVE0)
2542 |.else
2543 | lfd FARG1, 0(SAVE0)
2544 |.endif
2545 | bgey cr1, ->fff_resi
2546 | checknum CARG4
2547 |.if DUALNUM
2548 |.if FPU
2549 | bnel ->fff_bitop_fb
2550 |.else
2551 | beq >3
2552 | stw CARG1, SFSAVE_1
2553 | bl ->fff_bitop_fb
2554 | mr CARG2, CARG1
2555 | lwz CARG1, SFSAVE_1
2556 |3:
2557 |.endif
2558 |.else
2559 | fadd FARG1, FARG1, TOBIT
2560 | bge ->fff_fallback
2561 | stfd FARG1, TMPD
2562 | lwz CARG2, TMPD_LO
2563 |.endif
2564 | ins CARG1, CARG1, CARG2
2565 | addi SAVE0, SAVE0, 8
2566 | b <1
2567 |.endmacro
2568 |
2569 |.ffunc_bit_op band, and
2570 |.ffunc_bit_op bor, or
2571 |.ffunc_bit_op bxor, xor
2572 |
2573 |.ffunc_bit bswap
2574 | rotlwi TMP0, CARG1, 8
2575 | rlwimi TMP0, CARG1, 24, 0, 7
2576 | rlwimi TMP0, CARG1, 24, 16, 23
2577 | mr CRET1, TMP0
2578 | b ->fff_resi
2579 |
2580 |.ffunc_bit bnot
2581 | not CRET1, CARG1
2582 | b ->fff_resi
2583 |
2584 |.macro .ffunc_bit_sh, name, ins, shmod
2585 |.if DUALNUM
2586 | .ffunc_2 bit_..name
2587 |.if FPU
2588 | checknum CARG3; bnel ->fff_tobit_fb
2589 |.else
2590 | checknum CARG3; beq >1
2591 | bl ->fff_tobit_fb
2592 | lwz CARG2, 12(BASE) // Conversion polluted CARG2.
2593 |1:
2594 |.endif
2595 | // Note: no inline conversion from number for 2nd argument!
2596 | checknum CARG4; bne ->fff_fallback
2597 |.else
2598 | .ffunc_nn bit_..name
2599 | fadd FARG1, FARG1, TOBIT
2600 | fadd FARG2, FARG2, TOBIT
2601 | stfd FARG1, TMPD
2602 | lwz CARG1, TMPD_LO
2603 | stfd FARG2, TMPD
2604 | lwz CARG2, TMPD_LO
2605 |.endif
2606 |.if shmod == 1
2607 | rlwinm CARG2, CARG2, 0, 27, 31
2608 |.elif shmod == 2
2609 | neg CARG2, CARG2
2610 |.endif
2611 | ins CRET1, CARG1, CARG2
2612 | b ->fff_resi
2613 |.endmacro
2614 |
2615 |.ffunc_bit_sh lshift, slw, 1
2616 |.ffunc_bit_sh rshift, srw, 1
2617 |.ffunc_bit_sh arshift, sraw, 1
2618 |.ffunc_bit_sh rol, rotlw, 0
2619 |.ffunc_bit_sh ror, rotlw, 2
2620 |
2621 |.ffunc_bit tobit
2622 |.if DUALNUM
2623 | b ->fff_resi
2624 |.else
2625 |->fff_resi:
2626 | tonum_i FARG1, CRET1
2627 |.endif
2628 |->fff_resn:
2629 | lwz PC, FRAME_PC(BASE)
2630 | la RA, -8(BASE)
2631 |.if FPU
2632 | stfd FARG1, -8(BASE)
2633 |.else
2634 | stw CARG1, -8(BASE)
2635 | stw CARG2, -4(BASE)
2636 |.endif
2637 | b ->fff_res1
2638 |
2639 |// Fallback FP number to bit conversion.
2640 |->fff_tobit_fb:
2641 |.if DUALNUM
2642 |.if FPU
2643 | lfd FARG1, 0(BASE)
2644 | bgt ->fff_fallback
2645 | fadd FARG1, FARG1, TOBIT
2646 | stfd FARG1, TMPD
2647 | lwz CARG1, TMPD_LO
2648 | blr
2649 |.else
2650 | bgt ->fff_fallback
2651 | mr CARG2, CARG1
2652 | mr CARG1, CARG3
2653 |// Modifies: CARG1, CARG2, TMP0, TMP1, TMP2.
2654 |->vm_tobit:
2655 | slwi TMP2, CARG1, 1
2656 | addis TMP2, TMP2, 0x0020
2657 | cmpwi TMP2, 0
2658 | bge >2
2659 | li TMP1, 0x3e0
2660 | srawi TMP2, TMP2, 21
2661 | not TMP1, TMP1
2662 | sub. TMP2, TMP1, TMP2
2663 | cmpwi cr7, CARG1, 0
2664 | blt >1
2665 | slwi TMP1, CARG1, 11
2666 | srwi TMP0, CARG2, 21
2667 | oris TMP1, TMP1, 0x8000
2668 | or TMP1, TMP1, TMP0
2669 | srw CARG1, TMP1, TMP2
2670 | bclr 4, 28 // Return if cr7[lt] == 0, no hint.
2671 | neg CARG1, CARG1
2672 | blr
2673 |1:
2674 | addi TMP2, TMP2, 21
2675 | srw TMP1, CARG2, TMP2
2676 | slwi CARG2, CARG1, 12
2677 | subfic TMP2, TMP2, 20
2678 | slw TMP0, CARG2, TMP2
2679 | or CARG1, TMP1, TMP0
2680 | bclr 4, 28 // Return if cr7[lt] == 0, no hint.
2681 | neg CARG1, CARG1
2682 | blr
2683 |2:
2684 | li CARG1, 0
2685 | blr
2686 |.endif
2687 |.endif
2688 |->fff_bitop_fb:
2689 |.if DUALNUM
2690 |.if FPU
2691 | lfd FARG1, 0(SAVE0)
2692 | bgt ->fff_fallback
2693 | fadd FARG1, FARG1, TOBIT
2694 | stfd FARG1, TMPD
2695 | lwz CARG2, TMPD_LO
2696 | blr
2697 |.else
2698 | bgt ->fff_fallback
2699 | mr CARG1, CARG4
2700 | b ->vm_tobit
2701 |.endif
2702 |.endif
2703 |
2704 |//-----------------------------------------------------------------------
2705 |
2706 |->fff_fallback: // Call fast function fallback handler.
2707 | // BASE = new base, RB = CFUNC, RC = nargs*8
2708 | lp TMP3, CFUNC:RB->f
2709 | add TMP1, BASE, NARGS8:RC
2710 | lwz PC, FRAME_PC(BASE) // Fallback may overwrite PC.
2711 | addi TMP0, TMP1, 8*LUA_MINSTACK
2712 | lwz TMP2, L->maxstack
2713 | stw PC, SAVE_PC // Redundant (but a defined value).
2714 | .toc lp TMP3, 0(TMP3)
2715 | cmplw TMP0, TMP2
2716 | stp BASE, L->base
2717 | stp TMP1, L->top
2718 | mr CARG1, L
2719 | bgt >5 // Need to grow stack.
2720 | mtctr TMP3
2721 | bctrl // (lua_State *L)
2722 | // Either throws an error, or recovers and returns -1, 0 or nresults+1.
2723 | lp BASE, L->base
2724 | cmpwi CRET1, 0
2725 | slwi RD, CRET1, 3
2726 | la RA, -8(BASE)
2727 | bgt ->fff_res // Returned nresults+1?
2728 |1: // Returned 0 or -1: retry fast path.
2729 | lp TMP0, L->top
2730 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2731 | sub NARGS8:RC, TMP0, BASE
2732 | bne ->vm_call_tail // Returned -1?
2733 | ins_callt // Returned 0: retry fast path.
2734 |
2735 |// Reconstruct previous base for vmeta_call during tailcall.
2736 |->vm_call_tail:
2737 | andix. TMP0, PC, FRAME_TYPE
2738 | rlwinm TMP1, PC, 0, 0, 28
2739 | bne >3
2740 | lwz INS, -4(PC)
2741 | decode_RA8 TMP1, INS
2742 | addi TMP1, TMP1, 8
2743 |3:
2744 | sub TMP2, BASE, TMP1
2745 | b ->vm_call_dispatch // Resolve again for tailcall.
2746 |
2747 |5: // Grow stack for fallback handler.
2748 | li CARG2, LUA_MINSTACK
2749 | bl extern lj_state_growstack // (lua_State *L, int n)
2750 | lp BASE, L->base
2751 | cmpw TMP0, TMP0 // Set 4*cr0+eq to force retry.
2752 | b <1
2753 |
2754 |->fff_gcstep: // Call GC step function.
2755 | // BASE = new base, RC = nargs*8
2756 | mflr SAVE0
2757 | stp BASE, L->base
2758 | add TMP0, BASE, NARGS8:RC
2759 | stw PC, SAVE_PC // Redundant (but a defined value).
2760 | stp TMP0, L->top
2761 | mr CARG1, L
2762 | bl extern lj_gc_step // (lua_State *L)
2763 | lp BASE, L->base
2764 | mtlr SAVE0
2765 | lp TMP0, L->top
2766 | sub NARGS8:RC, TMP0, BASE
2767 | lwz CFUNC:RB, FRAME_FUNC(BASE)
2768 | blr
2769 |
2770 |//-----------------------------------------------------------------------
2771 |//-- Special dispatch targets -------------------------------------------
2772 |//-----------------------------------------------------------------------
2773 |
2774 |->vm_record: // Dispatch target for recording phase.
2775 |.if JIT
2776 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
2777 | andix. TMP0, TMP3, HOOK_VMEVENT // No recording while in vmevent.
2778 | bne >5
2779 | // Decrement the hookcount for consistency, but always do the call.
2780 | lwz TMP2, DISPATCH_GL(hookcount)(DISPATCH)
2781 | andix. TMP0, TMP3, HOOK_ACTIVE
2782 | bne >1
2783 | subi TMP2, TMP2, 1
2784 | andi. TMP0, TMP3, LUA_MASKLINE|LUA_MASKCOUNT
2785 | beqy >1
2786 | stw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
2787 | b >1
2788 |.endif
2789 |
2790 |->vm_rethook: // Dispatch target for return hooks.
2791 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
2792 | andix. TMP0, TMP3, HOOK_ACTIVE // Hook already active?
2793 | beq >1
2794 |5: // Re-dispatch to static ins.
2795 | addi TMP1, TMP1, GG_DISP2STATIC // Assumes decode_OPP TMP1, INS.
2796 | lpx TMP0, DISPATCH, TMP1
2797 | mtctr TMP0
2798 | bctr
2799 |
2800 |->vm_inshook: // Dispatch target for instr/line hooks.
2801 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
2802 | lwz TMP2, DISPATCH_GL(hookcount)(DISPATCH)
2803 | andix. TMP0, TMP3, HOOK_ACTIVE // Hook already active?
2804 | rlwinm TMP0, TMP3, 31-LUA_HOOKLINE, 31, 0
2805 | bne <5
2806 |
2807 | cmpwi cr1, TMP0, 0
2808 | addic. TMP2, TMP2, -1
2809 | beq cr1, <5
2810 | stw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
2811 | beq >1
2812 | bge cr1, <5
2813 |1:
2814 | mr CARG1, L
2815 | stw MULTRES, SAVE_MULTRES
2816 | mr CARG2, PC
2817 | stp BASE, L->base
2818 | // SAVE_PC must hold the _previous_ PC. The callee updates it with PC.
2819 | bl extern lj_dispatch_ins // (lua_State *L, const BCIns *pc)
2820 |3:
2821 | lp BASE, L->base
2822 |4: // Re-dispatch to static ins.
2823 | lwz INS, -4(PC)
2824 | decode_OPP TMP1, INS
2825 | decode_RB8 RB, INS
2826 | addi TMP1, TMP1, GG_DISP2STATIC
2827 | decode_RD8 RD, INS
2828 | lpx TMP0, DISPATCH, TMP1
2829 | decode_RA8 RA, INS
2830 | decode_RC8 RC, INS
2831 | mtctr TMP0
2832 | bctr
2833 |
2834 |->cont_hook: // Continue from hook yield.
2835 | addi PC, PC, 4
2836 | lwz MULTRES, -20(RB) // Restore MULTRES for *M ins.
2837 | b <4
2838 |
2839 |->vm_hotloop: // Hot loop counter underflow.
2840 |.if JIT
2841 | lwz LFUNC:TMP1, FRAME_FUNC(BASE)
2842 | addi CARG1, DISPATCH, GG_DISP2J
2843 | stw PC, SAVE_PC
2844 | lwz TMP1, LFUNC:TMP1->pc
2845 | mr CARG2, PC
2846 | stw L, DISPATCH_J(L)(DISPATCH)
2847 | lbz TMP1, PC2PROTO(framesize)(TMP1)
2848 | stp BASE, L->base
2849 | slwi TMP1, TMP1, 3
2850 | add TMP1, BASE, TMP1
2851 | stp TMP1, L->top
2852 | bl extern lj_trace_hot // (jit_State *J, const BCIns *pc)
2853 | b <3
2854 |.endif
2855 |
2856 |->vm_callhook: // Dispatch target for call hooks.
2857 | mr CARG2, PC
2858 |.if JIT
2859 | b >1
2860 |.endif
2861 |
2862 |->vm_hotcall: // Hot call counter underflow.
2863 |.if JIT
2864 | ori CARG2, PC, 1
2865 |1:
2866 |.endif
2867 | add TMP0, BASE, RC
2868 | stw PC, SAVE_PC
2869 | mr CARG1, L
2870 | stp BASE, L->base
2871 | sub RA, RA, BASE
2872 | stp TMP0, L->top
2873 | bl extern lj_dispatch_call // (lua_State *L, const BCIns *pc)
2874 | // Returns ASMFunction.
2875 | lp BASE, L->base
2876 | lp TMP0, L->top
2877 | stw ZERO, SAVE_PC // Invalidate for subsequent line hook.
2878 | sub NARGS8:RC, TMP0, BASE
2879 | add RA, BASE, RA
2880 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2881 | lwz INS, -4(PC)
2882 | mtctr CRET1
2883 | bctr
2884 |
2885 |->cont_stitch: // Trace stitching.
2886 |.if JIT
2887 | // RA = resultptr, RB = meta base
2888 | lwz INS, -4(PC)
2889 | lwz TRACE:TMP2, -20(RB) // Save previous trace.
2890 | addic. TMP1, MULTRES, -8
2891 | decode_RA8 RC, INS // Call base.
2892 | beq >2
2893 |1: // Move results down.
2894 |.if FPU
2895 | lfd f0, 0(RA)
2896 |.else
2897 | lwz CARG1, 0(RA)
2898 | lwz CARG2, 4(RA)
2899 |.endif
2900 | addic. TMP1, TMP1, -8
2901 | addi RA, RA, 8
2902 |.if FPU
2903 | stfdx f0, BASE, RC
2904 |.else
2905 | add CARG3, BASE, RC
2906 | stw CARG1, 0(CARG3)
2907 | stw CARG2, 4(CARG3)
2908 |.endif
2909 | addi RC, RC, 8
2910 | bne <1
2911 |2:
2912 | decode_RA8 RA, INS
2913 | decode_RB8 RB, INS
2914 | add RA, RA, RB
2915 |3:
2916 | cmplw RA, RC
2917 | bgt >9 // More results wanted?
2918 |
2919 | lhz TMP3, TRACE:TMP2->traceno
2920 | lhz RD, TRACE:TMP2->link
2921 | cmpw RD, TMP3
2922 | cmpwi cr1, RD, 0
2923 | beq ->cont_nop // Blacklisted.
2924 | slwi RD, RD, 3
2925 | bne cr1, =>BC_JLOOP // Jump to stitched trace.
2926 |
2927 | // Stitch a new trace to the previous trace.
2928 | stw TMP3, DISPATCH_J(exitno)(DISPATCH)
2929 | stp L, DISPATCH_J(L)(DISPATCH)
2930 | stp BASE, L->base
2931 | addi CARG1, DISPATCH, GG_DISP2J
2932 | mr CARG2, PC
2933 | bl extern lj_dispatch_stitch // (jit_State *J, const BCIns *pc)
2934 | lp BASE, L->base
2935 | b ->cont_nop
2936 |
2937 |9:
2938 | stwx TISNIL, BASE, RC
2939 | addi RC, RC, 8
2940 | b <3
2941 |.endif
2942 |
2943 |->vm_profhook: // Dispatch target for profiler hook.
2944 #if LJ_HASPROFILE
2945 | mr CARG1, L
2946 | stw MULTRES, SAVE_MULTRES
2947 | mr CARG2, PC
2948 | stp BASE, L->base
2949 | bl extern lj_dispatch_profile // (lua_State *L, const BCIns *pc)
2950 | // HOOK_PROFILE is off again, so re-dispatch to dynamic instruction.
2951 | lp BASE, L->base
2952 | subi PC, PC, 4
2953 | b ->cont_nop
2954 #endif
2955 |
2956 |//-----------------------------------------------------------------------
2957 |//-- Trace exit handler -------------------------------------------------
2958 |//-----------------------------------------------------------------------
2959 |
2960 |.macro savex_, a, b, c, d
2961 |.if FPU
2962 | stfd f..a, 16+a*8(sp)
2963 | stfd f..b, 16+b*8(sp)
2964 | stfd f..c, 16+c*8(sp)
2965 | stfd f..d, 16+d*8(sp)
2966 |.endif
2967 |.endmacro
2968 |
2969 |->vm_exit_handler:
2970 |.if JIT
2971 | addi sp, sp, -(16+32*8+32*4)
2972 | stmw r2, 16+32*8+2*4(sp)
2973 | addi DISPATCH, JGL, -GG_DISP2G-32768
2974 | li CARG2, ~LJ_VMST_EXIT
2975 | lwz CARG1, 16+32*8+32*4(sp) // Get stack chain.
2976 | stw CARG2, DISPATCH_GL(vmstate)(DISPATCH)
2977 | savex_ 0,1,2,3
2978 | stw CARG1, 0(sp) // Store extended stack chain.
2979 | clrso TMP1
2980 | savex_ 4,5,6,7
2981 | addi CARG2, sp, 16+32*8+32*4 // Recompute original value of sp.
2982 | savex_ 8,9,10,11
2983 | stw CARG2, 16+32*8+1*4(sp) // Store sp in RID_SP.
2984 | savex_ 12,13,14,15
2985 | mflr CARG3
2986 | li TMP1, 0
2987 | savex_ 16,17,18,19
2988 | stw TMP1, 16+32*8+0*4(sp) // Clear RID_TMP.
2989 | savex_ 20,21,22,23
2990 | lhz CARG4, 2(CARG3) // Load trace number.
2991 | savex_ 24,25,26,27
2992 | lwz L, DISPATCH_GL(cur_L)(DISPATCH)
2993 | savex_ 28,29,30,31
2994 | sub CARG3, TMP0, CARG3 // Compute exit number.
2995 | lp BASE, DISPATCH_GL(jit_base)(DISPATCH)
2996 | srwi CARG3, CARG3, 2
2997 | stp L, DISPATCH_J(L)(DISPATCH)
2998 | subi CARG3, CARG3, 2
2999 | stp BASE, L->base
3000 | stw CARG4, DISPATCH_J(parent)(DISPATCH)
3001 | stw TMP1, DISPATCH_GL(jit_base)(DISPATCH)
3002 | addi CARG1, DISPATCH, GG_DISP2J
3003 | stw CARG3, DISPATCH_J(exitno)(DISPATCH)
3004 | addi CARG2, sp, 16
3005 | bl extern lj_trace_exit // (jit_State *J, ExitState *ex)
3006 | // Returns MULTRES (unscaled) or negated error code.
3007 | lp TMP1, L->cframe
3008 | lwz TMP2, 0(sp)
3009 | lp BASE, L->base
3010 |.if GPR64
3011 | rldicr sp, TMP1, 0, 61
3012 |.else
3013 | rlwinm sp, TMP1, 0, 0, 29
3014 |.endif
3015 | lwz PC, SAVE_PC // Get SAVE_PC.
3016 | stw TMP2, 0(sp)
3017 | stw L, SAVE_L // Set SAVE_L (on-trace resume/yield).
3018 | b >1
3019 |.endif
3020 |->vm_exit_interp:
3021 |.if JIT
3022 | // CARG1 = MULTRES or negated error code, BASE, PC and JGL set.
3023 | lwz L, SAVE_L
3024 | addi DISPATCH, JGL, -GG_DISP2G-32768
3025 | stp BASE, L->base
3026 |1:
3027 | li TMP2, -LUA_ERRERR
3028 | cmplw CARG1, TMP2
3029 | bge >9 // Check for error from exit.
3030 | lwz LFUNC:RB, FRAME_FUNC(BASE)
3031 | slwi MULTRES, CARG1, 3
3032 | li TMP2, 0
3033 | stw MULTRES, SAVE_MULTRES
3034 | lwz TMP1, LFUNC:RB->pc
3035 | stw TMP2, DISPATCH_GL(jit_base)(DISPATCH)
3036 | lwz KBASE, PC2PROTO(k)(TMP1)
3037 | // Setup type comparison constants.
3038 | li TISNUM, LJ_TISNUM
3039 | .FPU lus TMP3, 0x59c0 // TOBIT = 2^52 + 2^51 (float).
3040 | .FPU stw TMP3, TMPD
3041 | li ZERO, 0
3042 | .FPU ori TMP3, TMP3, 0x0004 // TONUM = 2^52 + 2^51 + 2^31 (float).
3043 | .FPU lfs TOBIT, TMPD
3044 | .FPU stw TMP3, TMPD
3045 | .FPU lus TMP0, 0x4338 // Hiword of 2^52 + 2^51 (double)
3046 | li TISNIL, LJ_TNIL
3047 | .FPU stw TMP0, TONUM_HI
3048 | .FPU lfs TONUM, TMPD
3049 | // Modified copy of ins_next which handles function header dispatch, too.
3050 | lwz INS, 0(PC)
3051 | addi PC, PC, 4
3052 | // Assumes TISNIL == ~LJ_VMST_INTERP == -1.
3053 | stw TISNIL, DISPATCH_GL(vmstate)(DISPATCH)
3054 | cmpwi CARG1, -17 // Static dispatch?
3055 | beq >5
3056 | decode_OPP TMP1, INS
3057 | decode_RA8 RA, INS
3058 | lpx TMP0, DISPATCH, TMP1
3059 | mtctr TMP0
3060 | cmplwi TMP1, BC_FUNCF*4 // Function header?
3061 | bge >2
3062 | decode_RB8 RB, INS
3063 | decode_RD8 RD, INS
3064 | decode_RC8 RC, INS
3065 | bctr
3066 |2:
3067 | cmplwi TMP1, (BC_FUNCC+2)*4 // Fast function?
3068 | blt >3
3069 | // Check frame below fast function.
3070 | lwz TMP1, FRAME_PC(BASE)
3071 | andix. TMP0, TMP1, FRAME_TYPE
3072 | bney >3 // Trace stitching continuation?
3073 | // Otherwise set KBASE for Lua function below fast function.
3074 | lwz TMP2, -4(TMP1)
3075 | decode_RA8 TMP0, TMP2
3076 | sub TMP1, BASE, TMP0
3077 | lwz LFUNC:TMP2, -12(TMP1)
3078 | lwz TMP1, LFUNC:TMP2->pc
3079 | lwz KBASE, PC2PROTO(k)(TMP1)
3080 |3:
3081 | subi RC, MULTRES, 8
3082 | add RA, RA, BASE
3083 | bctr
3084 |
3085 |5: // Dispatch to static entry of original ins replaced by BC_JLOOP.
3086 | lwz TMP1, DISPATCH_J(trace)(DISPATCH)
3087 | decode_RD4 RD, INS
3088 | lwzx TRACE:TMP1, TMP1, RD
3089 | lwz INS, TRACE:TMP1->startins
3090 | decode_OPP TMP1, INS
3091 | addi TMP1, TMP1, GG_DISP2STATIC
3092 | lpx TMP0, DISPATCH, TMP1
3093 | mtctr TMP0
3094 | decode_RB8 RB, INS
3095 | decode_RD8 RD, INS
3096 | decode_RA8 RA, INS
3097 | decode_RC8 RC, INS
3098 | bctr
3099 |
3100 |9: // Rethrow error from the right C frame.
3101 | neg CARG2, CARG1
3102 | mr CARG1, L
3103 | bl extern lj_err_trace // (lua_State *L, int errcode)
3104 |.endif
3105 |
3106 |//-----------------------------------------------------------------------
3107 |//-- Math helper functions ----------------------------------------------
3108 |//-----------------------------------------------------------------------
3109 |
3110 |// NYI: Use internal implementations of floor, ceil, trunc, sfcmp.
3111 |
3112 |.macro sfi2d, AHI, ALO
3113 |.if not FPU
3114 | mr. AHI, ALO
3115 | bclr 12, 2 // Handle zero first.
3116 | srawi TMP0, ALO, 31
3117 | xor TMP1, ALO, TMP0
3118 | sub TMP1, TMP1, TMP0 // Absolute value in TMP1.
3119 | cntlzw AHI, TMP1
3120 | andix. TMP0, TMP0, 0x800 // Mask sign bit.
3121 | slw TMP1, TMP1, AHI // Align mantissa left with leading 1.
3122 | subfic AHI, AHI, 0x3ff+31-1 // Exponent -1 in AHI.
3123 | slwi ALO, TMP1, 21
3124 | or AHI, AHI, TMP0 // Sign | Exponent.
3125 | srwi TMP1, TMP1, 11
3126 | slwi AHI, AHI, 20 // Align left.
3127 | add AHI, AHI, TMP1 // Add mantissa, increment exponent.
3128 | blr
3129 |.endif
3130 |.endmacro
3131 |
3132 |// Input: CARG2. Output: CARG1, CARG2. Temporaries: TMP0, TMP1.
3133 |->vm_sfi2d_1:
3134 | sfi2d CARG1, CARG2
3135 |
3136 |// Input: CARG4. Output: CARG3, CARG4. Temporaries: TMP0, TMP1.
3137 |->vm_sfi2d_2:
3138 | sfi2d CARG3, CARG4
3139 |
3140 |->vm_modi:
3141 | divwo. TMP0, CARG1, CARG2
3142 | bso >1
3143 |.if GPR64
3144 | xor CARG3, CARG1, CARG2
3145 | cmpwi CARG3, 0
3146 |.else
3147 | xor. CARG3, CARG1, CARG2
3148 |.endif
3149 | mullw TMP0, TMP0, CARG2
3150 | sub CARG1, CARG1, TMP0
3151 | bgelr
3152 | cmpwi CARG1, 0; beqlr
3153 | add CARG1, CARG1, CARG2
3154 | blr
3155 |1:
3156 | cmpwi CARG2, 0
3157 | li CARG1, 0
3158 | beqlr
3159 | clrso TMP0 // Clear SO for -2147483648 % -1 and return 0.
3160 | blr
3161 |
3162 |//-----------------------------------------------------------------------
3163 |//-- Miscellaneous functions --------------------------------------------
3164 |//-----------------------------------------------------------------------
3165 |
3166 |// void lj_vm_cachesync(void *start, void *end)
3167 |// Flush D-Cache and invalidate I-Cache. Assumes 32 byte cache line size.
3168 |// This is a good lower bound, except for very ancient PPC models.
3169 |->vm_cachesync:
3170 |.if JIT or FFI
3171 | // Compute start of first cache line and number of cache lines.
3172 | rlwinm CARG1, CARG1, 0, 0, 26
3173 | sub CARG2, CARG2, CARG1
3174 | addi CARG2, CARG2, 31
3175 | rlwinm. CARG2, CARG2, 27, 5, 31
3176 | beqlr
3177 | mtctr CARG2
3178 | mr CARG3, CARG1
3179 |1: // Flush D-Cache.
3180 | dcbst r0, CARG1
3181 | addi CARG1, CARG1, 32
3182 | bdnz <1
3183 | sync
3184 | mtctr CARG2
3185 |1: // Invalidate I-Cache.
3186 | icbi r0, CARG3
3187 | addi CARG3, CARG3, 32
3188 | bdnz <1
3189 | isync
3190 | blr
3191 |.endif
3192 |
3193 |->vm_next:
3194 |.if JIT
3195 | NYI // On big-endian.
3196 |.endif
3197 |
3198 |//-----------------------------------------------------------------------
3199 |//-- FFI helper functions -----------------------------------------------
3200 |//-----------------------------------------------------------------------
3201 |
3202 |// Handler for callback functions. Callback slot number in r11, g in r12.
3203 |->vm_ffi_callback:
3204 |.if FFI
3205 |.type CTSTATE, CTState, PC
3206 | saveregs
3207 | lwz CTSTATE, GL:r12->ctype_state
3208 | addi DISPATCH, r12, GG_G2DISP
3209 | stw r11, CTSTATE->cb.slot
3210 | stw r3, CTSTATE->cb.gpr[0]
3211 | .FPU stfd f1, CTSTATE->cb.fpr[0]
3212 | stw r4, CTSTATE->cb.gpr[1]
3213 | .FPU stfd f2, CTSTATE->cb.fpr[1]
3214 | stw r5, CTSTATE->cb.gpr[2]
3215 | .FPU stfd f3, CTSTATE->cb.fpr[2]
3216 | stw r6, CTSTATE->cb.gpr[3]
3217 | .FPU stfd f4, CTSTATE->cb.fpr[3]
3218 | stw r7, CTSTATE->cb.gpr[4]
3219 | .FPU stfd f5, CTSTATE->cb.fpr[4]
3220 | stw r8, CTSTATE->cb.gpr[5]
3221 | .FPU stfd f6, CTSTATE->cb.fpr[5]
3222 | stw r9, CTSTATE->cb.gpr[6]
3223 | .FPU stfd f7, CTSTATE->cb.fpr[6]
3224 | stw r10, CTSTATE->cb.gpr[7]
3225 | .FPU stfd f8, CTSTATE->cb.fpr[7]
3226 | addi TMP0, sp, CFRAME_SPACE+8
3227 | stw TMP0, CTSTATE->cb.stack
3228 | mr CARG1, CTSTATE
3229 | stw CTSTATE, SAVE_PC // Any value outside of bytecode is ok.
3230 | mr CARG2, sp
3231 | bl extern lj_ccallback_enter // (CTState *cts, void *cf)
3232 | // Returns lua_State *.
3233 | lp BASE, L:CRET1->base
3234 | li TISNUM, LJ_TISNUM // Setup type comparison constants.
3235 | lp RC, L:CRET1->top
3236 | .FPU lus TMP3, 0x59c0 // TOBIT = 2^52 + 2^51 (float).
3237 | li ZERO, 0
3238 | mr L, CRET1
3239 | .FPU stw TMP3, TMPD
3240 | .FPU lus TMP0, 0x4338 // Hiword of 2^52 + 2^51 (double)
3241 | lwz LFUNC:RB, FRAME_FUNC(BASE)
3242 | .FPU ori TMP3, TMP3, 0x0004 // TONUM = 2^52 + 2^51 + 2^31 (float).
3243 | .FPU stw TMP0, TONUM_HI
3244 | li TISNIL, LJ_TNIL
3245 | li_vmstate INTERP
3246 | .FPU lfs TOBIT, TMPD
3247 | .FPU stw TMP3, TMPD
3248 | sub RC, RC, BASE
3249 | st_vmstate
3250 | .FPU lfs TONUM, TMPD
3251 | ins_callt
3252 |.endif
3253 |
3254 |->cont_ffi_callback: // Return from FFI callback.
3255 |.if FFI
3256 | lwz CTSTATE, DISPATCH_GL(ctype_state)(DISPATCH)
3257 | stp BASE, L->base
3258 | stp RB, L->top
3259 | stp L, CTSTATE->L
3260 | mr CARG1, CTSTATE
3261 | mr CARG2, RA
3262 | bl extern lj_ccallback_leave // (CTState *cts, TValue *o)
3263 | lwz CRET1, CTSTATE->cb.gpr[0]
3264 | .FPU lfd FARG1, CTSTATE->cb.fpr[0]
3265 | lwz CRET2, CTSTATE->cb.gpr[1]
3266 | b ->vm_leave_unw
3267 |.endif
3268 |
3269 |->vm_ffi_call: // Call C function via FFI.
3270 | // Caveat: needs special frame unwinding, see below.
3271 |.if FFI
3272 | .type CCSTATE, CCallState, CARG1
3273 | lwz TMP1, CCSTATE->spadj
3274 | mflr TMP0
3275 | lbz CARG2, CCSTATE->nsp
3276 | lbz CARG3, CCSTATE->nfpr
3277 | neg TMP1, TMP1
3278 | stw TMP0, 4(sp)
3279 | cmpwi cr1, CARG3, 0
3280 | mr TMP2, sp
3281 | addic. CARG2, CARG2, -4
3282 | stwux sp, sp, TMP1
3283 | crnot 4*cr1+eq, 4*cr1+eq // For vararg calls.
3284 | stw r14, -4(TMP2)
3285 | stw CCSTATE, -8(TMP2)
3286 | mr r14, TMP2
3287 | la TMP1, CCSTATE->stack
3288 | blty >2
3289 | la TMP2, 8(sp)
3290 |1:
3291 | lwzx TMP0, TMP1, CARG2
3292 | stwx TMP0, TMP2, CARG2
3293 | addic. CARG2, CARG2, -4
3294 | bge <1
3295 |2:
3296 | bney cr1, >3
3297 | .FPU lfd f1, CCSTATE->fpr[0]
3298 | .FPU lfd f2, CCSTATE->fpr[1]
3299 | .FPU lfd f3, CCSTATE->fpr[2]
3300 | .FPU lfd f4, CCSTATE->fpr[3]
3301 | .FPU lfd f5, CCSTATE->fpr[4]
3302 | .FPU lfd f6, CCSTATE->fpr[5]
3303 | .FPU lfd f7, CCSTATE->fpr[6]
3304 | .FPU lfd f8, CCSTATE->fpr[7]
3305 |3:
3306 | lp TMP0, CCSTATE->func
3307 | lwz CARG2, CCSTATE->gpr[1]
3308 | lwz CARG3, CCSTATE->gpr[2]
3309 | lwz CARG4, CCSTATE->gpr[3]
3310 | lwz CARG5, CCSTATE->gpr[4]
3311 | mtctr TMP0
3312 | lwz r8, CCSTATE->gpr[5]
3313 | lwz r9, CCSTATE->gpr[6]
3314 | lwz r10, CCSTATE->gpr[7]
3315 | lwz CARG1, CCSTATE->gpr[0] // Do this last, since CCSTATE is CARG1.
3316 | bctrl
3317 | lwz CCSTATE:TMP1, -8(r14)
3318 | lwz TMP2, -4(r14)
3319 | lwz TMP0, 4(r14)
3320 | stw CARG1, CCSTATE:TMP1->gpr[0]
3321 | .FPU stfd FARG1, CCSTATE:TMP1->fpr[0]
3322 | stw CARG2, CCSTATE:TMP1->gpr[1]
3323 | mtlr TMP0
3324 | stw CARG3, CCSTATE:TMP1->gpr[2]
3325 | mr sp, r14
3326 | stw CARG4, CCSTATE:TMP1->gpr[3]
3327 | mr r14, TMP2
3328 | blr
3329 |.endif
3330 |// Note: vm_ffi_call must be the last function in this object file!
3331 |
3332 |//-----------------------------------------------------------------------
3333 }
3335 /* Generate the code for a single instruction. */
3336 static void build_ins(BuildCtx *ctx, BCOp op, int defop)
3337 {
3338 int vk = 0;
3339 |=>defop:
3341 switch (op) {
3343 /* -- Comparison ops ---------------------------------------------------- */
3345 /* Remember: all ops branch for a true comparison, fall through otherwise. */
3347 case BC_ISLT: case BC_ISGE: case BC_ISLE: case BC_ISGT:
3348 | // RA = src1*8, RD = src2*8, JMP with RD = target
3349 |.if DUALNUM
3350 | lwzux CARG1, RA, BASE
3351 | addi PC, PC, 4
3352 | lwz CARG2, 4(RA)
3353 | lwzux CARG3, RD, BASE
3354 | lwz TMP2, -4(PC)
3355 | checknum cr0, CARG1
3356 | lwz CARG4, 4(RD)
3357 | decode_RD4 TMP2, TMP2
3358 | checknum cr1, CARG3
3359 | addis SAVE0, TMP2, -(BCBIAS_J*4 >> 16)
3360 | bne cr0, >7
3361 | bne cr1, >8
3362 | cmpw CARG2, CARG4
3363 if (op == BC_ISLT) {
3364 | bge >2
3365 } else if (op == BC_ISGE) {
3366 | blt >2
3367 } else if (op == BC_ISLE) {
3368 | bgt >2
3369 } else {
3370 | ble >2
3371 }
3372 |1:
3373 | add PC, PC, SAVE0
3374 |2:
3375 | ins_next
3376 |
3377 |7: // RA is not an integer.
3378 | bgt cr0, ->vmeta_comp
3379 | // RA is a number.
3380 | .FPU lfd f0, 0(RA)
3381 | bgt cr1, ->vmeta_comp
3382 | blt cr1, >4
3383 | // RA is a number, RD is an integer.
3384 |.if FPU
3385 | tonum_i f1, CARG4
3386 |.else
3387 | bl ->vm_sfi2d_2
3388 |.endif
3389 | b >5
3390 |
3391 |8: // RA is an integer, RD is not an integer.
3392 | bgt cr1, ->vmeta_comp
3393 | // RA is an integer, RD is a number.
3394 |.if FPU
3395 | tonum_i f0, CARG2
3396 |.else
3397 | bl ->vm_sfi2d_1
3398 |.endif
3399 |4:
3400 | .FPU lfd f1, 0(RD)
3401 |5:
3402 |.if FPU
3403 | fcmpu cr0, f0, f1
3404 |.else
3405 | blex __ledf2
3406 | cmpwi CRET1, 0
3407 |.endif
3408 if (op == BC_ISLT) {
3409 | bge <2
3410 } else if (op == BC_ISGE) {
3411 | blt <2
3412 } else if (op == BC_ISLE) {
3413 | cror 4*cr0+lt, 4*cr0+lt, 4*cr0+eq
3414 | bge <2
3415 } else {
3416 | cror 4*cr0+lt, 4*cr0+lt, 4*cr0+eq
3417 | blt <2
3418 }
3419 | b <1
3420 |.else
3421 | lwzx TMP0, BASE, RA
3422 | addi PC, PC, 4
3423 | lfdx f0, BASE, RA
3424 | lwzx TMP1, BASE, RD
3425 | checknum cr0, TMP0
3426 | lwz TMP2, -4(PC)
3427 | lfdx f1, BASE, RD
3428 | checknum cr1, TMP1
3429 | decode_RD4 TMP2, TMP2
3430 | bge cr0, ->vmeta_comp
3431 | addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
3432 | bge cr1, ->vmeta_comp
3433 | fcmpu cr0, f0, f1
3434 if (op == BC_ISLT) {
3435 | bge >1
3436 } else if (op == BC_ISGE) {
3437 | blt >1
3438 } else if (op == BC_ISLE) {
3439 | cror 4*cr0+lt, 4*cr0+lt, 4*cr0+eq
3440 | bge >1
3441 } else {
3442 | cror 4*cr0+lt, 4*cr0+lt, 4*cr0+eq
3443 | blt >1
3444 }
3445 | add PC, PC, TMP2
3446 |1:
3447 | ins_next
3448 |.endif
3449 break;
3451 case BC_ISEQV: case BC_ISNEV:
3452 vk = op == BC_ISEQV;
3453 | // RA = src1*8, RD = src2*8, JMP with RD = target
3454 |.if DUALNUM
3455 | lwzux CARG1, RA, BASE
3456 | addi PC, PC, 4
3457 | lwz CARG2, 4(RA)
3458 | lwzux CARG3, RD, BASE
3459 | checknum cr0, CARG1
3460 | lwz SAVE0, -4(PC)
3461 | checknum cr1, CARG3
3462 | decode_RD4 SAVE0, SAVE0
3463 | lwz CARG4, 4(RD)
3464 | cror 4*cr7+gt, 4*cr0+gt, 4*cr1+gt
3465 | addis SAVE0, SAVE0, -(BCBIAS_J*4 >> 16)
3466 if (vk) {
3467 | ble cr7, ->BC_ISEQN_Z
3468 } else {
3469 | ble cr7, ->BC_ISNEN_Z
3470 }
3471 |.else
3472 | lwzux CARG1, RA, BASE
3473 | lwz SAVE0, 0(PC)
3474 | lfd f0, 0(RA)
3475 | addi PC, PC, 4
3476 | lwzux CARG3, RD, BASE
3477 | checknum cr0, CARG1
3478 | decode_RD4 SAVE0, SAVE0
3479 | lfd f1, 0(RD)
3480 | checknum cr1, CARG3
3481 | addis SAVE0, SAVE0, -(BCBIAS_J*4 >> 16)
3482 | bge cr0, >5
3483 | bge cr1, >5
3484 | fcmpu cr0, f0, f1
3485 if (vk) {
3486 | bne >1
3487 | add PC, PC, SAVE0
3488 } else {
3489 | beq >1
3490 | add PC, PC, SAVE0
3491 }
3492 |1:
3493 | ins_next
3494 |.endif
3495 |5: // Either or both types are not numbers.
3496 |.if not DUALNUM
3497 | lwz CARG2, 4(RA)
3498 | lwz CARG4, 4(RD)
3499 |.endif
3500 |.if FFI
3501 | cmpwi cr7, CARG1, LJ_TCDATA
3502 | cmpwi cr5, CARG3, LJ_TCDATA
3503 |.endif
3504 | not TMP2, CARG1
3505 | cmplw CARG1, CARG3
3506 | cmplwi cr1, TMP2, ~LJ_TISPRI // Primitive?
3507 |.if FFI
3508 | cror 4*cr7+eq, 4*cr7+eq, 4*cr5+eq
3509 |.endif
3510 | cmplwi cr6, TMP2, ~LJ_TISTABUD // Table or userdata?
3511 |.if FFI
3512 | beq cr7, ->vmeta_equal_cd
3513 |.endif
3514 | cmplw cr5, CARG2, CARG4
3515 | crandc 4*cr0+gt, 4*cr0+eq, 4*cr1+gt // 2: Same type and primitive.
3516 | crorc 4*cr0+lt, 4*cr5+eq, 4*cr0+eq // 1: Same tv or different type.
3517 | crand 4*cr0+eq, 4*cr0+eq, 4*cr5+eq // 0: Same type and same tv.
3518 | mr SAVE1, PC
3519 | cror 4*cr0+eq, 4*cr0+eq, 4*cr0+gt // 0 or 2.
3520 | cror 4*cr0+lt, 4*cr0+lt, 4*cr0+gt // 1 or 2.
3521 if (vk) {
3522 | bne cr0, >6
3523 | add PC, PC, SAVE0
3524 |6:
3525 } else {
3526 | beq cr0, >6
3527 | add PC, PC, SAVE0
3528 |6:
3529 }
3530 |.if DUALNUM
3531 | bge cr0, >2 // Done if 1 or 2.
3532 |1:
3533 | ins_next
3534 |2:
3535 |.else
3536 | blt cr0, <1 // Done if 1 or 2.
3537 |.endif
3538 | blt cr6, <1 // Done if not tab/ud.
3539 |
3540 | // Different tables or userdatas. Need to check __eq metamethod.
3541 | // Field metatable must be at same offset for GCtab and GCudata!
3542 | mr CARG3, CARG4
3543 | lwz TAB:TMP2, TAB:CARG2->metatable
3544 | li CARG4, 1-vk // ne = 0 or 1.
3545 | cmplwi TAB:TMP2, 0
3546 | beq <1 // No metatable?
3547 | lbz TMP2, TAB:TMP2->nomm
3548 | andix. TMP2, TMP2, 1<<MM_eq
3549 | bne <1 // Or 'no __eq' flag set?
3550 | mr PC, SAVE1 // Restore old PC.
3551 | b ->vmeta_equal // Handle __eq metamethod.
3552 break;
3554 case BC_ISEQS: case BC_ISNES:
3555 vk = op == BC_ISEQS;
3556 | // RA = src*8, RD = str_const*8 (~), JMP with RD = target
3557 | lwzux TMP0, RA, BASE
3558 | srwi RD, RD, 1
3559 | lwz STR:TMP3, 4(RA)
3560 | lwz TMP2, 0(PC)
3561 | subfic RD, RD, -4
3562 | addi PC, PC, 4
3563 |.if FFI
3564 | cmpwi TMP0, LJ_TCDATA
3565 |.endif
3566 | lwzx STR:TMP1, KBASE, RD // KBASE-4-str_const*4
3567 | .gpr64 extsw TMP0, TMP0
3568 | subfic TMP0, TMP0, LJ_TSTR
3569 |.if FFI
3570 | beq ->vmeta_equal_cd
3571 |.endif
3572 | sub TMP1, STR:TMP1, STR:TMP3
3573 | or TMP0, TMP0, TMP1
3574 | decode_RD4 TMP2, TMP2
3575 | subfic TMP0, TMP0, 0
3576 | addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
3577 | subfe TMP1, TMP1, TMP1
3578 if (vk) {
3579 | andc TMP2, TMP2, TMP1
3580 } else {
3581 | and TMP2, TMP2, TMP1
3582 }
3583 | add PC, PC, TMP2
3584 | ins_next
3585 break;
3587 case BC_ISEQN: case BC_ISNEN:
3588 vk = op == BC_ISEQN;
3589 | // RA = src*8, RD = num_const*8, JMP with RD = target
3590 |.if DUALNUM
3591 | lwzux CARG1, RA, BASE
3592 | addi PC, PC, 4
3593 | lwz CARG2, 4(RA)
3594 | lwzux CARG3, RD, KBASE
3595 | checknum cr0, CARG1
3596 | lwz SAVE0, -4(PC)
3597 | checknum cr1, CARG3
3598 | decode_RD4 SAVE0, SAVE0
3599 | lwz CARG4, 4(RD)
3600 | addis SAVE0, SAVE0, -(BCBIAS_J*4 >> 16)
3601 if (vk) {
3602 |->BC_ISEQN_Z:
3603 } else {
3604 |->BC_ISNEN_Z:
3605 }
3606 | bne cr0, >7
3607 | bne cr1, >8
3608 | cmpw CARG2, CARG4
3609 |4:
3610 |.else
3611 if (vk) {
3612 |->BC_ISEQN_Z: // Dummy label.
3613 } else {
3614 |->BC_ISNEN_Z: // Dummy label.
3615 }
3616 | lwzx CARG1, BASE, RA
3617 | addi PC, PC, 4
3618 | lfdx f0, BASE, RA
3619 | lwz SAVE0, -4(PC)
3620 | lfdx f1, KBASE, RD
3621 | decode_RD4 SAVE0, SAVE0
3622 | checknum CARG1
3623 | addis SAVE0, SAVE0, -(BCBIAS_J*4 >> 16)
3624 | bge >3
3625 | fcmpu cr0, f0, f1
3626 |.endif
3627 if (vk) {
3628 | bne >1
3629 | add PC, PC, SAVE0
3630 |1:
3631 |.if not FFI
3632 |3:
3633 |.endif
3634 } else {
3635 | beq >2
3636 |1:
3637 |.if not FFI
3638 |3:
3639 |.endif
3640 | add PC, PC, SAVE0
3641 |2:
3642 }
3643 | ins_next
3644 |.if FFI
3645 |3:
3646 | cmpwi CARG1, LJ_TCDATA
3647 | beq ->vmeta_equal_cd
3648 | b <1
3649 |.endif
3650 |.if DUALNUM
3651 |7: // RA is not an integer.
3652 | bge cr0, <3
3653 | // RA is a number.
3654 | .FPU lfd f0, 0(RA)
3655 | blt cr1, >1
3656 | // RA is a number, RD is an integer.
3657 |.if FPU
3658 | tonum_i f1, CARG4
3659 |.else
3660 | bl ->vm_sfi2d_2
3661 |.endif
3662 | b >2
3663 |
3664 |8: // RA is an integer, RD is a number.
3665 |.if FPU
3666 | tonum_i f0, CARG2
3667 |.else
3668 | bl ->vm_sfi2d_1
3669 |.endif
3670 |1:
3671 | .FPU lfd f1, 0(RD)
3672 |2:
3673 |.if FPU
3674 | fcmpu cr0, f0, f1
3675 |.else
3676 | blex __ledf2
3677 | cmpwi CRET1, 0
3678 |.endif
3679 | b <4
3680 |.endif
3681 break;
3683 case BC_ISEQP: case BC_ISNEP:
3684 vk = op == BC_ISEQP;
3685 | // RA = src*8, RD = primitive_type*8 (~), JMP with RD = target
3686 | lwzx TMP0, BASE, RA
3687 | srwi TMP1, RD, 3
3688 | lwz TMP2, 0(PC)
3689 | not TMP1, TMP1
3690 | addi PC, PC, 4
3691 |.if FFI
3692 | cmpwi TMP0, LJ_TCDATA
3693 |.endif
3694 | sub TMP0, TMP0, TMP1
3695 |.if FFI
3696 | beq ->vmeta_equal_cd
3697 |.endif
3698 | decode_RD4 TMP2, TMP2
3699 | .gpr64 extsw TMP0, TMP0
3700 | addic TMP0, TMP0, -1
3701 | addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
3702 | subfe TMP1, TMP1, TMP1
3703 if (vk) {
3704 | and TMP2, TMP2, TMP1
3705 } else {
3706 | andc TMP2, TMP2, TMP1
3707 }
3708 | add PC, PC, TMP2
3709 | ins_next
3710 break;
3712 /* -- Unary test and copy ops ------------------------------------------- */
3714 case BC_ISTC: case BC_ISFC: case BC_IST: case BC_ISF:
3715 | // RA = dst*8 or unused, RD = src*8, JMP with RD = target
3716 | lwzx TMP0, BASE, RD
3717 | lwz INS, 0(PC)
3718 | addi PC, PC, 4
3719 if (op == BC_IST || op == BC_ISF) {
3720 | .gpr64 extsw TMP0, TMP0
3721 | subfic TMP0, TMP0, LJ_TTRUE
3722 | decode_RD4 TMP2, INS
3723 | subfe TMP1, TMP1, TMP1
3724 | addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
3725 if (op == BC_IST) {
3726 | andc TMP2, TMP2, TMP1
3727 } else {
3728 | and TMP2, TMP2, TMP1
3729 }
3730 | add PC, PC, TMP2
3731 } else {
3732 | li TMP1, LJ_TFALSE
3733 |.if FPU
3734 | lfdx f0, BASE, RD
3735 |.else
3736 | lwzux CARG1, RD, BASE
3737 | lwz CARG2, 4(RD)
3738 |.endif
3739 | cmplw TMP0, TMP1
3740 if (op == BC_ISTC) {
3741 | bge >1
3742 } else {
3743 | blt >1
3744 }
3745 | addis PC, PC, -(BCBIAS_J*4 >> 16)
3746 | decode_RD4 TMP2, INS
3747 |.if FPU
3748 | stfdx f0, BASE, RA
3749 |.else
3750 | stwux CARG1, RA, BASE
3751 | stw CARG2, 4(RA)
3752 |.endif
3753 | add PC, PC, TMP2
3754 |1:
3755 }
3756 | ins_next
3757 break;
3759 case BC_ISTYPE:
3760 | // RA = src*8, RD = -type*8
3761 | lwzx TMP0, BASE, RA
3762 | srwi TMP1, RD, 3
3763 | ins_next1
3764 |.if not PPE and not GPR64
3765 | add. TMP0, TMP0, TMP1
3766 |.else
3767 | neg TMP1, TMP1
3768 | cmpw TMP0, TMP1
3769 |.endif
3770 | bne ->vmeta_istype
3771 | ins_next2
3772 break;
3773 case BC_ISNUM:
3774 | // RA = src*8, RD = -(TISNUM-1)*8
3775 | lwzx TMP0, BASE, RA
3776 | ins_next1
3777 | checknum TMP0
3778 | bge ->vmeta_istype
3779 | ins_next2
3780 break;
3782 /* -- Unary ops --------------------------------------------------------- */
3784 case BC_MOV:
3785 | // RA = dst*8, RD = src*8
3786 | ins_next1
3787 |.if FPU
3788 | lfdx f0, BASE, RD
3789 | stfdx f0, BASE, RA
3790 |.else
3791 | lwzux TMP0, RD, BASE
3792 | lwz TMP1, 4(RD)
3793 | stwux TMP0, RA, BASE
3794 | stw TMP1, 4(RA)
3795 |.endif
3796 | ins_next2
3797 break;
3798 case BC_NOT:
3799 | // RA = dst*8, RD = src*8
3800 | ins_next1
3801 | lwzx TMP0, BASE, RD
3802 | .gpr64 extsw TMP0, TMP0
3803 | subfic TMP1, TMP0, LJ_TTRUE
3804 | adde TMP0, TMP0, TMP1
3805 | stwx TMP0, BASE, RA
3806 | ins_next2
3807 break;
3808 case BC_UNM:
3809 | // RA = dst*8, RD = src*8
3810 | lwzux TMP1, RD, BASE
3811 | lwz TMP0, 4(RD)
3812 | checknum TMP1
3813 |.if DUALNUM
3814 | bne >5
3815 |.if GPR64
3816 | lus TMP2, 0x8000
3817 | neg TMP0, TMP0
3818 | cmplw TMP0, TMP2
3819 | beq >4
3820 |.else
3821 | nego. TMP0, TMP0
3822 | bso >4
3823 |1:
3824 |.endif
3825 | ins_next1
3826 | stwux TISNUM, RA, BASE
3827 | stw TMP0, 4(RA)
3828 |3:
3829 | ins_next2
3830 |4:
3831 |.if not GPR64
3832 | // Potential overflow.
3833 | checkov TMP1, <1 // Ignore unrelated overflow.
3834 |.endif
3835 | lus TMP1, 0x41e0 // 2^31.
3836 | li TMP0, 0
3837 | b >7
3838 |.endif
3839 |5:
3840 | bge ->vmeta_unm
3841 | xoris TMP1, TMP1, 0x8000
3842 |7:
3843 | ins_next1
3844 | stwux TMP1, RA, BASE
3845 | stw TMP0, 4(RA)
3846 |.if DUALNUM
3847 | b <3
3848 |.else
3849 | ins_next2
3850 |.endif
3851 break;
3852 case BC_LEN:
3853 | // RA = dst*8, RD = src*8
3854 | lwzux TMP0, RD, BASE
3855 | lwz CARG1, 4(RD)
3856 | checkstr TMP0; bne >2
3857 | lwz CRET1, STR:CARG1->len
3858 |1:
3859 |.if DUALNUM
3860 | ins_next1
3861 | stwux TISNUM, RA, BASE
3862 | stw CRET1, 4(RA)
3863 |.else
3864 | tonum_u f0, CRET1 // Result is a non-negative integer.
3865 | ins_next1
3866 | stfdx f0, BASE, RA
3867 |.endif
3868 | ins_next2
3869 |2:
3870 | checktab TMP0; bne ->vmeta_len
3871 #if LJ_52
3872 | lwz TAB:TMP2, TAB:CARG1->metatable
3873 | cmplwi TAB:TMP2, 0
3874 | bne >9
3875 |3:
3876 #endif
3877 |->BC_LEN_Z:
3878 | bl extern lj_tab_len // (GCtab *t)
3879 | // Returns uint32_t (but less than 2^31).
3880 | b <1
3881 #if LJ_52
3882 |9:
3883 | lbz TMP0, TAB:TMP2->nomm
3884 | andix. TMP0, TMP0, 1<<MM_len
3885 | bne <3 // 'no __len' flag set: done.
3886 | b ->vmeta_len
3887 #endif
3888 break;
3890 /* -- Binary ops -------------------------------------------------------- */
3892 |.macro ins_arithpre
3893 | // RA = dst*8, RB = src1*8, RC = src2*8 | num_const*8
3894 ||vk = ((int)op - BC_ADDVN) / (BC_ADDNV-BC_ADDVN);
3895 ||switch (vk) {
3896 ||case 0:
3897 | lwzx CARG1, BASE, RB
3898 | .if DUALNUM
3899 | lwzx CARG3, KBASE, RC
3900 | .endif
3901 | .if FPU
3902 | lfdx f14, BASE, RB
3903 | lfdx f15, KBASE, RC
3904 | .else
3905 | add TMP1, BASE, RB
3906 | add TMP2, KBASE, RC
3907 | lwz CARG2, 4(TMP1)
3908 | lwz CARG4, 4(TMP2)
3909 | .endif
3910 | .if DUALNUM
3911 | checknum cr0, CARG1
3912 | checknum cr1, CARG3
3913 | crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3914 | bge ->vmeta_arith_vn
3915 | .else
3916 | checknum CARG1; bge ->vmeta_arith_vn
3917 | .endif
3918 || break;
3919 ||case 1:
3920 | lwzx CARG1, BASE, RB
3921 | .if DUALNUM
3922 | lwzx CARG3, KBASE, RC
3923 | .endif
3924 | .if FPU
3925 | lfdx f15, BASE, RB
3926 | lfdx f14, KBASE, RC
3927 | .else
3928 | add TMP1, BASE, RB
3929 | add TMP2, KBASE, RC
3930 | lwz CARG2, 4(TMP1)
3931 | lwz CARG4, 4(TMP2)
3932 | .endif
3933 | .if DUALNUM
3934 | checknum cr0, CARG1
3935 | checknum cr1, CARG3
3936 | crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3937 | bge ->vmeta_arith_nv
3938 | .else
3939 | checknum CARG1; bge ->vmeta_arith_nv
3940 | .endif
3941 || break;
3942 ||default:
3943 | lwzx CARG1, BASE, RB
3944 | lwzx CARG3, BASE, RC
3945 | .if FPU
3946 | lfdx f14, BASE, RB
3947 | lfdx f15, BASE, RC
3948 | .else
3949 | add TMP1, BASE, RB
3950 | add TMP2, BASE, RC
3951 | lwz CARG2, 4(TMP1)
3952 | lwz CARG4, 4(TMP2)
3953 | .endif
3954 | checknum cr0, CARG1
3955 | checknum cr1, CARG3
3956 | crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3957 | bge ->vmeta_arith_vv
3958 || break;
3959 ||}
3960 |.endmacro
3961 |
3962 |.macro ins_arithfallback, ins
3963 ||switch (vk) {
3964 ||case 0:
3965 | ins ->vmeta_arith_vn2
3966 || break;
3967 ||case 1:
3968 | ins ->vmeta_arith_nv2
3969 || break;
3970 ||default:
3971 | ins ->vmeta_arith_vv2
3972 || break;
3973 ||}
3974 |.endmacro
3975 |
3976 |.macro intmod, a, b, c
3977 | bl ->vm_modi
3978 |.endmacro
3979 |
3980 |.macro fpmod, a, b, c
3981 |->BC_MODVN_Z:
3982 | fdiv FARG1, b, c
3983 | // NYI: Use internal implementation of floor.
3984 | blex floor // floor(b/c)
3985 | fmul a, FARG1, c
3986 | fsub a, b, a // b - floor(b/c)*c
3987 |.endmacro
3988 |
3989 |.macro sfpmod
3990 |->BC_MODVN_Z:
3991 | stw CARG1, SFSAVE_1
3992 | stw CARG2, SFSAVE_2
3993 | mr SAVE0, CARG3
3994 | mr SAVE1, CARG4
3995 | blex __divdf3
3996 | blex floor
3997 | mr CARG3, SAVE0
3998 | mr CARG4, SAVE1
3999 | blex __muldf3
4000 | mr CARG3, CRET1
4001 | mr CARG4, CRET2
4002 | lwz CARG1, SFSAVE_1
4003 | lwz CARG2, SFSAVE_2
4004 | blex __subdf3
4005 |.endmacro
4006 |
4007 |.macro ins_arithfp, fpins
4008 | ins_arithpre
4009 |.if "fpins" == "fpmod_"
4010 | b ->BC_MODVN_Z // Avoid 3 copies. It's slow anyway.
4011 |.elif FPU
4012 | fpins f0, f14, f15
4013 | ins_next1
4014 | stfdx f0, BASE, RA
4015 | ins_next2
4016 |.else
4017 | blex __divdf3 // Only soft-float div uses this macro.
4018 | ins_next1
4019 | stwux CRET1, RA, BASE
4020 | stw CRET2, 4(RA)
4021 | ins_next2
4022 |.endif
4023 |.endmacro
4024 |
4025 |.macro ins_arithdn, intins, fpins, fpcall
4026 | // RA = dst*8, RB = src1*8, RC = src2*8 | num_const*8
4027 ||vk = ((int)op - BC_ADDVN) / (BC_ADDNV-BC_ADDVN);
4028 ||switch (vk) {
4029 ||case 0:
4030 | lwzux CARG1, RB, BASE
4031 | lwzux CARG3, RC, KBASE
4032 | lwz CARG2, 4(RB)
4033 | checknum cr0, CARG1
4034 | lwz CARG4, 4(RC)
4035 | checknum cr1, CARG3
4036 || break;
4037 ||case 1:
4038 | lwzux CARG3, RB, BASE
4039 | lwzux CARG1, RC, KBASE
4040 | lwz CARG4, 4(RB)
4041 | checknum cr0, CARG3
4042 | lwz CARG2, 4(RC)
4043 | checknum cr1, CARG1
4044 || break;
4045 ||default:
4046 | lwzux CARG1, RB, BASE
4047 | lwzux CARG3, RC, BASE
4048 | lwz CARG2, 4(RB)
4049 | checknum cr0, CARG1
4050 | lwz CARG4, 4(RC)
4051 | checknum cr1, CARG3
4052 || break;
4053 ||}
4054 | bne >5
4055 | bne cr1, >5
4056 |.if "intins" == "intmod"
4057 | mr CARG1, CARG2
4058 | mr CARG2, CARG4
4059 |.endif
4060 | intins CARG1, CARG2, CARG4
4061 | bso >4
4062 |1:
4063 | ins_next1
4064 | stwux TISNUM, RA, BASE
4065 | stw CARG1, 4(RA)
4066 |2:
4067 | ins_next2
4068 |4: // Overflow.
4069 | checkov TMP0, <1 // Ignore unrelated overflow.
4070 | ins_arithfallback b
4071 |5: // FP variant.
4072 |.if FPU
4073 ||if (vk == 1) {
4074 | lfd f15, 0(RB)
4075 | lfd f14, 0(RC)
4076 ||} else {
4077 | lfd f14, 0(RB)
4078 | lfd f15, 0(RC)
4079 ||}
4080 |.endif
4081 | crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
4082 | ins_arithfallback bge
4083 |.if "fpins" == "fpmod_"
4084 | b ->BC_MODVN_Z // Avoid 3 copies. It's slow anyway.
4085 |.else
4086 |.if FPU
4087 | fpins f0, f14, f15
4088 | stfdx f0, BASE, RA
4089 |.else
4090 |.if "fpcall" == "sfpmod"
4091 | sfpmod
4092 |.else
4093 | blex fpcall
4094 |.endif
4095 | stwux CRET1, RA, BASE
4096 | stw CRET2, 4(RA)
4097 |.endif
4098 | ins_next1
4099 | b <2
4100 |.endif
4101 |.endmacro
4102 |
4103 |.macro ins_arith, intins, fpins, fpcall
4104 |.if DUALNUM
4105 | ins_arithdn intins, fpins, fpcall
4106 |.else
4107 | ins_arithfp fpins
4108 |.endif
4109 |.endmacro
4111 case BC_ADDVN: case BC_ADDNV: case BC_ADDVV:
4112 |.if GPR64
4113 |.macro addo32., y, a, b
4114 | // Need to check overflow for (a<<32) + (b<<32).
4115 | rldicr TMP0, a, 32, 31
4116 | rldicr TMP1, b, 32, 31
4117 | addo. TMP0, TMP0, TMP1
4118 | add y, a, b
4119 |.endmacro
4120 | ins_arith addo32., fadd, __adddf3
4121 |.else
4122 | ins_arith addo., fadd, __adddf3
4123 |.endif
4124 break;
4125 case BC_SUBVN: case BC_SUBNV: case BC_SUBVV:
4126 |.if GPR64
4127 |.macro subo32., y, a, b
4128 | // Need to check overflow for (a<<32) - (b<<32).
4129 | rldicr TMP0, a, 32, 31
4130 | rldicr TMP1, b, 32, 31
4131 | subo. TMP0, TMP0, TMP1
4132 | sub y, a, b
4133 |.endmacro
4134 | ins_arith subo32., fsub, __subdf3
4135 |.else
4136 | ins_arith subo., fsub, __subdf3
4137 |.endif
4138 break;
4139 case BC_MULVN: case BC_MULNV: case BC_MULVV:
4140 | ins_arith mullwo., fmul, __muldf3
4141 break;
4142 case BC_DIVVN: case BC_DIVNV: case BC_DIVVV:
4143 | ins_arithfp fdiv
4144 break;
4145 case BC_MODVN:
4146 | ins_arith intmod, fpmod, sfpmod
4147 break;
4148 case BC_MODNV: case BC_MODVV:
4149 | ins_arith intmod, fpmod_, sfpmod
4150 break;
4151 case BC_POW:
4152 | // NYI: (partial) integer arithmetic.
4153 | lwzx CARG1, BASE, RB
4154 | lwzx CARG3, BASE, RC
4155 |.if FPU
4156 | lfdx FARG1, BASE, RB
4157 | lfdx FARG2, BASE, RC
4158 |.else
4159 | add TMP1, BASE, RB
4160 | add TMP2, BASE, RC
4161 | lwz CARG2, 4(TMP1)
4162 | lwz CARG4, 4(TMP2)
4163 |.endif
4164 | checknum cr0, CARG1
4165 | checknum cr1, CARG3
4166 | crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
4167 | bge ->vmeta_arith_vv
4168 | blex pow
4169 | ins_next1
4170 |.if FPU
4171 | stfdx FARG1, BASE, RA
4172 |.else
4173 | stwux CARG1, RA, BASE
4174 | stw CARG2, 4(RA)
4175 |.endif
4176 | ins_next2
4177 break;
4179 case BC_CAT:
4180 | // RA = dst*8, RB = src_start*8, RC = src_end*8
4181 | sub CARG3, RC, RB
4182 | stp BASE, L->base
4183 | add CARG2, BASE, RC
4184 | mr SAVE0, RB
4185 |->BC_CAT_Z:
4186 | stw PC, SAVE_PC
4187 | mr CARG1, L
4188 | srwi CARG3, CARG3, 3
4189 | bl extern lj_meta_cat // (lua_State *L, TValue *top, int left)
4190 | // Returns NULL (finished) or TValue * (metamethod).
4191 | cmplwi CRET1, 0
4192 | lp BASE, L->base
4193 | bne ->vmeta_binop
4194 | ins_next1
4195 |.if FPU
4196 | lfdx f0, BASE, SAVE0 // Copy result from RB to RA.
4197 | stfdx f0, BASE, RA
4198 |.else
4199 | lwzux TMP0, SAVE0, BASE
4200 | lwz TMP1, 4(SAVE0)
4201 | stwux TMP0, RA, BASE
4202 | stw TMP1, 4(RA)
4203 |.endif
4204 | ins_next2
4205 break;
4207 /* -- Constant ops ------------------------------------------------------ */
4209 case BC_KSTR:
4210 | // RA = dst*8, RD = str_const*8 (~)
4211 | srwi TMP1, RD, 1
4212 | subfic TMP1, TMP1, -4
4213 | ins_next1
4214 | lwzx TMP0, KBASE, TMP1 // KBASE-4-str_const*4
4215 | li TMP2, LJ_TSTR
4216 | stwux TMP2, RA, BASE
4217 | stw TMP0, 4(RA)
4218 | ins_next2
4219 break;
4220 case BC_KCDATA:
4221 |.if FFI
4222 | // RA = dst*8, RD = cdata_const*8 (~)
4223 | srwi TMP1, RD, 1
4224 | subfic TMP1, TMP1, -4
4225 | ins_next1
4226 | lwzx TMP0, KBASE, TMP1 // KBASE-4-cdata_const*4
4227 | li TMP2, LJ_TCDATA
4228 | stwux TMP2, RA, BASE
4229 | stw TMP0, 4(RA)
4230 | ins_next2
4231 |.endif
4232 break;
4233 case BC_KSHORT:
4234 | // RA = dst*8, RD = int16_literal*8
4235 |.if DUALNUM
4236 | slwi RD, RD, 13
4237 | srawi RD, RD, 16
4238 | ins_next1
4239 | stwux TISNUM, RA, BASE
4240 | stw RD, 4(RA)
4241 | ins_next2
4242 |.else
4243 | // The soft-float approach is faster.
4244 | slwi RD, RD, 13
4245 | srawi TMP1, RD, 31
4246 | xor TMP2, TMP1, RD
4247 | sub TMP2, TMP2, TMP1 // TMP2 = abs(x)
4248 | cntlzw TMP3, TMP2
4249 | subfic TMP1, TMP3, 0x40d // TMP1 = exponent-1
4250 | slw TMP2, TMP2, TMP3 // TMP2 = left aligned mantissa
4251 | subfic TMP3, RD, 0
4252 | slwi TMP1, TMP1, 20
4253 | rlwimi RD, TMP2, 21, 1, 31 // hi = sign(x) | (mantissa>>11)
4254 | subfe TMP0, TMP0, TMP0
4255 | add RD, RD, TMP1 // hi = hi + exponent-1
4256 | and RD, RD, TMP0 // hi = x == 0 ? 0 : hi
4257 | ins_next1
4258 | stwux RD, RA, BASE
4259 | stw ZERO, 4(RA)
4260 | ins_next2
4261 |.endif
4262 break;
4263 case BC_KNUM:
4264 | // RA = dst*8, RD = num_const*8
4265 | ins_next1
4266 |.if FPU
4267 | lfdx f0, KBASE, RD
4268 | stfdx f0, BASE, RA
4269 |.else
4270 | lwzux TMP0, RD, KBASE
4271 | lwz TMP1, 4(RD)
4272 | stwux TMP0, RA, BASE
4273 | stw TMP1, 4(RA)
4274 |.endif
4275 | ins_next2
4276 break;
4277 case BC_KPRI:
4278 | // RA = dst*8, RD = primitive_type*8 (~)
4279 | srwi TMP1, RD, 3
4280 | not TMP0, TMP1
4281 | ins_next1
4282 | stwx TMP0, BASE, RA
4283 | ins_next2
4284 break;
4285 case BC_KNIL:
4286 | // RA = base*8, RD = end*8
4287 | stwx TISNIL, BASE, RA
4288 | addi RA, RA, 8
4289 |1:
4290 | stwx TISNIL, BASE, RA
4291 | cmpw RA, RD
4292 | addi RA, RA, 8
4293 | blt <1
4294 | ins_next_
4295 break;
4297 /* -- Upvalue and function ops ------------------------------------------ */
4299 case BC_UGET:
4300 | // RA = dst*8, RD = uvnum*8
4301 | lwz LFUNC:RB, FRAME_FUNC(BASE)
4302 | srwi RD, RD, 1
4303 | addi RD, RD, offsetof(GCfuncL, uvptr)
4304 | lwzx UPVAL:RB, LFUNC:RB, RD
4305 | ins_next1
4306 | lwz TMP1, UPVAL:RB->v
4307 |.if FPU
4308 | lfd f0, 0(TMP1)
4309 | stfdx f0, BASE, RA
4310 |.else
4311 | lwz TMP2, 0(TMP1)
4312 | lwz TMP3, 4(TMP1)
4313 | stwux TMP2, RA, BASE
4314 | stw TMP3, 4(RA)
4315 |.endif
4316 | ins_next2
4317 break;
4318 case BC_USETV:
4319 | // RA = uvnum*8, RD = src*8
4320 | lwz LFUNC:RB, FRAME_FUNC(BASE)
4321 | srwi RA, RA, 1
4322 | addi RA, RA, offsetof(GCfuncL, uvptr)
4323 |.if FPU
4324 | lfdux f0, RD, BASE
4325 |.else
4326 | lwzux CARG1, RD, BASE
4327 | lwz CARG3, 4(RD)
4328 |.endif
4329 | lwzx UPVAL:RB, LFUNC:RB, RA
4330 | lbz TMP3, UPVAL:RB->marked
4331 | lwz CARG2, UPVAL:RB->v
4332 | andix. TMP3, TMP3, LJ_GC_BLACK // isblack(uv)
4333 | lbz TMP0, UPVAL:RB->closed
4334 | lwz TMP2, 0(RD)
4335 |.if FPU
4336 | stfd f0, 0(CARG2)
4337 |.else
4338 | stw CARG1, 0(CARG2)
4339 | stw CARG3, 4(CARG2)
4340 |.endif
4341 | cmplwi cr1, TMP0, 0
4342 | lwz TMP1, 4(RD)
4343 | cror 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
4344 | subi TMP2, TMP2, (LJ_TNUMX+1)
4345 | bne >2 // Upvalue is closed and black?
4346 |1:
4347 | ins_next
4348 |
4349 |2: // Check if new value is collectable.
4350 | cmplwi TMP2, LJ_TISGCV - (LJ_TNUMX+1)
4351 | bge <1 // tvisgcv(v)
4352 | lbz TMP3, GCOBJ:TMP1->gch.marked
4353 | andix. TMP3, TMP3, LJ_GC_WHITES // iswhite(v)
4354 | la CARG1, GG_DISP2G(DISPATCH)
4355 | // Crossed a write barrier. Move the barrier forward.
4356 | beq <1
4357 | bl extern lj_gc_barrieruv // (global_State *g, TValue *tv)
4358 | b <1
4359 break;
4360 case BC_USETS:
4361 | // RA = uvnum*8, RD = str_const*8 (~)
4362 | lwz LFUNC:RB, FRAME_FUNC(BASE)
4363 | srwi TMP1, RD, 1
4364 | srwi RA, RA, 1
4365 | subfic TMP1, TMP1, -4
4366 | addi RA, RA, offsetof(GCfuncL, uvptr)
4367 | lwzx STR:TMP1, KBASE, TMP1 // KBASE-4-str_const*4
4368 | lwzx UPVAL:RB, LFUNC:RB, RA
4369 | lbz TMP3, UPVAL:RB->marked
4370 | lwz CARG2, UPVAL:RB->v
4371 | andix. TMP3, TMP3, LJ_GC_BLACK // isblack(uv)
4372 | lbz TMP3, STR:TMP1->marked
4373 | lbz TMP2, UPVAL:RB->closed
4374 | li TMP0, LJ_TSTR
4375 | stw STR:TMP1, 4(CARG2)
4376 | stw TMP0, 0(CARG2)
4377 | bne >2
4378 |1:
4379 | ins_next
4380 |
4381 |2: // Check if string is white and ensure upvalue is closed.
4382 | andix. TMP3, TMP3, LJ_GC_WHITES // iswhite(str)
4383 | cmplwi cr1, TMP2, 0
4384 | cror 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
4385 | la CARG1, GG_DISP2G(DISPATCH)
4386 | // Crossed a write barrier. Move the barrier forward.
4387 | beq <1
4388 | bl extern lj_gc_barrieruv // (global_State *g, TValue *tv)
4389 | b <1
4390 break;
4391 case BC_USETN:
4392 | // RA = uvnum*8, RD = num_const*8
4393 | lwz LFUNC:RB, FRAME_FUNC(BASE)
4394 | srwi RA, RA, 1
4395 | addi RA, RA, offsetof(GCfuncL, uvptr)
4396 |.if FPU
4397 | lfdx f0, KBASE, RD
4398 |.else
4399 | lwzux TMP2, RD, KBASE
4400 | lwz TMP3, 4(RD)
4401 |.endif
4402 | lwzx UPVAL:RB, LFUNC:RB, RA
4403 | ins_next1
4404 | lwz TMP1, UPVAL:RB->v
4405 |.if FPU
4406 | stfd f0, 0(TMP1)
4407 |.else
4408 | stw TMP2, 0(TMP1)
4409 | stw TMP3, 4(TMP1)
4410 |.endif
4411 | ins_next2
4412 break;
4413 case BC_USETP:
4414 | // RA = uvnum*8, RD = primitive_type*8 (~)
4415 | lwz LFUNC:RB, FRAME_FUNC(BASE)
4416 | srwi RA, RA, 1
4417 | srwi TMP0, RD, 3
4418 | addi RA, RA, offsetof(GCfuncL, uvptr)
4419 | not TMP0, TMP0
4420 | lwzx UPVAL:RB, LFUNC:RB, RA
4421 | ins_next1
4422 | lwz TMP1, UPVAL:RB->v
4423 | stw TMP0, 0(TMP1)
4424 | ins_next2
4425 break;
4427 case BC_UCLO:
4428 | // RA = level*8, RD = target
4429 | lwz TMP1, L->openupval
4430 | branch_RD // Do this first since RD is not saved.
4431 | stp BASE, L->base
4432 | cmplwi TMP1, 0
4433 | mr CARG1, L
4434 | beq >1
4435 | add CARG2, BASE, RA
4436 | bl extern lj_func_closeuv // (lua_State *L, TValue *level)
4437 | lp BASE, L->base
4438 |1:
4439 | ins_next
4440 break;
4442 case BC_FNEW:
4443 | // RA = dst*8, RD = proto_const*8 (~) (holding function prototype)
4444 | srwi TMP1, RD, 1
4445 | stp BASE, L->base
4446 | subfic TMP1, TMP1, -4
4447 | stw PC, SAVE_PC
4448 | lwzx CARG2, KBASE, TMP1 // KBASE-4-tab_const*4
4449 | mr CARG1, L
4450 | lwz CARG3, FRAME_FUNC(BASE)
4451 | // (lua_State *L, GCproto *pt, GCfuncL *parent)
4452 | bl extern lj_func_newL_gc
4453 | // Returns GCfuncL *.
4454 | lp BASE, L->base
4455 | li TMP0, LJ_TFUNC
4456 | stwux TMP0, RA, BASE
4457 | stw LFUNC:CRET1, 4(RA)
4458 | ins_next
4459 break;
4461 /* -- Table ops --------------------------------------------------------- */
4463 case BC_TNEW:
4464 case BC_TDUP:
4465 | // RA = dst*8, RD = (hbits|asize)*8 | tab_const*8 (~)
4466 | lwz TMP0, DISPATCH_GL(gc.total)(DISPATCH)
4467 | mr CARG1, L
4468 | lwz TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
4469 | stp BASE, L->base
4470 | cmplw TMP0, TMP1
4471 | stw PC, SAVE_PC
4472 | bge >5
4473 |1:
4474 if (op == BC_TNEW) {
4475 | rlwinm CARG2, RD, 29, 21, 31
4476 | rlwinm CARG3, RD, 18, 27, 31
4477 | cmpwi CARG2, 0x7ff; beq >3
4478 |2:
4479 | bl extern lj_tab_new // (lua_State *L, int32_t asize, uint32_t hbits)
4480 | // Returns Table *.
4481 } else {
4482 | srwi TMP1, RD, 1
4483 | subfic TMP1, TMP1, -4
4484 | lwzx CARG2, KBASE, TMP1 // KBASE-4-tab_const*4
4485 | bl extern lj_tab_dup // (lua_State *L, Table *kt)
4486 | // Returns Table *.
4487 }
4488 | lp BASE, L->base
4489 | li TMP0, LJ_TTAB
4490 | stwux TMP0, RA, BASE
4491 | stw TAB:CRET1, 4(RA)
4492 | ins_next
4493 if (op == BC_TNEW) {
4494 |3:
4495 | li CARG2, 0x801
4496 | b <2
4497 }
4498 |5:
4499 | mr SAVE0, RD
4500 | bl extern lj_gc_step_fixtop // (lua_State *L)
4501 | mr RD, SAVE0
4502 | mr CARG1, L
4503 | b <1
4504 break;
4506 case BC_GGET:
4507 | // RA = dst*8, RD = str_const*8 (~)
4508 case BC_GSET:
4509 | // RA = src*8, RD = str_const*8 (~)
4510 | lwz LFUNC:TMP2, FRAME_FUNC(BASE)
4511 | srwi TMP1, RD, 1
4512 | lwz TAB:RB, LFUNC:TMP2->env
4513 | subfic TMP1, TMP1, -4
4514 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
4515 if (op == BC_GGET) {
4516 | b ->BC_TGETS_Z
4517 } else {
4518 | b ->BC_TSETS_Z
4519 }
4520 break;
4522 case BC_TGETV:
4523 | // RA = dst*8, RB = table*8, RC = key*8
4524 | lwzux CARG1, RB, BASE
4525 | lwzux CARG2, RC, BASE
4526 | lwz TAB:RB, 4(RB)
4527 |.if DUALNUM
4528 | lwz RC, 4(RC)
4529 |.else
4530 | lfd f0, 0(RC)
4531 |.endif
4532 | checktab CARG1
4533 | checknum cr1, CARG2
4534 | bne ->vmeta_tgetv
4535 |.if DUALNUM
4536 | lwz TMP0, TAB:RB->asize
4537 | bne cr1, >5
4538 | lwz TMP1, TAB:RB->array
4539 | cmplw TMP0, RC
4540 | slwi TMP2, RC, 3
4541 |.else
4542 | bge cr1, >5
4543 | // Convert number key to integer, check for integerness and range.
4544 | fctiwz f1, f0
4545 | fadd f2, f0, TOBIT
4546 | stfd f1, TMPD
4547 | lwz TMP0, TAB:RB->asize
4548 | fsub f2, f2, TOBIT
4549 | lwz TMP2, TMPD_LO
4550 | lwz TMP1, TAB:RB->array
4551 | fcmpu cr1, f0, f2
4552 | cmplw cr0, TMP0, TMP2
4553 | crand 4*cr0+gt, 4*cr0+gt, 4*cr1+eq
4554 | slwi TMP2, TMP2, 3
4555 |.endif
4556 | ble ->vmeta_tgetv // Integer key and in array part?
4557 | lwzx TMP0, TMP1, TMP2
4558 |.if FPU
4559 | lfdx f14, TMP1, TMP2
4560 |.else
4561 | lwzux SAVE0, TMP1, TMP2
4562 | lwz SAVE1, 4(TMP1)
4563 |.endif
4564 | checknil TMP0; beq >2
4565 |1:
4566 | ins_next1
4567 |.if FPU
4568 | stfdx f14, BASE, RA
4569 |.else
4570 | stwux SAVE0, RA, BASE
4571 | stw SAVE1, 4(RA)
4572 |.endif
4573 | ins_next2
4574 |
4575 |2: // Check for __index if table value is nil.
4576 | lwz TAB:TMP2, TAB:RB->metatable
4577 | cmplwi TAB:TMP2, 0
4578 | beq <1 // No metatable: done.
4579 | lbz TMP0, TAB:TMP2->nomm
4580 | andix. TMP0, TMP0, 1<<MM_index
4581 | bne <1 // 'no __index' flag set: done.
4582 | b ->vmeta_tgetv
4583 |
4584 |5:
4585 | checkstr CARG2; bne ->vmeta_tgetv
4586 |.if not DUALNUM
4587 | lwz STR:RC, 4(RC)
4588 |.endif
4589 | b ->BC_TGETS_Z // String key?
4590 break;
4591 case BC_TGETS:
4592 | // RA = dst*8, RB = table*8, RC = str_const*8 (~)
4593 | lwzux CARG1, RB, BASE
4594 | srwi TMP1, RC, 1
4595 | lwz TAB:RB, 4(RB)
4596 | subfic TMP1, TMP1, -4
4597 | checktab CARG1
4598 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
4599 | bne ->vmeta_tgets1
4600 |->BC_TGETS_Z:
4601 | // TAB:RB = GCtab *, STR:RC = GCstr *, RA = dst*8
4602 | lwz TMP0, TAB:RB->hmask
4603 | lwz TMP1, STR:RC->sid
4604 | lwz NODE:TMP2, TAB:RB->node
4605 | and TMP1, TMP1, TMP0 // idx = str->sid & tab->hmask
4606 | slwi TMP0, TMP1, 5
4607 | slwi TMP1, TMP1, 3
4608 | sub TMP1, TMP0, TMP1
4609 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
4610 |1:
4611 | lwz CARG1, NODE:TMP2->key
4612 | lwz TMP0, 4+offsetof(Node, key)(NODE:TMP2)
4613 | lwz CARG2, NODE:TMP2->val
4614 | lwz TMP1, 4+offsetof(Node, val)(NODE:TMP2)
4615 | checkstr CARG1; bne >4
4616 | cmpw TMP0, STR:RC; bne >4
4617 | checknil CARG2; beq >5 // Key found, but nil value?
4618 |3:
4619 | stwux CARG2, RA, BASE
4620 | stw TMP1, 4(RA)
4621 | ins_next
4622 |
4623 |4: // Follow hash chain.
4624 | lwz NODE:TMP2, NODE:TMP2->next
4625 | cmplwi NODE:TMP2, 0
4626 | bne <1
4627 | // End of hash chain: key not found, nil result.
4628 | li CARG2, LJ_TNIL
4629 |
4630 |5: // Check for __index if table value is nil.
4631 | lwz TAB:TMP2, TAB:RB->metatable
4632 | cmplwi TAB:TMP2, 0
4633 | beq <3 // No metatable: done.
4634 | lbz TMP0, TAB:TMP2->nomm
4635 | andix. TMP0, TMP0, 1<<MM_index
4636 | bne <3 // 'no __index' flag set: done.
4637 | b ->vmeta_tgets
4638 break;
4639 case BC_TGETB:
4640 | // RA = dst*8, RB = table*8, RC = index*8
4641 | lwzux CARG1, RB, BASE
4642 | srwi TMP0, RC, 3
4643 | lwz TAB:RB, 4(RB)
4644 | checktab CARG1; bne ->vmeta_tgetb
4645 | lwz TMP1, TAB:RB->asize
4646 | lwz TMP2, TAB:RB->array
4647 | cmplw TMP0, TMP1; bge ->vmeta_tgetb
4648 |.if FPU
4649 | lwzx TMP1, TMP2, RC
4650 | lfdx f0, TMP2, RC
4651 |.else
4652 | lwzux TMP1, TMP2, RC
4653 | lwz TMP3, 4(TMP2)
4654 |.endif
4655 | checknil TMP1; beq >5
4656 |1:
4657 | ins_next1
4658 |.if FPU
4659 | stfdx f0, BASE, RA
4660 |.else
4661 | stwux TMP1, RA, BASE
4662 | stw TMP3, 4(RA)
4663 |.endif
4664 | ins_next2
4665 |
4666 |5: // Check for __index if table value is nil.
4667 | lwz TAB:TMP2, TAB:RB->metatable
4668 | cmplwi TAB:TMP2, 0
4669 | beq <1 // No metatable: done.
4670 | lbz TMP2, TAB:TMP2->nomm
4671 | andix. TMP2, TMP2, 1<<MM_index
4672 | bne <1 // 'no __index' flag set: done.
4673 | b ->vmeta_tgetb // Caveat: preserve TMP0!
4674 break;
4675 case BC_TGETR:
4676 | // RA = dst*8, RB = table*8, RC = key*8
4677 | add RB, BASE, RB
4678 | lwz TAB:CARG1, 4(RB)
4679 |.if DUALNUM
4680 | add RC, BASE, RC
4681 | lwz TMP0, TAB:CARG1->asize
4682 | lwz CARG2, 4(RC)
4683 | lwz TMP1, TAB:CARG1->array
4684 |.else
4685 | lfdx f0, BASE, RC
4686 | lwz TMP0, TAB:CARG1->asize
4687 | toint CARG2, f0
4688 | lwz TMP1, TAB:CARG1->array
4689 |.endif
4690 | cmplw TMP0, CARG2
4691 | slwi TMP2, CARG2, 3
4692 | ble ->vmeta_tgetr // In array part?
4693 |.if FPU
4694 | lfdx f14, TMP1, TMP2
4695 |.else
4696 | lwzux SAVE0, TMP2, TMP1
4697 | lwz SAVE1, 4(TMP2)
4698 |.endif
4699 |->BC_TGETR_Z:
4700 | ins_next1
4701 |.if FPU
4702 | stfdx f14, BASE, RA
4703 |.else
4704 | stwux SAVE0, RA, BASE
4705 | stw SAVE1, 4(RA)
4706 |.endif
4707 | ins_next2
4708 break;
4710 case BC_TSETV:
4711 | // RA = src*8, RB = table*8, RC = key*8
4712 | lwzux CARG1, RB, BASE
4713 | lwzux CARG2, RC, BASE
4714 | lwz TAB:RB, 4(RB)
4715 |.if DUALNUM
4716 | lwz RC, 4(RC)
4717 |.else
4718 | lfd f0, 0(RC)
4719 |.endif
4720 | checktab CARG1
4721 | checknum cr1, CARG2
4722 | bne ->vmeta_tsetv
4723 |.if DUALNUM
4724 | lwz TMP0, TAB:RB->asize
4725 | bne cr1, >5
4726 | lwz TMP1, TAB:RB->array
4727 | cmplw TMP0, RC
4728 | slwi TMP0, RC, 3
4729 |.else
4730 | bge cr1, >5
4731 | // Convert number key to integer, check for integerness and range.
4732 | fctiwz f1, f0
4733 | fadd f2, f0, TOBIT
4734 | stfd f1, TMPD
4735 | lwz TMP0, TAB:RB->asize
4736 | fsub f2, f2, TOBIT
4737 | lwz TMP2, TMPD_LO
4738 | lwz TMP1, TAB:RB->array
4739 | fcmpu cr1, f0, f2
4740 | cmplw cr0, TMP0, TMP2
4741 | crand 4*cr0+gt, 4*cr0+gt, 4*cr1+eq
4742 | slwi TMP0, TMP2, 3
4743 |.endif
4744 | ble ->vmeta_tsetv // Integer key and in array part?
4745 | lwzx TMP2, TMP1, TMP0
4746 | lbz TMP3, TAB:RB->marked
4747 |.if FPU
4748 | lfdx f14, BASE, RA
4749 |.else
4750 | add SAVE1, BASE, RA
4751 | lwz SAVE0, 0(SAVE1)
4752 | lwz SAVE1, 4(SAVE1)
4753 |.endif
4754 | checknil TMP2; beq >3
4755 |1:
4756 | andix. TMP2, TMP3, LJ_GC_BLACK // isblack(table)
4757 |.if FPU
4758 | stfdx f14, TMP1, TMP0
4759 |.else
4760 | stwux SAVE0, TMP1, TMP0
4761 | stw SAVE1, 4(TMP1)
4762 |.endif
4763 | bne >7
4764 |2:
4765 | ins_next
4766 |
4767 |3: // Check for __newindex if previous value is nil.
4768 | lwz TAB:TMP2, TAB:RB->metatable
4769 | cmplwi TAB:TMP2, 0
4770 | beq <1 // No metatable: done.
4771 | lbz TMP2, TAB:TMP2->nomm
4772 | andix. TMP2, TMP2, 1<<MM_newindex
4773 | bne <1 // 'no __newindex' flag set: done.
4774 | b ->vmeta_tsetv
4775 |
4776 |5:
4777 | checkstr CARG2; bne ->vmeta_tsetv
4778 |.if not DUALNUM
4779 | lwz STR:RC, 4(RC)
4780 |.endif
4781 | b ->BC_TSETS_Z // String key?
4782 |
4783 |7: // Possible table write barrier for the value. Skip valiswhite check.
4784 | barrierback TAB:RB, TMP3, TMP0
4785 | b <2
4786 break;
4787 case BC_TSETS:
4788 | // RA = src*8, RB = table*8, RC = str_const*8 (~)
4789 | lwzux CARG1, RB, BASE
4790 | srwi TMP1, RC, 1
4791 | lwz TAB:RB, 4(RB)
4792 | subfic TMP1, TMP1, -4
4793 | checktab CARG1
4794 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
4795 | bne ->vmeta_tsets1
4796 |->BC_TSETS_Z:
4797 | // TAB:RB = GCtab *, STR:RC = GCstr *, RA = src*8
4798 | lwz TMP0, TAB:RB->hmask
4799 | lwz TMP1, STR:RC->sid
4800 | lwz NODE:TMP2, TAB:RB->node
4801 | stb ZERO, TAB:RB->nomm // Clear metamethod cache.
4802 | and TMP1, TMP1, TMP0 // idx = str->sid & tab->hmask
4803 |.if FPU
4804 | lfdx f14, BASE, RA
4805 |.else
4806 | add CARG2, BASE, RA
4807 | lwz SAVE0, 0(CARG2)
4808 | lwz SAVE1, 4(CARG2)
4809 |.endif
4810 | slwi TMP0, TMP1, 5
4811 | slwi TMP1, TMP1, 3
4812 | sub TMP1, TMP0, TMP1
4813 | lbz TMP3, TAB:RB->marked
4814 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
4815 |1:
4816 | lwz CARG1, NODE:TMP2->key
4817 | lwz TMP0, 4+offsetof(Node, key)(NODE:TMP2)
4818 | lwz CARG2, NODE:TMP2->val
4819 | lwz NODE:TMP1, NODE:TMP2->next
4820 | checkstr CARG1; bne >5
4821 | cmpw TMP0, STR:RC; bne >5
4822 | checknil CARG2; beq >4 // Key found, but nil value?
4823 |2:
4824 | andix. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
4825 |.if FPU
4826 | stfd f14, NODE:TMP2->val
4827 |.else
4828 | stw SAVE0, NODE:TMP2->val.u32.hi
4829 | stw SAVE1, NODE:TMP2->val.u32.lo
4830 |.endif
4831 | bne >7
4832 |3:
4833 | ins_next
4834 |
4835 |4: // Check for __newindex if previous value is nil.
4836 | lwz TAB:TMP1, TAB:RB->metatable
4837 | cmplwi TAB:TMP1, 0
4838 | beq <2 // No metatable: done.
4839 | lbz TMP0, TAB:TMP1->nomm
4840 | andix. TMP0, TMP0, 1<<MM_newindex
4841 | bne <2 // 'no __newindex' flag set: done.
4842 | b ->vmeta_tsets
4843 |
4844 |5: // Follow hash chain.
4845 | cmplwi NODE:TMP1, 0
4846 | mr NODE:TMP2, NODE:TMP1
4847 | bne <1
4848 | // End of hash chain: key not found, add a new one.
4849 |
4850 | // But check for __newindex first.
4851 | lwz TAB:TMP1, TAB:RB->metatable
4852 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
4853 | stw PC, SAVE_PC
4854 | mr CARG1, L
4855 | cmplwi TAB:TMP1, 0
4856 | stp BASE, L->base
4857 | beq >6 // No metatable: continue.
4858 | lbz TMP0, TAB:TMP1->nomm
4859 | andix. TMP0, TMP0, 1<<MM_newindex
4860 | beq ->vmeta_tsets // 'no __newindex' flag NOT set: check.
4861 |6:
4862 | li TMP0, LJ_TSTR
4863 | stw STR:RC, 4(CARG3)
4864 | mr CARG2, TAB:RB
4865 | stw TMP0, 0(CARG3)
4866 | bl extern lj_tab_newkey // (lua_State *L, GCtab *t, TValue *k)
4867 | // Returns TValue *.
4868 | lp BASE, L->base
4869 |.if FPU
4870 | stfd f14, 0(CRET1)
4871 |.else
4872 | stw SAVE0, 0(CRET1)
4873 | stw SAVE1, 4(CRET1)
4874 |.endif
4875 | b <3 // No 2nd write barrier needed.
4876 |
4877 |7: // Possible table write barrier for the value. Skip valiswhite check.
4878 | barrierback TAB:RB, TMP3, TMP0
4879 | b <3
4880 break;
4881 case BC_TSETB:
4882 | // RA = src*8, RB = table*8, RC = index*8
4883 | lwzux CARG1, RB, BASE
4884 | srwi TMP0, RC, 3
4885 | lwz TAB:RB, 4(RB)
4886 | checktab CARG1; bne ->vmeta_tsetb
4887 | lwz TMP1, TAB:RB->asize
4888 | lwz TMP2, TAB:RB->array
4889 | lbz TMP3, TAB:RB->marked
4890 | cmplw TMP0, TMP1
4891 |.if FPU
4892 | lfdx f14, BASE, RA
4893 |.else
4894 | add CARG2, BASE, RA
4895 | lwz SAVE0, 0(CARG2)
4896 | lwz SAVE1, 4(CARG2)
4897 |.endif
4898 | bge ->vmeta_tsetb
4899 | lwzx TMP1, TMP2, RC
4900 | checknil TMP1; beq >5
4901 |1:
4902 | andix. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
4903 |.if FPU
4904 | stfdx f14, TMP2, RC
4905 |.else
4906 | stwux SAVE0, RC, TMP2
4907 | stw SAVE1, 4(RC)
4908 |.endif
4909 | bne >7
4910 |2:
4911 | ins_next
4912 |
4913 |5: // Check for __newindex if previous value is nil.
4914 | lwz TAB:TMP1, TAB:RB->metatable
4915 | cmplwi TAB:TMP1, 0
4916 | beq <1 // No metatable: done.
4917 | lbz TMP1, TAB:TMP1->nomm
4918 | andix. TMP1, TMP1, 1<<MM_newindex
4919 | bne <1 // 'no __newindex' flag set: done.
4920 | b ->vmeta_tsetb // Caveat: preserve TMP0!
4921 |
4922 |7: // Possible table write barrier for the value. Skip valiswhite check.
4923 | barrierback TAB:RB, TMP3, TMP0
4924 | b <2
4925 break;
4926 case BC_TSETR:
4927 | // RA = dst*8, RB = table*8, RC = key*8
4928 | add RB, BASE, RB
4929 | lwz TAB:CARG2, 4(RB)
4930 |.if DUALNUM
4931 | add RC, BASE, RC
4932 | lbz TMP3, TAB:CARG2->marked
4933 | lwz TMP0, TAB:CARG2->asize
4934 | lwz CARG3, 4(RC)
4935 | lwz TMP1, TAB:CARG2->array
4936 |.else
4937 | lfdx f0, BASE, RC
4938 | lbz TMP3, TAB:CARG2->marked
4939 | lwz TMP0, TAB:CARG2->asize
4940 | toint CARG3, f0
4941 | lwz TMP1, TAB:CARG2->array
4942 |.endif
4943 | andix. TMP2, TMP3, LJ_GC_BLACK // isblack(table)
4944 | bne >7
4945 |2:
4946 | cmplw TMP0, CARG3
4947 | slwi TMP2, CARG3, 3
4948 |.if FPU
4949 | lfdx f14, BASE, RA
4950 |.else
4951 | lwzux SAVE0, RA, BASE
4952 | lwz SAVE1, 4(RA)
4953 |.endif
4954 | ble ->vmeta_tsetr // In array part?
4955 | ins_next1
4956 |.if FPU
4957 | stfdx f14, TMP1, TMP2
4958 |.else
4959 | stwux SAVE0, TMP1, TMP2
4960 | stw SAVE1, 4(TMP1)
4961 |.endif
4962 | ins_next2
4963 |
4964 |7: // Possible table write barrier for the value. Skip valiswhite check.
4965 | barrierback TAB:CARG2, TMP3, TMP2
4966 | b <2
4967 break;
4970 case BC_TSETM:
4971 | // RA = base*8 (table at base-1), RD = num_const*8 (start index)
4972 | add RA, BASE, RA
4973 |1:
4974 | add TMP3, KBASE, RD
4975 | lwz TAB:CARG2, -4(RA) // Guaranteed to be a table.
4976 | addic. TMP0, MULTRES, -8
4977 | lwz TMP3, 4(TMP3) // Integer constant is in lo-word.
4978 | srwi CARG3, TMP0, 3
4979 | beq >4 // Nothing to copy?
4980 | add CARG3, CARG3, TMP3
4981 | lwz TMP2, TAB:CARG2->asize
4982 | slwi TMP1, TMP3, 3
4983 | lbz TMP3, TAB:CARG2->marked
4984 | cmplw CARG3, TMP2
4985 | add TMP2, RA, TMP0
4986 | lwz TMP0, TAB:CARG2->array
4987 | bgt >5
4988 | add TMP1, TMP1, TMP0
4989 | andix. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
4990 |3: // Copy result slots to table.
4991 |.if FPU
4992 | lfd f0, 0(RA)
4993 |.else
4994 | lwz SAVE0, 0(RA)
4995 | lwz SAVE1, 4(RA)
4996 |.endif
4997 | addi RA, RA, 8
4998 | cmpw cr1, RA, TMP2
4999 |.if FPU
5000 | stfd f0, 0(TMP1)
5001 |.else
5002 | stw SAVE0, 0(TMP1)
5003 | stw SAVE1, 4(TMP1)
5004 |.endif
5005 | addi TMP1, TMP1, 8
5006 | blt cr1, <3
5007 | bne >7
5008 |4:
5009 | ins_next
5010 |
5011 |5: // Need to resize array part.
5012 | stp BASE, L->base
5013 | mr CARG1, L
5014 | stw PC, SAVE_PC
5015 | mr SAVE0, RD
5016 | bl extern lj_tab_reasize // (lua_State *L, GCtab *t, int nasize)
5017 | // Must not reallocate the stack.
5018 | mr RD, SAVE0
5019 | b <1
5020 |
5021 |7: // Possible table write barrier for any value. Skip valiswhite check.
5022 | barrierback TAB:CARG2, TMP3, TMP0
5023 | b <4
5024 break;
5026 /* -- Calls and vararg handling ----------------------------------------- */
5028 case BC_CALLM:
5029 | // RA = base*8, (RB = (nresults+1)*8,) RC = extra_nargs*8
5030 | add NARGS8:RC, NARGS8:RC, MULTRES
5031 | // Fall through. Assumes BC_CALL follows.
5032 break;
5033 case BC_CALL:
5034 | // RA = base*8, (RB = (nresults+1)*8,) RC = (nargs+1)*8
5035 | mr TMP2, BASE
5036 | lwzux TMP0, BASE, RA
5037 | lwz LFUNC:RB, 4(BASE)
5038 | subi NARGS8:RC, NARGS8:RC, 8
5039 | addi BASE, BASE, 8
5040 | checkfunc TMP0; bne ->vmeta_call
5041 | ins_call
5042 break;
5044 case BC_CALLMT:
5045 | // RA = base*8, (RB = 0,) RC = extra_nargs*8
5046 | add NARGS8:RC, NARGS8:RC, MULTRES
5047 | // Fall through. Assumes BC_CALLT follows.
5048 break;
5049 case BC_CALLT:
5050 | // RA = base*8, (RB = 0,) RC = (nargs+1)*8
5051 | lwzux TMP0, RA, BASE
5052 | lwz LFUNC:RB, 4(RA)
5053 | subi NARGS8:RC, NARGS8:RC, 8
5054 | lwz TMP1, FRAME_PC(BASE)
5055 | checkfunc TMP0
5056 | addi RA, RA, 8
5057 | bne ->vmeta_callt
5058 |->BC_CALLT_Z:
5059 | andix. TMP0, TMP1, FRAME_TYPE // Caveat: preserve cr0 until the crand.
5060 | lbz TMP3, LFUNC:RB->ffid
5061 | xori TMP2, TMP1, FRAME_VARG
5062 | cmplwi cr1, NARGS8:RC, 0
5063 | bne >7
5064 |1:
5065 | stw LFUNC:RB, FRAME_FUNC(BASE) // Copy function down, but keep PC.
5066 | li TMP2, 0
5067 | cmplwi cr7, TMP3, 1 // (> FF_C) Calling a fast function?
5068 | beq cr1, >3
5069 |2:
5070 | addi TMP3, TMP2, 8
5071 |.if FPU
5072 | lfdx f0, RA, TMP2
5073 |.else
5074 | add CARG3, RA, TMP2
5075 | lwz CARG1, 0(CARG3)
5076 | lwz CARG2, 4(CARG3)
5077 |.endif
5078 | cmplw cr1, TMP3, NARGS8:RC
5079 |.if FPU
5080 | stfdx f0, BASE, TMP2
5081 |.else
5082 | stwux CARG1, TMP2, BASE
5083 | stw CARG2, 4(TMP2)
5084 |.endif
5085 | mr TMP2, TMP3
5086 | bne cr1, <2
5087 |3:
5088 | crand 4*cr0+eq, 4*cr0+eq, 4*cr7+gt
5089 | beq >5
5090 |4:
5091 | ins_callt
5092 |
5093 |5: // Tailcall to a fast function with a Lua frame below.
5094 | lwz INS, -4(TMP1)
5095 | decode_RA8 RA, INS
5096 | sub TMP1, BASE, RA
5097 | lwz LFUNC:TMP1, FRAME_FUNC-8(TMP1)
5098 | lwz TMP1, LFUNC:TMP1->pc
5099 | lwz KBASE, PC2PROTO(k)(TMP1) // Need to prepare KBASE.
5100 | b <4
5101 |
5102 |7: // Tailcall from a vararg function.
5103 | andix. TMP0, TMP2, FRAME_TYPEP
5104 | bne <1 // Vararg frame below?
5105 | sub BASE, BASE, TMP2 // Relocate BASE down.
5106 | lwz TMP1, FRAME_PC(BASE)
5107 | andix. TMP0, TMP1, FRAME_TYPE
5108 | b <1
5109 break;
5111 case BC_ITERC:
5112 | // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 ((2+1)*8))
5113 | mr TMP2, BASE
5114 | add BASE, BASE, RA
5115 | lwz TMP1, -24(BASE)
5116 | lwz LFUNC:RB, -20(BASE)
5117 |.if FPU
5118 | lfd f1, -8(BASE)
5119 | lfd f0, -16(BASE)
5120 |.else
5121 | lwz CARG1, -8(BASE)
5122 | lwz CARG2, -4(BASE)
5123 | lwz CARG3, -16(BASE)
5124 | lwz CARG4, -12(BASE)
5125 |.endif
5126 | stw TMP1, 0(BASE) // Copy callable.
5127 | stw LFUNC:RB, 4(BASE)
5128 | checkfunc TMP1
5129 | li NARGS8:RC, 16 // Iterators get 2 arguments.
5130 |.if FPU
5131 | stfd f1, 16(BASE) // Copy control var.
5132 | stfdu f0, 8(BASE) // Copy state.
5133 |.else
5134 | stw CARG1, 16(BASE) // Copy control var.
5135 | stw CARG2, 20(BASE)
5136 | stwu CARG3, 8(BASE) // Copy state.
5137 | stw CARG4, 4(BASE)
5138 |.endif
5139 | bne ->vmeta_call
5140 | ins_call
5141 break;
5143 case BC_ITERN:
5144 | // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 (2+1)*8)
5145 |.if JIT
5146 | // NYI on big-endian
5147 |.endif
5148 |->vm_IITERN:
5149 | add RA, BASE, RA
5150 | lwz TAB:RB, -12(RA)
5151 | lwz RC, -4(RA) // Get index from control var.
5152 | lwz TMP0, TAB:RB->asize
5153 | lwz TMP1, TAB:RB->array
5154 | addi PC, PC, 4
5155 |1: // Traverse array part.
5156 | cmplw RC, TMP0
5157 | slwi TMP3, RC, 3
5158 | bge >5 // Index points after array part?
5159 | lwzx TMP2, TMP1, TMP3
5160 |.if FPU
5161 | lfdx f0, TMP1, TMP3
5162 |.else
5163 | lwzux CARG1, TMP3, TMP1
5164 | lwz CARG2, 4(TMP3)
5165 |.endif
5166 | checknil TMP2
5167 | lwz INS, -4(PC)
5168 | beq >4
5169 |.if DUALNUM
5170 | stw RC, 4(RA)
5171 | stw TISNUM, 0(RA)
5172 |.else
5173 | tonum_u f1, RC
5174 |.endif
5175 | addi RC, RC, 1
5176 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
5177 |.if FPU
5178 | stfd f0, 8(RA)
5179 |.else
5180 | stw CARG1, 8(RA)
5181 | stw CARG2, 12(RA)
5182 |.endif
5183 | decode_RD4 TMP1, INS
5184 | stw RC, -4(RA) // Update control var.
5185 | add PC, TMP1, TMP3
5186 |.if not DUALNUM
5187 | stfd f1, 0(RA)
5188 |.endif
5189 |3:
5190 | ins_next
5191 |
5192 |4: // Skip holes in array part.
5193 | addi RC, RC, 1
5194 | b <1
5195 |
5196 |5: // Traverse hash part.
5197 | lwz TMP1, TAB:RB->hmask
5198 | sub RC, RC, TMP0
5199 | lwz TMP2, TAB:RB->node
5200 |6:
5201 | cmplw RC, TMP1 // End of iteration? Branch to ITERL+1.
5202 | slwi TMP3, RC, 5
5203 | bgty <3
5204 | slwi RB, RC, 3
5205 | sub TMP3, TMP3, RB
5206 | lwzx RB, TMP2, TMP3
5207 |.if FPU
5208 | lfdx f0, TMP2, TMP3
5209 |.else
5210 | add CARG3, TMP2, TMP3
5211 | lwz CARG1, 0(CARG3)
5212 | lwz CARG2, 4(CARG3)
5213 |.endif
5214 | add NODE:TMP3, TMP2, TMP3
5215 | checknil RB
5216 | lwz INS, -4(PC)
5217 | beq >7
5218 |.if FPU
5219 | lfd f1, NODE:TMP3->key
5220 |.else
5221 | lwz CARG3, NODE:TMP3->key.u32.hi
5222 | lwz CARG4, NODE:TMP3->key.u32.lo
5223 |.endif
5224 | addis TMP2, PC, -(BCBIAS_J*4 >> 16)
5225 |.if FPU
5226 | stfd f0, 8(RA)
5227 |.else
5228 | stw CARG1, 8(RA)
5229 | stw CARG2, 12(RA)
5230 |.endif
5231 | add RC, RC, TMP0
5232 | decode_RD4 TMP1, INS
5233 |.if FPU
5234 | stfd f1, 0(RA)
5235 |.else
5236 | stw CARG3, 0(RA)
5237 | stw CARG4, 4(RA)
5238 |.endif
5239 | addi RC, RC, 1
5240 | add PC, TMP1, TMP2
5241 | stw RC, -4(RA) // Update control var.
5242 | b <3
5243 |
5244 |7: // Skip holes in hash part.
5245 | addi RC, RC, 1
5246 | b <6
5247 break;
5249 case BC_ISNEXT:
5250 | // RA = base*8, RD = target (points to ITERN)
5251 | add RA, BASE, RA
5252 | lwz TMP0, -24(RA)
5253 | lwz CFUNC:TMP1, -20(RA)
5254 | lwz TMP2, -16(RA)
5255 | lwz TMP3, -8(RA)
5256 | cmpwi cr0, TMP2, LJ_TTAB
5257 | cmpwi cr1, TMP0, LJ_TFUNC
5258 | cmpwi cr6, TMP3, LJ_TNIL
5259 | bne cr1, >5
5260 | lbz TMP1, CFUNC:TMP1->ffid
5261 | crand 4*cr0+eq, 4*cr0+eq, 4*cr6+eq
5262 | cmpwi cr7, TMP1, FF_next_N
5263 | srwi TMP0, RD, 1
5264 | crand 4*cr0+eq, 4*cr0+eq, 4*cr7+eq
5265 | add TMP3, PC, TMP0
5266 | bne cr0, >5
5267 | lus TMP1, (LJ_KEYINDEX >> 16)
5268 | ori TMP1, TMP1, (LJ_KEYINDEX & 0xffff)
5269 | stw ZERO, -4(RA) // Initialize control var.
5270 | stw TMP1, -8(RA)
5271 | addis PC, TMP3, -(BCBIAS_J*4 >> 16)
5272 |1:
5273 | ins_next
5274 |5: // Despecialize bytecode if any of the checks fail.
5275 | li TMP0, BC_JMP
5276 | li TMP1, BC_ITERC
5277 | stb TMP0, -1(PC)
5278 | addis PC, TMP3, -(BCBIAS_J*4 >> 16)
5279 | // NYI on big-endian: unpatch JLOOP.
5280 | stb TMP1, 3(PC)
5281 | b <1
5282 break;
5284 case BC_VARG:
5285 | // RA = base*8, RB = (nresults+1)*8, RC = numparams*8
5286 | lwz TMP0, FRAME_PC(BASE)
5287 | add RC, BASE, RC
5288 | add RA, BASE, RA
5289 | addi RC, RC, FRAME_VARG
5290 | add TMP2, RA, RB
5291 | subi TMP3, BASE, 8 // TMP3 = vtop
5292 | sub RC, RC, TMP0 // RC = vbase
5293 | // Note: RC may now be even _above_ BASE if nargs was < numparams.
5294 | cmplwi cr1, RB, 0
5295 |.if PPE
5296 | sub TMP1, TMP3, RC
5297 | cmpwi TMP1, 0
5298 |.else
5299 | sub. TMP1, TMP3, RC
5300 |.endif
5301 | beq cr1, >5 // Copy all varargs?
5302 | subi TMP2, TMP2, 16
5303 | ble >2 // No vararg slots?
5304 |1: // Copy vararg slots to destination slots.
5305 |.if FPU
5306 | lfd f0, 0(RC)
5307 |.else
5308 | lwz CARG1, 0(RC)
5309 | lwz CARG2, 4(RC)
5310 |.endif
5311 | addi RC, RC, 8
5312 |.if FPU
5313 | stfd f0, 0(RA)
5314 |.else
5315 | stw CARG1, 0(RA)
5316 | stw CARG2, 4(RA)
5317 |.endif
5318 | cmplw RA, TMP2
5319 | cmplw cr1, RC, TMP3
5320 | bge >3 // All destination slots filled?
5321 | addi RA, RA, 8
5322 | blt cr1, <1 // More vararg slots?
5323 |2: // Fill up remainder with nil.
5324 | stw TISNIL, 0(RA)
5325 | cmplw RA, TMP2
5326 | addi RA, RA, 8
5327 | blt <2
5328 |3:
5329 | ins_next
5330 |
5331 |5: // Copy all varargs.
5332 | lwz TMP0, L->maxstack
5333 | li MULTRES, 8 // MULTRES = (0+1)*8
5334 | bley <3 // No vararg slots?
5335 | add TMP2, RA, TMP1
5336 | cmplw TMP2, TMP0
5337 | addi MULTRES, TMP1, 8
5338 | bgt >7
5339 |6:
5340 |.if FPU
5341 | lfd f0, 0(RC)
5342 |.else
5343 | lwz CARG1, 0(RC)
5344 | lwz CARG2, 4(RC)
5345 |.endif
5346 | addi RC, RC, 8
5347 |.if FPU
5348 | stfd f0, 0(RA)
5349 |.else
5350 | stw CARG1, 0(RA)
5351 | stw CARG2, 4(RA)
5352 |.endif
5353 | cmplw RC, TMP3
5354 | addi RA, RA, 8
5355 | blt <6 // More vararg slots?
5356 | b <3
5357 |
5358 |7: // Grow stack for varargs.
5359 | mr CARG1, L
5360 | stp RA, L->top
5361 | sub SAVE0, RC, BASE // Need delta, because BASE may change.
5362 | stp BASE, L->base
5363 | sub RA, RA, BASE
5364 | stw PC, SAVE_PC
5365 | srwi CARG2, TMP1, 3
5366 | bl extern lj_state_growstack // (lua_State *L, int n)
5367 | lp BASE, L->base
5368 | add RA, BASE, RA
5369 | add RC, BASE, SAVE0
5370 | subi TMP3, BASE, 8
5371 | b <6
5372 break;
5374 /* -- Returns ----------------------------------------------------------- */
5376 case BC_RETM:
5377 | // RA = results*8, RD = extra_nresults*8
5378 | add RD, RD, MULTRES // MULTRES >= 8, so RD >= 8.
5379 | // Fall through. Assumes BC_RET follows.
5380 break;
5382 case BC_RET:
5383 | // RA = results*8, RD = (nresults+1)*8
5384 | lwz PC, FRAME_PC(BASE)
5385 | add RA, BASE, RA
5386 | mr MULTRES, RD
5387 |1:
5388 | andix. TMP0, PC, FRAME_TYPE
5389 | xori TMP1, PC, FRAME_VARG
5390 | bne ->BC_RETV_Z
5391 |
5392 |->BC_RET_Z:
5393 | // BASE = base, RA = resultptr, RD = (nresults+1)*8, PC = return
5394 | lwz INS, -4(PC)
5395 | cmpwi RD, 8
5396 | subi TMP2, BASE, 8
5397 | subi RC, RD, 8
5398 | decode_RB8 RB, INS
5399 | beq >3
5400 | li TMP1, 0
5401 |2:
5402 | addi TMP3, TMP1, 8
5403 |.if FPU
5404 | lfdx f0, RA, TMP1
5405 |.else
5406 | add CARG3, RA, TMP1
5407 | lwz CARG1, 0(CARG3)
5408 | lwz CARG2, 4(CARG3)
5409 |.endif
5410 | cmpw TMP3, RC
5411 |.if FPU
5412 | stfdx f0, TMP2, TMP1
5413 |.else
5414 | add CARG3, TMP2, TMP1
5415 | stw CARG1, 0(CARG3)
5416 | stw CARG2, 4(CARG3)
5417 |.endif
5418 | beq >3
5419 | addi TMP1, TMP3, 8
5420 |.if FPU
5421 | lfdx f1, RA, TMP3
5422 |.else
5423 | add CARG3, RA, TMP3
5424 | lwz CARG1, 0(CARG3)
5425 | lwz CARG2, 4(CARG3)
5426 |.endif
5427 | cmpw TMP1, RC
5428 |.if FPU
5429 | stfdx f1, TMP2, TMP3
5430 |.else
5431 | add CARG3, TMP2, TMP3
5432 | stw CARG1, 0(CARG3)
5433 | stw CARG2, 4(CARG3)
5434 |.endif
5435 | bne <2
5436 |3:
5437 |5:
5438 | cmplw RB, RD
5439 | decode_RA8 RA, INS
5440 | bgt >6
5441 | sub BASE, TMP2, RA
5442 | lwz LFUNC:TMP1, FRAME_FUNC(BASE)
5443 | ins_next1
5444 | lwz TMP1, LFUNC:TMP1->pc
5445 | lwz KBASE, PC2PROTO(k)(TMP1)
5446 | ins_next2
5447 |
5448 |6: // Fill up results with nil.
5449 | subi TMP1, RD, 8
5450 | addi RD, RD, 8
5451 | stwx TISNIL, TMP2, TMP1
5452 | b <5
5453 |
5454 |->BC_RETV_Z: // Non-standard return case.
5455 | andix. TMP2, TMP1, FRAME_TYPEP
5456 | bne ->vm_return
5457 | // Return from vararg function: relocate BASE down.
5458 | sub BASE, BASE, TMP1
5459 | lwz PC, FRAME_PC(BASE)
5460 | b <1
5461 break;
5463 case BC_RET0: case BC_RET1:
5464 | // RA = results*8, RD = (nresults+1)*8
5465 | lwz PC, FRAME_PC(BASE)
5466 | add RA, BASE, RA
5467 | mr MULTRES, RD
5468 | andix. TMP0, PC, FRAME_TYPE
5469 | xori TMP1, PC, FRAME_VARG
5470 | bney ->BC_RETV_Z
5471 |
5472 | lwz INS, -4(PC)
5473 | subi TMP2, BASE, 8
5474 | decode_RB8 RB, INS
5475 if (op == BC_RET1) {
5476 |.if FPU
5477 | lfd f0, 0(RA)
5478 | stfd f0, 0(TMP2)
5479 |.else
5480 | lwz CARG1, 0(RA)
5481 | lwz CARG2, 4(RA)
5482 | stw CARG1, 0(TMP2)
5483 | stw CARG2, 4(TMP2)
5484 |.endif
5485 }
5486 |5:
5487 | cmplw RB, RD
5488 | decode_RA8 RA, INS
5489 | bgt >6
5490 | sub BASE, TMP2, RA
5491 | lwz LFUNC:TMP1, FRAME_FUNC(BASE)
5492 | ins_next1
5493 | lwz TMP1, LFUNC:TMP1->pc
5494 | lwz KBASE, PC2PROTO(k)(TMP1)
5495 | ins_next2
5496 |
5497 |6: // Fill up results with nil.
5498 | subi TMP1, RD, 8
5499 | addi RD, RD, 8
5500 | stwx TISNIL, TMP2, TMP1
5501 | b <5
5502 break;
5504 /* -- Loops and branches ------------------------------------------------ */
5506 case BC_FORL:
5507 |.if JIT
5508 | hotloop
5509 |.endif
5510 | // Fall through. Assumes BC_IFORL follows.
5511 break;
5513 case BC_JFORI:
5514 case BC_JFORL:
5515 #if !LJ_HASJIT
5516 break;
5517 #endif
5518 case BC_FORI:
5519 case BC_IFORL:
5520 | // RA = base*8, RD = target (after end of loop or start of loop)
5521 vk = (op == BC_IFORL || op == BC_JFORL);
5522 |.if DUALNUM
5523 | // Integer loop.
5524 | lwzux TMP1, RA, BASE
5525 | lwz CARG1, FORL_IDX*8+4(RA)
5526 | cmplw cr0, TMP1, TISNUM
5527 if (vk) {
5528 | lwz CARG3, FORL_STEP*8+4(RA)
5529 | bne >9
5530 |.if GPR64
5531 | // Need to check overflow for (a<<32) + (b<<32).
5532 | rldicr TMP0, CARG1, 32, 31
5533 | rldicr TMP2, CARG3, 32, 31
5534 | add CARG1, CARG1, CARG3
5535 | addo. TMP0, TMP0, TMP2
5536 |.else
5537 | addo. CARG1, CARG1, CARG3
5538 |.endif
5539 | cmpwi cr6, CARG3, 0
5540 | lwz CARG2, FORL_STOP*8+4(RA)
5541 | bso >6
5542 |4:
5543 | stw CARG1, FORL_IDX*8+4(RA)
5544 } else {
5545 | lwz SAVE0, FORL_STEP*8(RA)
5546 | lwz CARG3, FORL_STEP*8+4(RA)
5547 | lwz TMP2, FORL_STOP*8(RA)
5548 | lwz CARG2, FORL_STOP*8+4(RA)
5549 | cmplw cr7, SAVE0, TISNUM
5550 | cmplw cr1, TMP2, TISNUM
5551 | crand 4*cr0+eq, 4*cr0+eq, 4*cr7+eq
5552 | crand 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
5553 | cmpwi cr6, CARG3, 0
5554 | bne >9
5555 }
5556 | blt cr6, >5
5557 | cmpw CARG1, CARG2
5558 |1:
5559 | stw TISNUM, FORL_EXT*8(RA)
5560 if (op != BC_JFORL) {
5561 | srwi RD, RD, 1
5562 }
5563 | stw CARG1, FORL_EXT*8+4(RA)
5564 if (op != BC_JFORL) {
5565 | add RD, PC, RD
5566 }
5567 if (op == BC_FORI) {
5568 | bgt >3 // See FP loop below.
5569 } else if (op == BC_JFORI) {
5570 | addis PC, RD, -(BCBIAS_J*4 >> 16)
5571 | bley >7
5572 } else if (op == BC_IFORL) {
5573 | bgt >2
5574 | addis PC, RD, -(BCBIAS_J*4 >> 16)
5575 } else {
5576 | bley =>BC_JLOOP
5577 }
5578 |2:
5579 | ins_next
5580 |5: // Invert check for negative step.
5581 | cmpw CARG2, CARG1
5582 | b <1
5583 if (vk) {
5584 |6: // Potential overflow.
5585 | checkov TMP0, <4 // Ignore unrelated overflow.
5586 | b <2
5587 }
5588 |.endif
5589 if (vk) {
5590 |.if DUALNUM
5591 |9: // FP loop.
5592 |.if FPU
5593 | lfd f1, FORL_IDX*8(RA)
5594 |.else
5595 | lwz CARG1, FORL_IDX*8(RA)
5596 | lwz CARG2, FORL_IDX*8+4(RA)
5597 |.endif
5598 |.else
5599 | lfdux f1, RA, BASE
5600 |.endif
5601 |.if FPU
5602 | lfd f3, FORL_STEP*8(RA)
5603 | lfd f2, FORL_STOP*8(RA)
5604 | fadd f1, f1, f3
5605 | stfd f1, FORL_IDX*8(RA)
5606 |.else
5607 | lwz CARG3, FORL_STEP*8(RA)
5608 | lwz CARG4, FORL_STEP*8+4(RA)
5609 | mr SAVE1, RD
5610 | blex __adddf3
5611 | mr RD, SAVE1
5612 | stw CRET1, FORL_IDX*8(RA)
5613 | stw CRET2, FORL_IDX*8+4(RA)
5614 | lwz CARG3, FORL_STOP*8(RA)
5615 | lwz CARG4, FORL_STOP*8+4(RA)
5616 |.endif
5617 | lwz SAVE0, FORL_STEP*8(RA)
5618 } else {
5619 |.if DUALNUM
5620 |9: // FP loop.
5621 |.else
5622 | lwzux TMP1, RA, BASE
5623 | lwz SAVE0, FORL_STEP*8(RA)
5624 | lwz TMP2, FORL_STOP*8(RA)
5625 | cmplw cr0, TMP1, TISNUM
5626 | cmplw cr7, SAVE0, TISNUM
5627 | cmplw cr1, TMP2, TISNUM
5628 |.endif
5629 |.if FPU
5630 | lfd f1, FORL_IDX*8(RA)
5631 |.else
5632 | lwz CARG1, FORL_IDX*8(RA)
5633 | lwz CARG2, FORL_IDX*8+4(RA)
5634 |.endif
5635 | crand 4*cr0+lt, 4*cr0+lt, 4*cr7+lt
5636 | crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
5637 |.if FPU
5638 | lfd f2, FORL_STOP*8(RA)
5639 |.else
5640 | lwz CARG3, FORL_STOP*8(RA)
5641 | lwz CARG4, FORL_STOP*8+4(RA)
5642 |.endif
5643 | bge ->vmeta_for
5644 }
5645 | cmpwi cr6, SAVE0, 0
5646 if (op != BC_JFORL) {
5647 | srwi RD, RD, 1
5648 }
5649 |.if FPU
5650 | stfd f1, FORL_EXT*8(RA)
5651 |.else
5652 | stw CARG1, FORL_EXT*8(RA)
5653 | stw CARG2, FORL_EXT*8+4(RA)
5654 |.endif
5655 if (op != BC_JFORL) {
5656 | add RD, PC, RD
5657 }
5658 |.if FPU
5659 | fcmpu cr0, f1, f2
5660 |.else
5661 | mr SAVE1, RD
5662 | blex __ledf2
5663 | cmpwi CRET1, 0
5664 | mr RD, SAVE1
5665 |.endif
5666 if (op == BC_JFORI) {
5667 | addis PC, RD, -(BCBIAS_J*4 >> 16)
5668 }
5669 | blt cr6, >5
5670 if (op == BC_FORI) {
5671 | bgt >3
5672 } else if (op == BC_IFORL) {
5673 |.if DUALNUM
5674 | bgty <2
5675 |.else
5676 | bgt >2
5677 |.endif
5678 |1:
5679 | addis PC, RD, -(BCBIAS_J*4 >> 16)
5680 } else if (op == BC_JFORI) {
5681 | bley >7
5682 } else {
5683 | bley =>BC_JLOOP
5684 }
5685 |.if DUALNUM
5686 | b <2
5687 |.else
5688 |2:
5689 | ins_next
5690 |.endif
5691 |5: // Negative step.
5692 if (op == BC_FORI) {
5693 | bge <2
5694 |3: // Used by integer loop, too.
5695 | addis PC, RD, -(BCBIAS_J*4 >> 16)
5696 } else if (op == BC_IFORL) {
5697 | bgey <1
5698 } else if (op == BC_JFORI) {
5699 | bgey >7
5700 } else {
5701 | bgey =>BC_JLOOP
5702 }
5703 | b <2
5704 if (op == BC_JFORI) {
5705 |7:
5706 | lwz INS, -4(PC)
5707 | decode_RD8 RD, INS
5708 | b =>BC_JLOOP
5709 }
5710 break;
5712 case BC_ITERL:
5713 |.if JIT
5714 | hotloop
5715 |.endif
5716 | // Fall through. Assumes BC_IITERL follows.
5717 break;
5719 case BC_JITERL:
5720 #if !LJ_HASJIT
5721 break;
5722 #endif
5723 case BC_IITERL:
5724 | // RA = base*8, RD = target
5725 | lwzux TMP1, RA, BASE
5726 | lwz TMP2, 4(RA)
5727 | checknil TMP1; beq >1 // Stop if iterator returned nil.
5728 if (op == BC_JITERL) {
5729 | stw TMP1, -8(RA)
5730 | stw TMP2, -4(RA)
5731 | b =>BC_JLOOP
5732 } else {
5733 | branch_RD // Otherwise save control var + branch.
5734 | stw TMP1, -8(RA)
5735 | stw TMP2, -4(RA)
5736 }
5737 |1:
5738 | ins_next
5739 break;
5741 case BC_LOOP:
5742 | // RA = base*8, RD = target (loop extent)
5743 | // Note: RA/RD is only used by trace recorder to determine scope/extent
5744 | // This opcode does NOT jump, it's only purpose is to detect a hot loop.
5745 |.if JIT
5746 | hotloop
5747 |.endif
5748 | // Fall through. Assumes BC_ILOOP follows.
5749 break;
5751 case BC_ILOOP:
5752 | // RA = base*8, RD = target (loop extent)
5753 | ins_next
5754 break;
5756 case BC_JLOOP:
5757 |.if JIT
5758 | // RA = base*8 (ignored), RD = traceno*8
5759 | lwz TMP1, DISPATCH_J(trace)(DISPATCH)
5760 | srwi RD, RD, 1
5761 | // Traces on PPC don't store the trace number, so use 0.
5762 | stw ZERO, DISPATCH_GL(vmstate)(DISPATCH)
5763 | lwzx TRACE:TMP2, TMP1, RD
5764 | clrso TMP1
5765 | lp TMP2, TRACE:TMP2->mcode
5766 | stw BASE, DISPATCH_GL(jit_base)(DISPATCH)
5767 | mtctr TMP2
5768 | addi JGL, DISPATCH, GG_DISP2G+32768
5769 | stw L, DISPATCH_GL(tmpbuf.L)(DISPATCH)
5770 | bctr
5771 |.endif
5772 break;
5774 case BC_JMP:
5775 | // RA = base*8 (only used by trace recorder), RD = target
5776 | branch_RD
5777 | ins_next
5778 break;
5780 /* -- Function headers -------------------------------------------------- */
5782 case BC_FUNCF:
5783 |.if JIT
5784 | hotcall
5785 |.endif
5786 case BC_FUNCV: /* NYI: compiled vararg functions. */
5787 | // Fall through. Assumes BC_IFUNCF/BC_IFUNCV follow.
5788 break;
5790 case BC_JFUNCF:
5791 #if !LJ_HASJIT
5792 break;
5793 #endif
5794 case BC_IFUNCF:
5795 | // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
5796 | lwz TMP2, L->maxstack
5797 | lbz TMP1, -4+PC2PROTO(numparams)(PC)
5798 | lwz KBASE, -4+PC2PROTO(k)(PC)
5799 | cmplw RA, TMP2
5800 | slwi TMP1, TMP1, 3
5801 | bgt ->vm_growstack_l
5802 if (op != BC_JFUNCF) {
5803 | ins_next1
5804 }
5805 |2:
5806 | cmplw NARGS8:RC, TMP1 // Check for missing parameters.
5807 | blt >3
5808 if (op == BC_JFUNCF) {
5809 | decode_RD8 RD, INS
5810 | b =>BC_JLOOP
5811 } else {
5812 | ins_next2
5813 }
5814 |
5815 |3: // Clear missing parameters.
5816 | stwx TISNIL, BASE, NARGS8:RC
5817 | addi NARGS8:RC, NARGS8:RC, 8
5818 | b <2
5819 break;
5821 case BC_JFUNCV:
5822 #if !LJ_HASJIT
5823 break;
5824 #endif
5825 | NYI // NYI: compiled vararg functions
5826 break; /* NYI: compiled vararg functions. */
5828 case BC_IFUNCV:
5829 | // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
5830 | lwz TMP2, L->maxstack
5831 | add TMP1, BASE, RC
5832 | add TMP0, RA, RC
5833 | stw LFUNC:RB, 4(TMP1) // Store copy of LFUNC.
5834 | addi TMP3, RC, 8+FRAME_VARG
5835 | lwz KBASE, -4+PC2PROTO(k)(PC)
5836 | cmplw TMP0, TMP2
5837 | stw TMP3, 0(TMP1) // Store delta + FRAME_VARG.
5838 | bge ->vm_growstack_l
5839 | lbz TMP2, -4+PC2PROTO(numparams)(PC)
5840 | mr RA, BASE
5841 | mr RC, TMP1
5842 | ins_next1
5843 | cmpwi TMP2, 0
5844 | addi BASE, TMP1, 8
5845 | beq >3
5846 |1:
5847 | cmplw RA, RC // Less args than parameters?
5848 | lwz TMP0, 0(RA)
5849 | lwz TMP3, 4(RA)
5850 | bge >4
5851 | stw TISNIL, 0(RA) // Clear old fixarg slot (help the GC).
5852 | addi RA, RA, 8
5853 |2:
5854 | addic. TMP2, TMP2, -1
5855 | stw TMP0, 8(TMP1)
5856 | stw TMP3, 12(TMP1)
5857 | addi TMP1, TMP1, 8
5858 | bne <1
5859 |3:
5860 | ins_next2
5861 |
5862 |4: // Clear missing parameters.
5863 | li TMP0, LJ_TNIL
5864 | b <2
5865 break;
5867 case BC_FUNCC:
5868 case BC_FUNCCW:
5869 | // BASE = new base, RA = BASE+framesize*8, RB = CFUNC, RC = nargs*8
5870 if (op == BC_FUNCC) {
5871 | lp RD, CFUNC:RB->f
5872 } else {
5873 | lp RD, DISPATCH_GL(wrapf)(DISPATCH)
5874 }
5875 | add TMP1, RA, NARGS8:RC
5876 | lwz TMP2, L->maxstack
5877 | .toc lp TMP3, 0(RD)
5878 | add RC, BASE, NARGS8:RC
5879 | stp BASE, L->base
5880 | cmplw TMP1, TMP2
5881 | stp RC, L->top
5882 | li_vmstate C
5883 |.if TOC
5884 | mtctr TMP3
5885 |.else
5886 | mtctr RD
5887 |.endif
5888 if (op == BC_FUNCCW) {
5889 | lp CARG2, CFUNC:RB->f
5890 }
5891 | mr CARG1, L
5892 | bgt ->vm_growstack_c // Need to grow stack.
5893 | .toc lp TOCREG, TOC_OFS(RD)
5894 | .tocenv lp ENVREG, ENV_OFS(RD)
5895 | st_vmstate
5896 | bctrl // (lua_State *L [, lua_CFunction f])
5897 | // Returns nresults.
5898 | lp BASE, L->base
5899 | .toc ld TOCREG, SAVE_TOC
5900 | slwi RD, CRET1, 3
5901 | lp TMP1, L->top
5902 | li_vmstate INTERP
5903 | lwz PC, FRAME_PC(BASE) // Fetch PC of caller.
5904 | stw L, DISPATCH_GL(cur_L)(DISPATCH)
5905 | sub RA, TMP1, RD // RA = L->top - nresults*8
5906 | st_vmstate
5907 | b ->vm_returnc
5908 break;
5910 /* ---------------------------------------------------------------------- */
5912 default:
5913 fprintf(stderr, "Error: undefined opcode BC_%s\n", bc_names[op]);
5914 exit(2);
5915 break;
5916 }
5917 }
5919 static int build_backend(BuildCtx *ctx)
5920 {
5921 int op;
5923 dasm_growpc(Dst, BC__MAX);
5925 build_subroutines(ctx);
5927 |.code_op
5928 for (op = 0; op < BC__MAX; op++)
5929 build_ins(ctx, (BCOp)op, op);
5931 return BC__MAX;
5932 }
5934 /* Emit pseudo frame-info for all assembler functions. */
5935 static void emit_asm_debug(BuildCtx *ctx)
5936 {
5937 int fcofs = (int)((uint8_t *)ctx->glob[GLOB_vm_ffi_call] - ctx->code);
5938 int i;
5939 switch (ctx->mode) {
5940 case BUILD_elfasm:
5941 fprintf(ctx->fp, "\t.section .debug_frame,\"\",@progbits\n");
5942 fprintf(ctx->fp,
5943 ".Lframe0:\n"
5944 "\t.long .LECIE0-.LSCIE0\n"
5945 ".LSCIE0:\n"
5946 "\t.long 0xffffffff\n"
5947 "\t.byte 0x1\n"
5948 "\t.string \"\"\n"
5949 "\t.uleb128 0x1\n"
5950 "\t.sleb128 -4\n"
5951 "\t.byte 65\n"
5952 "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
5953 "\t.align 2\n"
5954 ".LECIE0:\n\n");
5955 fprintf(ctx->fp,
5956 ".LSFDE0:\n"
5957 "\t.long .LEFDE0-.LASFDE0\n"
5958 ".LASFDE0:\n"
5959 "\t.long .Lframe0\n"
5960 "\t.long .Lbegin\n"
5961 "\t.long %d\n"
5962 "\t.byte 0xe\n\t.uleb128 %d\n"
5963 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
5964 "\t.byte 0x5\n\t.uleb128 70\n\t.uleb128 55\n",
5965 fcofs, CFRAME_SIZE);
5966 for (i = 14; i <= 31; i++)
5967 fprintf(ctx->fp,
5968 "\t.byte %d\n\t.uleb128 %d\n"
5969 "\t.byte %d\n\t.uleb128 %d\n",
5970 0x80+i, 37+(31-i), 0x80+32+i, 2+2*(31-i));
5971 fprintf(ctx->fp,
5972 "\t.align 2\n"
5973 ".LEFDE0:\n\n");
5974 #if LJ_HASFFI
5975 fprintf(ctx->fp,
5976 ".LSFDE1:\n"
5977 "\t.long .LEFDE1-.LASFDE1\n"
5978 ".LASFDE1:\n"
5979 "\t.long .Lframe0\n"
5980 #if LJ_TARGET_PS3
5981 "\t.long .lj_vm_ffi_call\n"
5982 #else
5983 "\t.long lj_vm_ffi_call\n"
5984 #endif
5985 "\t.long %d\n"
5986 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
5987 "\t.byte 0x8e\n\t.uleb128 2\n"
5988 "\t.byte 0xd\n\t.uleb128 0xe\n"
5989 "\t.align 2\n"
5990 ".LEFDE1:\n\n", (int)ctx->codesz - fcofs);
5991 #endif
5992 #if !LJ_NO_UNWIND
5993 fprintf(ctx->fp, "\t.section .eh_frame,\"a\",@progbits\n");
5994 fprintf(ctx->fp,
5995 ".Lframe1:\n"
5996 "\t.long .LECIE1-.LSCIE1\n"
5997 ".LSCIE1:\n"
5998 "\t.long 0\n"
5999 "\t.byte 0x1\n"
6000 "\t.string \"zPR\"\n"
6001 "\t.uleb128 0x1\n"
6002 "\t.sleb128 -4\n"
6003 "\t.byte 65\n"
6004 "\t.uleb128 6\n" /* augmentation length */
6005 "\t.byte 0x1b\n" /* pcrel|sdata4 */
6006 "\t.long lj_err_unwind_dwarf-.\n"
6007 "\t.byte 0x1b\n" /* pcrel|sdata4 */
6008 "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
6009 "\t.align 2\n"
6010 ".LECIE1:\n\n");
6011 fprintf(ctx->fp,
6012 ".LSFDE2:\n"
6013 "\t.long .LEFDE2-.LASFDE2\n"
6014 ".LASFDE2:\n"
6015 "\t.long .LASFDE2-.Lframe1\n"
6016 "\t.long .Lbegin-.\n"
6017 "\t.long %d\n"
6018 "\t.uleb128 0\n" /* augmentation length */
6019 "\t.byte 0xe\n\t.uleb128 %d\n"
6020 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
6021 "\t.byte 0x5\n\t.uleb128 70\n\t.uleb128 55\n",
6022 fcofs, CFRAME_SIZE);
6023 for (i = 14; i <= 31; i++)
6024 fprintf(ctx->fp,
6025 "\t.byte %d\n\t.uleb128 %d\n"
6026 "\t.byte %d\n\t.uleb128 %d\n",
6027 0x80+i, 37+(31-i), 0x80+32+i, 2+2*(31-i));
6028 fprintf(ctx->fp,
6029 "\t.align 2\n"
6030 ".LEFDE2:\n\n");
6031 #if LJ_HASFFI
6032 fprintf(ctx->fp,
6033 ".Lframe2:\n"
6034 "\t.long .LECIE2-.LSCIE2\n"
6035 ".LSCIE2:\n"
6036 "\t.long 0\n"
6037 "\t.byte 0x1\n"
6038 "\t.string \"zR\"\n"
6039 "\t.uleb128 0x1\n"
6040 "\t.sleb128 -4\n"
6041 "\t.byte 65\n"
6042 "\t.uleb128 1\n" /* augmentation length */
6043 "\t.byte 0x1b\n" /* pcrel|sdata4 */
6044 "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
6045 "\t.align 2\n"
6046 ".LECIE2:\n\n");
6047 fprintf(ctx->fp,
6048 ".LSFDE3:\n"
6049 "\t.long .LEFDE3-.LASFDE3\n"
6050 ".LASFDE3:\n"
6051 "\t.long .LASFDE3-.Lframe2\n"
6052 "\t.long lj_vm_ffi_call-.\n"
6053 "\t.long %d\n"
6054 "\t.uleb128 0\n" /* augmentation length */
6055 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
6056 "\t.byte 0x8e\n\t.uleb128 2\n"
6057 "\t.byte 0xd\n\t.uleb128 0xe\n"
6058 "\t.align 2\n"
6059 ".LEFDE3:\n\n", (int)ctx->codesz - fcofs);
6060 #endif
6061 #endif
6062 break;
6063 default:
6064 break;
6065 }
6066 }