src/ps4build.bat

   1 @rem Script to build LuaJIT with the PS4 SDK.\r
   2 @rem Donated to the public domain.\r
   3 @rem\r
   4 @rem Open a "Visual Studio .NET Command Prompt" (64 bit host compiler)\r
   5 @rem or "VS2015 x64 Native Tools Command Prompt".\r
   6 @rem\r
   7 @rem Then cd to this directory and run this script.\r
   8 @rem\r
   9 @rem Recommended invocation:\r
  10 @rem\r
  11 @rem ps4build        release build, amalgamated, 64-bit GC\r
  12 @rem ps4build debug    debug build, amalgamated, 64-bit GC\r
  13 @rem\r
  14 @rem Additional command-line options (not generally recommended):\r
  15 @rem\r
  16 @rem gc32 (before debug)    32-bit GC\r
  17 @rem noamalg (after debug)  non-amalgamated build\r
  18 \r
  19 @if not defined INCLUDE goto :FAIL\r
  20 @if not defined SCE_ORBIS_SDK_DIR goto :FAIL\r
  21 \r
  22 @setlocal\r
  23 @rem ---- Host compiler ----\r
  24 @set LJCOMPILE=cl /nologo /c /MD /O2 /W3 /D_CRT_SECURE_NO_DEPRECATE\r
  25 @set LJLINK=link /nologo\r
  26 @set LJMT=mt /nologo\r
  27 @set DASMDIR=..\dynasm\r
  28 @set DASM=%DASMDIR%\dynasm.lua\r
  29 @set ALL_LIB=lib_base.c lib_math.c lib_bit.c lib_string.c lib_table.c lib_io.c lib_os.c lib_package.c lib_debug.c lib_jit.c lib_ffi.c lib_buffer.c\r
  30 @set GC64=\r
  31 @set DASC=vm_x64.dasc\r
  32 \r
  33 @if "%1" neq "gc32" goto :NOGC32\r
  34 @shift\r
  35 @set GC64=-DLUAJIT_DISABLE_GC64\r
  36 @set DASC=vm_x86.dasc\r
  37 :NOGC32\r
  38 \r
  39 %LJCOMPILE% host\minilua.c\r
  40 @if errorlevel 1 goto :BAD\r
  41 %LJLINK% /out:minilua.exe minilua.obj\r
  42 @if errorlevel 1 goto :BAD\r
  43 if exist minilua.exe.manifest^\r
  44   %LJMT% -manifest minilua.exe.manifest -outputresource:minilua.exe\r
  45 \r
  46 @rem Check for 64 bit host compiler.\r
  47 @minilua\r
  48 @if not errorlevel 8 goto :FAIL\r
  49 \r
  50 @set DASMFLAGS=-D P64 -D NO_UNWIND\r
  51 minilua %DASM% -LN %DASMFLAGS% -o host\buildvm_arch.h %DASC%\r
  52 @if errorlevel 1 goto :BAD\r
  53 \r
  54 if exist ..\.git ( git show -s --format=%%ct >luajit_relver.txt ) else ( type ..\.relver >luajit_relver.txt )\r
  55 minilua host\genversion.lua\r
  56 \r
  57 %LJCOMPILE% /I "." /I %DASMDIR% %GC64% -DLUAJIT_TARGET=LUAJIT_ARCH_X64 -DLUAJIT_OS=LUAJIT_OS_OTHER -DLUAJIT_DISABLE_JIT -DLUAJIT_DISABLE_FFI -DLUAJIT_USE_SYSMALLOC -DLUAJIT_NO_UNWIND host\buildvm*.c\r
  58 \r
  59 @if errorlevel 1 goto :BAD\r
  60 %LJLINK% /out:buildvm.exe buildvm*.obj\r
  61 @if errorlevel 1 goto :BAD\r
  62 if exist buildvm.exe.manifest^\r
  63   %LJMT% -manifest buildvm.exe.manifest -outputresource:buildvm.exe\r
  64 \r
  65 buildvm -m elfasm -o lj_vm.s\r
  66 @if errorlevel 1 goto :BAD\r
  67 buildvm -m bcdef -o lj_bcdef.h %ALL_LIB%\r
  68 @if errorlevel 1 goto :BAD\r
  69 buildvm -m ffdef -o lj_ffdef.h %ALL_LIB%\r
  70 @if errorlevel 1 goto :BAD\r
  71 buildvm -m libdef -o lj_libdef.h %ALL_LIB%\r
  72 @if errorlevel 1 goto :BAD\r
  73 buildvm -m recdef -o lj_recdef.h %ALL_LIB%\r
  74 @if errorlevel 1 goto :BAD\r
  75 buildvm -m vmdef -o jit\vmdef.lua %ALL_LIB%\r
  76 @if errorlevel 1 goto :BAD\r
  77 buildvm -m folddef -o lj_folddef.h lj_opt_fold.c\r
  78 @if errorlevel 1 goto :BAD\r
  79 \r
  80 @rem ---- Cross compiler ----\r
  81 @set LJCOMPILE="%SCE_ORBIS_SDK_DIR%\host_tools\bin\orbis-clang" -c -Wall -DLUAJIT_DISABLE_FFI %GC64%\r
  82 @set LJLIB="%SCE_ORBIS_SDK_DIR%\host_tools\bin\orbis-ar" rcus\r
  83 @set INCLUDE=""\r
  84 \r
  85 "%SCE_ORBIS_SDK_DIR%\host_tools\bin\orbis-as" -o lj_vm.o lj_vm.s\r
  86 \r
  87 @if "%1" neq "debug" goto :NODEBUG\r
  88 @shift\r
  89 @set LJCOMPILE=%LJCOMPILE% -g -O0\r
  90 @set TARGETLIB=libluajitD_ps4.a\r
  91 goto :BUILD\r
  92 :NODEBUG\r
  93 @set LJCOMPILE=%LJCOMPILE% -O2\r
  94 @set TARGETLIB=libluajit_ps4.a\r
  95 :BUILD\r
  96 del %TARGETLIB%\r
  97 @if "%1" neq "noamalg" goto :AMALG\r
  98 for %%f in (lj_*.c lib_*.c) do (\r
  99   %LJCOMPILE% %%f\r
 100   @if errorlevel 1 goto :BAD\r
 101 )\r
 102 \r
 103 %LJLIB% %TARGETLIB% lj_*.o lib_*.o\r
 104 @if errorlevel 1 goto :BAD\r
 105 @goto :NOAMALG\r
 106 :AMALG\r
 107 %LJCOMPILE% ljamalg.c\r
 108 @if errorlevel 1 goto :BAD\r
 109 %LJLIB% %TARGETLIB% ljamalg.o lj_vm.o\r
 110 @if errorlevel 1 goto :BAD\r
 111 :NOAMALG\r
 112 \r
 113 @del *.o *.obj *.manifest minilua.exe buildvm.exe\r
 114 @echo.\r
 115 @echo === Successfully built LuaJIT for PS4 ===\r
 116 \r
 117 @goto :END\r
 118 :BAD\r
 119 @echo.\r
 120 @echo *******************************************************\r
 121 @echo *** Build FAILED -- Please check the error messages ***\r
 122 @echo *******************************************************\a\r
 123 @goto :END\r
 124 :FAIL\r
 125 @echo To run this script you must open a "Visual Studio .NET Command Prompt"\r
 126 @echo (64 bit host compiler). The PS4 Orbis SDK must be installed, too.\r
 127 :END\r