src/msvcbuild.bat

   1 @rem Script to build LuaJIT with MSVC.\r
   2 @rem Copyright (C) 2005-2021 Mike Pall. See Copyright Notice in luajit.h\r
   3 @rem\r
   4 @rem Open a "Visual Studio Command Prompt" (either x86 or x64).\r
   5 @rem Then cd to this directory and run this script. Use the following\r
   6 @rem options (in order), if needed. The default is a dynamic release build.\r
   7 @rem\r
   8 @rem   debug    emit debug symbols\r
   9 @rem   amalg    amalgamated build\r
  10 @rem   static   static linkage\r
  11 \r
  12 @if not defined INCLUDE goto :FAIL\r
  13 \r
  14 @setlocal\r
  15 @rem Add more debug flags here, e.g. DEBUGCFLAGS=/DLUA_USE_APICHECK\r
  16 @set DEBUGCFLAGS=\r
  17 @set LJCOMPILE=cl /nologo /c /O2 /W3 /D_CRT_SECURE_NO_DEPRECATE /D_CRT_STDIO_INLINE=__declspec(dllexport)__inline\r
  18 @set LJLINK=link /nologo\r
  19 @set LJMT=mt /nologo\r
  20 @set LJLIB=lib /nologo /nodefaultlib\r
  21 @set DASMDIR=..\dynasm\r
  22 @set DASM=%DASMDIR%\dynasm.lua\r
  23 @set LJDLLNAME=lua51.dll\r
  24 @set LJLIBNAME=lua51.lib\r
  25 @set BUILDTYPE=release\r
  26 @set ALL_LIB=lib_base.c lib_math.c lib_bit.c lib_string.c lib_table.c lib_io.c lib_os.c lib_package.c lib_debug.c lib_jit.c lib_ffi.c\r
  27 \r
  28 %LJCOMPILE% host\minilua.c\r
  29 @if errorlevel 1 goto :BAD\r
  30 %LJLINK% /out:minilua.exe minilua.obj\r
  31 @if errorlevel 1 goto :BAD\r
  32 if exist minilua.exe.manifest^\r
  33   %LJMT% -manifest minilua.exe.manifest -outputresource:minilua.exe\r
  34 \r
  35 @set DASMFLAGS=-D WIN -D JIT -D FFI -D P64\r
  36 @set LJARCH=x64\r
  37 @minilua\r
  38 @if errorlevel 8 goto :X64\r
  39 @set DASMFLAGS=-D WIN -D JIT -D FFI\r
  40 @set LJARCH=x86\r
  41 :X64\r
  42 minilua %DASM% -LN %DASMFLAGS% -o host\buildvm_arch.h vm_x86.dasc\r
  43 @if errorlevel 1 goto :BAD\r
  44 \r
  45 %LJCOMPILE% /I "." /I %DASMDIR% host\buildvm*.c\r
  46 @if errorlevel 1 goto :BAD\r
  47 %LJLINK% /out:buildvm.exe buildvm*.obj\r
  48 @if errorlevel 1 goto :BAD\r
  49 if exist buildvm.exe.manifest^\r
  50   %LJMT% -manifest buildvm.exe.manifest -outputresource:buildvm.exe\r
  51 \r
  52 buildvm -m peobj -o lj_vm.obj\r
  53 @if errorlevel 1 goto :BAD\r
  54 buildvm -m bcdef -o lj_bcdef.h %ALL_LIB%\r
  55 @if errorlevel 1 goto :BAD\r
  56 buildvm -m ffdef -o lj_ffdef.h %ALL_LIB%\r
  57 @if errorlevel 1 goto :BAD\r
  58 buildvm -m libdef -o lj_libdef.h %ALL_LIB%\r
  59 @if errorlevel 1 goto :BAD\r
  60 buildvm -m recdef -o lj_recdef.h %ALL_LIB%\r
  61 @if errorlevel 1 goto :BAD\r
  62 buildvm -m vmdef -o jit\vmdef.lua %ALL_LIB%\r
  63 @if errorlevel 1 goto :BAD\r
  64 buildvm -m folddef -o lj_folddef.h lj_opt_fold.c\r
  65 @if errorlevel 1 goto :BAD\r
  66 \r
  67 @if "%1" neq "debug" goto :NODEBUG\r
  68 @shift\r
  69 @set BUILDTYPE=debug\r
  70 @set LJCOMPILE=%LJCOMPILE% /Zi %DEBUGCFLAGS%\r
  71 :NODEBUG\r
  72 @set LJLINK=%LJLINK% /%BUILDTYPE%\r
  73 @if "%1"=="amalg" goto :AMALGDLL\r
  74 @if "%1"=="static" goto :STATIC\r
  75 %LJCOMPILE% /MD /DLUA_BUILD_AS_DLL lj_*.c lib_*.c\r
  76 @if errorlevel 1 goto :BAD\r
  77 %LJLINK% /DLL /out:%LJDLLNAME% lj_*.obj lib_*.obj\r
  78 @if errorlevel 1 goto :BAD\r
  79 @goto :MTDLL\r
  80 :STATIC\r
  81 %LJCOMPILE% lj_*.c lib_*.c\r
  82 @if errorlevel 1 goto :BAD\r
  83 %LJLIB% /OUT:%LJLIBNAME% lj_*.obj lib_*.obj\r
  84 @if errorlevel 1 goto :BAD\r
  85 @goto :MTDLL\r
  86 :AMALGDLL\r
  87 %LJCOMPILE% /MD /DLUA_BUILD_AS_DLL ljamalg.c\r
  88 @if errorlevel 1 goto :BAD\r
  89 %LJLINK% /DLL /out:%LJDLLNAME% ljamalg.obj lj_vm.obj\r
  90 @if errorlevel 1 goto :BAD\r
  91 :MTDLL\r
  92 if exist %LJDLLNAME%.manifest^\r
  93   %LJMT% -manifest %LJDLLNAME%.manifest -outputresource:%LJDLLNAME%;2\r
  94 \r
  95 %LJCOMPILE% luajit.c\r
  96 @if errorlevel 1 goto :BAD\r
  97 %LJLINK% /out:luajit.exe luajit.obj %LJLIBNAME%\r
  98 @if errorlevel 1 goto :BAD\r
  99 if exist luajit.exe.manifest^\r
 100   %LJMT% -manifest luajit.exe.manifest -outputresource:luajit.exe\r
 101 \r
 102 @del *.obj *.manifest minilua.exe buildvm.exe\r
 103 @del host\buildvm_arch.h\r
 104 @del lj_bcdef.h lj_ffdef.h lj_libdef.h lj_recdef.h lj_folddef.h\r
 105 @echo.\r
 106 @echo === Successfully built LuaJIT for Windows/%LJARCH% ===\r
 107 \r
 108 @goto :END\r
 109 :BAD\r
 110 @echo.\r
 111 @echo *******************************************************\r
 112 @echo *** Build FAILED -- Please check the error messages ***\r
 113 @echo *******************************************************\a\r
 114 @goto :END\r
 115 :FAIL\r
 116 @echo You must open a "Visual Studio Command Prompt" to run this script\r
 117 :END\r