src/buildvm_ppc.dasc

   1 |// Low-level VM code for PowerPC CPUs.
   2 |// Bytecode interpreter, fast functions and helper functions.
   3 |// Copyright (C) 2005-2012 Mike Pall. See Copyright Notice in luajit.h
   4 |
   5 |.arch ppc
   6 |.section code_op, code_sub
   7 |
   8 |.actionlist build_actionlist
   9 |.globals GLOB_
  10 |.globalnames globnames
  11 |.externnames extnames
  12 |
  13 |// Note: The ragged indentation of the instructions is intentional.
  14 |//       The starting columns indicate data dependencies.
  15 |
  16 |//-----------------------------------------------------------------------
  17 |
  18 |// Fixed register assignments for the interpreter.
  19 |// Don't use: r1 = sp, r2 and r13 = reserved (TOC, TLS or SDATA)
  20 |
  21 |// The following must be C callee-save (but BASE is often refetched).
  22 |.define BASE,          r14     // Base of current Lua stack frame.
  23 |.define KBASE,         r15     // Constants of current Lua function.
  24 |.define PC,            r16     // Next PC.
  25 |.define DISPATCH,      r17     // Opcode dispatch table.
  26 |.define LREG,          r18     // Register holding lua_State (also in SAVE_L).
  27 |.define MULTRES,       r19     // Size of multi-result: (nresults+1)*8.
  28 |.define JGL,           r31     // On-trace: global_State + 32768.
  29 |
  30 |// Constants for type-comparisons, stores and conversions. C callee-save.
  31 |.define TISNUM,        r22
  32 |.define TISNIL,        r23
  33 |.define ZERO,          r24
  34 |.define TOBIT,         f30     // 2^52 + 2^51.
  35 |.define TONUM,         f31     // 2^52 + 2^51 + 2^31.
  36 |
  37 |// The following temporaries are not saved across C calls, except for RA.
  38 |.define RA,            r20     // Callee-save.
  39 |.define RB,            r10
  40 |.define RC,            r11
  41 |.define RD,            r12
  42 |.define INS,           r7      // Overlaps CARG5.
  43 |
  44 |.define TMP0,          r0
  45 |.define TMP1,          r8
  46 |.define TMP2,          r9
  47 |.define TMP3,          r6      // Overlaps CARG4.
  48 |
  49 |// Saved temporaries.
  50 |.define SAVE0,         r21
  51 |
  52 |// Calling conventions.
  53 |.define CARG1,         r3
  54 |.define CARG2,         r4
  55 |.define CARG3,         r5
  56 |.define CARG4,         r6      // Overlaps TMP3.
  57 |.define CARG5,         r7      // Overlaps INS.
  58 |
  59 |.define FARG1,         f1
  60 |.define FARG2,         f2
  61 |
  62 |.define CRET1,         r3
  63 |.define CRET2,         r4
  64 |
  65 |// Stack layout while in interpreter. Must match with lj_frame.h.
  66 |.define SAVE_LR,       276(sp)
  67 |.define CFRAME_SPACE,  272     // Delta for sp.
  68 |// Back chain for sp:  272(sp) <-- sp entering interpreter
  69 |.define SAVE_FPR_,     128     // .. 128+18*8: 64 bit FPR saves.
  70 |.define SAVE_GPR_,     56      // .. 56+18*4: 32 bit GPR saves.
  71 |.define SAVE_CR,       52(sp)  // 32 bit CR save.
  72 |.define SAVE_ERRF,     48(sp)  // 32 bit C frame info.
  73 |.define SAVE_NRES,     44(sp)
  74 |.define SAVE_CFRAME,   40(sp)
  75 |.define SAVE_L,        36(sp)
  76 |.define SAVE_PC,       32(sp)
  77 |.define SAVE_MULTRES,  28(sp)
  78 |.define UNUSED1,       24(sp)
  79 |.define TMPD_LO,       20(sp)
  80 |.define TMPD_HI,       16(sp)
  81 |.define TONUM_LO,      12(sp)
  82 |.define TONUM_HI,      8(sp)
  83 |// Next frame lr:      4(sp)
  84 |// Back chain for sp:  0(sp)   <-- sp while in interpreter
  85 |
  86 |.define TMPD_BLO,      23(sp)
  87 |.define TMPD,          TMPD_HI
  88 |.define TONUM_D,       TONUM_HI
  89 |
  90 |.macro save_, reg
  91 |  stw r..reg, SAVE_GPR_+(reg-14)*4(sp)
  92 |  stfd f..reg, SAVE_FPR_+(reg-14)*8(sp)
  93 |.endmacro
  94 |.macro rest_, reg
  95 |  lwz r..reg, SAVE_GPR_+(reg-14)*4(sp)
  96 |  lfd f..reg, SAVE_FPR_+(reg-14)*8(sp)
  97 |.endmacro
  98 |
  99 |.macro saveregs
 100 |  stwu sp, -CFRAME_SPACE(sp)
 101 |  save_ 14; save_ 15; save_ 16
 102 |  mflr r0
 103 |  save_ 17; save_ 18; save_ 19; save_ 20; save_ 21; save_ 22
 104 |  stw  r0, SAVE_LR
 105 |  save_ 23; save_ 24; save_ 25
 106 |  mfcr r0
 107 |  save_ 26; save_ 27; save_ 28; save_ 29; save_ 30; save_ 31
 108 |  stw r0, SAVE_CR
 109 |.endmacro
 110 |
 111 |.macro restoreregs
 112 |  lwz r0, SAVE_LR; lwz r12, SAVE_CR
 113 |  rest_ 14; rest_ 15; rest_ 16; rest_ 17; rest_ 18; rest_ 19
 114 |  mtlr r0; mtcrf 0x38, r12
 115 |  rest_ 20; rest_ 21; rest_ 22; rest_ 23; rest_ 24; rest_ 25
 116 |  rest_ 26; rest_ 27; rest_ 28; rest_ 29; rest_ 30; rest_ 31
 117 |  addi sp, sp, CFRAME_SPACE
 118 |.endmacro
 119 |
 120 |// Type definitions. Some of these are only used for documentation.
 121 |.type L,               lua_State,      LREG
 122 |.type GL,              global_State
 123 |.type TVALUE,          TValue
 124 |.type GCOBJ,           GCobj
 125 |.type STR,             GCstr
 126 |.type TAB,             GCtab
 127 |.type LFUNC,           GCfuncL
 128 |.type CFUNC,           GCfuncC
 129 |.type PROTO,           GCproto
 130 |.type UPVAL,           GCupval
 131 |.type NODE,            Node
 132 |.type NARGS8,          int
 133 |.type TRACE,           GCtrace
 134 |
 135 |//-----------------------------------------------------------------------
 136 |
 137 |// These basic macros should really be part of DynASM.
 138 |.macro srwi, rx, ry, n; rlwinm rx, ry, 32-n, n, 31; .endmacro
 139 |.macro slwi, rx, ry, n; rlwinm rx, ry, n, 0, 31-n; .endmacro
 140 |.macro rotlwi, rx, ry, n; rlwinm rx, ry, n, 0, 31; .endmacro
 141 |.macro rotlw, rx, ry, rn; rlwnm rx, ry, rn, 0, 31; .endmacro
 142 |.macro subi, rx, ry, i; addi rx, ry, -i; .endmacro
 143 |
 144 |// Trap for not-yet-implemented parts.
 145 |.macro NYI; tw 4, sp, sp; .endmacro
 146 |
 147 |// int/FP conversions.
 148 |.macro tonum_i, freg, reg
 149 |  xoris reg, reg, 0x8000
 150 |  stw reg, TONUM_LO
 151 |  lfd freg, TONUM_D
 152 |  fsub freg, freg, TONUM
 153 |.endmacro
 154 |
 155 |.macro tonum_u, freg, reg
 156 |  stw reg, TONUM_LO
 157 |  lfd freg, TONUM_D
 158 |  fsub freg, freg, TOBIT
 159 |.endmacro
 160 |
 161 |.macro toint, reg, freg, tmpfreg
 162 |  fctiwz tmpfreg, freg
 163 |  stfd tmpfreg, TMPD
 164 |  lwz reg, TMPD_LO
 165 |.endmacro
 166 |
 167 |.macro toint, reg, freg
 168 |  toint reg, freg, freg
 169 |.endmacro
 170 |
 171 |//-----------------------------------------------------------------------
 172 |
 173 |// Access to frame relative to BASE.
 174 |.define FRAME_PC,      -8
 175 |.define FRAME_FUNC,    -4
 176 |
 177 |// Instruction decode.
 178 |.macro decode_OP4, dst, ins; rlwinm dst, ins, 2, 22, 29; .endmacro
 179 |.macro decode_RA8, dst, ins; rlwinm dst, ins, 27, 21, 28; .endmacro
 180 |.macro decode_RB8, dst, ins; rlwinm dst, ins, 11, 21, 28; .endmacro
 181 |.macro decode_RC8, dst, ins; rlwinm dst, ins, 19, 21, 28; .endmacro
 182 |.macro decode_RD8, dst, ins; rlwinm dst, ins, 19, 13, 28; .endmacro
 183 |
 184 |.macro decode_OP1, dst, ins; rlwinm dst, ins, 0, 24, 31; .endmacro
 185 |.macro decode_RD4, dst, ins; rlwinm dst, ins, 18, 14, 29; .endmacro
 186 |
 187 |// Instruction fetch.
 188 |.macro ins_NEXT1
 189 |  lwz INS, 0(PC)
 190 |   addi PC, PC, 4
 191 |.endmacro
 192 |// Instruction decode+dispatch. Note: optimized for e300!
 193 |.macro ins_NEXT2
 194 |  decode_OP4 TMP1, INS
 195 |  lwzx TMP0, DISPATCH, TMP1
 196 |  mtctr TMP0
 197 |   decode_RB8 RB, INS
 198 |   decode_RD8 RD, INS
 199 |   decode_RA8 RA, INS
 200 |   decode_RC8 RC, INS
 201 |  bctr
 202 |.endmacro
 203 |.macro ins_NEXT
 204 |  ins_NEXT1
 205 |  ins_NEXT2
 206 |.endmacro
 207 |
 208 |// Instruction footer.
 209 |.if 1
 210 |  // Replicated dispatch. Less unpredictable branches, but higher I-Cache use.
 211 |  .define ins_next, ins_NEXT
 212 |  .define ins_next_, ins_NEXT
 213 |  .define ins_next1, ins_NEXT1
 214 |  .define ins_next2, ins_NEXT2
 215 |.else
 216 |  // Common dispatch. Lower I-Cache use, only one (very) unpredictable branch.
 217 |  // Affects only certain kinds of benchmarks (and only with -j off).
 218 |  .macro ins_next
 219 |    b ->ins_next
 220 |  .endmacro
 221 |  .macro ins_next1
 222 |  .endmacro
 223 |  .macro ins_next2
 224 |    b ->ins_next
 225 |  .endmacro
 226 |  .macro ins_next_
 227 |  ->ins_next:
 228 |    ins_NEXT
 229 |  .endmacro
 230 |.endif
 231 |
 232 |// Call decode and dispatch.
 233 |.macro ins_callt
 234 |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
 235 |  lwz PC, LFUNC:RB->pc
 236 |  lwz INS, 0(PC)
 237 |   addi PC, PC, 4
 238 |  decode_OP4 TMP1, INS
 239 |   decode_RA8 RA, INS
 240 |  lwzx TMP0, DISPATCH, TMP1
 241 |   add RA, RA, BASE
 242 |  mtctr TMP0
 243 |  bctr
 244 |.endmacro
 245 |
 246 |.macro ins_call
 247 |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, PC = caller PC
 248 |  stw PC, FRAME_PC(BASE)
 249 |  ins_callt
 250 |.endmacro
 251 |
 252 |//-----------------------------------------------------------------------
 253 |
 254 |// Macros to test operand types.
 255 |.macro checknum, reg; cmplw reg, TISNUM; .endmacro
 256 |.macro checknum, cr, reg; cmplw cr, reg, TISNUM; .endmacro
 257 |.macro checkstr, reg; cmpwi reg, LJ_TSTR; .endmacro
 258 |.macro checktab, reg; cmpwi reg, LJ_TTAB; .endmacro
 259 |.macro checkfunc, reg; cmpwi reg, LJ_TFUNC; .endmacro
 260 |.macro checknil, reg; cmpwi reg, LJ_TNIL; .endmacro
 261 |
 262 |.macro branch_RD
 263 |  srwi TMP0, RD, 1
 264 |  addis PC, PC, -(BCBIAS_J*4 >> 16)
 265 |  add PC, PC, TMP0
 266 |.endmacro
 267 |
 268 |// Assumes DISPATCH is relative to GL.
 269 #define DISPATCH_GL(field)      (GG_DISP2G + (int)offsetof(global_State, field))
 270 #define DISPATCH_J(field)       (GG_DISP2J + (int)offsetof(jit_State, field))
 271 |
 272 #define PC2PROTO(field)  ((int)offsetof(GCproto, field)-(int)sizeof(GCproto))
 273 |
 274 |.macro hotcheck, delta, target
 275 |  rlwinm TMP1, PC, 31, 25, 30
 276 |  addi TMP1, TMP1, GG_DISP2HOT
 277 |  lhzx TMP2, DISPATCH, TMP1
 278 |  addic. TMP2, TMP2, -delta
 279 |  sthx TMP2, DISPATCH, TMP1
 280 |  blt target
 281 |.endmacro
 282 |
 283 |.macro hotloop
 284 |  hotcheck HOTCOUNT_LOOP, ->vm_hotloop
 285 |.endmacro
 286 |
 287 |.macro hotcall
 288 |  hotcheck HOTCOUNT_CALL, ->vm_hotcall
 289 |.endmacro
 290 |
 291 |// Set current VM state. Uses TMP0.
 292 |.macro li_vmstate, st; li TMP0, ~LJ_VMST_..st; .endmacro
 293 |.macro st_vmstate; stw TMP0, DISPATCH_GL(vmstate)(DISPATCH); .endmacro
 294 |
 295 |// Move table write barrier back. Overwrites mark and tmp.
 296 |.macro barrierback, tab, mark, tmp
 297 |  lwz tmp, DISPATCH_GL(gc.grayagain)(DISPATCH)
 298 |  // Assumes LJ_GC_BLACK is 0x04.
 299 |   rlwinm mark, mark, 0, 30, 28                // black2gray(tab)
 300 |  stw tab, DISPATCH_GL(gc.grayagain)(DISPATCH)
 301 |   stb mark, tab->marked
 302 |  stw tmp, tab->gclist
 303 |.endmacro
 304 |
 305 |//-----------------------------------------------------------------------
 306
 307 /* Generate subroutines used by opcodes and other parts of the VM. */
 308 /* The .code_sub section should be last to help static branch prediction. */
 309 static void build_subroutines(BuildCtx *ctx)
 310 {
 311   |.code_sub
 312   |
 313   |//-----------------------------------------------------------------------
 314   |//-- Return handling ----------------------------------------------------
 315   |//-----------------------------------------------------------------------
 316   |
 317   |->vm_returnp:
 318   |  // See vm_return. Also: TMP2 = previous base.
 319   |  andi. TMP0, PC, FRAME_P
 320   |   li TMP1, LJ_TTRUE
 321   |  beq ->cont_dispatch
 322   |
 323   |  // Return from pcall or xpcall fast func.
 324   |  lwz PC, FRAME_PC(TMP2)             // Fetch PC of previous frame.
 325   |  mr BASE, TMP2                      // Restore caller base.
 326   |  // Prepending may overwrite the pcall frame, so do it at the end.
 327   |   stwu TMP1, FRAME_PC(RA)           // Prepend true to results.
 328   |
 329   |->vm_returnc:
 330   |  andi. TMP0, PC, FRAME_TYPE
 331   |   addi RD, RD, 8                    // RD = (nresults+1)*8.
 332   |   mr MULTRES, RD
 333   |  beq ->BC_RET_Z                     // Handle regular return to Lua.
 334   |
 335   |->vm_return:
 336   |  // BASE = base, RA = resultptr, RD/MULTRES = (nresults+1)*8, PC = return
 337   |  // TMP0 = PC & FRAME_TYPE
 338   |  cmpwi TMP0, FRAME_C
 339   |   rlwinm TMP2, PC, 0, 0, 28
 340   |    li_vmstate C
 341   |   sub TMP2, BASE, TMP2              // TMP2 = previous base.
 342   |  bney ->vm_returnp
 343   |
 344   |  addic. TMP1, RD, -8
 345   |   stw TMP2, L->base
 346   |   lwz TMP2, SAVE_NRES
 347   |    subi BASE, BASE, 8
 348   |    st_vmstate
 349   |   slwi TMP2, TMP2, 3
 350   |  beq >2
 351   |1:
 352   |  addic. TMP1, TMP1, -8
 353   |   lfd f0, 0(RA)
 354   |    addi RA, RA, 8
 355   |   stfd f0, 0(BASE)
 356   |    addi BASE, BASE, 8
 357   |  bney <1
 358   |
 359   |2:
 360   |  cmpw TMP2, RD                      // More/less results wanted?
 361   |  bne >6
 362   |3:
 363   |  stw BASE, L->top                   // Store new top.
 364   |
 365   |->vm_leave_cp:
 366   |  lwz TMP0, SAVE_CFRAME              // Restore previous C frame.
 367   |   li CRET1, 0                       // Ok return status for vm_pcall.
 368   |  stw TMP0, L->cframe
 369   |
 370   |->vm_leave_unw:
 371   |  restoreregs
 372   |  blr
 373   |
 374   |6:
 375   |  ble >7                             // Less results wanted?
 376   |  // More results wanted. Check stack size and fill up results with nil.
 377   |  lwz TMP1, L->maxstack
 378   |  cmplw BASE, TMP1
 379   |  bge >8
 380   |  stw TISNIL, 0(BASE)
 381   |  addi RD, RD, 8
 382   |  addi BASE, BASE, 8
 383   |  b <2
 384   |
 385   |7:  // Less results wanted.
 386   |  subfic TMP3, TMP2, 0               // LUA_MULTRET+1 case?
 387   |   sub TMP0, RD, TMP2
 388   |  subfe TMP1, TMP1, TMP1             // TMP1 = TMP2 == 0 ? 0 : -1
 389   |   and TMP0, TMP0, TMP1
 390   |  sub BASE, BASE, TMP0               // Either keep top or shrink it.
 391   |  b <3
 392   |
 393   |8:  // Corner case: need to grow stack for filling up results.
 394   |  // This can happen if:
 395   |  // - A C function grows the stack (a lot).
 396   |  // - The GC shrinks the stack in between.
 397   |  // - A return back from a lua_call() with (high) nresults adjustment.
 398   |  stw BASE, L->top                   // Save current top held in BASE (yes).
 399   |   mr SAVE0, RD
 400   |  mr CARG2, TMP2
 401   |  mr CARG1, L
 402   |  bl extern lj_state_growstack       // (lua_State *L, int n)
 403   |    lwz TMP2, SAVE_NRES
 404   |   mr RD, SAVE0
 405   |    slwi TMP2, TMP2, 3
 406   |  lwz BASE, L->top                   // Need the (realloced) L->top in BASE.
 407   |  b <2
 408   |
 409   |->vm_unwind_c:                       // Unwind C stack, return from vm_pcall.
 410   |  // (void *cframe, int errcode)
 411   |  mr sp, CARG1
 412   |  mr CRET1, CARG2
 413   |->vm_unwind_c_eh:                    // Landing pad for external unwinder.
 414   |  lwz L, SAVE_L
 415   |   li TMP0, ~LJ_VMST_C
 416   |  lwz GL:TMP1, L->glref
 417   |   stw TMP0, GL:TMP1->vmstate
 418   |  b ->vm_leave_unw
 419   |
 420   |->vm_unwind_ff:                      // Unwind C stack, return from ff pcall.
 421   |  // (void *cframe)
 422   |  rlwinm sp, CARG1, 0, 0, 29
 423   |->vm_unwind_ff_eh:                   // Landing pad for external unwinder.
 424   |  lwz L, SAVE_L
 425   |     li TISNUM, LJ_TISNUM            // Setup type comparison constants.
 426   |  lwz BASE, L->base
 427   |     lus TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 428   |   lwz DISPATCH, L->glref            // Setup pointer to dispatch table.
 429   |     li ZERO, 0
 430   |     stw TMP3, TMPD
 431   |  li TMP1, LJ_TFALSE
 432   |     ori TMP3, TMP3, 0x0004          // TONUM = 2^52 + 2^51 + 2^31 (float).
 433   |     li TISNIL, LJ_TNIL
 434   |    li_vmstate INTERP
 435   |     lfs TOBIT, TMPD
 436   |  lwz PC, FRAME_PC(BASE)             // Fetch PC of previous frame.
 437   |  la RA, -8(BASE)                    // Results start at BASE-8.
 438   |     stw TMP3, TMPD
 439   |   addi DISPATCH, DISPATCH, GG_G2DISP
 440   |  stw TMP1, 0(RA)                    // Prepend false to error message.
 441   |  li RD, 16                          // 2 results: false + error message.
 442   |    st_vmstate
 443   |     lfs TONUM, TMPD
 444   |  b ->vm_returnc
 445   |
 446   |//-----------------------------------------------------------------------
 447   |//-- Grow stack for calls -----------------------------------------------
 448   |//-----------------------------------------------------------------------
 449   |
 450   |->vm_growstack_c:                    // Grow stack for C function.
 451   |  li CARG2, LUA_MINSTACK
 452   |  b >2
 453   |
 454   |->vm_growstack_l:                    // Grow stack for Lua function.
 455   |  // BASE = new base, RA = BASE+framesize*8, RC = nargs*8, PC = first PC
 456   |  add RC, BASE, RC
 457   |   sub RA, RA, BASE
 458   |  stw BASE, L->base
 459   |   addi PC, PC, 4                    // Must point after first instruction.
 460   |  stw RC, L->top
 461   |   srwi CARG2, RA, 3
 462   |2:
 463   |  // L->base = new base, L->top = top
 464   |   stw PC, SAVE_PC
 465   |  mr CARG1, L
 466   |  bl extern lj_state_growstack       // (lua_State *L, int n)
 467   |  lwz BASE, L->base
 468   |  lwz RC, L->top
 469   |  lwz LFUNC:RB, FRAME_FUNC(BASE)
 470   |  sub RC, RC, BASE
 471   |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
 472   |  ins_callt                          // Just retry the call.
 473   |
 474   |//-----------------------------------------------------------------------
 475   |//-- Entry points into the assembler VM ---------------------------------
 476   |//-----------------------------------------------------------------------
 477   |
 478   |->vm_resume:                         // Setup C frame and resume thread.
 479   |  // (lua_State *L, TValue *base, int nres1 = 0, ptrdiff_t ef = 0)
 480   |  saveregs
 481   |  mr L, CARG1
 482   |    lwz DISPATCH, L->glref           // Setup pointer to dispatch table.
 483   |  mr BASE, CARG2
 484   |    lbz TMP1, L->status
 485   |   stw L, SAVE_L
 486   |  li PC, FRAME_CP
 487   |  addi TMP0, sp, CFRAME_RESUME
 488   |    addi DISPATCH, DISPATCH, GG_G2DISP
 489   |   stw CARG3, SAVE_NRES
 490   |    cmplwi TMP1, 0
 491   |   stw CARG3, SAVE_ERRF
 492   |  stw TMP0, L->cframe
 493   |   stw CARG3, SAVE_CFRAME
 494   |   stw CARG1, SAVE_PC                // Any value outside of bytecode is ok.
 495   |    beq >3
 496   |
 497   |  // Resume after yield (like a return).
 498   |  mr RA, BASE
 499   |   lwz BASE, L->base
 500   |     li TISNUM, LJ_TISNUM            // Setup type comparison constants.
 501   |   lwz TMP1, L->top
 502   |  lwz PC, FRAME_PC(BASE)
 503   |     lus TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 504   |    stb CARG3, L->status
 505   |     stw TMP3, TMPD
 506   |     ori TMP3, TMP3, 0x0004          // TONUM = 2^52 + 2^51 + 2^31 (float).
 507   |     lfs TOBIT, TMPD
 508   |   sub RD, TMP1, BASE
 509   |     stw TMP3, TMPD
 510   |     lus TMP0, 0x4338                // Hiword of 2^52 + 2^51 (double)
 511   |   addi RD, RD, 8
 512   |     stw TMP0, TONUM_HI
 513   |    li_vmstate INTERP
 514   |     li ZERO, 0
 515   |    st_vmstate
 516   |  andi. TMP0, PC, FRAME_TYPE
 517   |   mr MULTRES, RD
 518   |     lfs TONUM, TMPD
 519   |     li TISNIL, LJ_TNIL
 520   |  beq ->BC_RET_Z
 521   |  b ->vm_return
 522   |
 523   |->vm_pcall:                          // Setup protected C frame and enter VM.
 524   |  // (lua_State *L, TValue *base, int nres1, ptrdiff_t ef)
 525   |  saveregs
 526   |  li PC, FRAME_CP
 527   |  stw CARG4, SAVE_ERRF
 528   |  b >1
 529   |
 530   |->vm_call:                           // Setup C frame and enter VM.
 531   |  // (lua_State *L, TValue *base, int nres1)
 532   |  saveregs
 533   |  li PC, FRAME_C
 534   |
 535   |1:  // Entry point for vm_pcall above (PC = ftype).
 536   |  lwz TMP1, L:CARG1->cframe
 537   |   stw CARG3, SAVE_NRES
 538   |    mr L, CARG1
 539   |   stw CARG1, SAVE_L
 540   |    mr BASE, CARG2
 541   |  stw sp, L->cframe                  // Add our C frame to cframe chain.
 542   |    lwz DISPATCH, L->glref           // Setup pointer to dispatch table.
 543   |   stw CARG1, SAVE_PC                // Any value outside of bytecode is ok.
 544   |  stw TMP1, SAVE_CFRAME
 545   |    addi DISPATCH, DISPATCH, GG_G2DISP
 546   |
 547   |3:  // Entry point for vm_cpcall/vm_resume (BASE = base, PC = ftype).
 548   |  lwz TMP2, L->base                  // TMP2 = old base (used in vmeta_call).
 549   |     li TISNUM, LJ_TISNUM            // Setup type comparison constants.
 550   |   lwz TMP1, L->top
 551   |     lus TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 552   |  add PC, PC, BASE
 553   |     stw TMP3, TMPD
 554   |     li ZERO, 0
 555   |     ori TMP3, TMP3, 0x0004          // TONUM = 2^52 + 2^51 + 2^31 (float).
 556   |     lfs TOBIT, TMPD
 557   |  sub PC, PC, TMP2                   // PC = frame delta + frame type
 558   |     stw TMP3, TMPD
 559   |     lus TMP0, 0x4338                // Hiword of 2^52 + 2^51 (double)
 560   |   sub NARGS8:RC, TMP1, BASE
 561   |     stw TMP0, TONUM_HI
 562   |    li_vmstate INTERP
 563   |     lfs TONUM, TMPD
 564   |     li TISNIL, LJ_TNIL
 565   |    st_vmstate
 566   |
 567   |->vm_call_dispatch:
 568   |  // TMP2 = old base, BASE = new base, RC = nargs*8, PC = caller PC
 569   |  lwz TMP0, FRAME_PC(BASE)
 570   |   lwz LFUNC:RB, FRAME_FUNC(BASE)
 571   |  checkfunc TMP0; bne ->vmeta_call
 572   |
 573   |->vm_call_dispatch_f:
 574   |  ins_call
 575   |  // BASE = new base, RB = func, RC = nargs*8, PC = caller PC
 576   |
 577   |->vm_cpcall:                         // Setup protected C frame, call C.
 578   |  // (lua_State *L, lua_CFunction func, void *ud, lua_CPFunction cp)
 579   |  saveregs
 580   |  mr L, CARG1
 581   |   lwz TMP0, L:CARG1->stack
 582   |  stw CARG1, SAVE_L
 583   |   lwz TMP1, L->top
 584   |  stw CARG1, SAVE_PC                 // Any value outside of bytecode is ok.
 585   |   sub TMP0, TMP0, TMP1              // Compute -savestack(L, L->top).
 586   |    lwz TMP1, L->cframe
 587   |    stw sp, L->cframe                // Add our C frame to cframe chain.
 588   |  li TMP2, 0
 589   |   stw TMP0, SAVE_NRES               // Neg. delta means cframe w/o frame.
 590   |  stw TMP2, SAVE_ERRF                // No error function.
 591   |    stw TMP1, SAVE_CFRAME
 592   |  mtctr CARG4
 593   |  bctrl                      // (lua_State *L, lua_CFunction func, void *ud)
 594   |  mr. BASE, CRET1
 595   |   lwz DISPATCH, L->glref            // Setup pointer to dispatch table.
 596   |    li PC, FRAME_CP
 597   |   addi DISPATCH, DISPATCH, GG_G2DISP
 598   |  bne <3                             // Else continue with the call.
 599   |  b ->vm_leave_cp                    // No base? Just remove C frame.
 600   |
 601   |//-----------------------------------------------------------------------
 602   |//-- Metamethod handling ------------------------------------------------
 603   |//-----------------------------------------------------------------------
 604   |
 605   |// The lj_meta_* functions (except for lj_meta_cat) don't reallocate the
 606   |// stack, so BASE doesn't need to be reloaded across these calls.
 607   |
 608   |//-- Continuation dispatch ----------------------------------------------
 609   |
 610   |->cont_dispatch:
 611   |  // BASE = meta base, RA = resultptr, RD = (nresults+1)*8
 612   |  lwz TMP0, -12(BASE)                // Continuation.
 613   |   mr RB, BASE
 614   |   mr BASE, TMP2                     // Restore caller BASE.
 615   |    lwz LFUNC:TMP1, FRAME_FUNC(TMP2)
 616 #if LJ_HASFFI
 617   |  cmplwi TMP0, 1
 618 #endif
 619   |     lwz PC, -16(RB)                 // Restore PC from [cont|PC].
 620   |   subi TMP2, RD, 8
 621   |    lwz TMP1, LFUNC:TMP1->pc
 622   |   stwx TISNIL, RA, TMP2             // Ensure one valid arg.
 623 #if LJ_HASFFI
 624   |  ble >1
 625 #endif
 626   |    lwz KBASE, PC2PROTO(k)(TMP1)
 627   |  // BASE = base, RA = resultptr, RB = meta base
 628   |  mtctr TMP0
 629   |  bctr                               // Jump to continuation.
 630   |
 631 #if LJ_HASFFI
 632   |1:
 633   |  beq ->cont_ffi_callback            // cont = 1: return from FFI callback.
 634   |  // cont = 0: tailcall from C function.
 635   |  subi TMP1, RB, 16
 636   |  sub RC, TMP1, BASE
 637   |  b ->vm_call_tail
 638 #endif
 639   |
 640   |->cont_cat:                          // RA = resultptr, RB = meta base
 641   |  lwz INS, -4(PC)
 642   |   subi CARG2, RB, 16
 643   |  decode_RB8 SAVE0, INS
 644   |   lfd f0, 0(RA)
 645   |  add TMP1, BASE, SAVE0
 646   |   stw BASE, L->base
 647   |  cmplw TMP1, CARG2
 648   |   sub CARG3, CARG2, TMP1
 649   |  decode_RA8 RA, INS
 650   |   stfd f0, 0(CARG2)
 651   |  bney ->BC_CAT_Z
 652   |   stfdx f0, BASE, RA
 653   |  b ->cont_nop
 654   |
 655   |//-- Table indexing metamethods -----------------------------------------
 656   |
 657   |->vmeta_tgets1:
 658   |  la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
 659   |  li TMP0, LJ_TSTR
 660   |   decode_RB8 RB, INS
 661   |  stw STR:RC, 4(CARG3)
 662   |   add CARG2, BASE, RB
 663   |  stw TMP0, 0(CARG3)
 664   |  b >1
 665   |
 666   |->vmeta_tgets:
 667   |  la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
 668   |  li TMP0, LJ_TTAB
 669   |  stw TAB:RB, 4(CARG2)
 670   |   la CARG3, DISPATCH_GL(tmptv2)(DISPATCH)
 671   |  stw TMP0, 0(CARG2)
 672   |   li TMP1, LJ_TSTR
 673   |   stw STR:RC, 4(CARG3)
 674   |   stw TMP1, 0(CARG3)
 675   |  b >1
 676   |
 677   |->vmeta_tgetb:                       // TMP0 = index
 678   if (!LJ_DUALNUM) {
 679     |  tonum_u f0, TMP0
 680   }
 681   |   decode_RB8 RB, INS
 682   |  la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
 683   |   add CARG2, BASE, RB
 684   if (LJ_DUALNUM) {
 685     |  stw TISNUM, 0(CARG3)
 686     |  stw TMP0, 4(CARG3)
 687   } else {
 688     |  stfd f0, 0(CARG3)
 689   }
 690   |  b >1
 691   |
 692   |->vmeta_tgetv:
 693   |  decode_RB8 RB, INS
 694   |   decode_RC8 RC, INS
 695   |  add CARG2, BASE, RB
 696   |   add CARG3, BASE, RC
 697   |1:
 698   |  stw BASE, L->base
 699   |  mr CARG1, L
 700   |  stw PC, SAVE_PC
 701   |  bl extern lj_meta_tget             // (lua_State *L, TValue *o, TValue *k)
 702   |  // Returns TValue * (finished) or NULL (metamethod).
 703   |  cmplwi CRET1, 0
 704   |  beq >3
 705   |   lfd f0, 0(CRET1)
 706   |  ins_next1
 707   |   stfdx f0, BASE, RA
 708   |  ins_next2
 709   |
 710   |3:  // Call __index metamethod.
 711   |  // BASE = base, L->top = new base, stack = cont/func/t/k
 712   |  subfic TMP1, BASE, FRAME_CONT
 713   |  lwz BASE, L->top
 714   |  stw PC, -16(BASE)                  // [cont|PC]
 715   |   add PC, TMP1, BASE
 716   |  lwz LFUNC:RB, FRAME_FUNC(BASE)     // Guaranteed to be a function here.
 717   |   li NARGS8:RC, 16                  // 2 args for func(t, k).
 718   |  b ->vm_call_dispatch_f
 719   |
 720   |//-----------------------------------------------------------------------
 721   |
 722   |->vmeta_tsets1:
 723   |  la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
 724   |  li TMP0, LJ_TSTR
 725   |   decode_RB8 RB, INS
 726   |  stw STR:RC, 4(CARG3)
 727   |   add CARG2, BASE, RB
 728   |  stw TMP0, 0(CARG3)
 729   |  b >1
 730   |
 731   |->vmeta_tsets:
 732   |  la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
 733   |  li TMP0, LJ_TTAB
 734   |  stw TAB:RB, 4(CARG2)
 735   |   la CARG3, DISPATCH_GL(tmptv2)(DISPATCH)
 736   |  stw TMP0, 0(CARG2)
 737   |   li TMP1, LJ_TSTR
 738   |   stw STR:RC, 4(CARG3)
 739   |   stw TMP1, 0(CARG3)
 740   |  b >1
 741   |
 742   |->vmeta_tsetb:                       // TMP0 = index
 743   if (!LJ_DUALNUM) {
 744     |  tonum_u f0, TMP0
 745   }
 746   |   decode_RB8 RB, INS
 747   |  la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
 748   |   add CARG2, BASE, RB
 749   if (LJ_DUALNUM) {
 750     |  stw TISNUM, 0(CARG3)
 751     |  stw TMP0, 4(CARG3)
 752   } else {
 753     |  stfd f0, 0(CARG3)
 754   }
 755   |  b >1
 756   |
 757   |->vmeta_tsetv:
 758   |  decode_RB8 RB, INS
 759   |   decode_RC8 RC, INS
 760   |  add CARG2, BASE, RB
 761   |   add CARG3, BASE, RC
 762   |1:
 763   |  stw BASE, L->base
 764   |  mr CARG1, L
 765   |  stw PC, SAVE_PC
 766   |  bl extern lj_meta_tset             // (lua_State *L, TValue *o, TValue *k)
 767   |  // Returns TValue * (finished) or NULL (metamethod).
 768   |  cmplwi CRET1, 0
 769   |   lfdx f0, BASE, RA
 770   |  beq >3
 771   |  // NOBARRIER: lj_meta_tset ensures the table is not black.
 772   |  ins_next1
 773   |   stfd f0, 0(CRET1)
 774   |  ins_next2
 775   |
 776   |3:  // Call __newindex metamethod.
 777   |  // BASE = base, L->top = new base, stack = cont/func/t/k/(v)
 778   |  subfic TMP1, BASE, FRAME_CONT
 779   |  lwz BASE, L->top
 780   |  stw PC, -16(BASE)                  // [cont|PC]
 781   |   add PC, TMP1, BASE
 782   |  lwz LFUNC:RB, FRAME_FUNC(BASE)     // Guaranteed to be a function here.
 783   |   li NARGS8:RC, 24                  // 3 args for func(t, k, v)
 784   |  stfd f0, 16(BASE)                  // Copy value to third argument.
 785   |  b ->vm_call_dispatch_f
 786   |
 787   |//-- Comparison metamethods ---------------------------------------------
 788   |
 789   |->vmeta_comp:
 790   |  mr CARG1, L
 791   |   subi PC, PC, 4
 792   if (LJ_DUALNUM) {
 793     |  mr CARG2, RA
 794   } else {
 795     |  add CARG2, BASE, RA
 796   }
 797   |   stw PC, SAVE_PC
 798   if (LJ_DUALNUM) {
 799     |  mr CARG3, RD
 800   } else {
 801     |  add CARG3, BASE, RD
 802   }
 803   |   stw BASE, L->base
 804   |  decode_OP1 CARG4, INS
 805   |  bl extern lj_meta_comp  // (lua_State *L, TValue *o1, *o2, int op)
 806   |  // Returns 0/1 or TValue * (metamethod).
 807   |3:
 808   |  cmplwi CRET1, 1
 809   |  bgt ->vmeta_binop
 810   |  subfic CRET1, CRET1, 0
 811   |4:
 812   |  lwz INS, 0(PC)
 813   |   addi PC, PC, 4
 814   |  decode_RD4 TMP2, INS
 815   |  addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
 816   |  and TMP2, TMP2, CRET1
 817   |  add PC, PC, TMP2
 818   |->cont_nop:
 819   |  ins_next
 820   |
 821   |->cont_ra:                           // RA = resultptr
 822   |  lwz INS, -4(PC)
 823   |   lfd f0, 0(RA)
 824   |  decode_RA8 TMP1, INS
 825   |   stfdx f0, BASE, TMP1
 826   |  b ->cont_nop
 827   |
 828   |->cont_condt:                        // RA = resultptr
 829   |  lwz TMP0, 0(RA)
 830   |  subfic TMP0, TMP0, LJ_TTRUE        // Branch if result is true.
 831   |  subfe CRET1, CRET1, CRET1
 832   |  not CRET1, CRET1
 833   |  b <4
 834   |
 835   |->cont_condf:                        // RA = resultptr
 836   |  lwz TMP0, 0(RA)
 837   |  subfic TMP0, TMP0, LJ_TTRUE        // Branch if result is false.
 838   |  subfe CRET1, CRET1, CRET1
 839   |  b <4
 840   |
 841   |->vmeta_equal:
 842   |  // CARG2, CARG3, CARG4 are already set by BC_ISEQV/BC_ISNEV.
 843   |  subi PC, PC, 4
 844   |   stw BASE, L->base
 845   |  mr CARG1, L
 846   |   stw PC, SAVE_PC
 847   |  bl extern lj_meta_equal  // (lua_State *L, GCobj *o1, *o2, int ne)
 848   |  // Returns 0/1 or TValue * (metamethod).
 849   |  b <3
 850   |
 851   |->vmeta_equal_cd:
 852 #if LJ_HASFFI
 853   |  mr CARG2, INS
 854   |  subi PC, PC, 4
 855   |   stw BASE, L->base
 856   |  mr CARG1, L
 857   |   stw PC, SAVE_PC
 858   |  bl extern lj_meta_equal_cd         // (lua_State *L, BCIns op)
 859   |  // Returns 0/1 or TValue * (metamethod).
 860   |  b <3
 861 #endif
 862   |
 863   |//-- Arithmetic metamethods ---------------------------------------------
 864   |
 865   |->vmeta_arith_nv:
 866   |  add CARG3, KBASE, RC
 867   |  add CARG4, BASE, RB
 868   |  b >1
 869   |->vmeta_arith_nv2:
 870   if (LJ_DUALNUM) {
 871     |  mr CARG3, RC
 872     |  mr CARG4, RB
 873     |  b >1
 874   }
 875   |
 876   |->vmeta_unm:
 877   |  mr CARG3, RD
 878   |  mr CARG4, RD
 879   |  b >1
 880   |
 881   |->vmeta_arith_vn:
 882   |  add CARG3, BASE, RB
 883   |  add CARG4, KBASE, RC
 884   |  b >1
 885   |
 886   |->vmeta_arith_vv:
 887   |  add CARG3, BASE, RB
 888   |  add CARG4, BASE, RC
 889   if (LJ_DUALNUM) {
 890     |  b >1
 891   }
 892   |->vmeta_arith_vn2:
 893   |->vmeta_arith_vv2:
 894   if (LJ_DUALNUM) {
 895     |  mr CARG3, RB
 896     |  mr CARG4, RC
 897   }
 898   |1:
 899   |  add CARG2, BASE, RA
 900   |   stw BASE, L->base
 901   |  mr CARG1, L
 902   |   stw PC, SAVE_PC
 903   |  decode_OP1 CARG5, INS              // Caveat: CARG5 overlaps INS.
 904   |  bl extern lj_meta_arith  // (lua_State *L, TValue *ra,*rb,*rc, BCReg op)
 905   |  // Returns NULL (finished) or TValue * (metamethod).
 906   |  cmplwi CRET1, 0
 907   |  beq ->cont_nop
 908   |
 909   |  // Call metamethod for binary op.
 910   |->vmeta_binop:
 911   |  // BASE = old base, CRET1 = new base, stack = cont/func/o1/o2
 912   |  sub TMP1, CRET1, BASE
 913   |   stw PC, -16(CRET1)                // [cont|PC]
 914   |   mr TMP2, BASE
 915   |  addi PC, TMP1, FRAME_CONT
 916   |   mr BASE, CRET1
 917   |  li NARGS8:RC, 16                   // 2 args for func(o1, o2).
 918   |  b ->vm_call_dispatch
 919   |
 920   |->vmeta_len:
 921 #ifdef LUAJIT_ENABLE_LUA52COMPAT
 922   |  mr SAVE0, CARG1
 923 #endif
 924   |  mr CARG2, RD
 925   |   stw BASE, L->base
 926   |  mr CARG1, L
 927   |   stw PC, SAVE_PC
 928   |  bl extern lj_meta_len              // (lua_State *L, TValue *o)
 929   |  // Returns NULL (retry) or TValue * (metamethod base).
 930 #ifdef LUAJIT_ENABLE_LUA52COMPAT
 931   |  cmplwi CRET1, 0
 932   |  bne ->vmeta_binop                  // Binop call for compatibility.
 933   |  mr CARG1, SAVE0
 934   |  b ->BC_LEN_Z
 935 #else
 936   |  b ->vmeta_binop                    // Binop call for compatibility.
 937 #endif
 938   |
 939   |//-- Call metamethod ----------------------------------------------------
 940   |
 941   |->vmeta_call:                        // Resolve and call __call metamethod.
 942   |  // TMP2 = old base, BASE = new base, RC = nargs*8
 943   |  mr CARG1, L
 944   |   stw TMP2, L->base                 // This is the callers base!
 945   |  subi CARG2, BASE, 8
 946   |   stw PC, SAVE_PC
 947   |  add CARG3, BASE, RC
 948   |   mr SAVE0, NARGS8:RC
 949   |  bl extern lj_meta_call     // (lua_State *L, TValue *func, TValue *top)
 950   |  lwz LFUNC:RB, FRAME_FUNC(BASE)     // Guaranteed to be a function here.
 951   |   addi NARGS8:RC, SAVE0, 8          // Got one more argument now.
 952   |  ins_call
 953   |
 954   |->vmeta_callt:                       // Resolve __call for BC_CALLT.
 955   |  // BASE = old base, RA = new base, RC = nargs*8
 956   |  mr CARG1, L
 957   |   stw BASE, L->base
 958   |  subi CARG2, RA, 8
 959   |   stw PC, SAVE_PC
 960   |  add CARG3, RA, RC
 961   |   mr SAVE0, NARGS8:RC
 962   |  bl extern lj_meta_call     // (lua_State *L, TValue *func, TValue *top)
 963   |  lwz TMP1, FRAME_PC(BASE)
 964   |   addi NARGS8:RC, SAVE0, 8          // Got one more argument now.
 965   |   lwz LFUNC:RB, FRAME_FUNC(RA)      // Guaranteed to be a function here.
 966   |  b ->BC_CALLT_Z
 967   |
 968   |//-- Argument coercion for 'for' statement ------------------------------
 969   |
 970   |->vmeta_for:
 971   |  mr CARG1, L
 972   |   stw BASE, L->base
 973   |  mr CARG2, RA
 974   |   stw PC, SAVE_PC
 975   |  mr SAVE0, INS
 976   |  bl extern lj_meta_for      // (lua_State *L, TValue *base)
 977 #if LJ_HASJIT
 978   |   decode_OP1 TMP0, SAVE0
 979 #endif
 980   |  decode_RA8 RA, SAVE0
 981 #if LJ_HASJIT
 982   |   cmpwi TMP0, BC_JFORI
 983 #endif
 984   |  decode_RD8 RD, SAVE0
 985 #if LJ_HASJIT
 986   |   beqy =>BC_JFORI
 987 #endif
 988   |  b =>BC_FORI
 989   |
 990   |//-----------------------------------------------------------------------
 991   |//-- Fast functions -----------------------------------------------------
 992   |//-----------------------------------------------------------------------
 993   |
 994   |.macro .ffunc, name
 995   |->ff_ .. name:
 996   |.endmacro
 997   |
 998   |.macro .ffunc_1, name
 999   |->ff_ .. name:
1000   |  cmplwi NARGS8:RC, 8
1001   |   lwz CARG3, 0(BASE)
1002   |    lwz CARG1, 4(BASE)
1003   |  blt ->fff_fallback
1004   |.endmacro
1005   |
1006   |.macro .ffunc_2, name
1007   |->ff_ .. name:
1008   |  cmplwi NARGS8:RC, 16
1009   |   lwz CARG3, 0(BASE)
1010   |    lwz CARG4, 8(BASE)
1011   |   lwz CARG1, 4(BASE)
1012   |    lwz CARG2, 12(BASE)
1013   |  blt ->fff_fallback
1014   |.endmacro
1015   |
1016   |.macro .ffunc_n, name
1017   |->ff_ .. name:
1018   |  cmplwi NARGS8:RC, 8
1019   |   lwz CARG3, 0(BASE)
1020   |    lfd FARG1, 0(BASE)
1021   |  blt ->fff_fallback
1022   |  checknum CARG3; bge ->fff_fallback
1023   |.endmacro
1024   |
1025   |.macro .ffunc_nn, name
1026   |->ff_ .. name:
1027   |  cmplwi NARGS8:RC, 16
1028   |   lwz CARG3, 0(BASE)
1029   |    lfd FARG1, 0(BASE)
1030   |   lwz CARG4, 8(BASE)
1031   |    lfd FARG2, 8(BASE)
1032   |  blt ->fff_fallback
1033   |  checknum CARG3; bge ->fff_fallback
1034   |  checknum CARG4; bge ->fff_fallback
1035   |.endmacro
1036   |
1037   |// Inlined GC threshold check. Caveat: uses TMP0 and TMP1.
1038   |.macro ffgccheck
1039   |  lwz TMP0, DISPATCH_GL(gc.total)(DISPATCH)
1040   |  lwz TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
1041   |  cmplw TMP0, TMP1
1042   |  bgel ->fff_gcstep
1043   |.endmacro
1044   |
1045   |//-- Base library: checks -----------------------------------------------
1046   |
1047   |.ffunc_1 assert
1048   |  li TMP1, LJ_TFALSE
1049   |   la RA, -8(BASE)
1050   |  cmplw cr1, CARG3, TMP1
1051   |    lwz PC, FRAME_PC(BASE)
1052   |  bge cr1, ->fff_fallback
1053   |   stw CARG3, 0(RA)
1054   |  addi RD, NARGS8:RC, 8              // Compute (nresults+1)*8.
1055   |   stw CARG1, 4(RA)
1056   |  beq ->fff_res                      // Done if exactly 1 argument.
1057   |  li TMP1, 8
1058   |  subi RC, RC, 8
1059   |1:
1060   |  cmplw TMP1, RC
1061   |   lfdx f0, BASE, TMP1
1062   |   stfdx f0, RA, TMP1
1063   |    addi TMP1, TMP1, 8
1064   |  bney <1
1065   |  b ->fff_res
1066   |
1067   |.ffunc type
1068   |  cmplwi NARGS8:RC, 8
1069   |   lwz CARG1, 0(BASE)
1070   |  blt ->fff_fallback
1071   |  subfc TMP0, TISNUM, CARG1
1072   |  subfe TMP2, CARG1, CARG1
1073   |  orc TMP1, TMP2, TMP0
1074   |  addi TMP1, TMP1, ~LJ_TISNUM+1
1075   |  slwi TMP1, TMP1, 3
1076   |   la TMP2, CFUNC:RB->upvalue
1077   |  lfdx FARG1, TMP2, TMP1
1078   |  b ->fff_resn
1079   |
1080   |//-- Base library: getters and setters ---------------------------------
1081   |
1082   |.ffunc_1 getmetatable
1083   |  checktab CARG3; bne >6
1084   |1:  // Field metatable must be at same offset for GCtab and GCudata!
1085   |  lwz TAB:CARG1, TAB:CARG1->metatable
1086   |2:
1087   |  li CARG3, LJ_TNIL
1088   |   cmplwi TAB:CARG1, 0
1089   |  lwz STR:RC, DISPATCH_GL(gcroot[GCROOT_MMNAME+MM_metatable])(DISPATCH)
1090   |   beq ->fff_restv
1091   |  lwz TMP0, TAB:CARG1->hmask
1092   |   li CARG3, LJ_TTAB                 // Use metatable as default result.
1093   |  lwz TMP1, STR:RC->hash
1094   |  lwz NODE:TMP2, TAB:CARG1->node
1095   |  and TMP1, TMP1, TMP0               // idx = str->hash & tab->hmask
1096   |  slwi TMP0, TMP1, 5
1097   |  slwi TMP1, TMP1, 3
1098   |  sub TMP1, TMP0, TMP1
1099   |  add NODE:TMP2, NODE:TMP2, TMP1     // node = tab->node + (idx*32-idx*8)
1100   |3:  // Rearranged logic, because we expect _not_ to find the key.
1101   |  lwz CARG4, NODE:TMP2->key
1102   |   lwz TMP0, 4+offsetof(Node, key)(NODE:TMP2)
1103   |    lwz CARG2, NODE:TMP2->val
1104   |     lwz TMP1, 4+offsetof(Node, val)(NODE:TMP2)
1105   |  checkstr CARG4; bne >4
1106   |   cmpw TMP0, STR:RC; beq >5
1107   |4:
1108   |  lwz NODE:TMP2, NODE:TMP2->next
1109   |  cmplwi NODE:TMP2, 0
1110   |  beq ->fff_restv                    // Not found, keep default result.
1111   |  b <3
1112   |5:
1113   |  checknil CARG2
1114   |  beq ->fff_restv                    // Ditto for nil value.
1115   |  mr CARG3, CARG2                    // Return value of mt.__metatable.
1116   |  mr CARG1, TMP1
1117   |  b ->fff_restv
1118   |
1119   |6:
1120   |  cmpwi CARG3, LJ_TUDATA; beq <1
1121   |  subfc TMP0, TISNUM, CARG3
1122   |  subfe TMP2, CARG3, CARG3
1123   |  orc TMP1, TMP2, TMP0
1124   |  addi TMP1, TMP1, ~LJ_TISNUM+1
1125   |  slwi TMP1, TMP1, 2
1126   |   la TMP2, DISPATCH_GL(gcroot[GCROOT_BASEMT])(DISPATCH)
1127   |  lwzx TAB:CARG1, TMP2, TMP1
1128   |  b <2
1129   |
1130   |.ffunc_2 setmetatable
1131   |  // Fast path: no mt for table yet and not clearing the mt.
1132   |   checktab CARG3; bne ->fff_fallback
1133   |  lwz TAB:TMP1, TAB:CARG1->metatable
1134   |   checktab CARG4; bne ->fff_fallback
1135   |  cmplwi TAB:TMP1, 0
1136   |   lbz TMP3, TAB:CARG1->marked
1137   |  bne ->fff_fallback
1138   |   andi. TMP0, TMP3, LJ_GC_BLACK     // isblack(table)
1139   |    stw TAB:CARG2, TAB:CARG1->metatable
1140   |   beq ->fff_restv
1141   |  barrierback TAB:CARG1, TMP3, TMP0
1142   |  b ->fff_restv
1143   |
1144   |.ffunc rawget
1145   |  cmplwi NARGS8:RC, 16
1146   |   lwz CARG4, 0(BASE)
1147   |    lwz TAB:CARG2, 4(BASE)
1148   |  blt ->fff_fallback
1149   |  checktab CARG4; bne ->fff_fallback
1150   |   la CARG3, 8(BASE)
1151   |   mr CARG1, L
1152   |  bl extern lj_tab_get  // (lua_State *L, GCtab *t, cTValue *key)
1153   |  // Returns cTValue *.
1154   |  lfd FARG1, 0(CRET1)
1155   |  b ->fff_resn
1156   |
1157   |//-- Base library: conversions ------------------------------------------
1158   |
1159   |.ffunc tonumber
1160   |  // Only handles the number case inline (without a base argument).
1161   |  cmplwi NARGS8:RC, 8
1162   |   lwz CARG1, 0(BASE)
1163   |    lfd FARG1, 0(BASE)
1164   |  bne ->fff_fallback                 // Exactly one argument.
1165   |   checknum CARG1; bgt ->fff_fallback
1166   |  b ->fff_resn
1167   |
1168   |.ffunc_1 tostring
1169   |  // Only handles the string or number case inline.
1170   |  checkstr CARG3
1171   |  // A __tostring method in the string base metatable is ignored.
1172   |  beq ->fff_restv                    // String key?
1173   |  // Handle numbers inline, unless a number base metatable is present.
1174   |  lwz TMP0, DISPATCH_GL(gcroot[GCROOT_BASEMT_NUM])(DISPATCH)
1175   |  checknum CARG3
1176   |  cmplwi cr1, TMP0, 0
1177   |   stw BASE, L->base                 // Add frame since C call can throw.
1178   |  crorc 4*cr0+eq, 4*cr0+gt, 4*cr1+eq
1179   |   stw PC, SAVE_PC                   // Redundant (but a defined value).
1180   |  beq ->fff_fallback
1181   |  ffgccheck
1182   |  mr CARG1, L
1183   |  mr CARG2, BASE
1184   if (LJ_DUALNUM) {
1185     |  bl extern lj_str_fromnumber      // (lua_State *L, cTValue *o)
1186   } else {
1187     |  bl extern lj_str_fromnum         // (lua_State *L, lua_Number *np)
1188   }
1189   |  // Returns GCstr *.
1190   |  li CARG3, LJ_TSTR
1191   |  b ->fff_restv
1192   |
1193   |//-- Base library: iterators -------------------------------------------
1194   |
1195   |.ffunc next
1196   |  cmplwi NARGS8:RC, 8
1197   |   lwz CARG1, 0(BASE)
1198   |    lwz TAB:CARG2, 4(BASE)
1199   |  blt ->fff_fallback
1200   |   stwx TISNIL, BASE, NARGS8:RC      // Set missing 2nd arg to nil.
1201   |  checktab CARG1
1202   |   lwz PC, FRAME_PC(BASE)
1203   |  bne ->fff_fallback
1204   |   stw BASE, L->base                 // Add frame since C call can throw.
1205   |  mr CARG1, L
1206   |   stw BASE, L->top                  // Dummy frame length is ok.
1207   |  la CARG3, 8(BASE)
1208   |   stw PC, SAVE_PC
1209   |  bl extern lj_tab_next      // (lua_State *L, GCtab *t, TValue *key)
1210   |  // Returns 0 at end of traversal.
1211   |  cmplwi CRET1, 0
1212   |   li CARG3, LJ_TNIL
1213   |  beq ->fff_restv                    // End of traversal: return nil.
1214   |  lfd f0, 8(BASE)                    // Copy key and value to results.
1215   |   la RA, -8(BASE)
1216   |  lfd f1, 16(BASE)
1217   |  stfd f0, 0(RA)
1218   |   li RD, (2+1)*8
1219   |  stfd f1, 8(RA)
1220   |  b ->fff_res
1221   |
1222   |.ffunc_1 pairs
1223   |  checktab CARG3
1224   |   lwz PC, FRAME_PC(BASE)
1225   |  bne ->fff_fallback
1226 #ifdef LUAJIT_ENABLE_LUA52COMPAT
1227   |   lwz TAB:TMP2, TAB:CARG1->metatable
1228   |  lfd f0, CFUNC:RB->upvalue[0]
1229   |   cmplwi TAB:TMP2, 0
1230   |  la RA, -8(BASE)
1231   |   bne ->fff_fallback
1232 #else
1233   |  lfd f0, CFUNC:RB->upvalue[0]
1234   |  la RA, -8(BASE)
1235 #endif
1236   |   stw TISNIL, 8(BASE)
1237   |  li RD, (3+1)*8
1238   |  stfd f0, 0(RA)
1239   |  b ->fff_res
1240   |
1241   |.ffunc ipairs_aux
1242   |  cmplwi NARGS8:RC, 16
1243   |   lwz CARG3, 0(BASE)
1244   |    lwz TAB:CARG1, 4(BASE)
1245   |   lwz CARG4, 8(BASE)
1246   if (LJ_DUALNUM) {
1247     |    lwz TMP2, 12(BASE)
1248   } else {
1249     |    lfd FARG2, 8(BASE)
1250   }
1251   |  blt ->fff_fallback
1252   |  checktab CARG3
1253   |  checknum cr1, CARG4
1254   |   lwz PC, FRAME_PC(BASE)
1255   if (LJ_DUALNUM) {
1256     |  bne ->fff_fallback
1257     |  bne cr1, ->fff_fallback
1258   } else {
1259     |    lus TMP0, 0x3ff0
1260     |    stw ZERO, TMPD_LO
1261     |  bne ->fff_fallback
1262     |    stw TMP0, TMPD_HI
1263     |  bge cr1, ->fff_fallback
1264     |    lfd FARG1, TMPD
1265     |  toint TMP2, FARG2, f0
1266   }
1267   |   lwz TMP0, TAB:CARG1->asize
1268   |   lwz TMP1, TAB:CARG1->array
1269   if (!LJ_DUALNUM) {
1270     |  fadd FARG2, FARG2, FARG1
1271   }
1272   |  addi TMP2, TMP2, 1
1273   |   la RA, -8(BASE)
1274   |  cmplw TMP0, TMP2
1275   if (LJ_DUALNUM) {
1276     |  stw TISNUM, 0(RA)
1277     |   slwi TMP3, TMP2, 3
1278     |  stw TMP2, 4(RA)
1279   } else {
1280     |   slwi TMP3, TMP2, 3
1281     |  stfd FARG2, 0(RA)
1282   }
1283   |  ble >2                             // Not in array part?
1284   |  lwzx TMP2, TMP1, TMP3
1285   |  lfdx f0, TMP1, TMP3
1286   |1:
1287   |  checknil TMP2
1288   |   li RD, (0+1)*8
1289   |  beq ->fff_res                      // End of iteration, return 0 results.
1290   |   li RD, (2+1)*8
1291   |  stfd f0, 8(RA)
1292   |  b ->fff_res
1293   |2:  // Check for empty hash part first. Otherwise call C function.
1294   |  lwz TMP0, TAB:CARG1->hmask
1295   |  cmplwi TMP0, 0
1296   |   li RD, (0+1)*8
1297   |  beq ->fff_res
1298   |   mr CARG2, TMP2
1299   |  bl extern lj_tab_getinth           // (GCtab *t, int32_t key)
1300   |  // Returns cTValue * or NULL.
1301   |  cmplwi CRET1, 0
1302   |   li RD, (0+1)*8
1303   |  beq ->fff_res
1304   |  lwz TMP2, 0(CRET1)
1305   |  lfd f0, 0(CRET1)
1306   |  b <1
1307   |
1308   |.ffunc_1 ipairs
1309   |  checktab CARG3
1310   |   lwz PC, FRAME_PC(BASE)
1311   |  bne ->fff_fallback
1312 #ifdef LUAJIT_ENABLE_LUA52COMPAT
1313   |   lwz TAB:TMP2, TAB:CARG1->metatable
1314   |  lfd f0, CFUNC:RB->upvalue[0]
1315   |   cmplwi TAB:TMP2, 0
1316   |  la RA, -8(BASE)
1317   |   bne ->fff_fallback
1318 #else
1319   |  lfd f0, CFUNC:RB->upvalue[0]
1320   |  la RA, -8(BASE)
1321 #endif
1322   if (LJ_DUALNUM) {
1323     |  stw TISNUM, 8(BASE)
1324   } else {
1325     |  stw ZERO, 8(BASE)
1326   }
1327   |   stw ZERO, 12(BASE)
1328   |  li RD, (3+1)*8
1329   |  stfd f0, 0(RA)
1330   |  b ->fff_res
1331   |
1332   |//-- Base library: catch errors ----------------------------------------
1333   |
1334   |.ffunc pcall
1335   |  cmplwi NARGS8:RC, 8
1336   |   lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1337   |  blt ->fff_fallback
1338   |   mr TMP2, BASE
1339   |   la BASE, 8(BASE)
1340   |  // Remember active hook before pcall.
1341   |  rlwinm TMP3, TMP3, 32-HOOK_ACTIVE_SHIFT, 31, 31
1342   |   subi NARGS8:RC, NARGS8:RC, 8
1343   |  addi PC, TMP3, 8+FRAME_PCALL
1344   |  b ->vm_call_dispatch
1345   |
1346   |.ffunc xpcall
1347   |  cmplwi NARGS8:RC, 16
1348   |   lwz CARG4, 8(BASE)
1349   |    lfd FARG2, 8(BASE)
1350   |    lfd FARG1, 0(BASE)
1351   |  blt ->fff_fallback
1352   |  lbz TMP1, DISPATCH_GL(hookmask)(DISPATCH)
1353   |   mr TMP2, BASE
1354   |  checkfunc CARG4; bne ->fff_fallback  // Traceback must be a function.
1355   |   la BASE, 16(BASE)
1356   |  // Remember active hook before pcall.
1357   |  rlwinm TMP1, TMP1, 32-HOOK_ACTIVE_SHIFT, 31, 31
1358   |    stfd FARG2, 0(TMP2)              // Swap function and traceback.
1359   |  subi NARGS8:RC, NARGS8:RC, 16
1360   |    stfd FARG1, 8(TMP2)
1361   |  addi PC, TMP1, 16+FRAME_PCALL
1362   |  b ->vm_call_dispatch
1363   |
1364   |//-- Coroutine library --------------------------------------------------
1365   |
1366   |.macro coroutine_resume_wrap, resume
1367   |.if resume
1368   |.ffunc_1 coroutine_resume
1369   |  cmpwi CARG3, LJ_TTHREAD; bne ->fff_fallback
1370   |.else
1371   |.ffunc coroutine_wrap_aux
1372   |  lwz L:CARG1, CFUNC:RB->upvalue[0].gcr
1373   |.endif
1374   |  lbz TMP0, L:CARG1->status
1375   |   lwz TMP1, L:CARG1->cframe
1376   |    lwz CARG2, L:CARG1->top
1377   |  cmplwi cr0, TMP0, LUA_YIELD
1378   |    lwz TMP2, L:CARG1->base
1379   |   cmplwi cr1, TMP1, 0
1380   |   lwz TMP0, L:CARG1->maxstack
1381   |    cmplw cr7, CARG2, TMP2
1382   |   lwz PC, FRAME_PC(BASE)
1383   |  crorc 4*cr6+lt, 4*cr0+gt, 4*cr1+eq         // st>LUA_YIELD || cframe!=0
1384   |   add TMP2, CARG2, NARGS8:RC
1385   |  crandc 4*cr6+gt, 4*cr7+eq, 4*cr0+eq        // base==top && st!=LUA_YIELD
1386   |   cmplw cr1, TMP2, TMP0
1387   |  cror 4*cr6+lt, 4*cr6+lt, 4*cr6+gt
1388   |   stw PC, SAVE_PC
1389   |  cror 4*cr6+lt, 4*cr6+lt, 4*cr1+gt          // cond1 || cond2 || stackov
1390   |   stw BASE, L->base
1391   |  blt cr6, ->fff_fallback
1392   |1:
1393   |.if resume
1394   |  addi BASE, BASE, 8                 // Keep resumed thread in stack for GC.
1395   |  subi NARGS8:RC, NARGS8:RC, 8
1396   |  subi TMP2, TMP2, 8
1397   |.endif
1398   |  stw TMP2, L:CARG1->top
1399   |  li TMP1, 0
1400   |  stw BASE, L->top
1401   |2:  // Move args to coroutine.
1402   |  cmpw TMP1, NARGS8:RC
1403   |   lfdx f0, BASE, TMP1
1404   |  beq >3
1405   |   stfdx f0, CARG2, TMP1
1406   |  addi TMP1, TMP1, 8
1407   |  b <2
1408   |3:
1409   |  li CARG3, 0
1410   |   mr L:SAVE0, L:CARG1
1411   |  li CARG4, 0
1412   |  bl ->vm_resume                     // (lua_State *L, TValue *base, 0, 0)
1413   |  // Returns thread status.
1414   |4:
1415   |  lwz TMP2, L:SAVE0->base
1416   |   cmplwi CRET1, LUA_YIELD
1417   |  lwz TMP3, L:SAVE0->top
1418   |    li_vmstate INTERP
1419   |  lwz BASE, L->base
1420   |    st_vmstate
1421   |   bgt >8
1422   |  sub RD, TMP3, TMP2
1423   |   lwz TMP0, L->maxstack
1424   |  cmplwi RD, 0
1425   |   add TMP1, BASE, RD
1426   |  beq >6                             // No results?
1427   |  cmplw TMP1, TMP0
1428   |   li TMP1, 0
1429   |  bgt >9                             // Need to grow stack?
1430   |
1431   |  subi TMP3, RD, 8
1432   |   stw TMP2, L:SAVE0->top            // Clear coroutine stack.
1433   |5:  // Move results from coroutine.
1434   |  cmplw TMP1, TMP3
1435   |   lfdx f0, TMP2, TMP1
1436   |   stfdx f0, BASE, TMP1
1437   |    addi TMP1, TMP1, 8
1438   |  bne <5
1439   |6:
1440   |  andi. TMP0, PC, FRAME_TYPE
1441   |.if resume
1442   |  li TMP1, LJ_TTRUE
1443   |   la RA, -8(BASE)
1444   |  stw TMP1, -8(BASE)                 // Prepend true to results.
1445   |  addi RD, RD, 16
1446   |.else
1447   |  mr RA, BASE
1448   |  addi RD, RD, 8
1449   |.endif
1450   |7:
1451   |    stw PC, SAVE_PC
1452   |   mr MULTRES, RD
1453   |  beq ->BC_RET_Z
1454   |  b ->vm_return
1455   |
1456   |8:  // Coroutine returned with error (at co->top-1).
1457   |.if resume
1458   |  andi. TMP0, PC, FRAME_TYPE
1459   |  la TMP3, -8(TMP3)
1460   |   li TMP1, LJ_TFALSE
1461   |  lfd f0, 0(TMP3)
1462   |   stw TMP3, L:SAVE0->top            // Remove error from coroutine stack.
1463   |    li RD, (2+1)*8
1464   |   stw TMP1, -8(BASE)                // Prepend false to results.
1465   |    la RA, -8(BASE)
1466   |  stfd f0, 0(BASE)                   // Copy error message.
1467   |  b <7
1468   |.else
1469   |  mr CARG1, L
1470   |  mr CARG2, L:SAVE0
1471   |  bl extern lj_ffh_coroutine_wrap_err  // (lua_State *L, lua_State *co)
1472   |.endif
1473   |
1474   |9:  // Handle stack expansion on return from yield.
1475   |  mr CARG1, L
1476   |  srwi CARG2, RD, 3
1477   |  bl extern lj_state_growstack       // (lua_State *L, int n)
1478   |  li CRET1, 0
1479   |  b <4
1480   |.endmacro
1481   |
1482   |  coroutine_resume_wrap 1            // coroutine.resume
1483   |  coroutine_resume_wrap 0            // coroutine.wrap
1484   |
1485   |.ffunc coroutine_yield
1486   |  lwz TMP0, L->cframe
1487   |   add TMP1, BASE, NARGS8:RC
1488   |   stw BASE, L->base
1489   |  andi. TMP0, TMP0, CFRAME_RESUME
1490   |   stw TMP1, L->top
1491   |    li CRET1, LUA_YIELD
1492   |  beq ->fff_fallback
1493   |   stw ZERO, L->cframe
1494   |    stb CRET1, L->status
1495   |  b ->vm_leave_unw
1496   |
1497   |//-- Math library -------------------------------------------------------
1498   |
1499   |.ffunc_1 math_abs
1500   |  checknum CARG3
1501   if (LJ_DUALNUM) {
1502     |  bne >2
1503     |  srawi TMP1, CARG1, 31
1504     |  xor TMP2, TMP1, CARG1
1505     |  sub. CARG1, TMP2, TMP1
1506     |  blt >1
1507     |->fff_resi:
1508     |  lwz PC, FRAME_PC(BASE)
1509     |  la RA, -8(BASE)
1510     |  stw TISNUM, -8(BASE)
1511     |  stw CRET1, -4(BASE)
1512     |  b ->fff_res1
1513     |1:
1514     |  lus CARG3, 0x41e0        // 2^31.
1515     |  li CARG1, 0
1516     |  b ->fff_restv
1517     |2:
1518   }
1519   |  bge ->fff_fallback
1520   |  rlwinm CARG3, CARG3, 0, 1, 31
1521   |  // Fallthrough.
1522   |
1523   |->fff_restv:
1524   |  // CARG3/CARG1 = TValue result.
1525   |  lwz PC, FRAME_PC(BASE)
1526   |   stw CARG3, -8(BASE)
1527   |  la RA, -8(BASE)
1528   |   stw CARG1, -4(BASE)
1529   |->fff_res1:
1530   |  // RA = results, PC = return.
1531   |  li RD, (1+1)*8
1532   |->fff_res:
1533   |  // RA = results, RD = (nresults+1)*8, PC = return.
1534   |  andi. TMP0, PC, FRAME_TYPE
1535   |   mr MULTRES, RD
1536   |  bney ->vm_return
1537   |  lwz INS, -4(PC)
1538   |  decode_RB8 RB, INS
1539   |5:
1540   |  cmplw RB, RD                       // More results expected?
1541   |   decode_RA8 TMP0, INS
1542   |  bgt >6
1543   |  ins_next1
1544   |  // Adjust BASE. KBASE is assumed to be set for the calling frame.
1545   |   sub BASE, RA, TMP0
1546   |  ins_next2
1547   |
1548   |6:  // Fill up results with nil.
1549   |  subi TMP1, RD, 8
1550   |   addi RD, RD, 8
1551   |  stwx TISNIL, RA, TMP1
1552   |  b <5
1553   |
1554   |.macro math_extern, func
1555   |  .ffunc_n math_ .. func
1556   |  bl extern func
1557   |  b ->fff_resn
1558   |.endmacro
1559   |
1560   |.macro math_extern2, func
1561   |  .ffunc_nn math_ .. func
1562   |  bl extern func
1563   |  b ->fff_resn
1564   |.endmacro
1565   |
1566   |.macro math_round, func
1567   |  .ffunc_1 math_ .. func
1568   |   checknum CARG3; beqy ->fff_restv
1569   |  rlwinm TMP2, CARG3, 12, 21, 31
1570   |   bge ->fff_fallback
1571   |  addic. TMP2, TMP2, -1023           // exp = exponent(x) - 1023
1572   |  cmplwi cr1, TMP2, 31               // 0 <= exp < 31?
1573   |   subfic TMP0, TMP2, 31
1574   |  blt >3
1575   |  slwi TMP1, CARG3, 11
1576   |   srwi TMP3, CARG1, 21
1577   |  oris TMP1, TMP1, 0x8000
1578   |   addi TMP2, TMP2, 1
1579   |  or TMP1, TMP1, TMP3
1580   |   slwi CARG2, CARG1, 11
1581   |  bge cr1, >4
1582   |   slw TMP3, TMP1, TMP2
1583   |  srw CARG1, TMP1, TMP0
1584   |   or TMP3, TMP3, CARG2
1585   |  srawi TMP2, CARG3, 31
1586   |.if "func" == "floor"
1587   |  and TMP1, TMP3, TMP2
1588   |  addic TMP0, TMP1, -1
1589   |  subfe TMP1, TMP0, TMP1
1590   |  add CARG1, CARG1, TMP1
1591   |  xor CARG1, CARG1, TMP2
1592   |  sub CARG1, CARG1, TMP2
1593   |  b ->fff_resi
1594   |.else
1595   |  andc TMP1, TMP3, TMP2
1596   |  addic TMP0, TMP1, -1
1597   |  subfe TMP1, TMP0, TMP1
1598   |  addo. CARG1, CARG1, TMP1
1599   |  xor CARG1, CARG1, TMP2
1600   |  sub CARG1, CARG1, TMP2
1601   |  bns ->fff_resi
1602   |  // Potential overflow.
1603   |  mcrxr cr0; bley ->fff_resi         // Ignore unrelated overflow.
1604   |  lus CARG3, 0x41e0                  // 2^31.
1605   |  li CARG1, 0
1606   |  b ->fff_restv
1607   |.endif
1608   |3:  // |x| < 1
1609   |  add TMP2, CARG3, CARG3
1610   |   srawi TMP1, CARG3, 31
1611   |  or TMP2, CARG1, TMP2               // ztest = (hi+hi) | lo
1612   |.if "func" == "floor"
1613   |  and TMP1, TMP2, TMP1               // (ztest & sign) == 0 ? 0 : -1
1614   |  subfic TMP2, TMP1, 0
1615   |  subfe CARG1, CARG1, CARG1
1616   |.else
1617   |  andc TMP1, TMP2, TMP1              // (ztest & ~sign) == 0 ? 0 : 1
1618   |  addic TMP2, TMP1, -1
1619   |  subfe CARG1, TMP2, TMP1
1620   |.endif
1621   |  b ->fff_resi
1622   |4:  // exp >= 31. Check for -(2^31).
1623   |  xoris TMP1, TMP1, 0x8000
1624   |  srawi TMP2, CARG3, 31
1625   |.if "func" == "floor"
1626   |  or TMP1, TMP1, CARG2
1627   |.endif
1628   |  orc. TMP1, TMP1, TMP2
1629   |  crand 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
1630   |  lus CARG1, 0x8000                  // -(2^31).
1631   |  beqy ->fff_resi
1632   |5:
1633   |  lfd FARG1, 0(BASE)
1634   |  bl extern func
1635   |  b ->fff_resn
1636   |.endmacro
1637   |
1638   if (LJ_DUALNUM) {
1639     |  math_round floor
1640     |  math_round ceil
1641   } else {
1642     |  // NYI: use internal implementation.
1643     |  math_extern floor
1644     |  math_extern ceil
1645   }
1646   |
1647   |  math_extern sqrt
1648   |  math_extern log
1649   |  math_extern log10
1650   |  math_extern exp
1651   |  math_extern sin
1652   |  math_extern cos
1653   |  math_extern tan
1654   |  math_extern asin
1655   |  math_extern acos
1656   |  math_extern atan
1657   |  math_extern sinh
1658   |  math_extern cosh
1659   |  math_extern tanh
1660   |  math_extern2 pow
1661   |  math_extern2 atan2
1662   |  math_extern2 fmod
1663   |
1664   |->ff_math_deg:
1665   |.ffunc_n math_rad
1666   |  lfd FARG2, CFUNC:RB->upvalue[0]
1667   |  fmul FARG1, FARG1, FARG2
1668   |  b ->fff_resn
1669   |
1670   if (LJ_DUALNUM) {
1671     |.ffunc math_ldexp
1672     |  cmplwi NARGS8:RC, 16
1673     |   lwz CARG3, 0(BASE)
1674     |    lfd FARG1, 0(BASE)
1675     |   lwz CARG4, 8(BASE)
1676     |    lwz CARG1, 12(BASE)
1677     |  blt ->fff_fallback
1678     |  checknum CARG3; bge ->fff_fallback
1679     |  checknum CARG4; bne ->fff_fallback
1680   } else {
1681     |.ffunc_nn math_ldexp
1682     |  toint CARG1, FARG2
1683   }
1684   |  bl extern ldexp
1685   |  b ->fff_resn
1686   |
1687   |.ffunc_n math_frexp
1688   |  la CARG1, DISPATCH_GL(tmptv)(DISPATCH)
1689   |   lwz PC, FRAME_PC(BASE)
1690   |  bl extern frexp
1691   |   lwz TMP1, DISPATCH_GL(tmptv)(DISPATCH)
1692   |   la RA, -8(BASE)
1693   if (!LJ_DUALNUM) {
1694     |   tonum_i FARG2, TMP1
1695   }
1696   |  stfd FARG1, 0(RA)
1697   |  li RD, (2+1)*8
1698   if (LJ_DUALNUM) {
1699     |   stw TISNUM, 8(RA)
1700     |   stw TMP1, 12(RA)
1701   } else {
1702     |   stfd FARG2, 8(RA)
1703   }
1704   |  b ->fff_res
1705   |
1706   |.ffunc_n math_modf
1707   |  la CARG1, -8(BASE)
1708   |   lwz PC, FRAME_PC(BASE)
1709   |  bl extern modf
1710   |   la RA, -8(BASE)
1711   |  stfd FARG1, 0(BASE)
1712   |  li RD, (2+1)*8
1713   |  b ->fff_res
1714   |
1715   |.macro math_minmax, name, ismax
1716   ||if (LJ_DUALNUM) {
1717   |  .ffunc_1 name
1718   |  checknum CARG3
1719   |   addi TMP1, BASE, 8
1720   |   add TMP2, BASE, NARGS8:RC
1721   |  bne >4
1722   |1:  // Handle integers.
1723   |  lwz CARG4, 0(TMP1)
1724   |   cmplw cr1, TMP1, TMP2
1725   |  lwz CARG2, 4(TMP1)
1726   |   bge cr1, ->fff_resi
1727   |  checknum CARG4
1728   |   xoris TMP0, CARG1, 0x8000
1729   |   xoris TMP3, CARG2, 0x8000
1730   |  bne >3
1731   |  subfc TMP3, TMP3, TMP0
1732   |  subfe TMP0, TMP0, TMP0
1733   |.if ismax
1734   |  andc TMP3, TMP3, TMP0
1735   |.else
1736   |  and TMP3, TMP3, TMP0
1737   |.endif
1738   |  add CARG1, TMP3, CARG2
1739   |   addi TMP1, TMP1, 8
1740   |  b <1
1741   |3:
1742   |  bge ->fff_fallback
1743   |  // Convert intermediate result to number and continue below.
1744   |  tonum_i FARG1, CARG1
1745   |  lfd FARG2, 0(TMP1)
1746   |  b >6
1747   |4:
1748   |   lfd FARG1, 0(BASE)
1749   |  bge ->fff_fallback
1750   |5:  // Handle numbers.
1751   |  lwz CARG4, 0(TMP1)
1752   |   cmplw cr1, TMP1, TMP2
1753   |  lfd FARG2, 0(TMP1)
1754   |   bge cr1, ->fff_resn
1755   |  checknum CARG4; bge >7
1756   |6:
1757   |  fsub f0, FARG1, FARG2
1758   |   addi TMP1, TMP1, 8
1759   |.if ismax
1760   |  fsel FARG1, f0, FARG1, FARG2
1761   |.else
1762   |  fsel FARG1, f0, FARG2, FARG1
1763   |.endif
1764   |  b <5
1765   |7:  // Convert integer to number and continue above.
1766   |   lwz CARG2, 4(TMP1)
1767   |  bne ->fff_fallback
1768   |  tonum_i FARG2, CARG2
1769   |  b <6
1770   ||} else {
1771   |  .ffunc_n name
1772   |  li TMP1, 8
1773   |1:
1774   |   lwzx CARG2, BASE, TMP1
1775   |   lfdx FARG2, BASE, TMP1
1776   |  cmplw cr1, TMP1, NARGS8:RC
1777   |   checknum CARG2
1778   |  bge cr1, ->fff_resn
1779   |   bge ->fff_fallback
1780   |  fsub f0, FARG1, FARG2
1781   |   addi TMP1, TMP1, 8
1782   |.if ismax
1783   |  fsel FARG1, f0, FARG1, FARG2
1784   |.else
1785   |  fsel FARG1, f0, FARG2, FARG1
1786   |.endif
1787   |  b <1
1788   ||}
1789   |.endmacro
1790   |
1791   |  math_minmax math_min, 0
1792   |  math_minmax math_max, 1
1793   |
1794   |//-- String library -----------------------------------------------------
1795   |
1796   |.ffunc_1 string_len
1797   |  checkstr CARG3; bne ->fff_fallback
1798   |  lwz CRET1, STR:CARG1->len
1799   |  b ->fff_resi
1800   |
1801   |.ffunc string_byte                   // Only handle the 1-arg case here.
1802   |  cmplwi NARGS8:RC, 8
1803   |   lwz CARG3, 0(BASE)
1804   |    lwz STR:CARG1, 4(BASE)
1805   |  bne ->fff_fallback                 // Need exactly 1 argument.
1806   |   checkstr CARG3
1807   |   bne ->fff_fallback
1808   |  lwz TMP0, STR:CARG1->len
1809   if (LJ_DUALNUM) {
1810     |   lbz CARG1, STR:CARG1[1]         // Access is always ok (NUL at end).
1811     |   li RD, (0+1)*8
1812     |   lwz PC, FRAME_PC(BASE)
1813     |  cmplwi TMP0, 0
1814     |   la RA, -8(BASE)
1815     |  beqy ->fff_res
1816     |  b ->fff_resi
1817   } else {
1818     |   lbz TMP1, STR:CARG1[1]          // Access is always ok (NUL at end).
1819     |  addic TMP3, TMP0, -1             // RD = ((str->len != 0)+1)*8
1820     |  subfe RD, TMP3, TMP0
1821     |   stw TMP1, TONUM_LO              // Inlined tonum_u f0, TMP1.
1822     |  addi RD, RD, 1
1823     |   lfd f0, TONUM_D
1824     |  la RA, -8(BASE)
1825     |  lwz PC, FRAME_PC(BASE)
1826     |   fsub f0, f0, TOBIT
1827     |  slwi RD, RD, 3
1828     |   stfd f0, 0(RA)
1829     |  b ->fff_res
1830   }
1831   |
1832   |.ffunc string_char                   // Only handle the 1-arg case here.
1833   |  ffgccheck
1834   |  cmplwi NARGS8:RC, 8
1835   |   lwz CARG3, 0(BASE)
1836   if (LJ_DUALNUM) {
1837     |    lwz TMP0, 4(BASE)
1838     |  bne ->fff_fallback               // Exactly 1 argument.
1839     |  checknum CARG3; bne ->fff_fallback
1840     |   la CARG2, 7(BASE)
1841   } else {
1842     |    lfd FARG1, 0(BASE)
1843     |  bne ->fff_fallback               // Exactly 1 argument.
1844     |  checknum CARG3; bge ->fff_fallback
1845     |  toint TMP0, FARG1
1846     |   la CARG2, TMPD_BLO
1847   }
1848   |   li CARG3, 1
1849   |  cmplwi TMP0, 255; bgt ->fff_fallback
1850   |->fff_newstr:
1851   |  mr CARG1, L
1852   |  stw BASE, L->base
1853   |  stw PC, SAVE_PC
1854   |  bl extern lj_str_new               // (lua_State *L, char *str, size_t l)
1855   |  // Returns GCstr *.
1856   |  lwz BASE, L->base
1857   |  li CARG3, LJ_TSTR
1858   |  b ->fff_restv
1859   |
1860   |.ffunc string_sub
1861   |  ffgccheck
1862   |  cmplwi NARGS8:RC, 16
1863   |   lwz CARG3, 16(BASE)
1864   if (!LJ_DUALNUM) {
1865     |    lfd f0, 16(BASE)
1866   }
1867   |   lwz TMP0, 0(BASE)
1868   |    lwz STR:CARG1, 4(BASE)
1869   |  blt ->fff_fallback
1870   |   lwz CARG2, 8(BASE)
1871   if (LJ_DUALNUM) {
1872     |    lwz TMP1, 12(BASE)
1873   } else {
1874     |    lfd f1, 8(BASE)
1875   }
1876   |   li TMP2, -1
1877   |  beq >1
1878   if (LJ_DUALNUM) {
1879     |  checknum CARG3
1880     |   lwz TMP2, 20(BASE)
1881     |  bne ->fff_fallback
1882     |1:
1883     |  checknum CARG2; bne ->fff_fallback
1884   } else {
1885     |  checknum CARG3; bge ->fff_fallback
1886     |  toint TMP2, f0
1887     |1:
1888     |  checknum CARG2; bge ->fff_fallback
1889   }
1890   |  checkstr TMP0; bne ->fff_fallback
1891   if (!LJ_DUALNUM) {
1892     |   toint TMP1, f1
1893   }
1894   |   lwz TMP0, STR:CARG1->len
1895   |  cmplw TMP0, TMP2                   // len < end? (unsigned compare)
1896   |   addi TMP3, TMP2, 1
1897   |  blt >5
1898   |2:
1899   |  cmpwi TMP1, 0                      // start <= 0?
1900   |   add TMP3, TMP1, TMP0
1901   |  ble >7
1902   |3:
1903   |  sub CARG3, TMP2, TMP1
1904   |    addi CARG2, STR:CARG1, #STR-1
1905   |  srawi TMP0, CARG3, 31
1906   |   addi CARG3, CARG3, 1
1907   |    add CARG2, CARG2, TMP1
1908   |  andc CARG3, CARG3, TMP0
1909   |  b ->fff_newstr
1910   |
1911   |5:  // Negative end or overflow.
1912   |  sub CARG2, TMP0, TMP2
1913   |  srawi CARG2, CARG2, 31
1914   |  andc TMP3, TMP3, CARG2             // end = end > len ? len : end+len+1
1915   |  add TMP2, TMP0, TMP3
1916   |  b <2
1917   |
1918   |7:  // Negative start or underflow.
1919   |  addic CARG3, TMP1, -1
1920   |  subfe CARG3, CARG3, CARG3
1921   |   srawi CARG2, TMP3, 31             // Note: modifies carry.
1922   |  andc TMP3, TMP3, CARG3
1923   |   andc TMP1, TMP3, CARG2
1924   |  addi TMP1, TMP1, 1                 // start = 1 + (start ? start+len : 0)
1925   |  b <3
1926   |
1927   |.ffunc string_rep                    // Only handle the 1-char case inline.
1928   |  ffgccheck
1929   |  cmplwi NARGS8:RC, 16
1930   |   lwz TMP0, 0(BASE)
1931   |    lwz STR:CARG1, 4(BASE)
1932   |   lwz CARG4, 8(BASE)
1933   if (LJ_DUALNUM) {
1934     |    lwz CARG3, 12(BASE)
1935   } else {
1936     |    lfd FARG2, 8(BASE)
1937   }
1938   |  blt ->fff_fallback
1939   |  checkstr TMP0; bne ->fff_fallback
1940   if (LJ_DUALNUM) {
1941     |  checknum CARG4; bne ->fff_fallback
1942   } else {
1943     |  checknum CARG4; bge ->fff_fallback
1944     |    toint CARG3, FARG2
1945   }
1946   |   lwz TMP0, STR:CARG1->len
1947   |  cmpwi CARG3, 0
1948   |   lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1949   |  ble >2                             // Count <= 0? (or non-int)
1950   |   cmplwi TMP0, 1
1951   |  subi TMP2, CARG3, 1
1952   |   blt >2                            // Zero length string?
1953   |  cmplw cr1, TMP1, CARG3
1954   |   bne ->fff_fallback                // Fallback for > 1-char strings.
1955   |   lbz TMP0, STR:CARG1[1]
1956   |   lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1957   |  blt cr1, ->fff_fallback
1958   |1:  // Fill buffer with char. Yes, this is suboptimal code (do you care?).
1959   |  cmplwi TMP2, 0
1960   |   stbx TMP0, CARG2, TMP2
1961   |   subi TMP2, TMP2, 1
1962   |  bne <1
1963   |  b ->fff_newstr
1964   |2:  // Return empty string.
1965   |  la STR:CARG1, DISPATCH_GL(strempty)(DISPATCH)
1966   |  li CARG3, LJ_TSTR
1967   |  b ->fff_restv
1968   |
1969   |.ffunc string_reverse
1970   |  ffgccheck
1971   |  cmplwi NARGS8:RC, 8
1972   |   lwz CARG3, 0(BASE)
1973   |    lwz STR:CARG1, 4(BASE)
1974   |  blt ->fff_fallback
1975   |  checkstr CARG3
1976   |   lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1977   |  bne ->fff_fallback
1978   |  lwz CARG3, STR:CARG1->len
1979   |   la CARG1, #STR(STR:CARG1)
1980   |   lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1981   |   li TMP2, 0
1982   |  cmplw TMP1, CARG3
1983   |   subi TMP3, CARG3, 1
1984   |  blt ->fff_fallback
1985   |1:  // Reverse string copy.
1986   |  cmpwi TMP3, 0
1987   |   lbzx TMP1, CARG1, TMP2
1988   |  blty ->fff_newstr
1989   |   stbx TMP1, CARG2, TMP3
1990   |  subi TMP3, TMP3, 1
1991   |  addi TMP2, TMP2, 1
1992   |  b <1
1993   |
1994   |.macro ffstring_case, name, lo
1995   |  .ffunc name
1996   |  ffgccheck
1997   |  cmplwi NARGS8:RC, 8
1998   |   lwz CARG3, 0(BASE)
1999   |    lwz STR:CARG1, 4(BASE)
2000   |  blt ->fff_fallback
2001   |  checkstr CARG3
2002   |   lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
2003   |  bne ->fff_fallback
2004   |  lwz CARG3, STR:CARG1->len
2005   |   la CARG1, #STR(STR:CARG1)
2006   |   lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
2007   |  cmplw TMP1, CARG3
2008   |   li TMP2, 0
2009   |  blt ->fff_fallback
2010   |1:  // ASCII case conversion.
2011   |  cmplw TMP2, CARG3
2012   |   lbzx TMP1, CARG1, TMP2
2013   |  bgey ->fff_newstr
2014   |   subi TMP0, TMP1, lo
2015   |    xori TMP3, TMP1, 0x20
2016   |   addic TMP0, TMP0, -26
2017   |   subfe TMP3, TMP3, TMP3
2018   |   andi. TMP3, TMP3, 0x20
2019   |   xor TMP1, TMP1, TMP3
2020   |   stbx TMP1, CARG2, TMP2
2021   |  addi TMP2, TMP2, 1
2022   |  b <1
2023   |.endmacro
2024   |
2025   |ffstring_case string_lower, 65
2026   |ffstring_case string_upper, 97
2027   |
2028   |//-- Table library ------------------------------------------------------
2029   |
2030   |.ffunc_1 table_getn
2031   |  checktab CARG3; bne ->fff_fallback
2032   |  bl extern lj_tab_len               // (GCtab *t)
2033   |  // Returns uint32_t (but less than 2^31).
2034   |  b ->fff_resi
2035   |
2036   |//-- Bit library --------------------------------------------------------
2037   |
2038   |.macro .ffunc_bit, name
2039   ||if (LJ_DUALNUM) {
2040   |  .ffunc_1 bit_..name
2041   |  checknum CARG3; bnel ->fff_tobit_fb
2042   ||} else {
2043   |  .ffunc_n bit_..name
2044   |  fadd FARG1, FARG1, TOBIT
2045   |  stfd FARG1, TMPD
2046   |  lwz CARG1, TMPD_LO
2047   ||}
2048   |.endmacro
2049   |
2050   |.macro .ffunc_bit_op, name, ins
2051   |  .ffunc_bit name
2052   |  addi TMP1, BASE, 8
2053   |  add TMP2, BASE, NARGS8:RC
2054   |1:
2055   |  lwz CARG4, 0(TMP1)
2056   |   cmplw cr1, TMP1, TMP2
2057   ||if (LJ_DUALNUM) {
2058   |  lwz CARG2, 4(TMP1)
2059   ||} else {
2060   |  lfd FARG1, 0(TMP1)
2061   ||}
2062   |   bgey cr1, ->fff_resi
2063   |  checknum CARG4
2064   ||if (LJ_DUALNUM) {
2065   |  bnel ->fff_bitop_fb
2066   ||} else {
2067   |  fadd FARG1, FARG1, TOBIT
2068   |  bge ->fff_fallback
2069   |  stfd FARG1, TMPD
2070   |  lwz CARG2, TMPD_LO
2071   ||}
2072   |  ins CARG1, CARG1, CARG2
2073   |   addi TMP1, TMP1, 8
2074   |  b <1
2075   |.endmacro
2076   |
2077   |.ffunc_bit_op band, and
2078   |.ffunc_bit_op bor, or
2079   |.ffunc_bit_op bxor, xor
2080   |
2081   |.ffunc_bit bswap
2082   |  rotlwi TMP0, CARG1, 8
2083   |  rlwimi TMP0, CARG1, 24, 0, 7
2084   |  rlwimi TMP0, CARG1, 24, 16, 23
2085   |  mr CRET1, TMP0
2086   |  b ->fff_resi
2087   |
2088   |.ffunc_bit bnot
2089   |  not CRET1, CARG1
2090   |  b ->fff_resi
2091   |
2092   |.macro .ffunc_bit_sh, name, ins, shmod
2093   ||if (LJ_DUALNUM) {
2094   |  .ffunc_2 bit_..name
2095   |  checknum CARG3; bnel ->fff_tobit_fb
2096   |  // Note: no inline conversion from number for 2nd argument!
2097   |  checknum CARG4; bne ->fff_fallback
2098   ||} else {
2099   |  .ffunc_nn bit_..name
2100   |  fadd FARG1, FARG1, TOBIT
2101   |  fadd FARG2, FARG2, TOBIT
2102   |  stfd FARG1, TMPD
2103   |  lwz CARG1, TMPD_LO
2104   |  stfd FARG2, TMPD
2105   |  lwz CARG2, TMPD_LO
2106   ||}
2107   |.if shmod == 1
2108   |  rlwinm CARG2, CARG2, 0, 27, 31
2109   |.elif shmod == 2
2110   |  neg CARG2, CARG2
2111   |.endif
2112   |  ins CRET1, CARG1, CARG2
2113   |  b ->fff_resi
2114   |.endmacro
2115   |
2116   |.ffunc_bit_sh lshift, slw, 1
2117   |.ffunc_bit_sh rshift, srw, 1
2118   |.ffunc_bit_sh arshift, sraw, 1
2119   |.ffunc_bit_sh rol, rotlw, 0
2120   |.ffunc_bit_sh ror, rotlw, 2
2121   |
2122   |.ffunc_bit tobit
2123   if (LJ_DUALNUM) {
2124     |  b ->fff_resi
2125   } else {
2126     |->fff_resi:
2127     |  tonum_i FARG1, CRET1
2128   }
2129   |->fff_resn:
2130   |  lwz PC, FRAME_PC(BASE)
2131   |  la RA, -8(BASE)
2132   |  stfd FARG1, -8(BASE)
2133   |  b ->fff_res1
2134   |
2135   |// Fallback FP number to bit conversion.
2136   |->fff_tobit_fb:
2137   if (LJ_DUALNUM) {
2138     |  lfd FARG1, 0(BASE)
2139     |  bgt ->fff_fallback
2140     |  fadd FARG1, FARG1, TOBIT
2141     |  stfd FARG1, TMPD
2142     |  lwz CARG1, TMPD_LO
2143     |  blr
2144   }
2145   |->fff_bitop_fb:
2146   if (LJ_DUALNUM) {
2147     |  lfd FARG1, 0(TMP1)
2148     |  bgt ->fff_fallback
2149     |  fadd FARG1, FARG1, TOBIT
2150     |  stfd FARG1, TMPD
2151     |  lwz CARG2, TMPD_LO
2152     |  blr
2153   }
2154   |
2155   |//-----------------------------------------------------------------------
2156   |
2157   |->fff_fallback:                      // Call fast function fallback handler.
2158   |  // BASE = new base, RB = CFUNC, RC = nargs*8
2159   |  lwz TMP3, CFUNC:RB->f
2160   |    add TMP1, BASE, NARGS8:RC
2161   |   lwz PC, FRAME_PC(BASE)            // Fallback may overwrite PC.
2162   |    addi TMP0, TMP1, 8*LUA_MINSTACK
2163   |     lwz TMP2, L->maxstack
2164   |   stw PC, SAVE_PC                   // Redundant (but a defined value).
2165   |  cmplw TMP0, TMP2
2166   |     stw BASE, L->base
2167   |    stw TMP1, L->top
2168   |   mr CARG1, L
2169   |  bgt >5                             // Need to grow stack.
2170   |  mtctr TMP3
2171   |  bctrl                              // (lua_State *L)
2172   |  // Either throws an error, or recovers and returns -1, 0 or nresults+1.
2173   |  lwz BASE, L->base
2174   |  cmpwi CRET1, 0
2175   |   slwi RD, CRET1, 3
2176   |   la RA, -8(BASE)
2177   |  bgt ->fff_res                      // Returned nresults+1?
2178   |1:  // Returned 0 or -1: retry fast path.
2179   |  lwz TMP0, L->top
2180   |   lwz LFUNC:RB, FRAME_FUNC(BASE)
2181   |  sub NARGS8:RC, TMP0, BASE
2182   |  bne ->vm_call_tail                 // Returned -1?
2183   |  ins_callt                          // Returned 0: retry fast path.
2184   |
2185   |// Reconstruct previous base for vmeta_call during tailcall.
2186   |->vm_call_tail:
2187   |  andi. TMP0, PC, FRAME_TYPE
2188   |   rlwinm TMP1, PC, 0, 0, 28
2189   |  bne >3
2190   |  lwz INS, -4(PC)
2191   |  decode_RA8 TMP1, INS
2192   |3:
2193   |  sub TMP2, BASE, TMP1
2194   |  b ->vm_call_dispatch               // Resolve again for tailcall.
2195   |
2196   |5:  // Grow stack for fallback handler.
2197   |  li CARG2, LUA_MINSTACK
2198   |  bl extern lj_state_growstack       // (lua_State *L, int n)
2199   |  lwz BASE, L->base
2200   |  cmpw TMP0, TMP0                    // Set 4*cr0+eq to force retry.
2201   |  b <1
2202   |
2203   |->fff_gcstep:                        // Call GC step function.
2204   |  // BASE = new base, RC = nargs*8
2205   |  mflr SAVE0
2206   |   stw BASE, L->base
2207   |  add TMP0, BASE, NARGS8:RC
2208   |   stw PC, SAVE_PC                   // Redundant (but a defined value).
2209   |  stw TMP0, L->top
2210   |  mr CARG1, L
2211   |  bl extern lj_gc_step               // (lua_State *L)
2212   |   lwz BASE, L->base
2213   |  mtlr SAVE0
2214   |    lwz TMP0, L->top
2215   |   sub NARGS8:RC, TMP0, BASE
2216   |   lwz CFUNC:RB, FRAME_FUNC(BASE)
2217   |  blr
2218   |
2219   |//-----------------------------------------------------------------------
2220   |//-- Special dispatch targets -------------------------------------------
2221   |//-----------------------------------------------------------------------
2222   |
2223   |->vm_record:                         // Dispatch target for recording phase.
2224 #if LJ_HASJIT
2225   |  lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
2226   |  andi. TMP0, TMP3, HOOK_VMEVENT     // No recording while in vmevent.
2227   |  bne >5
2228   |  // Decrement the hookcount for consistency, but always do the call.
2229   |   lwz TMP2, DISPATCH_GL(hookcount)(DISPATCH)
2230   |  andi. TMP0, TMP3, HOOK_ACTIVE
2231   |  bne >1
2232   |   subi TMP2, TMP2, 1
2233   |  andi. TMP0, TMP3, LUA_MASKLINE|LUA_MASKCOUNT
2234   |  beqy >1
2235   |   stw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
2236   |  b >1
2237 #endif
2238   |
2239   |->vm_rethook:                        // Dispatch target for return hooks.
2240   |  lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
2241   |  andi. TMP0, TMP3, HOOK_ACTIVE      // Hook already active?
2242   |  beq >1
2243   |5:  // Re-dispatch to static ins.
2244   |  addi TMP1, TMP1, GG_DISP2STATIC    // Assumes decode_OP4 TMP1, INS.
2245   |  lwzx TMP0, DISPATCH, TMP1
2246   |  mtctr TMP0
2247   |  bctr
2248   |
2249   |->vm_inshook:                        // Dispatch target for instr/line hooks.
2250   |  lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
2251   |  lwz TMP2, DISPATCH_GL(hookcount)(DISPATCH)
2252   |  andi. TMP0, TMP3, HOOK_ACTIVE      // Hook already active?
2253   |   rlwinm TMP0, TMP3, 31-LUA_HOOKLINE, 31, 0
2254   |  bne <5
2255   |
2256   |   cmpwi cr1, TMP0, 0
2257   |  addic. TMP2, TMP2, -1
2258   |   beq cr1, <5
2259   |  stw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
2260   |  beq >1
2261   |   bge cr1, <5
2262   |1:
2263   |  mr CARG1, L
2264   |   stw MULTRES, SAVE_MULTRES
2265   |  mr CARG2, PC
2266   |   stw BASE, L->base
2267   |  // SAVE_PC must hold the _previous_ PC. The callee updates it with PC.
2268   |  bl extern lj_dispatch_ins          // (lua_State *L, const BCIns *pc)
2269   |3:
2270   |  lwz BASE, L->base
2271   |4:  // Re-dispatch to static ins.
2272   |  lwz INS, -4(PC)
2273   |  decode_OP4 TMP1, INS
2274   |   decode_RB8 RB, INS
2275   |  addi TMP1, TMP1, GG_DISP2STATIC
2276   |   decode_RD8 RD, INS
2277   |  lwzx TMP0, DISPATCH, TMP1
2278   |   decode_RA8 RA, INS
2279   |   decode_RC8 RC, INS
2280   |  mtctr TMP0
2281   |  bctr
2282   |
2283   |->cont_hook:                         // Continue from hook yield.
2284   |  addi PC, PC, 4
2285   |  lwz MULTRES, -20(RB)               // Restore MULTRES for *M ins.
2286   |  b <4
2287   |
2288   |->vm_hotloop:                        // Hot loop counter underflow.
2289 #if LJ_HASJIT
2290   |  lwz LFUNC:TMP1, FRAME_FUNC(BASE)
2291   |   addi CARG1, DISPATCH, GG_DISP2J
2292   |   stw PC, SAVE_PC
2293   |  lwz TMP1, LFUNC:TMP1->pc
2294   |   mr CARG2, PC
2295   |   stw L, DISPATCH_J(L)(DISPATCH)
2296   |  lbz TMP1, PC2PROTO(framesize)(TMP1)
2297   |   stw BASE, L->base
2298   |  slwi TMP1, TMP1, 3
2299   |  add TMP1, BASE, TMP1
2300   |  stw TMP1, L->top
2301   |  bl extern lj_trace_hot             // (jit_State *J, const BCIns *pc)
2302   |  b <3
2303 #endif
2304   |
2305   |->vm_callhook:                       // Dispatch target for call hooks.
2306   |  mr CARG2, PC
2307 #if LJ_HASJIT
2308   |  b >1
2309 #endif
2310   |
2311   |->vm_hotcall:                        // Hot call counter underflow.
2312 #if LJ_HASJIT
2313   |  ori CARG2, PC, 1
2314   |1:
2315 #endif
2316   |  add TMP0, BASE, RC
2317   |   stw PC, SAVE_PC
2318   |  mr CARG1, L
2319   |   stw BASE, L->base
2320   |  sub RA, RA, BASE
2321   |   stw TMP0, L->top
2322   |  bl extern lj_dispatch_call         // (lua_State *L, const BCIns *pc)
2323   |  // Returns ASMFunction.
2324   |  lwz BASE, L->base
2325   |   lwz TMP0, L->top
2326   |   stw ZERO, SAVE_PC                 // Invalidate for subsequent line hook.
2327   |  sub NARGS8:RC, TMP0, BASE
2328   |  add RA, BASE, RA
2329   |  lwz LFUNC:RB, FRAME_FUNC(BASE)
2330   |  lwz INS, -4(PC)
2331   |  mtctr CRET1
2332   |  bctr
2333   |
2334   |//-----------------------------------------------------------------------
2335   |//-- Trace exit handler -------------------------------------------------
2336   |//-----------------------------------------------------------------------
2337   |
2338   |.macro savex_, a, b, c, d
2339   |  stfd f..a, 16+a*8(sp)
2340   |  stfd f..b, 16+b*8(sp)
2341   |  stfd f..c, 16+c*8(sp)
2342   |  stfd f..d, 16+d*8(sp)
2343   |.endmacro
2344   |
2345   |->vm_exit_handler:
2346 #if LJ_HASJIT
2347   |  addi sp, sp, -(16+32*8+32*4)
2348   |  stmw r2, 16+32*8+2*4(sp)
2349   |    addi DISPATCH, JGL, -GG_DISP2G-32768
2350   |    li CARG2, ~LJ_VMST_EXIT
2351   |   lwz CARG1, 16+32*8+32*4(sp)       // Get stack chain.
2352   |    stw CARG2, DISPATCH_GL(vmstate)(DISPATCH)
2353   |  savex_ 0,1,2,3
2354   |   stw CARG1, 0(sp)                  // Store extended stack chain.
2355   |   mcrxr cr0                         // Clear SO flag.
2356   |  savex_ 4,5,6,7
2357   |   addi CARG2, sp, 16+32*8+32*4      // Recompute original value of sp.
2358   |  savex_ 8,9,10,11
2359   |   stw CARG2, 16+32*8+1*4(sp)        // Store sp in RID_SP.
2360   |  savex_ 12,13,14,15
2361   |   mflr CARG3
2362   |   li TMP1, 0
2363   |  savex_ 16,17,18,19
2364   |   stw TMP1, 16+32*8+0*4(sp)         // Clear RID_TMP.
2365   |  savex_ 20,21,22,23
2366   |   lhz CARG4, 2(CARG3)               // Load trace number.
2367   |  savex_ 24,25,26,27
2368   |  lwz L, DISPATCH_GL(jit_L)(DISPATCH)
2369   |  savex_ 28,29,30,31
2370   |   sub CARG3, TMP0, CARG3            // Compute exit number.
2371   |  lwz BASE, DISPATCH_GL(jit_base)(DISPATCH)
2372   |   srwi CARG3, CARG3, 2
2373   |  stw L, DISPATCH_J(L)(DISPATCH)
2374   |   subi CARG3, CARG3, 2
2375   |  stw TMP1, DISPATCH_GL(jit_L)(DISPATCH)
2376   |   stw CARG4, DISPATCH_J(parent)(DISPATCH)
2377   |  stw BASE, L->base
2378   |  addi CARG1, DISPATCH, GG_DISP2J
2379   |   stw CARG3, DISPATCH_J(exitno)(DISPATCH)
2380   |  addi CARG2, sp, 16
2381   |  bl extern lj_trace_exit            // (jit_State *J, ExitState *ex)
2382   |  // Returns MULTRES (unscaled) or negated error code.
2383   |  lwz TMP1, L->cframe
2384   |  lwz TMP2, 0(sp)
2385   |   lwz BASE, L->base
2386   |  rlwinm sp, TMP1, 0, 0, 29
2387   |   lwz PC, SAVE_PC                   // Get SAVE_PC.
2388   |  stw TMP2, 0(sp)
2389   |  stw L, SAVE_L                      // Set SAVE_L (on-trace resume/yield).
2390   |  b >1
2391 #endif
2392   |->vm_exit_interp:
2393 #if LJ_HASJIT
2394   |  // CARG1 = MULTRES or negated error code, BASE, PC and JGL set.
2395   |  lwz L, SAVE_L
2396   |  addi DISPATCH, JGL, -GG_DISP2G-32768
2397   |1:
2398   |  cmpwi CARG1, 0
2399   |  blt >3                             // Check for error from exit.
2400   |  lwz LFUNC:TMP1, FRAME_FUNC(BASE)
2401   |   slwi MULTRES, CARG1, 3
2402   |    li TMP2, 0
2403   |   stw MULTRES, SAVE_MULTRES
2404   |  lwz TMP1, LFUNC:TMP1->pc
2405   |    stw TMP2, DISPATCH_GL(jit_L)(DISPATCH)
2406   |  lwz KBASE, PC2PROTO(k)(TMP1)
2407   |  // Setup type comparison constants.
2408   |  li TISNUM, LJ_TISNUM
2409   |  lus TMP3, 0x59c0                   // TOBIT = 2^52 + 2^51 (float).
2410   |  stw TMP3, TMPD
2411   |  li ZERO, 0
2412   |  ori TMP3, TMP3, 0x0004             // TONUM = 2^52 + 2^51 + 2^31 (float).
2413   |  lfs TOBIT, TMPD
2414   |  stw TMP3, TMPD
2415   |  lus TMP0, 0x4338                   // Hiword of 2^52 + 2^51 (double)
2416   |    li TISNIL, LJ_TNIL
2417   |  stw TMP0, TONUM_HI
2418   |  lfs TONUM, TMPD
2419   |  // Modified copy of ins_next which handles function header dispatch, too.
2420   |  lwz INS, 0(PC)
2421   |   addi PC, PC, 4
2422   |    // Assumes TISNIL == ~LJ_VMST_INTERP == -1.
2423   |    stw TISNIL, DISPATCH_GL(vmstate)(DISPATCH)
2424   |  decode_OP4 TMP1, INS
2425   |   decode_RA8 RA, INS
2426   |  lwzx TMP0, DISPATCH, TMP1
2427   |  mtctr TMP0
2428   |  cmplwi TMP1, BC_FUNCF*4            // Function header?
2429   |  bge >2
2430   |   decode_RB8 RB, INS
2431   |   decode_RD8 RD, INS
2432   |   decode_RC8 RC, INS
2433   |  bctr
2434   |2:
2435   |   subi RC, MULTRES, 8
2436   |   add RA, RA, BASE
2437   |  bctr
2438   |
2439   |3:  // Rethrow error from the right C frame.
2440   |  neg CARG2, CARG1
2441   |  mr CARG1, L
2442   |  bl extern lj_err_throw             // (lua_State *L, int errcode)
2443 #endif
2444   |
2445   |//-----------------------------------------------------------------------
2446   |//-- Math helper functions ----------------------------------------------
2447   |//-----------------------------------------------------------------------
2448   |
2449   |  // NYI: Use internal implementation.
2450   |->vm_floor:
2451   |  b extern floor
2452   |->vm_ceil:
2453   |  b extern ceil
2454   |->vm_trunc:
2455 #if LJ_HASJIT
2456   |  b extern trunc
2457 #endif
2458   |
2459   |->vm_modi:
2460   |  divwo. TMP0, CARG1, CARG2
2461   |  bso >1
2462   |   xor. CARG3, CARG1, CARG2
2463   |  mullw TMP0, TMP0, CARG2
2464   |  sub CARG1, CARG1, TMP0
2465   |   bgelr
2466   |  cmpwi CARG1, 0; beqlr
2467   |  add CARG1, CARG1, CARG2
2468   |  blr
2469   |1:
2470   |  cmpwi CARG2, 0
2471   |   li CARG1, 0
2472   |  beqlr
2473   |  mcrxr cr0                  // Clear SO for -2147483648 % -1 and return 0.
2474   |  blr
2475   |
2476   |// Callable from C: double lj_vm_foldarith(double x, double y, int op)
2477   |// Compute x op y for basic arithmetic operators (+ - * / % ^ and unary -)
2478   |// and basic math functions. ORDER ARITH
2479   |->vm_foldarith:
2480   |  cmplwi CARG1, 1
2481   |  beq >1; bgt >2
2482   |  fadd FARG1, FARG1, FARG2; blr
2483   |1:
2484   |  fsub FARG1, FARG1, FARG2; blr
2485   |2:
2486   |   cmplwi CARG1, 3; beq >1; bgt >2
2487   |  fmul FARG1, FARG1, FARG2; blr
2488   |1:
2489   |  fdiv FARG1, FARG1, FARG2; blr
2490   |2:
2491   |   cmplwi CARG1, 5; beq >1; bgt >2
2492   |  // NYI: Use internal implementation of floor and avoid spills.
2493   |  stwu sp, -32(sp); stfd f14, 16(sp); stfd f15, 24(sp)
2494   |   mflr r0
2495   |  fmr f14, FARG1
2496   |  fdiv FARG1, FARG1, FARG2
2497   |   stw r0, 36(sp)
2498   |  fmr f15, FARG2
2499   |  bl extern floor
2500   |   lwz r0, 36(sp)
2501   |  fmul FARG1, FARG1, f15
2502   |   mtlr r0
2503   |  fsub FARG1, f14, FARG1
2504   |  lfd f14, 16(sp); lfd f15, 24(sp); addi sp, sp, 32; blr
2505   |1:
2506   |  b extern pow
2507   |2:
2508   |   cmplwi CARG1, 7; beq >1; bgt >2
2509   |  fneg FARG1, FARG1; blr
2510   |1:
2511   |  fabs FARG1, FARG1; blr
2512   |2:
2513 #if LJ_HASJIT
2514   |   cmplwi CARG1, 9; beq >9; bgt >2
2515   |  b extern atan2
2516   |  // No support needed for IR_LDEXP.
2517   |2:
2518   |   cmplwi CARG1, 11; bgt >9
2519   |  fsub f0, FARG1, FARG2
2520   |  beq >1
2521   |  fsel FARG1, f0, FARG2, FARG1       // IR_MAX
2522   |  blr
2523   |1:
2524   |  fsel FARG1, f0, FARG1, FARG2       // IR_MIN
2525   |  blr
2526   |9:
2527   |  NYI  // Bad op.
2528 #else
2529   |  NYI  // Other operations only needed by JIT compiler.
2530 #endif
2531   |
2532   |//-----------------------------------------------------------------------
2533   |//-- Miscellaneous functions --------------------------------------------
2534   |//-----------------------------------------------------------------------
2535   |
2536   |// void lj_vm_cachesync(void *start, void *end)
2537   |// Flush D-Cache and invalidate I-Cache. Assumes 32 byte cache line size.
2538   |// This is a good lower bound, except for very ancient PPC models.
2539   |->vm_cachesync:
2540   |  // Compute start of first cache line and number of cache lines.
2541   |  rlwinm CARG1, CARG1, 0, 0, 26
2542   |  sub CARG2, CARG2, CARG1
2543   |  addi CARG2, CARG2, 31
2544   |  rlwinm. CARG2, CARG2, 27, 5, 31
2545   |  beqlr
2546   |  mtctr CARG2
2547   |  mr CARG3, CARG1
2548   |1:  // Flush D-Cache.
2549   |  dcbst r0, CARG1
2550   |  addi CARG1, CARG1, 32
2551   |  bdnz <1
2552   |  sync
2553   |  mtctr CARG2
2554   |1:  // Invalidate I-Cache.
2555   |  icbi r0, CARG3
2556   |  addi CARG3, CARG3, 32
2557   |  bdnz <1
2558   |  isync
2559   |  blr
2560   |
2561   |//-----------------------------------------------------------------------
2562   |//-- FFI helper functions -----------------------------------------------
2563   |//-----------------------------------------------------------------------
2564   |
2565   |// Handler for callback functions. Callback slot number in r11, g in r12.
2566   |->vm_ffi_callback:
2567 #if LJ_HASFFI
2568   |.type CTSTATE, CTState, PC
2569   |  saveregs
2570   |  lwz CTSTATE, GL:r12->ctype_state
2571   |   addi DISPATCH, r12, GG_G2DISP
2572   |  stw r11, CTSTATE->cb.slot
2573   |  stw r3, CTSTATE->cb.gpr[0]
2574   |   stfd f1, CTSTATE->cb.fpr[0]
2575   |  stw r4, CTSTATE->cb.gpr[1]
2576   |   stfd f2, CTSTATE->cb.fpr[1]
2577   |  stw r5, CTSTATE->cb.gpr[2]
2578   |   stfd f3, CTSTATE->cb.fpr[2]
2579   |  stw r6, CTSTATE->cb.gpr[3]
2580   |   stfd f4, CTSTATE->cb.fpr[3]
2581   |  stw r7, CTSTATE->cb.gpr[4]
2582   |   stfd f5, CTSTATE->cb.fpr[4]
2583   |  stw r8, CTSTATE->cb.gpr[5]
2584   |   stfd f6, CTSTATE->cb.fpr[5]
2585   |  stw r9, CTSTATE->cb.gpr[6]
2586   |   stfd f7, CTSTATE->cb.fpr[6]
2587   |  stw r10, CTSTATE->cb.gpr[7]
2588   |   stfd f8, CTSTATE->cb.fpr[7]
2589   |  addi TMP0, sp, CFRAME_SPACE+8
2590   |  stw TMP0, CTSTATE->cb.stack
2591   |   mr CARG1, CTSTATE
2592   |  stw CTSTATE, SAVE_PC               // Any value outside of bytecode is ok.
2593   |   mr CARG2, sp
2594   |  bl extern lj_ccallback_enter       // (CTState *cts, void *cf)
2595   |  // Returns lua_State *.
2596   |  lwz BASE, L:CRET1->base
2597   |     li TISNUM, LJ_TISNUM            // Setup type comparison constants.
2598   |  lwz RC, L:CRET1->top
2599   |     lus TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
2600   |     li ZERO, 0
2601   |   mr L, CRET1
2602   |     stw TMP3, TMPD
2603   |  lwz LFUNC:RB, FRAME_FUNC(BASE)
2604   |     ori TMP3, TMP3, 0x0004          // TONUM = 2^52 + 2^51 + 2^31 (float).
2605   |     li TISNIL, LJ_TNIL
2606   |    li_vmstate INTERP
2607   |     lfs TOBIT, TMPD
2608   |     stw TMP3, TMPD
2609   |  sub RC, RC, BASE
2610   |    st_vmstate
2611   |     lfs TONUM, TMPD
2612   |  ins_callt
2613 #endif
2614   |
2615   |->cont_ffi_callback:                 // Return from FFI callback.
2616 #if LJ_HASFFI
2617   |  lwz CTSTATE, DISPATCH_GL(ctype_state)(DISPATCH)
2618   |   stw BASE, L->base
2619   |   stw RB, L->top
2620   |  stw L, CTSTATE->L
2621   |  mr CARG1, CTSTATE
2622   |  mr CARG2, RA
2623   |  bl extern lj_ccallback_leave       // (CTState *cts, TValue *o)
2624   |  lwz CRET1, CTSTATE->cb.gpr[0]
2625   |  lfd FARG1, CTSTATE->cb.fpr[0]
2626   |  lwz CRET2, CTSTATE->cb.gpr[1]
2627   |  b ->vm_leave_unw
2628 #endif
2629   |
2630   |->vm_ffi_call:                       // Call C function via FFI.
2631   |  // Caveat: needs special frame unwinding, see below.
2632 #if LJ_HASFFI
2633   |  .type CCSTATE, CCallState, CARG1
2634   |  lwz TMP1, CCSTATE->spadj
2635   |    mflr TMP0
2636   |   lbz CARG2, CCSTATE->nsp
2637   |   lbz CARG3, CCSTATE->nfpr
2638   |  neg TMP1, TMP1
2639   |    stw TMP0, 4(sp)
2640   |   cmpwi cr1, CARG3, 0
2641   |  mr TMP2, sp
2642   |   addic. CARG2, CARG2, -1
2643   |  stwux sp, sp, TMP1
2644   |   crnot 4*cr1+eq, 4*cr1+eq          // For vararg calls.
2645   |  stw r14, -4(TMP2)
2646   |  stw CCSTATE, -8(TMP2)
2647   |  mr r14, TMP2
2648   |  la TMP1, CCSTATE->stack
2649   |   slwi CARG2, CARG2, 2
2650   |   blty >2
2651   |  la TMP2, 8(sp)
2652   |1:
2653   |  lwzx TMP0, TMP1, CARG2
2654   |  stwx TMP0, TMP2, CARG2
2655   |   addic. CARG2, CARG2, -4
2656   |  bge <1
2657   |2:
2658   |  bney cr1, >3
2659   |  lfd f1, CCSTATE->fpr[0]
2660   |  lfd f2, CCSTATE->fpr[1]
2661   |  lfd f3, CCSTATE->fpr[2]
2662   |  lfd f4, CCSTATE->fpr[3]
2663   |  lfd f5, CCSTATE->fpr[4]
2664   |  lfd f6, CCSTATE->fpr[5]
2665   |  lfd f7, CCSTATE->fpr[6]
2666   |  lfd f8, CCSTATE->fpr[7]
2667   |3:
2668   |   lwz TMP0, CCSTATE->func
2669   |  lwz CARG2, CCSTATE->gpr[1]
2670   |  lwz CARG3, CCSTATE->gpr[2]
2671   |  lwz CARG4, CCSTATE->gpr[3]
2672   |  lwz CARG5, CCSTATE->gpr[4]
2673   |   mtctr TMP0
2674   |  lwz r8, CCSTATE->gpr[5]
2675   |  lwz r9, CCSTATE->gpr[6]
2676   |  lwz r10, CCSTATE->gpr[7]
2677   |  lwz CARG1, CCSTATE->gpr[0]         // Do this last, since CCSTATE is CARG1.
2678   |   bctrl
2679   |  lwz CCSTATE:TMP1, -8(r14)
2680   |  lwz TMP2, -4(r14)
2681   |   lwz TMP0, 4(r14)
2682   |  stw CARG1, CCSTATE:TMP1->gpr[0]
2683   |  stfd FARG1, CCSTATE:TMP1->fpr[0]
2684   |  stw CARG2, CCSTATE:TMP1->gpr[1]
2685   |   mtlr TMP0
2686   |  stw CARG3, CCSTATE:TMP1->gpr[2]
2687   |   mr sp, r14
2688   |  stw CARG4, CCSTATE:TMP1->gpr[3]
2689   |   mr r14, TMP2
2690   |  blr
2691 #endif
2692   |// Note: vm_ffi_call must be the last function in this object file!
2693   |
2694   |//-----------------------------------------------------------------------
2695 }
2696
2697 /* Generate the code for a single instruction. */
2698 static void build_ins(BuildCtx *ctx, BCOp op, int defop)
2699 {
2700   int vk = 0;
2701   |=>defop:
2702
2703   switch (op) {
2704
2705   /* -- Comparison ops ---------------------------------------------------- */
2706
2707   /* Remember: all ops branch for a true comparison, fall through otherwise. */
2708
2709   case BC_ISLT: case BC_ISGE: case BC_ISLE: case BC_ISGT:
2710     |  // RA = src1*8, RD = src2*8, JMP with RD = target
2711     if (LJ_DUALNUM) {
2712       |  lwzux TMP0, RA, BASE
2713       |    addi PC, PC, 4
2714       |   lwz CARG2, 4(RA)
2715       |  lwzux TMP1, RD, BASE
2716       |    lwz TMP2, -4(PC)
2717       |  checknum cr0, TMP0
2718       |   lwz CARG3, 4(RD)
2719       |    decode_RD4 TMP2, TMP2
2720       |  checknum cr1, TMP1
2721       |    addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
2722       |  bne cr0, >7
2723       |  bne cr1, >8
2724       |   cmpw CARG2, CARG3
2725       if (op == BC_ISLT) {
2726         |  bge >2
2727       } else if (op == BC_ISGE) {
2728         |  blt >2
2729       } else if (op == BC_ISLE) {
2730         |  bgt >2
2731       } else {
2732         |  ble >2
2733       }
2734       |1:
2735       |  add PC, PC, TMP2
2736       |2:
2737       |  ins_next
2738       |
2739       |7:  // RA is not an integer.
2740       |  bgt cr0, ->vmeta_comp
2741       |  // RA is a number.
2742       |   lfd f0, 0(RA)
2743       |  bgt cr1, ->vmeta_comp
2744       |  blt cr1, >4
2745       |  // RA is a number, RD is an integer.
2746       |  tonum_i f1, CARG3
2747       |  b >5
2748       |
2749       |8: // RA is an integer, RD is not an integer.
2750       |  bgt cr1, ->vmeta_comp
2751       |  // RA is an integer, RD is a number.
2752       |  tonum_i f0, CARG2
2753       |4:
2754       |  lfd f1, 0(RD)
2755       |5:
2756       |  fcmpu cr0, f0, f1
2757       if (op == BC_ISLT) {
2758         |  bge <2
2759       } else if (op == BC_ISGE) {
2760         |  blt <2
2761       } else if (op == BC_ISLE) {
2762         |  cror 4*cr0+lt, 4*cr0+lt, 4*cr0+eq
2763         |  bge <2
2764       } else {
2765         |  cror 4*cr0+lt, 4*cr0+lt, 4*cr0+eq
2766         |  blt <2
2767       }
2768       |  b <1
2769     } else {
2770       |  lwzx TMP0, BASE, RA
2771       |    addi PC, PC, 4
2772       |   lfdx f0, BASE, RA
2773       |  lwzx TMP1, BASE, RD
2774       |  checknum cr0, TMP0
2775       |    lwz TMP2, -4(PC)
2776       |   lfdx f1, BASE, RD
2777       |  checknum cr1, TMP1
2778       |    decode_RD4 TMP2, TMP2
2779       |  bge cr0, ->vmeta_comp
2780       |    addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
2781       |  bge cr1, ->vmeta_comp
2782       |  fcmpu cr0, f0, f1
2783       if (op == BC_ISLT) {
2784         |  bge >1
2785       } else if (op == BC_ISGE) {
2786         |  blt >1
2787       } else if (op == BC_ISLE) {
2788         |  cror 4*cr0+lt, 4*cr0+lt, 4*cr0+eq
2789         |  bge >1
2790       } else {
2791         |  cror 4*cr0+lt, 4*cr0+lt, 4*cr0+eq
2792         |  blt >1
2793       }
2794       |  add PC, PC, TMP2
2795       |1:
2796       |  ins_next
2797     }
2798     break;
2799
2800   case BC_ISEQV: case BC_ISNEV:
2801     vk = op == BC_ISEQV;
2802     |  // RA = src1*8, RD = src2*8, JMP with RD = target
2803     if (LJ_DUALNUM) {
2804       |  lwzux TMP0, RA, BASE
2805       |    addi PC, PC, 4
2806       |   lwz CARG2, 4(RA)
2807       |  lwzux TMP1, RD, BASE
2808       |  checknum cr0, TMP0
2809       |    lwz TMP2, -4(PC)
2810       |  checknum cr1, TMP1
2811       |    decode_RD4 TMP2, TMP2
2812       |   lwz CARG3, 4(RD)
2813       |  cror 4*cr7+gt, 4*cr0+gt, 4*cr1+gt
2814       |    addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
2815       if (vk) {
2816         |  ble cr7, ->BC_ISEQN_Z
2817       } else {
2818         |  ble cr7, ->BC_ISNEN_Z
2819       }
2820     } else {
2821       |  lwzux TMP0, RA, BASE
2822       |   lwz TMP2, 0(PC)
2823       |    lfd f0, 0(RA)
2824       |   addi PC, PC, 4
2825       |  lwzux TMP1, RD, BASE
2826       |  checknum cr0, TMP0
2827       |   decode_RD4 TMP2, TMP2
2828       |    lfd f1, 0(RD)
2829       |  checknum cr1, TMP1
2830       |   addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
2831       |  bge cr0, >5
2832       |  bge cr1, >5
2833       |  fcmpu cr0, f0, f1
2834       if (vk) {
2835         |  bne >1
2836         |  add PC, PC, TMP2
2837       } else {
2838         |  beq >1
2839         |  add PC, PC, TMP2
2840       }
2841       |1:
2842       |  ins_next
2843     }
2844     |5:  // Either or both types are not numbers.
2845     if (!LJ_DUALNUM) {
2846       |    lwz CARG2, 4(RA)
2847       |    lwz CARG3, 4(RD)
2848     }
2849     if (LJ_HASFFI) {
2850       |  cmpwi cr7, TMP0, LJ_TCDATA
2851       |  cmpwi cr5, TMP1, LJ_TCDATA
2852     }
2853     |   not TMP3, TMP0
2854     |  cmplw TMP0, TMP1
2855     |   cmplwi cr1, TMP3, ~LJ_TISPRI            // Primitive?
2856     if (LJ_HASFFI) {
2857       |  cror 4*cr7+eq, 4*cr7+eq, 4*cr5+eq
2858     }
2859     |   cmplwi cr6, TMP3, ~LJ_TISTABUD          // Table or userdata?
2860     if (LJ_HASFFI) {
2861       |  beq cr7, ->vmeta_equal_cd
2862     }
2863     |    cmplw cr5, CARG2, CARG3
2864     |  crandc 4*cr0+gt, 4*cr0+eq, 4*cr1+gt      // 2: Same type and primitive.
2865     |  crorc 4*cr0+lt, 4*cr5+eq, 4*cr0+eq       // 1: Same tv or different type.
2866     |  crand 4*cr0+eq, 4*cr0+eq, 4*cr5+eq       // 0: Same type and same tv.
2867     |   mr SAVE0, PC
2868     |  cror 4*cr0+eq, 4*cr0+eq, 4*cr0+gt        // 0 or 2.
2869     |  cror 4*cr0+lt, 4*cr0+lt, 4*cr0+gt        // 1 or 2.
2870     if (vk) {
2871       |  bne cr0, >6
2872       |  add PC, PC, TMP2
2873       |6:
2874     } else {
2875       |  beq cr0, >6
2876       |  add PC, PC, TMP2
2877       |6:
2878     }
2879     if (LJ_DUALNUM) {
2880       |  bge cr0, >2                    // Done if 1 or 2.
2881       |1:
2882       |  ins_next
2883       |2:
2884     } else {
2885       |  blt cr0, <1                    // Done if 1 or 2.
2886     }
2887     |  blt cr6, <1                      // Done if not tab/ud.
2888     |
2889     |  // Different tables or userdatas. Need to check __eq metamethod.
2890     |  // Field metatable must be at same offset for GCtab and GCudata!
2891     |  lwz TAB:TMP2, TAB:CARG2->metatable
2892     |   li CARG4, 1-vk                  // ne = 0 or 1.
2893     |  cmplwi TAB:TMP2, 0
2894     |  beq <1                           // No metatable?
2895     |  lbz TMP2, TAB:TMP2->nomm
2896     |  andi. TMP2, TMP2, 1<<MM_eq
2897     |  bne <1                           // Or 'no __eq' flag set?
2898     |  mr PC, SAVE0                     // Restore old PC.
2899     |  b ->vmeta_equal                  // Handle __eq metamethod.
2900     break;
2901
2902   case BC_ISEQS: case BC_ISNES:
2903     vk = op == BC_ISEQS;
2904     |  // RA = src*8, RD = str_const*8 (~), JMP with RD = target
2905     |  lwzux TMP0, RA, BASE
2906     |   srwi RD, RD, 1
2907     |  lwz STR:TMP3, 4(RA)
2908     |    lwz TMP2, 0(PC)
2909     |   subfic RD, RD, -4
2910     |    addi PC, PC, 4
2911     if (LJ_HASFFI) {
2912       |  cmpwi TMP0, LJ_TCDATA
2913     }
2914     |   lwzx STR:TMP1, KBASE, RD        // KBASE-4-str_const*4
2915     |  subfic TMP0, TMP0, LJ_TSTR
2916     if (LJ_HASFFI) {
2917       |  beq ->vmeta_equal_cd
2918     }
2919     |  sub TMP1, STR:TMP1, STR:TMP3
2920     |  or TMP0, TMP0, TMP1
2921     |    decode_RD4 TMP2, TMP2
2922     |  subfic TMP0, TMP0, 0
2923     |    addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
2924     |  subfe TMP1, TMP1, TMP1
2925     if (vk) {
2926       |  andc TMP2, TMP2, TMP1
2927     } else {
2928       |  and TMP2, TMP2, TMP1
2929     }
2930     |  add PC, PC, TMP2
2931     |  ins_next
2932     break;
2933
2934   case BC_ISEQN: case BC_ISNEN:
2935     vk = op == BC_ISEQN;
2936     |  // RA = src*8, RD = num_const*8, JMP with RD = target
2937     if (LJ_DUALNUM) {
2938       |  lwzux TMP0, RA, BASE
2939       |    addi PC, PC, 4
2940       |   lwz CARG2, 4(RA)
2941       |  lwzux TMP1, RD, KBASE
2942       |  checknum cr0, TMP0
2943       |    lwz TMP2, -4(PC)
2944       |  checknum cr1, TMP1
2945       |    decode_RD4 TMP2, TMP2
2946       |   lwz CARG3, 4(RD)
2947       |    addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
2948       if (vk) {
2949         |->BC_ISEQN_Z:
2950       } else {
2951         |->BC_ISNEN_Z:
2952       }
2953       |  bne cr0, >7
2954       |  bne cr1, >8
2955       |   cmpw CARG2, CARG3
2956       |4:
2957     } else {
2958       if (vk) {
2959         |->BC_ISEQN_Z:  // Dummy label.
2960       } else {
2961         |->BC_ISNEN_Z:  // Dummy label.
2962       }
2963       |  lwzx TMP0, BASE, RA
2964       |    addi PC, PC, 4
2965       |   lfdx f0, BASE, RA
2966       |    lwz TMP2, -4(PC)
2967       |  lfdx f1, KBASE, RD
2968       |    decode_RD4 TMP2, TMP2
2969       |  checknum TMP0
2970       |    addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
2971       |  bge >3
2972       |  fcmpu cr0, f0, f1
2973     }
2974     if (vk) {
2975       |  bne >1
2976       |  add PC, PC, TMP2
2977       |1:
2978       if (!LJ_HASFFI) {
2979         |3:
2980       }
2981     } else {
2982       |  beq >2
2983       |1:
2984       if (!LJ_HASFFI) {
2985         |3:
2986       }
2987       |  add PC, PC, TMP2
2988       |2:
2989     }
2990     |  ins_next
2991     if (LJ_HASFFI) {
2992       |3:
2993       |  cmpwi TMP0, LJ_TCDATA
2994       |  beq ->vmeta_equal_cd
2995       |  b <1
2996     }
2997     if (LJ_DUALNUM) {
2998       |7:  // RA is not an integer.
2999       |  bge cr0, <3
3000       |  // RA is a number.
3001       |   lfd f0, 0(RA)
3002       |  blt cr1, >1
3003       |  // RA is a number, RD is an integer.
3004       |  tonum_i f1, CARG3
3005       |  b >2
3006       |
3007       |8: // RA is an integer, RD is a number.
3008       |  tonum_i f0, CARG2
3009       |1:
3010       |  lfd f1, 0(RD)
3011       |2:
3012       |  fcmpu cr0, f0, f1
3013       |  b <4
3014     }
3015     break;
3016
3017   case BC_ISEQP: case BC_ISNEP:
3018     vk = op == BC_ISEQP;
3019     |  // RA = src*8, RD = primitive_type*8 (~), JMP with RD = target
3020     |  lwzx TMP0, BASE, RA
3021     |   srwi TMP1, RD, 3
3022     |    lwz TMP2, 0(PC)
3023     |   not TMP1, TMP1
3024     |    addi PC, PC, 4
3025     if (LJ_HASFFI) {
3026       |  cmpwi TMP0, LJ_TCDATA
3027     }
3028     |  sub TMP0, TMP0, TMP1
3029     if (LJ_HASFFI) {
3030       |  beq ->vmeta_equal_cd
3031     }
3032     |    decode_RD4 TMP2, TMP2
3033     |  addic TMP0, TMP0, -1
3034     |    addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
3035     |  subfe TMP1, TMP1, TMP1
3036     if (vk) {
3037       |  and TMP2, TMP2, TMP1
3038     } else {
3039       |  andc TMP2, TMP2, TMP1
3040     }
3041     |  add PC, PC, TMP2
3042     |  ins_next
3043     break;
3044
3045   /* -- Unary test and copy ops ------------------------------------------- */
3046
3047   case BC_ISTC: case BC_ISFC: case BC_IST: case BC_ISF:
3048     |  // RA = dst*8 or unused, RD = src*8, JMP with RD = target
3049     |  lwzx TMP0, BASE, RD
3050     |   lwz INS, 0(PC)
3051     |   addi PC, PC, 4
3052     if (op == BC_IST || op == BC_ISF) {
3053       |  subfic TMP0, TMP0, LJ_TTRUE
3054       |   decode_RD4 TMP2, INS
3055       |  subfe TMP1, TMP1, TMP1
3056       |   addis TMP2, TMP2, -(BCBIAS_J*4 >> 16)
3057       if (op == BC_IST) {
3058         |  andc TMP2, TMP2, TMP1
3059       } else {
3060         |  and TMP2, TMP2, TMP1
3061       }
3062       |  add PC, PC, TMP2
3063     } else {
3064       |  li TMP1, LJ_TFALSE
3065       |   lfdx f0, BASE, RD
3066       |  cmplw TMP0, TMP1
3067       if (op == BC_ISTC) {
3068         |  bge >1
3069       } else {
3070         |  blt >1
3071       }
3072       |  addis PC, PC, -(BCBIAS_J*4 >> 16)
3073       |  decode_RD4 TMP2, INS
3074       |   stfdx f0, BASE, RA
3075       |  add PC, PC, TMP2
3076       |1:
3077     }
3078     |  ins_next
3079     break;
3080
3081   /* -- Unary ops --------------------------------------------------------- */
3082
3083   case BC_MOV:
3084     |  // RA = dst*8, RD = src*8
3085     |  ins_next1
3086     |  lfdx f0, BASE, RD
3087     |  stfdx f0, BASE, RA
3088     |  ins_next2
3089     break;
3090   case BC_NOT:
3091     |  // RA = dst*8, RD = src*8
3092     |  ins_next1
3093     |  lwzx TMP0, BASE, RD
3094     |  subfic TMP1, TMP0, LJ_TTRUE
3095     |  adde TMP0, TMP0, TMP1
3096     |  stwx TMP0, BASE, RA
3097     |  ins_next2
3098     break;
3099   case BC_UNM:
3100     |  // RA = dst*8, RD = src*8
3101     |  lwzux TMP1, RD, BASE
3102     |   lwz TMP0, 4(RD)
3103     |  checknum TMP1
3104     if (LJ_DUALNUM) {
3105       |  bne >5
3106       |  nego. TMP0, TMP0
3107       |  bso >4
3108       |1:
3109       |  ins_next1
3110       |  stwux TISNUM, RA, BASE
3111       |   stw TMP0, 4(RA)
3112       |3:
3113       |  ins_next2
3114       |4:  // Potential overflow.
3115       |  mcrxr cr0; bley <1             // Ignore unrelated overflow.
3116       |  lus TMP1, 0x41e0               // 2^31.
3117       |  li TMP0, 0
3118       |  b >7
3119     }
3120     |5:
3121     |  bge ->vmeta_unm
3122     |  xoris TMP1, TMP1, 0x8000
3123     |7:
3124     |  ins_next1
3125     |  stwux TMP1, RA, BASE
3126     |   stw TMP0, 4(RA)
3127     if (LJ_DUALNUM) {
3128       |  b <3
3129     } else {
3130       |  ins_next2
3131     }
3132     break;
3133   case BC_LEN:
3134     |  // RA = dst*8, RD = src*8
3135     |  lwzux TMP0, RD, BASE
3136     |   lwz CARG1, 4(RD)
3137     |  checkstr TMP0; bne >2
3138     |  lwz CRET1, STR:CARG1->len
3139     |1:
3140     if (LJ_DUALNUM) {
3141       |  ins_next1
3142       |  stwux TISNUM, RA, BASE
3143       |   stw CRET1, 4(RA)
3144     } else {
3145       |  tonum_u f0, CRET1              // Result is a non-negative integer.
3146       |  ins_next1
3147       |  stfdx f0, BASE, RA
3148     }
3149     |  ins_next2
3150     |2:
3151     |  checktab TMP0; bne ->vmeta_len
3152 #ifdef LUAJIT_ENABLE_LUA52COMPAT
3153     |  lwz TAB:TMP2, TAB:CARG1->metatable
3154     |  cmplwi TAB:TMP2, 0
3155     |  bne >9
3156     |3:
3157 #endif
3158     |->BC_LEN_Z:
3159     |  bl extern lj_tab_len             // (GCtab *t)
3160     |  // Returns uint32_t (but less than 2^31).
3161     |  b <1
3162 #ifdef LUAJIT_ENABLE_LUA52COMPAT
3163     |9:
3164     |  lbz TMP0, TAB:TMP2->nomm
3165     |  andi. TMP0, TMP0, 1<<MM_len
3166     |  bne <3                           // 'no __len' flag set: done.
3167     |  b ->vmeta_len
3168 #endif
3169     break;
3170
3171   /* -- Binary ops -------------------------------------------------------- */
3172
3173     |.macro ins_arithpre
3174     |  // RA = dst*8, RB = src1*8, RC = src2*8 | num_const*8
3175     ||vk = ((int)op - BC_ADDVN) / (BC_ADDNV-BC_ADDVN);
3176     ||switch (vk) {
3177     ||case 0:
3178     |   lwzx TMP1, BASE, RB
3179     ||if (LJ_DUALNUM) {
3180     |   lwzx TMP2, KBASE, RC
3181     ||}
3182     |    lfdx f14, BASE, RB
3183     |    lfdx f15, KBASE, RC
3184     ||if (LJ_DUALNUM) {
3185     |   checknum cr0, TMP1
3186     |   checknum cr1, TMP2
3187     |   crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3188     |   bge ->vmeta_arith_vn
3189     ||} else {
3190     |   checknum TMP1; bge ->vmeta_arith_vn
3191     ||}
3192     ||  break;
3193     ||case 1:
3194     |   lwzx TMP1, BASE, RB
3195     ||if (LJ_DUALNUM) {
3196     |   lwzx TMP2, KBASE, RC
3197     ||}
3198     |    lfdx f15, BASE, RB
3199     |    lfdx f14, KBASE, RC
3200     ||if (LJ_DUALNUM) {
3201     |   checknum cr0, TMP1
3202     |   checknum cr1, TMP2
3203     |   crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3204     |   bge ->vmeta_arith_nv
3205     ||} else {
3206     |   checknum TMP1; bge ->vmeta_arith_nv
3207     ||}
3208     ||  break;
3209     ||default:
3210     |   lwzx TMP1, BASE, RB
3211     |   lwzx TMP2, BASE, RC
3212     |    lfdx f14, BASE, RB
3213     |    lfdx f15, BASE, RC
3214     |   checknum cr0, TMP1
3215     |   checknum cr1, TMP2
3216     |   crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3217     |   bge ->vmeta_arith_vv
3218     ||  break;
3219     ||}
3220     |.endmacro
3221     |
3222     |.macro ins_arithfallback, ins
3223     ||switch (vk) {
3224     ||case 0:
3225     |   ins ->vmeta_arith_vn2
3226     ||  break;
3227     ||case 1:
3228     |   ins ->vmeta_arith_nv2
3229     ||  break;
3230     ||default:
3231     |   ins ->vmeta_arith_vv2
3232     ||  break;
3233     ||}
3234     |.endmacro
3235     |
3236     |.macro intmod, a, b, c
3237     |  bl ->vm_modi
3238     |.endmacro
3239     |
3240     |.macro fpmod, a, b, c
3241     |->BC_MODVN_Z:
3242     |  fdiv FARG1, b, c
3243     |  // NYI: Use internal implementation of floor.
3244     |  bl extern floor                  // floor(b/c)
3245     |  fmul a, FARG1, c
3246     |  fsub a, b, a                     // b - floor(b/c)*c
3247     |.endmacro
3248     |
3249     |.macro ins_arithfp, fpins
3250     |  ins_arithpre
3251     |.if "fpins" == "fpmod_"
3252     |  b ->BC_MODVN_Z                   // Avoid 3 copies. It's slow anyway.
3253     |.else
3254     |  fpins f0, f14, f15
3255     |  ins_next1
3256     |  stfdx f0, BASE, RA
3257     |  ins_next2
3258     |.endif
3259     |.endmacro
3260     |
3261     |.macro ins_arithdn, intins, fpins
3262     |  // RA = dst*8, RB = src1*8, RC = src2*8 | num_const*8
3263     ||vk = ((int)op - BC_ADDVN) / (BC_ADDNV-BC_ADDVN);
3264     ||switch (vk) {
3265     ||case 0:
3266     |   lwzux TMP1, RB, BASE
3267     |   lwzux TMP2, RC, KBASE
3268     |    lwz CARG1, 4(RB)
3269     |   checknum cr0, TMP1
3270     |    lwz CARG2, 4(RC)
3271     ||  break;
3272     ||case 1:
3273     |   lwzux TMP1, RB, BASE
3274     |   lwzux TMP2, RC, KBASE
3275     |    lwz CARG2, 4(RB)
3276     |   checknum cr0, TMP1
3277     |    lwz CARG1, 4(RC)
3278     ||  break;
3279     ||default:
3280     |   lwzux TMP1, RB, BASE
3281     |   lwzux TMP2, RC, BASE
3282     |    lwz CARG1, 4(RB)
3283     |   checknum cr0, TMP1
3284     |    lwz CARG2, 4(RC)
3285     ||  break;
3286     ||}
3287     |  checknum cr1, TMP2
3288     |  bne >5
3289     |  bne cr1, >5
3290     |  intins CARG1, CARG1, CARG2
3291     |  bso >4
3292     |1:
3293     |  ins_next1
3294     |  stwux TISNUM, RA, BASE
3295     |  stw CARG1, 4(RA)
3296     |2:
3297     |  ins_next2
3298     |4:  // Overflow.
3299     |  mcrxr cr0; bley <1               // Ignore unrelated overflow.
3300     |  ins_arithfallback b
3301     |5:  // FP variant.
3302     ||if (vk == 1) {
3303     |  lfd f15, 0(RB)
3304     |   crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3305     |  lfd f14, 0(RC)
3306     ||} else {
3307     |  lfd f14, 0(RB)
3308     |   crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3309     |  lfd f15, 0(RC)
3310     ||}
3311     |   ins_arithfallback bge
3312     |.if "fpins" == "fpmod_"
3313     |  b ->BC_MODVN_Z                   // Avoid 3 copies. It's slow anyway.
3314     |.else
3315     |  fpins f0, f14, f15
3316     |  ins_next1
3317     |  stfdx f0, BASE, RA
3318     |  b <2
3319     |.endif
3320     |.endmacro
3321     |
3322     |.macro ins_arith, intins, fpins
3323     ||if (LJ_DUALNUM) {
3324     |  ins_arithdn intins, fpins
3325     ||} else {
3326     |  ins_arithfp fpins
3327     ||}
3328     |.endmacro
3329
3330   case BC_ADDVN: case BC_ADDNV: case BC_ADDVV:
3331     |  ins_arith addo., fadd
3332     break;
3333   case BC_SUBVN: case BC_SUBNV: case BC_SUBVV:
3334     |  ins_arith subo., fsub
3335     break;
3336   case BC_MULVN: case BC_MULNV: case BC_MULVV:
3337     |  ins_arith mullwo., fmul
3338     break;
3339   case BC_DIVVN: case BC_DIVNV: case BC_DIVVV:
3340     |  ins_arithfp fdiv
3341     break;
3342   case BC_MODVN:
3343     |  ins_arith intmod, fpmod
3344     break;
3345   case BC_MODNV: case BC_MODVV:
3346     |  ins_arith intmod, fpmod_
3347     break;
3348   case BC_POW:
3349     |  // NYI: (partial) integer arithmetic.
3350     |  lwzx TMP1, BASE, RB
3351     |   lfdx FARG1, BASE, RB
3352     |  lwzx TMP2, BASE, RC
3353     |   lfdx FARG2, BASE, RC
3354     |  checknum cr0, TMP1
3355     |  checknum cr1, TMP2
3356     |  crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3357     |  bge ->vmeta_arith_vv
3358     |  bl extern pow
3359     |  ins_next1
3360     |  stfdx FARG1, BASE, RA
3361     |  ins_next2
3362     break;
3363
3364   case BC_CAT:
3365     |  // RA = dst*8, RB = src_start*8, RC = src_end*8
3366     |  sub CARG3, RC, RB
3367     |   stw BASE, L->base
3368     |  add CARG2, BASE, RC
3369     |  mr SAVE0, RB
3370     |->BC_CAT_Z:
3371     |   stw PC, SAVE_PC
3372     |  mr CARG1, L
3373     |  srwi CARG3, CARG3, 3
3374     |  bl extern lj_meta_cat            // (lua_State *L, TValue *top, int left)
3375     |  // Returns NULL (finished) or TValue * (metamethod).
3376     |  cmplwi CRET1, 0
3377     |   lwz BASE, L->base
3378     |  bne ->vmeta_binop
3379     |  ins_next1
3380     |  lfdx f0, BASE, SAVE0             // Copy result from RB to RA.
3381     |  stfdx f0, BASE, RA
3382     |  ins_next2
3383     break;
3384
3385   /* -- Constant ops ------------------------------------------------------ */
3386
3387   case BC_KSTR:
3388     |  // RA = dst*8, RD = str_const*8 (~)
3389     |  srwi TMP1, RD, 1
3390     |  subfic TMP1, TMP1, -4
3391     |  ins_next1
3392     |  lwzx TMP0, KBASE, TMP1           // KBASE-4-str_const*4
3393     |  li TMP2, LJ_TSTR
3394     |  stwux TMP2, RA, BASE
3395     |  stw TMP0, 4(RA)
3396     |  ins_next2
3397     break;
3398   case BC_KCDATA:
3399 #if LJ_HASFFI
3400     |  // RA = dst*8, RD = cdata_const*8 (~)
3401     |  srwi TMP1, RD, 1
3402     |  subfic TMP1, TMP1, -4
3403     |  ins_next1
3404     |  lwzx TMP0, KBASE, TMP1           // KBASE-4-cdata_const*4
3405     |  li TMP2, LJ_TCDATA
3406     |  stwux TMP2, RA, BASE
3407     |  stw TMP0, 4(RA)
3408     |  ins_next2
3409 #endif
3410     break;
3411   case BC_KSHORT:
3412     |  // RA = dst*8, RD = int16_literal*8
3413     if (LJ_DUALNUM) {
3414       |  slwi RD, RD, 13
3415       |  srawi RD, RD, 16
3416       |  ins_next1
3417       |   stwux TISNUM, RA, BASE
3418       |   stw RD, 4(RA)
3419       |  ins_next2
3420     } else {
3421       |  // The soft-float approach is faster.
3422       |  slwi RD, RD, 13
3423       |  srawi TMP1, RD, 31
3424       |  xor TMP2, TMP1, RD
3425       |  sub TMP2, TMP2, TMP1           // TMP2 = abs(x)
3426       |  cntlzw TMP3, TMP2
3427       |  subfic TMP1, TMP3, 0x40d       // TMP1 = exponent-1
3428       |   slw TMP2, TMP2, TMP3          // TMP2 = left aligned mantissa
3429       |    subfic TMP3, RD, 0
3430       |  slwi TMP1, TMP1, 20
3431       |   rlwimi RD, TMP2, 21, 1, 31    // hi = sign(x) | (mantissa>>11)
3432       |    subfe TMP0, TMP0, TMP0
3433       |   add RD, RD, TMP1              // hi = hi + exponent-1
3434       |    and RD, RD, TMP0             // hi = x == 0 ? 0 : hi
3435       |  ins_next1
3436       |    stwux RD, RA, BASE
3437       |    stw ZERO, 4(RA)
3438       |  ins_next2
3439     }
3440     break;
3441   case BC_KNUM:
3442     |  // RA = dst*8, RD = num_const*8
3443     |  ins_next1
3444     |  lfdx f0, KBASE, RD
3445     |  stfdx f0, BASE, RA
3446     |  ins_next2
3447     break;
3448   case BC_KPRI:
3449     |  // RA = dst*8, RD = primitive_type*8 (~)
3450     |  srwi TMP1, RD, 3
3451     |  not TMP0, TMP1
3452     |  ins_next1
3453     |  stwx TMP0, BASE, RA
3454     |  ins_next2
3455     break;
3456   case BC_KNIL:
3457     |  // RA = base*8, RD = end*8
3458     |  stwx TISNIL, BASE, RA
3459     |   addi RA, RA, 8
3460     |1:
3461     |  stwx TISNIL, BASE, RA
3462     |  cmpw RA, RD
3463     |   addi RA, RA, 8
3464     |  blt <1
3465     |  ins_next_
3466     break;
3467
3468   /* -- Upvalue and function ops ------------------------------------------ */
3469
3470   case BC_UGET:
3471     |  // RA = dst*8, RD = uvnum*8
3472     |  lwz LFUNC:RB, FRAME_FUNC(BASE)
3473     |   srwi RD, RD, 1
3474     |   addi RD, RD, offsetof(GCfuncL, uvptr)
3475     |  lwzx UPVAL:RB, LFUNC:RB, RD
3476     |  ins_next1
3477     |  lwz TMP1, UPVAL:RB->v
3478     |  lfd f0, 0(TMP1)
3479     |  stfdx f0, BASE, RA
3480     |  ins_next2
3481     break;
3482   case BC_USETV:
3483     |  // RA = uvnum*8, RD = src*8
3484     |  lwz LFUNC:RB, FRAME_FUNC(BASE)
3485     |    srwi RA, RA, 1
3486     |    addi RA, RA, offsetof(GCfuncL, uvptr)
3487     |   lfdux f0, RD, BASE
3488     |  lwzx UPVAL:RB, LFUNC:RB, RA
3489     |  lbz TMP3, UPVAL:RB->marked
3490     |   lwz CARG2, UPVAL:RB->v
3491     |  andi. TMP3, TMP3, LJ_GC_BLACK    // isblack(uv)
3492     |    lbz TMP0, UPVAL:RB->closed
3493     |   lwz TMP2, 0(RD)
3494     |   stfd f0, 0(CARG2)
3495     |    cmplwi cr1, TMP0, 0
3496     |   lwz TMP1, 4(RD)
3497     |  cror 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
3498     |   subi TMP2, TMP2, (LJ_TISNUM+1)
3499     |  bne >2                           // Upvalue is closed and black?
3500     |1:
3501     |  ins_next
3502     |
3503     |2:  // Check if new value is collectable.
3504     |  cmplwi TMP2, LJ_TISGCV - (LJ_TISNUM+1)
3505     |  bge <1                           // tvisgcv(v)
3506     |  lbz TMP3, GCOBJ:TMP1->gch.marked
3507     |  andi. TMP3, TMP3, LJ_GC_WHITES   // iswhite(v)
3508     |   la CARG1, GG_DISP2G(DISPATCH)
3509     |  // Crossed a write barrier. Move the barrier forward.
3510     |  beq <1
3511     |  bl extern lj_gc_barrieruv        // (global_State *g, TValue *tv)
3512     |  b <1
3513     break;
3514   case BC_USETS:
3515     |  // RA = uvnum*8, RD = str_const*8 (~)
3516     |  lwz LFUNC:RB, FRAME_FUNC(BASE)
3517     |   srwi TMP1, RD, 1
3518     |    srwi RA, RA, 1
3519     |   subfic TMP1, TMP1, -4
3520     |    addi RA, RA, offsetof(GCfuncL, uvptr)
3521     |   lwzx STR:TMP1, KBASE, TMP1      // KBASE-4-str_const*4
3522     |  lwzx UPVAL:RB, LFUNC:RB, RA
3523     |  lbz TMP3, UPVAL:RB->marked
3524     |   lwz CARG2, UPVAL:RB->v
3525     |  andi. TMP3, TMP3, LJ_GC_BLACK    // isblack(uv)
3526     |   lbz TMP3, STR:TMP1->marked
3527     |   lbz TMP2, UPVAL:RB->closed
3528     |   li TMP0, LJ_TSTR
3529     |   stw STR:TMP1, 4(CARG2)
3530     |   stw TMP0, 0(CARG2)
3531     |  bne >2
3532     |1:
3533     |  ins_next
3534     |
3535     |2:  // Check if string is white and ensure upvalue is closed.
3536     |  andi. TMP3, TMP3, LJ_GC_WHITES   // iswhite(str)
3537     |   cmplwi cr1, TMP2, 0
3538     |  cror 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
3539     |   la CARG1, GG_DISP2G(DISPATCH)
3540     |  // Crossed a write barrier. Move the barrier forward.
3541     |  beq <1
3542     |  bl extern lj_gc_barrieruv        // (global_State *g, TValue *tv)
3543     |  b <1
3544     break;
3545   case BC_USETN:
3546     |  // RA = uvnum*8, RD = num_const*8
3547     |  lwz LFUNC:RB, FRAME_FUNC(BASE)
3548     |   srwi RA, RA, 1
3549     |   addi RA, RA, offsetof(GCfuncL, uvptr)
3550     |    lfdx f0, KBASE, RD
3551     |  lwzx UPVAL:RB, LFUNC:RB, RA
3552     |  ins_next1
3553     |  lwz TMP1, UPVAL:RB->v
3554     |  stfd f0, 0(TMP1)
3555     |  ins_next2
3556     break;
3557   case BC_USETP:
3558     |  // RA = uvnum*8, RD = primitive_type*8 (~)
3559     |  lwz LFUNC:RB, FRAME_FUNC(BASE)
3560     |   srwi RA, RA, 1
3561     |    srwi TMP0, RD, 3
3562     |   addi RA, RA, offsetof(GCfuncL, uvptr)
3563     |    not TMP0, TMP0
3564     |  lwzx UPVAL:RB, LFUNC:RB, RA
3565     |  ins_next1
3566     |  lwz TMP1, UPVAL:RB->v
3567     |  stw TMP0, 0(TMP1)
3568     |  ins_next2
3569     break;
3570
3571   case BC_UCLO:
3572     |  // RA = level*8, RD = target
3573     |  lwz TMP1, L->openupval
3574     |  branch_RD                        // Do this first since RD is not saved.
3575     |   stw BASE, L->base
3576     |  cmplwi TMP1, 0
3577     |   mr CARG1, L
3578     |  beq >1
3579     |   add CARG2, BASE, RA
3580     |  bl extern lj_func_closeuv        // (lua_State *L, TValue *level)
3581     |  lwz BASE, L->base
3582     |1:
3583     |  ins_next
3584     break;
3585
3586   case BC_FNEW:
3587     |  // RA = dst*8, RD = proto_const*8 (~) (holding function prototype)
3588     |  srwi TMP1, RD, 1
3589     |   stw BASE, L->base
3590     |  subfic TMP1, TMP1, -4
3591     |   stw PC, SAVE_PC
3592     |  lwzx CARG2, KBASE, TMP1          // KBASE-4-tab_const*4
3593     |   mr CARG1, L
3594     |  lwz CARG3, FRAME_FUNC(BASE)
3595     |  // (lua_State *L, GCproto *pt, GCfuncL *parent)
3596     |  bl extern lj_func_newL_gc
3597     |  // Returns GCfuncL *.
3598     |  lwz BASE, L->base
3599     |   li TMP0, LJ_TFUNC
3600     |  stwux TMP0, RA, BASE
3601     |  stw LFUNC:CRET1, 4(RA)
3602     |  ins_next
3603     break;
3604
3605   /* -- Table ops --------------------------------------------------------- */
3606
3607   case BC_TNEW:
3608   case BC_TDUP:
3609     |  // RA = dst*8, RD = (hbits|asize)*8 | tab_const*8 (~)
3610     |  lwz TMP0, DISPATCH_GL(gc.total)(DISPATCH)
3611     |   mr CARG1, L
3612     |  lwz TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
3613     |   stw BASE, L->base
3614     |  cmplw TMP0, TMP1
3615     |   stw PC, SAVE_PC
3616     |  bge >5
3617     |1:
3618     if (op == BC_TNEW) {
3619       |  rlwinm CARG2, RD, 29, 21, 31
3620       |  rlwinm CARG3, RD, 18, 27, 31
3621       |  cmpwi CARG2, 0x7ff; beq >3
3622       |2:
3623       |  bl extern lj_tab_new  // (lua_State *L, int32_t asize, uint32_t hbits)
3624       |  // Returns Table *.
3625     } else {
3626       |  srwi TMP1, RD, 1
3627       |  subfic TMP1, TMP1, -4
3628       |  lwzx CARG2, KBASE, TMP1                // KBASE-4-tab_const*4
3629       |  bl extern lj_tab_dup  // (lua_State *L, Table *kt)
3630       |  // Returns Table *.
3631     }
3632     |  lwz BASE, L->base
3633     |   li TMP0, LJ_TTAB
3634     |  stwux TMP0, RA, BASE
3635     |  stw TAB:CRET1, 4(RA)
3636     |  ins_next
3637     if (op == BC_TNEW) {
3638       |3:
3639       |  li CARG2, 0x801
3640       |  b <2
3641     }
3642     |5:
3643     |  mr SAVE0, RD
3644     |  bl extern lj_gc_step_fixtop  // (lua_State *L)
3645     |  mr RD, SAVE0
3646     |  mr CARG1, L
3647     |  b <1
3648     break;
3649
3650   case BC_GGET:
3651     |  // RA = dst*8, RD = str_const*8 (~)
3652   case BC_GSET:
3653     |  // RA = src*8, RD = str_const*8 (~)
3654     |  lwz LFUNC:TMP2, FRAME_FUNC(BASE)
3655     |   srwi TMP1, RD, 1
3656     |  lwz TAB:RB, LFUNC:TMP2->env
3657     |   subfic TMP1, TMP1, -4
3658     |   lwzx STR:RC, KBASE, TMP1        // KBASE-4-str_const*4
3659     if (op == BC_GGET) {
3660       |  b ->BC_TGETS_Z
3661     } else {
3662       |  b ->BC_TSETS_Z
3663     }
3664     break;
3665
3666   case BC_TGETV:
3667     |  // RA = dst*8, RB = table*8, RC = key*8
3668     |  lwzux CARG1, RB, BASE
3669     |  lwzux CARG2, RC, BASE
3670     |   lwz TAB:RB, 4(RB)
3671     if (LJ_DUALNUM) {
3672       |   lwz RC, 4(RC)
3673     } else {
3674       |   lfd f0, 0(RC)
3675     }
3676     |  checktab CARG1
3677     |   checknum cr1, CARG2
3678     |  bne ->vmeta_tgetv
3679     if (LJ_DUALNUM) {
3680       |  lwz TMP0, TAB:RB->asize
3681       |   bne cr1, >5
3682       |   lwz TMP1, TAB:RB->array
3683       |  cmplw TMP0, RC
3684       |   slwi TMP2, RC, 3
3685     } else {
3686       |   bge cr1, >5
3687       |  // Convert number key to integer, check for integerness and range.
3688       |  fctiwz f1, f0
3689       |    fadd f2, f0, TOBIT
3690       |  stfd f1, TMPD
3691       |   lwz TMP0, TAB:RB->asize
3692       |    fsub f2, f2, TOBIT
3693       |  lwz TMP2, TMPD_LO
3694       |   lwz TMP1, TAB:RB->array
3695       |    fcmpu cr1, f0, f2
3696       |  cmplw cr0, TMP0, TMP2
3697       |  crand 4*cr0+gt, 4*cr0+gt, 4*cr1+eq
3698       |   slwi TMP2, TMP2, 3
3699     }
3700     |  ble ->vmeta_tgetv                // Integer key and in array part?
3701     |  lwzx TMP0, TMP1, TMP2
3702     |   lfdx f14, TMP1, TMP2
3703     |  checknil TMP0; beq >2
3704     |1:
3705     |  ins_next1
3706     |   stfdx f14, BASE, RA
3707     |  ins_next2
3708     |
3709     |2:  // Check for __index if table value is nil.
3710     |  lwz TAB:TMP2, TAB:RB->metatable
3711     |  cmplwi TAB:TMP2, 0
3712     |  beq <1                           // No metatable: done.
3713     |  lbz TMP0, TAB:TMP2->nomm
3714     |  andi. TMP0, TMP0, 1<<MM_index
3715     |  bne <1                           // 'no __index' flag set: done.
3716     |  b ->vmeta_tgetv
3717     |
3718     |5:
3719     |  checkstr CARG2; bne ->vmeta_tgetv
3720     if (!LJ_DUALNUM) {
3721       |  lwz STR:RC, 4(RC)
3722     }
3723     |  b ->BC_TGETS_Z                   // String key?
3724     break;
3725   case BC_TGETS:
3726     |  // RA = dst*8, RB = table*8, RC = str_const*8 (~)
3727     |  lwzux CARG1, RB, BASE
3728     |   srwi TMP1, RC, 1
3729     |    lwz TAB:RB, 4(RB)
3730     |   subfic TMP1, TMP1, -4
3731     |  checktab CARG1
3732     |   lwzx STR:RC, KBASE, TMP1        // KBASE-4-str_const*4
3733     |  bne ->vmeta_tgets1
3734     |->BC_TGETS_Z:
3735     |  // TAB:RB = GCtab *, STR:RC = GCstr *, RA = dst*8
3736     |  lwz TMP0, TAB:RB->hmask
3737     |  lwz TMP1, STR:RC->hash
3738     |  lwz NODE:TMP2, TAB:RB->node
3739     |  and TMP1, TMP1, TMP0             // idx = str->hash & tab->hmask
3740     |  slwi TMP0, TMP1, 5
3741     |  slwi TMP1, TMP1, 3
3742     |  sub TMP1, TMP0, TMP1
3743     |  add NODE:TMP2, NODE:TMP2, TMP1   // node = tab->node + (idx*32-idx*8)
3744     |1:
3745     |  lwz CARG1, NODE:TMP2->key
3746     |   lwz TMP0, 4+offsetof(Node, key)(NODE:TMP2)
3747     |    lwz CARG2, NODE:TMP2->val
3748     |     lwz TMP1, 4+offsetof(Node, val)(NODE:TMP2)
3749     |  checkstr CARG1; bne >4
3750     |   cmpw TMP0, STR:RC; bne >4
3751     |    checknil CARG2; beq >5         // Key found, but nil value?
3752     |3:
3753     |    stwux CARG2, RA, BASE
3754     |     stw TMP1, 4(RA)
3755     |  ins_next
3756     |
3757     |4:  // Follow hash chain.
3758     |  lwz NODE:TMP2, NODE:TMP2->next
3759     |  cmplwi NODE:TMP2, 0
3760     |  bne <1
3761     |  // End of hash chain: key not found, nil result.
3762     |   li CARG2, LJ_TNIL
3763     |
3764     |5:  // Check for __index if table value is nil.
3765     |  lwz TAB:TMP2, TAB:RB->metatable
3766     |  cmplwi TAB:TMP2, 0
3767     |  beq <3                           // No metatable: done.
3768     |  lbz TMP0, TAB:TMP2->nomm
3769     |  andi. TMP0, TMP0, 1<<MM_index
3770     |  bne <3                           // 'no __index' flag set: done.
3771     |  b ->vmeta_tgets
3772     break;
3773   case BC_TGETB:
3774     |  // RA = dst*8, RB = table*8, RC = index*8
3775     |  lwzux CARG1, RB, BASE
3776     |   srwi TMP0, RC, 3
3777     |   lwz TAB:RB, 4(RB)
3778     |  checktab CARG1; bne ->vmeta_tgetb
3779     |  lwz TMP1, TAB:RB->asize
3780     |   lwz TMP2, TAB:RB->array
3781     |  cmplw TMP0, TMP1; bge ->vmeta_tgetb
3782     |  lwzx TMP1, TMP2, RC
3783     |   lfdx f0, TMP2, RC
3784     |  checknil TMP1; beq >5
3785     |1:
3786     |  ins_next1
3787     |   stfdx f0, BASE, RA
3788     |  ins_next2
3789     |
3790     |5:  // Check for __index if table value is nil.
3791     |  lwz TAB:TMP2, TAB:RB->metatable
3792     |  cmplwi TAB:TMP2, 0
3793     |  beq <1                           // No metatable: done.
3794     |  lbz TMP2, TAB:TMP2->nomm
3795     |  andi. TMP2, TMP2, 1<<MM_index
3796     |  bne <1                           // 'no __index' flag set: done.
3797     |  b ->vmeta_tgetb                  // Caveat: preserve TMP0!
3798     break;
3799
3800   case BC_TSETV:
3801     |  // RA = src*8, RB = table*8, RC = key*8
3802     |  lwzux CARG1, RB, BASE
3803     |  lwzux CARG2, RC, BASE
3804     |   lwz TAB:RB, 4(RB)
3805     if (LJ_DUALNUM) {
3806       |   lwz RC, 4(RC)
3807     } else {
3808       |   lfd f0, 0(RC)
3809     }
3810     |  checktab CARG1
3811     |   checknum cr1, CARG2
3812     |  bne ->vmeta_tsetv
3813     if (LJ_DUALNUM) {
3814       |  lwz TMP0, TAB:RB->asize
3815       |   bne cr1, >5
3816       |   lwz TMP1, TAB:RB->array
3817       |  cmplw TMP0, RC
3818       |   slwi TMP0, RC, 3
3819     } else {
3820       |   bge cr1, >5
3821       |  // Convert number key to integer, check for integerness and range.
3822       |  fctiwz f1, f0
3823       |    fadd f2, f0, TOBIT
3824       |  stfd f1, TMPD
3825       |   lwz TMP0, TAB:RB->asize
3826       |    fsub f2, f2, TOBIT
3827       |  lwz TMP2, TMPD_LO
3828       |   lwz TMP1, TAB:RB->array
3829       |    fcmpu cr1, f0, f2
3830       |  cmplw cr0, TMP0, TMP2
3831       |  crand 4*cr0+gt, 4*cr0+gt, 4*cr1+eq
3832       |   slwi TMP0, TMP2, 3
3833     }
3834     |  ble ->vmeta_tsetv                // Integer key and in array part?
3835     |   lwzx TMP2, TMP1, TMP0
3836     |  lbz TMP3, TAB:RB->marked
3837     |    lfdx f14, BASE, RA
3838     |   checknil TMP2; beq >3
3839     |1:
3840     |  andi. TMP2, TMP3, LJ_GC_BLACK    // isblack(table)
3841     |    stfdx f14, TMP1, TMP0
3842     |  bne >7
3843     |2:
3844     |  ins_next
3845     |
3846     |3:  // Check for __newindex if previous value is nil.
3847     |  lwz TAB:TMP2, TAB:RB->metatable
3848     |  cmplwi TAB:TMP2, 0
3849     |  beq <1                           // No metatable: done.
3850     |  lbz TMP2, TAB:TMP2->nomm
3851     |  andi. TMP2, TMP2, 1<<MM_newindex
3852     |  bne <1                           // 'no __newindex' flag set: done.
3853     |  b ->vmeta_tsetv
3854     |
3855     |5:
3856     |  checkstr CARG2; bne ->vmeta_tsetv
3857     if (!LJ_DUALNUM) {
3858       |  lwz STR:RC, 4(RC)
3859     }
3860     |  b ->BC_TSETS_Z                   // String key?
3861     |
3862     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3863     |  barrierback TAB:RB, TMP3, TMP0
3864     |  b <2
3865     break;
3866   case BC_TSETS:
3867     |  // RA = src*8, RB = table*8, RC = str_const*8 (~)
3868     |  lwzux CARG1, RB, BASE
3869     |   srwi TMP1, RC, 1
3870     |    lwz TAB:RB, 4(RB)
3871     |   subfic TMP1, TMP1, -4
3872     |  checktab CARG1
3873     |   lwzx STR:RC, KBASE, TMP1        // KBASE-4-str_const*4
3874     |  bne ->vmeta_tsets1
3875     |->BC_TSETS_Z:
3876     |  // TAB:RB = GCtab *, STR:RC = GCstr *, RA = src*8
3877     |  lwz TMP0, TAB:RB->hmask
3878     |  lwz TMP1, STR:RC->hash
3879     |  lwz NODE:TMP2, TAB:RB->node
3880     |    stb ZERO, TAB:RB->nomm         // Clear metamethod cache.
3881     |  and TMP1, TMP1, TMP0             // idx = str->hash & tab->hmask
3882     |    lfdx f14, BASE, RA
3883     |  slwi TMP0, TMP1, 5
3884     |  slwi TMP1, TMP1, 3
3885     |  sub TMP1, TMP0, TMP1
3886     |    lbz TMP3, TAB:RB->marked
3887     |  add NODE:TMP2, NODE:TMP2, TMP1   // node = tab->node + (idx*32-idx*8)
3888     |1:
3889     |  lwz CARG1, NODE:TMP2->key
3890     |   lwz TMP0, 4+offsetof(Node, key)(NODE:TMP2)
3891     |    lwz CARG2, NODE:TMP2->val
3892     |     lwz NODE:TMP1, NODE:TMP2->next
3893     |  checkstr CARG1; bne >5
3894     |   cmpw TMP0, STR:RC; bne >5
3895     |    checknil CARG2; beq >4         // Key found, but nil value?
3896     |2:
3897     |  andi. TMP0, TMP3, LJ_GC_BLACK    // isblack(table)
3898     |    stfd f14, NODE:TMP2->val
3899     |  bne >7
3900     |3:
3901     |  ins_next
3902     |
3903     |4:  // Check for __newindex if previous value is nil.
3904     |  lwz TAB:TMP1, TAB:RB->metatable
3905     |  cmplwi TAB:TMP1, 0
3906     |  beq <2                           // No metatable: done.
3907     |  lbz TMP0, TAB:TMP1->nomm
3908     |  andi. TMP0, TMP0, 1<<MM_newindex
3909     |  bne <2                           // 'no __newindex' flag set: done.
3910     |  b ->vmeta_tsets
3911     |
3912     |5:  // Follow hash chain.
3913     |  cmplwi NODE:TMP1, 0
3914     |   mr NODE:TMP2, NODE:TMP1
3915     |  bne <1
3916     |  // End of hash chain: key not found, add a new one.
3917     |
3918     |  // But check for __newindex first.
3919     |  lwz TAB:TMP1, TAB:RB->metatable
3920     |   la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
3921     |   stw PC, SAVE_PC
3922     |   mr CARG1, L
3923     |  cmplwi TAB:TMP1, 0
3924     |   stw BASE, L->base
3925     |  beq >6                           // No metatable: continue.
3926     |  lbz TMP0, TAB:TMP1->nomm
3927     |  andi. TMP0, TMP0, 1<<MM_newindex
3928     |  beq ->vmeta_tsets                // 'no __newindex' flag NOT set: check.
3929     |6:
3930     |  li TMP0, LJ_TSTR
3931     |   stw STR:RC, 4(CARG3)
3932     |   mr CARG2, TAB:RB
3933     |  stw TMP0, 0(CARG3)
3934     |  bl extern lj_tab_newkey          // (lua_State *L, GCtab *t, TValue *k)
3935     |  // Returns TValue *.
3936     |  lwz BASE, L->base
3937     |  stfd f14, 0(CRET1)
3938     |  b <3                             // No 2nd write barrier needed.
3939     |
3940     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3941     |  barrierback TAB:RB, TMP3, TMP0
3942     |  b <3
3943     break;
3944   case BC_TSETB:
3945     |  // RA = src*8, RB = table*8, RC = index*8
3946     |  lwzux CARG1, RB, BASE
3947     |   srwi TMP0, RC, 3
3948     |   lwz TAB:RB, 4(RB)
3949     |  checktab CARG1; bne ->vmeta_tsetb
3950     |  lwz TMP1, TAB:RB->asize
3951     |   lwz TMP2, TAB:RB->array
3952     |    lbz TMP3, TAB:RB->marked
3953     |  cmplw TMP0, TMP1
3954     |   lfdx f14, BASE, RA
3955     |  bge ->vmeta_tsetb
3956     |  lwzx TMP1, TMP2, RC
3957     |  checknil TMP1; beq >5
3958     |1:
3959     |  andi. TMP0, TMP3, LJ_GC_BLACK    // isblack(table)
3960     |   stfdx f14, TMP2, RC
3961     |  bne >7
3962     |2:
3963     |  ins_next
3964     |
3965     |5:  // Check for __newindex if previous value is nil.
3966     |  lwz TAB:TMP1, TAB:RB->metatable
3967     |  cmplwi TAB:TMP1, 0
3968     |  beq <1                           // No metatable: done.
3969     |  lbz TMP1, TAB:TMP1->nomm
3970     |  andi. TMP1, TMP1, 1<<MM_newindex
3971     |  bne <1                           // 'no __newindex' flag set: done.
3972     |  b ->vmeta_tsetb                  // Caveat: preserve TMP0!
3973     |
3974     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3975     |  barrierback TAB:RB, TMP3, TMP0
3976     |  b <2
3977     break;
3978
3979   case BC_TSETM:
3980     |  // RA = base*8 (table at base-1), RD = num_const*8 (start index)
3981     |  add RA, BASE, RA
3982     |1:
3983     |   add TMP3, KBASE, RD
3984     |  lwz TAB:CARG2, -4(RA)            // Guaranteed to be a table.
3985     |    addic. TMP0, MULTRES, -8
3986     |   lwz TMP3, 4(TMP3)               // Integer constant is in lo-word.
3987     |    srwi CARG3, TMP0, 3
3988     |    beq >4                         // Nothing to copy?
3989     |  add CARG3, CARG3, TMP3
3990     |  lwz TMP2, TAB:CARG2->asize
3991     |   slwi TMP1, TMP3, 3
3992     |    lbz TMP3, TAB:CARG2->marked
3993     |  cmplw CARG3, TMP2
3994     |   add TMP2, RA, TMP0
3995     |   lwz TMP0, TAB:CARG2->array
3996     |  bgt >5
3997     |   add TMP1, TMP1, TMP0
3998     |    andi. TMP0, TMP3, LJ_GC_BLACK  // isblack(table)
3999     |3:  // Copy result slots to table.
4000     |   lfd f0, 0(RA)
4001     |  addi RA, RA, 8
4002     |  cmpw cr1, RA, TMP2
4003     |   stfd f0, 0(TMP1)
4004     |    addi TMP1, TMP1, 8
4005     |  blt cr1, <3
4006     |  bne >7
4007     |4:
4008     |  ins_next
4009     |
4010     |5:  // Need to resize array part.
4011     |   stw BASE, L->base
4012     |  mr CARG1, L
4013     |   stw PC, SAVE_PC
4014     |  mr SAVE0, RD
4015     |  bl extern lj_tab_reasize         // (lua_State *L, GCtab *t, int nasize)
4016     |  // Must not reallocate the stack.
4017     |  mr RD, SAVE0
4018     |  b <1
4019     |
4020     |7:  // Possible table write barrier for any value. Skip valiswhite check.
4021     |  barrierback TAB:CARG2, TMP3, TMP0
4022     |  b <4
4023     break;
4024
4025   /* -- Calls and vararg handling ----------------------------------------- */
4026
4027   case BC_CALLM:
4028     |  // RA = base*8, (RB = (nresults+1)*8,) RC = extra_nargs*8
4029     |  add NARGS8:RC, NARGS8:RC, MULTRES
4030     |  // Fall through. Assumes BC_CALL follows.
4031     break;
4032   case BC_CALL:
4033     |  // RA = base*8, (RB = (nresults+1)*8,) RC = (nargs+1)*8
4034     |  mr TMP2, BASE
4035     |  lwzux TMP0, BASE, RA
4036     |   lwz LFUNC:RB, 4(BASE)
4037     |    subi NARGS8:RC, NARGS8:RC, 8
4038     |   addi BASE, BASE, 8
4039     |  checkfunc TMP0; bne ->vmeta_call
4040     |  ins_call
4041     break;
4042
4043   case BC_CALLMT:
4044     |  // RA = base*8, (RB = 0,) RC = extra_nargs*8
4045     |  add NARGS8:RC, NARGS8:RC, MULTRES
4046     |  // Fall through. Assumes BC_CALLT follows.
4047     break;
4048   case BC_CALLT:
4049     |  // RA = base*8, (RB = 0,) RC = (nargs+1)*8
4050     |  lwzux TMP0, RA, BASE
4051     |   lwz LFUNC:RB, 4(RA)
4052     |    subi NARGS8:RC, NARGS8:RC, 8
4053     |    lwz TMP1, FRAME_PC(BASE)
4054     |  checkfunc TMP0
4055     |   addi RA, RA, 8
4056     |  bne ->vmeta_callt
4057     |->BC_CALLT_Z:
4058     |  andi. TMP0, TMP1, FRAME_TYPE     // Caveat: preserve cr0 until the crand.
4059     |   lbz TMP3, LFUNC:RB->ffid
4060     |    xori TMP2, TMP1, FRAME_VARG
4061     |    cmplwi cr1, NARGS8:RC, 0
4062     |  bne >7
4063     |1:
4064     |  stw LFUNC:RB, FRAME_FUNC(BASE)   // Copy function down, but keep PC.
4065     |  li TMP2, 0
4066     |   cmplwi cr7, TMP3, 1             // (> FF_C) Calling a fast function?
4067     |    beq cr1, >3
4068     |2:
4069     |  addi TMP3, TMP2, 8
4070     |   lfdx f0, RA, TMP2
4071     |  cmplw cr1, TMP3, NARGS8:RC
4072     |   stfdx f0, BASE, TMP2
4073     |  mr TMP2, TMP3
4074     |  bne cr1, <2
4075     |3:
4076     |  crand 4*cr0+eq, 4*cr0+eq, 4*cr7+gt
4077     |  beq >5
4078     |4:
4079     |  ins_callt
4080     |
4081     |5:  // Tailcall to a fast function with a Lua frame below.
4082     |  lwz INS, -4(TMP1)
4083     |  decode_RA8 RA, INS
4084     |  sub TMP1, BASE, RA
4085     |  lwz LFUNC:TMP1, FRAME_FUNC-8(TMP1)
4086     |  lwz TMP1, LFUNC:TMP1->pc
4087     |  lwz KBASE, PC2PROTO(k)(TMP1)     // Need to prepare KBASE.
4088     |  b <4
4089     |
4090     |7:  // Tailcall from a vararg function.
4091     |  andi. TMP0, TMP2, FRAME_TYPEP
4092     |  bne <1                           // Vararg frame below?
4093     |  sub BASE, BASE, TMP2             // Relocate BASE down.
4094     |  lwz TMP1, FRAME_PC(BASE)
4095     |  andi. TMP0, TMP1, FRAME_TYPE
4096     |  b <1
4097     break;
4098
4099   case BC_ITERC:
4100     |  // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 ((2+1)*8))
4101     |  mr TMP2, BASE
4102     |  add BASE, BASE, RA
4103     |  lwz TMP1, -24(BASE)
4104     |   lwz LFUNC:RB, -20(BASE)
4105     |    lfd f1, -8(BASE)
4106     |    lfd f0, -16(BASE)
4107     |  stw TMP1, 0(BASE)                // Copy callable.
4108     |   stw LFUNC:RB, 4(BASE)
4109     |  checkfunc TMP1
4110     |    stfd f1, 16(BASE)              // Copy control var.
4111     |     li NARGS8:RC, 16              // Iterators get 2 arguments.
4112     |    stfdu f0, 8(BASE)              // Copy state.
4113     |  bne ->vmeta_call
4114     |  ins_call
4115     break;
4116
4117   case BC_ITERN:
4118     |  // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 (2+1)*8)
4119 #if LJ_HASJIT
4120     |  // NYI: add hotloop, record BC_ITERN.
4121 #endif
4122     |  add RA, BASE, RA
4123     |  lwz TAB:RB, -12(RA)
4124     |  lwz RC, -4(RA)                   // Get index from control var.
4125     |  lwz TMP0, TAB:RB->asize
4126     |  lwz TMP1, TAB:RB->array
4127     |   addi PC, PC, 4
4128     |1:  // Traverse array part.
4129     |  cmplw RC, TMP0
4130     |   slwi TMP3, RC, 3
4131     |  bge >5                           // Index points after array part?
4132     |  lwzx TMP2, TMP1, TMP3
4133     |   lfdx f0, TMP1, TMP3
4134     |  checknil TMP2
4135     |     lwz INS, -4(PC)
4136     |  beq >4
4137     if (LJ_DUALNUM) {
4138       |   stw RC, 4(RA)
4139       |   stw TISNUM, 0(RA)
4140     } else {
4141       |   tonum_u f1, RC
4142     }
4143     |    addi RC, RC, 1
4144     |     addis TMP3, PC, -(BCBIAS_J*4 >> 16)
4145     |  stfd f0, 8(RA)
4146     |     decode_RD4 TMP1, INS
4147     |    stw RC, -4(RA)                 // Update control var.
4148     |     add PC, TMP1, TMP3
4149     if (!LJ_DUALNUM) {
4150       |   stfd f1, 0(RA)
4151     }
4152     |3:
4153     |  ins_next
4154     |
4155     |4:  // Skip holes in array part.
4156     |  addi RC, RC, 1
4157     |  b <1
4158     |
4159     |5:  // Traverse hash part.
4160     |  lwz TMP1, TAB:RB->hmask
4161     |  sub RC, RC, TMP0
4162     |   lwz TMP2, TAB:RB->node
4163     |6:
4164     |  cmplw RC, TMP1                   // End of iteration? Branch to ITERL+1.
4165     |   slwi TMP3, RC, 5
4166     |  bgty <3
4167     |   slwi RB, RC, 3
4168     |   sub TMP3, TMP3, RB
4169     |  lwzx RB, TMP2, TMP3
4170     |  lfdx f0, TMP2, TMP3
4171     |   add NODE:TMP3, TMP2, TMP3
4172     |  checknil RB
4173     |     lwz INS, -4(PC)
4174     |  beq >7
4175     |   lfd f1, NODE:TMP3->key
4176     |     addis TMP2, PC, -(BCBIAS_J*4 >> 16)
4177     |  stfd f0, 8(RA)
4178     |    add RC, RC, TMP0
4179     |     decode_RD4 TMP1, INS
4180     |   stfd f1, 0(RA)
4181     |    addi RC, RC, 1
4182     |     add PC, TMP1, TMP2
4183     |    stw RC, -4(RA)                 // Update control var.
4184     |  b <3
4185     |
4186     |7:  // Skip holes in hash part.
4187     |  addi RC, RC, 1
4188     |  b <6
4189     break;
4190
4191   case BC_ISNEXT:
4192     |  // RA = base*8, RD = target (points to ITERN)
4193     |  add RA, BASE, RA
4194     |  lwz TMP0, -24(RA)
4195     |  lwz CFUNC:TMP1, -20(RA)
4196     |   lwz TMP2, -16(RA)
4197     |    lwz TMP3, -8(RA)
4198     |   cmpwi cr0, TMP2, LJ_TTAB
4199     |  cmpwi cr1, TMP0, LJ_TFUNC
4200     |    cmpwi cr6, TMP3, LJ_TNIL
4201     |  bne cr1, >5
4202     |  lbz TMP1, CFUNC:TMP1->ffid
4203     |   crand 4*cr0+eq, 4*cr0+eq, 4*cr6+eq
4204     |  cmpwi cr7, TMP1, FF_next_N
4205     |    srwi TMP0, RD, 1
4206     |  crand 4*cr0+eq, 4*cr0+eq, 4*cr7+eq
4207     |    add TMP3, PC, TMP0
4208     |  bne cr0, >5
4209     |  stw ZERO, -4(RA)                 // Initialize control var.
4210     |    addis PC, TMP3, -(BCBIAS_J*4 >> 16)
4211     |1:
4212     |  ins_next
4213     |5:  // Despecialize bytecode if any of the checks fail.
4214     |  li TMP0, BC_JMP
4215     |   li TMP1, BC_ITERC
4216     |  stb TMP0, -1(PC)
4217     |    addis PC, TMP3, -(BCBIAS_J*4 >> 16)
4218     |   stb TMP1, 3(PC)
4219     |  b <1
4220     break;
4221
4222   case BC_VARG:
4223     |  // RA = base*8, RB = (nresults+1)*8, RC = numparams*8
4224     |  lwz TMP0, FRAME_PC(BASE)
4225     |  add RC, BASE, RC
4226     |   add RA, BASE, RA
4227     |  addi RC, RC, FRAME_VARG
4228     |   add TMP2, RA, RB
4229     |  subi TMP3, BASE, 8               // TMP3 = vtop
4230     |  sub RC, RC, TMP0                 // RC = vbase
4231     |  // Note: RC may now be even _above_ BASE if nargs was < numparams.
4232     |  cmplwi cr1, RB, 0
4233     |   sub. TMP1, TMP3, RC
4234     |  beq cr1, >5                      // Copy all varargs?
4235     |   subi TMP2, TMP2, 16
4236     |   ble >2                          // No vararg slots?
4237     |1:  // Copy vararg slots to destination slots.
4238     |  lfd f0, 0(RC)
4239     |   addi RC, RC, 8
4240     |  stfd f0, 0(RA)
4241     |  cmplw RA, TMP2
4242     |   cmplw cr1, RC, TMP3
4243     |  bge >3                           // All destination slots filled?
4244     |    addi RA, RA, 8
4245     |   blt cr1, <1                     // More vararg slots?
4246     |2:  // Fill up remainder with nil.
4247     |  stw TISNIL, 0(RA)
4248     |  cmplw RA, TMP2
4249     |   addi RA, RA, 8
4250     |  blt <2
4251     |3:
4252     |  ins_next
4253     |
4254     |5:  // Copy all varargs.
4255     |  lwz TMP0, L->maxstack
4256     |   li MULTRES, 8                   // MULTRES = (0+1)*8
4257     |  bley <3                          // No vararg slots?
4258     |  add TMP2, RA, TMP1
4259     |  cmplw TMP2, TMP0
4260     |   addi MULTRES, TMP1, 8
4261     |  bgt >7
4262     |6:
4263     |  lfd f0, 0(RC)
4264     |   addi RC, RC, 8
4265     |  stfd f0, 0(RA)
4266     |  cmplw RC, TMP3
4267     |   addi RA, RA, 8
4268     |  blt <6                           // More vararg slots?
4269     |  b <3
4270     |
4271     |7:  // Grow stack for varargs.
4272     |  mr CARG1, L
4273     |   stw RA, L->top
4274     |  sub SAVE0, RC, BASE              // Need delta, because BASE may change.
4275     |   stw BASE, L->base
4276     |  sub RA, RA, BASE
4277     |   stw PC, SAVE_PC
4278     |  srwi CARG2, TMP1, 3
4279     |  bl extern lj_state_growstack     // (lua_State *L, int n)
4280     |  lwz BASE, L->base
4281     |  add RA, BASE, RA
4282     |  add RC, BASE, SAVE0
4283     |  subi TMP3, BASE, 8
4284     |  b <6
4285     break;
4286
4287   /* -- Returns ----------------------------------------------------------- */
4288
4289   case BC_RETM:
4290     |  // RA = results*8, RD = extra_nresults*8
4291     |  add RD, RD, MULTRES              // MULTRES >= 8, so RD >= 8.
4292     |  // Fall through. Assumes BC_RET follows.
4293     break;
4294
4295   case BC_RET:
4296     |  // RA = results*8, RD = (nresults+1)*8
4297     |  lwz PC, FRAME_PC(BASE)
4298     |   add RA, BASE, RA
4299     |    mr MULTRES, RD
4300     |1:
4301     |  andi. TMP0, PC, FRAME_TYPE
4302     |   xori TMP1, PC, FRAME_VARG
4303     |  bne ->BC_RETV_Z
4304     |
4305     |->BC_RET_Z:
4306     |  // BASE = base, RA = resultptr, RD = (nresults+1)*8, PC = return
4307     |   lwz INS, -4(PC)
4308     |  cmpwi RD, 8
4309     |   subi TMP2, BASE, 8
4310     |   subi RC, RD, 8
4311     |   decode_RB8 RB, INS
4312     |  beq >3
4313     |   li TMP1, 0
4314     |2:
4315     |  addi TMP3, TMP1, 8
4316     |   lfdx f0, RA, TMP1
4317     |  cmpw TMP3, RC
4318     |   stfdx f0, TMP2, TMP1
4319     |  beq >3
4320     |  addi TMP1, TMP3, 8
4321     |   lfdx f1, RA, TMP3
4322     |  cmpw TMP1, RC
4323     |   stfdx f1, TMP2, TMP3
4324     |  bne <2
4325     |3:
4326     |5:
4327     |  cmplw RB, RD
4328     |   decode_RA8 RA, INS
4329     |  bgt >6
4330     |   sub BASE, TMP2, RA
4331     |  lwz LFUNC:TMP1, FRAME_FUNC(BASE)
4332     |  ins_next1
4333     |  lwz TMP1, LFUNC:TMP1->pc
4334     |  lwz KBASE, PC2PROTO(k)(TMP1)
4335     |  ins_next2
4336     |
4337     |6:  // Fill up results with nil.
4338     |  subi TMP1, RD, 8
4339     |   addi RD, RD, 8
4340     |  stwx TISNIL, TMP2, TMP1
4341     |  b <5
4342     |
4343     |->BC_RETV_Z:  // Non-standard return case.
4344     |  andi. TMP2, TMP1, FRAME_TYPEP
4345     |  bne ->vm_return
4346     |  // Return from vararg function: relocate BASE down.
4347     |  sub BASE, BASE, TMP1
4348     |  lwz PC, FRAME_PC(BASE)
4349     |  b <1
4350     break;
4351
4352   case BC_RET0: case BC_RET1:
4353     |  // RA = results*8, RD = (nresults+1)*8
4354     |  lwz PC, FRAME_PC(BASE)
4355     |   add RA, BASE, RA
4356     |    mr MULTRES, RD
4357     |  andi. TMP0, PC, FRAME_TYPE
4358     |   xori TMP1, PC, FRAME_VARG
4359     |  bney ->BC_RETV_Z
4360     |
4361     |  lwz INS, -4(PC)
4362     |   subi TMP2, BASE, 8
4363     |  decode_RB8 RB, INS
4364     if (op == BC_RET1) {
4365       |  lfd f0, 0(RA)
4366       |  stfd f0, 0(TMP2)
4367     }
4368     |5:
4369     |  cmplw RB, RD
4370     |   decode_RA8 RA, INS
4371     |  bgt >6
4372     |   sub BASE, TMP2, RA
4373     |  lwz LFUNC:TMP1, FRAME_FUNC(BASE)
4374     |  ins_next1
4375     |  lwz TMP1, LFUNC:TMP1->pc
4376     |  lwz KBASE, PC2PROTO(k)(TMP1)
4377     |  ins_next2
4378     |
4379     |6:  // Fill up results with nil.
4380     |  subi TMP1, RD, 8
4381     |   addi RD, RD, 8
4382     |  stwx TISNIL, TMP2, TMP1
4383     |  b <5
4384     break;
4385
4386   /* -- Loops and branches ------------------------------------------------ */
4387
4388   case BC_FORL:
4389 #if LJ_HASJIT
4390     |  hotloop
4391 #endif
4392     |  // Fall through. Assumes BC_IFORL follows.
4393     break;
4394
4395   case BC_JFORI:
4396   case BC_JFORL:
4397 #if !LJ_HASJIT
4398     break;
4399 #endif
4400   case BC_FORI:
4401   case BC_IFORL:
4402     |  // RA = base*8, RD = target (after end of loop or start of loop)
4403     vk = (op == BC_IFORL || op == BC_JFORL);
4404     if (LJ_DUALNUM) {
4405       |  // Integer loop.
4406       |  lwzux TMP1, RA, BASE
4407       |   lwz CARG1, FORL_IDX*8+4(RA)
4408       |  cmplw cr0, TMP1, TISNUM
4409       if (vk) {
4410         |   lwz CARG3, FORL_STEP*8+4(RA)
4411         |  bne >9
4412         |  addo. CARG1, CARG1, CARG3
4413         |    cmpwi cr6, CARG3, 0
4414         |   lwz CARG2, FORL_STOP*8+4(RA)
4415         |  bso >6
4416         |4:
4417         |  stw CARG1, FORL_IDX*8+4(RA)
4418       } else {
4419         |  lwz TMP3, FORL_STEP*8(RA)
4420         |   lwz CARG3, FORL_STEP*8+4(RA)
4421         |  lwz TMP2, FORL_STOP*8(RA)
4422         |   lwz CARG2, FORL_STOP*8+4(RA)
4423         |  cmplw cr7, TMP3, TISNUM
4424         |  cmplw cr1, TMP2, TISNUM
4425         |  crand 4*cr0+eq, 4*cr0+eq, 4*cr7+eq
4426         |  crand 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
4427         |    cmpwi cr6, CARG3, 0
4428         |  bne >9
4429       }
4430       |    blt cr6, >5
4431       |  cmpw CARG1, CARG2
4432       |1:
4433       |   stw TISNUM, FORL_EXT*8(RA)
4434       if (op != BC_JFORL) {
4435         |  srwi RD, RD, 1
4436       }
4437       |   stw CARG1, FORL_EXT*8+4(RA)
4438       if (op != BC_JFORL) {
4439         |  add RD, PC, RD
4440       }
4441       if (op == BC_FORI) {
4442         |  bgt >3  // See FP loop below.
4443       } else if (op == BC_JFORI) {
4444         |  addis PC, RD, -(BCBIAS_J*4 >> 16)
4445         |  bley >7
4446       } else if (op == BC_IFORL) {
4447         |  bgt >2
4448         |  addis PC, RD, -(BCBIAS_J*4 >> 16)
4449       } else {
4450         |  bley =>BC_JLOOP
4451       }
4452       |2:
4453       |  ins_next
4454       |5:  // Invert check for negative step.
4455       |  cmpw CARG2, CARG1
4456       |  b <1
4457       if (vk) {
4458         |6:  // Potential overflow.
4459         |  mcrxr cr0; bley <4           // Ignore unrelated overflow.
4460         |  b <2
4461       }
4462     }
4463     if (vk) {
4464       if (LJ_DUALNUM) {
4465         |9:  // FP loop.
4466         |  lfd f1, FORL_IDX*8(RA)
4467       } else {
4468         |  lfdux f1, RA, BASE
4469       }
4470       |  lfd f3, FORL_STEP*8(RA)
4471       |  lfd f2, FORL_STOP*8(RA)
4472       |   lwz TMP3, FORL_STEP*8(RA)
4473       |  fadd f1, f1, f3
4474       |  stfd f1, FORL_IDX*8(RA)
4475     } else {
4476       if (LJ_DUALNUM) {
4477         |9:  // FP loop.
4478       } else {
4479         |  lwzux TMP1, RA, BASE
4480         |  lwz TMP3, FORL_STEP*8(RA)
4481         |  lwz TMP2, FORL_STOP*8(RA)
4482         |  cmplw cr0, TMP1, TISNUM
4483         |  cmplw cr7, TMP3, TISNUM
4484         |  cmplw cr1, TMP2, TISNUM
4485       }
4486       |   lfd f1, FORL_IDX*8(RA)
4487       |  crand 4*cr0+lt, 4*cr0+lt, 4*cr7+lt
4488       |  crand 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
4489       |   lfd f2, FORL_STOP*8(RA)
4490       |  bge ->vmeta_for
4491     }
4492     |  cmpwi cr6, TMP3, 0
4493     if (op != BC_JFORL) {
4494       |  srwi RD, RD, 1
4495     }
4496     |   stfd f1, FORL_EXT*8(RA)
4497     if (op != BC_JFORL) {
4498       |  add RD, PC, RD
4499     }
4500     |  fcmpu cr0, f1, f2
4501     if (op == BC_JFORI) {
4502       |  addis PC, RD, -(BCBIAS_J*4 >> 16)
4503     }
4504     |  blt cr6, >5
4505     if (op == BC_FORI) {
4506       |  bgt >3
4507     } else if (op == BC_IFORL) {
4508       if (LJ_DUALNUM) {
4509         |  bgty <2
4510       } else {
4511         |  bgt >2
4512       }
4513       |1:
4514       |  addis PC, RD, -(BCBIAS_J*4 >> 16)
4515     } else if (op == BC_JFORI) {
4516       |  bley >7
4517     } else {
4518       |  bley =>BC_JLOOP
4519     }
4520     if (LJ_DUALNUM) {
4521       |  b <2
4522     } else {
4523       |2:
4524       |  ins_next
4525     }
4526     |5:  // Negative step.
4527     if (op == BC_FORI) {
4528       |  bge <2
4529       |3:  // Used by integer loop, too.
4530       |  addis PC, RD, -(BCBIAS_J*4 >> 16)
4531     } else if (op == BC_IFORL) {
4532       |  bgey <1
4533     } else if (op == BC_JFORI) {
4534       |  bgey >7
4535     } else {
4536       |  bgey =>BC_JLOOP
4537     }
4538     |  b <2
4539     if (op == BC_JFORI) {
4540       |7:
4541       |  lwz INS, -4(PC)
4542       |  decode_RD8 RD, INS
4543       |  b =>BC_JLOOP
4544     }
4545     break;
4546
4547   case BC_ITERL:
4548 #if LJ_HASJIT
4549     |  hotloop
4550 #endif
4551     |  // Fall through. Assumes BC_IITERL follows.
4552     break;
4553
4554   case BC_JITERL:
4555 #if !LJ_HASJIT
4556     break;
4557 #endif
4558   case BC_IITERL:
4559     |  // RA = base*8, RD = target
4560     |  lwzux TMP1, RA, BASE
4561     |   lwz TMP2, 4(RA)
4562     |  checknil TMP1; beq >1            // Stop if iterator returned nil.
4563     if (op == BC_JITERL) {
4564       |  stw TMP1, -8(RA)
4565       |   stw TMP2, -4(RA)
4566       |  b =>BC_JLOOP
4567     } else {
4568       |  branch_RD                      // Otherwise save control var + branch.
4569       |  stw TMP1, -8(RA)
4570       |   stw TMP2, -4(RA)
4571     }
4572     |1:
4573     |  ins_next
4574     break;
4575
4576   case BC_LOOP:
4577     |  // RA = base*8, RD = target (loop extent)
4578     |  // Note: RA/RD is only used by trace recorder to determine scope/extent
4579     |  // This opcode does NOT jump, it's only purpose is to detect a hot loop.
4580 #if LJ_HASJIT
4581     |  hotloop
4582 #endif
4583     |  // Fall through. Assumes BC_ILOOP follows.
4584     break;
4585
4586   case BC_ILOOP:
4587     |  // RA = base*8, RD = target (loop extent)
4588     |  ins_next
4589     break;
4590
4591   case BC_JLOOP:
4592 #if LJ_HASJIT
4593     |  // RA = base*8 (ignored), RD = traceno*8
4594     |  lwz TMP1, DISPATCH_J(trace)(DISPATCH)
4595     |  srwi RD, RD, 1
4596     |  // Traces on PPC don't store the trace number, so use 0.
4597     |   stw ZERO, DISPATCH_GL(vmstate)(DISPATCH)
4598     |  lwzx TRACE:TMP2, TMP1, RD
4599     |  mcrxr cr0                        // Clear SO flag.
4600     |  lwz TMP2, TRACE:TMP2->mcode
4601     |   stw BASE, DISPATCH_GL(jit_base)(DISPATCH)
4602     |  mtctr TMP2
4603     |   stw L, DISPATCH_GL(jit_L)(DISPATCH)
4604     |   addi JGL, DISPATCH, GG_DISP2G+32768
4605     |  bctr
4606 #endif
4607     break;
4608
4609   case BC_JMP:
4610     |  // RA = base*8 (only used by trace recorder), RD = target
4611     |  branch_RD
4612     |  ins_next
4613     break;
4614
4615   /* -- Function headers -------------------------------------------------- */
4616
4617   case BC_FUNCF:
4618 #if LJ_HASJIT
4619     |  hotcall
4620 #endif
4621   case BC_FUNCV:  /* NYI: compiled vararg functions. */
4622     |  // Fall through. Assumes BC_IFUNCF/BC_IFUNCV follow.
4623     break;
4624
4625   case BC_JFUNCF:
4626 #if !LJ_HASJIT
4627     break;
4628 #endif
4629   case BC_IFUNCF:
4630     |  // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
4631     |  lwz TMP2, L->maxstack
4632     |   lbz TMP1, -4+PC2PROTO(numparams)(PC)
4633     |    lwz KBASE, -4+PC2PROTO(k)(PC)
4634     |  cmplw RA, TMP2
4635     |   slwi TMP1, TMP1, 3
4636     |  bgt ->vm_growstack_l
4637     if (op != BC_JFUNCF) {
4638       |  ins_next1
4639     }
4640     |2:
4641     |  cmplw NARGS8:RC, TMP1            // Check for missing parameters.
4642     |  blt >3
4643     if (op == BC_JFUNCF) {
4644       |  decode_RD8 RD, INS
4645       |  b =>BC_JLOOP
4646     } else {
4647       |  ins_next2
4648     }
4649     |
4650     |3:  // Clear missing parameters.
4651     |  stwx TISNIL, BASE, NARGS8:RC
4652     |  addi NARGS8:RC, NARGS8:RC, 8
4653     |  b <2
4654     break;
4655
4656   case BC_JFUNCV:
4657 #if !LJ_HASJIT
4658     break;
4659 #endif
4660     |  NYI  // NYI: compiled vararg functions
4661     break;  /* NYI: compiled vararg functions. */
4662
4663   case BC_IFUNCV:
4664     |  // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
4665     |  lwz TMP2, L->maxstack
4666     |   add TMP1, BASE, RC
4667     |  add TMP0, RA, RC
4668     |   stw LFUNC:RB, 4(TMP1)           // Store copy of LFUNC.
4669     |   addi TMP3, RC, 8+FRAME_VARG
4670     |    lwz KBASE, -4+PC2PROTO(k)(PC)
4671     |  cmplw TMP0, TMP2
4672     |   stw TMP3, 0(TMP1)               // Store delta + FRAME_VARG.
4673     |  bge ->vm_growstack_l
4674     |  lbz TMP2, -4+PC2PROTO(numparams)(PC)
4675     |   mr RA, BASE
4676     |   mr RC, TMP1
4677     |  ins_next1
4678     |  cmpwi TMP2, 0
4679     |   addi BASE, TMP1, 8
4680     |  beq >3
4681     |1:
4682     |  cmplw RA, RC                     // Less args than parameters?
4683     |   lwz TMP0, 0(RA)
4684     |   lwz TMP3, 4(RA)
4685     |  bge >4
4686     |    stw TISNIL, 0(RA)              // Clear old fixarg slot (help the GC).
4687     |    addi RA, RA, 8
4688     |2:
4689     |  addic. TMP2, TMP2, -1
4690     |   stw TMP0, 8(TMP1)
4691     |   stw TMP3, 12(TMP1)
4692     |    addi TMP1, TMP1, 8
4693     |  bne <1
4694     |3:
4695     |  ins_next2
4696     |
4697     |4:  // Clear missing parameters.
4698     |  li TMP0, LJ_TNIL
4699     |  b <2
4700     break;
4701
4702   case BC_FUNCC:
4703   case BC_FUNCCW:
4704     |  // BASE = new base, RA = BASE+framesize*8, RB = CFUNC, RC = nargs*8
4705     if (op == BC_FUNCC) {
4706       |  lwz TMP3, CFUNC:RB->f
4707     } else {
4708       |  lwz TMP3, DISPATCH_GL(wrapf)(DISPATCH)
4709     }
4710     |   add TMP1, RA, NARGS8:RC
4711     |   lwz TMP2, L->maxstack
4712     |    add RC, BASE, NARGS8:RC
4713     |   stw BASE, L->base
4714     |   cmplw TMP1, TMP2
4715     |    stw RC, L->top
4716     |     li_vmstate C
4717     |  mtctr TMP3
4718     if (op == BC_FUNCCW) {
4719       |  lwz CARG2, CFUNC:RB->f
4720     }
4721     |  mr CARG1, L
4722     |   bgt ->vm_growstack_c            // Need to grow stack.
4723     |     st_vmstate
4724     |  bctrl                            // (lua_State *L [, lua_CFunction f])
4725     |  // Returns nresults.
4726     |  lwz BASE, L->base
4727     |   slwi RD, CRET1, 3
4728     |  lwz TMP1, L->top
4729     |    li_vmstate INTERP
4730     |  lwz PC, FRAME_PC(BASE)           // Fetch PC of caller.
4731     |   sub RA, TMP1, RD                // RA = L->top - nresults*8
4732     |    st_vmstate
4733     |  b ->vm_returnc
4734     break;
4735
4736   /* ---------------------------------------------------------------------- */
4737
4738   default:
4739     fprintf(stderr, "Error: undefined opcode BC_%s\n", bc_names[op]);
4740     exit(2);
4741     break;
4742   }
4743 }
4744
4745 static int build_backend(BuildCtx *ctx)
4746 {
4747   int op;
4748
4749   dasm_growpc(Dst, BC__MAX);
4750
4751   build_subroutines(ctx);
4752
4753   |.code_op
4754   for (op = 0; op < BC__MAX; op++)
4755     build_ins(ctx, (BCOp)op, op);
4756
4757   return BC__MAX;
4758 }
4759
4760 /* Emit pseudo frame-info for all assembler functions. */
4761 static void emit_asm_debug(BuildCtx *ctx)
4762 {
4763   int fcofs = (int)((uint8_t *)ctx->glob[GLOB_vm_ffi_call] - ctx->code);
4764   int i;
4765   switch (ctx->mode) {
4766   case BUILD_elfasm:
4767     fprintf(ctx->fp, "\t.section .debug_frame,\"\",@progbits\n");
4768     fprintf(ctx->fp,
4769         ".Lframe0:\n"
4770         "\t.long .LECIE0-.LSCIE0\n"
4771         ".LSCIE0:\n"
4772         "\t.long 0xffffffff\n"
4773         "\t.byte 0x1\n"
4774         "\t.string \"\"\n"
4775         "\t.uleb128 0x1\n"
4776         "\t.sleb128 -4\n"
4777         "\t.byte 65\n"
4778         "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
4779         "\t.align 2\n"
4780         ".LECIE0:\n\n");
4781     fprintf(ctx->fp,
4782         ".LSFDE0:\n"
4783         "\t.long .LEFDE0-.LASFDE0\n"
4784         ".LASFDE0:\n"
4785         "\t.long .Lframe0\n"
4786         "\t.long .Lbegin\n"
4787         "\t.long %d\n"
4788         "\t.byte 0xe\n\t.uleb128 %d\n"
4789         "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
4790         "\t.byte 0x5\n\t.uleb128 70\n\t.uleb128 55\n",
4791         fcofs, CFRAME_SIZE);
4792     for (i = 14; i <= 31; i++)
4793       fprintf(ctx->fp,
4794         "\t.byte %d\n\t.uleb128 %d\n"
4795         "\t.byte %d\n\t.uleb128 %d\n",
4796         0x80+i, 37+(31-i), 0x80+32+i, 2+2*(31-i));
4797     fprintf(ctx->fp,
4798         "\t.align 2\n"
4799         ".LEFDE0:\n\n");
4800 #if LJ_HASFFI
4801     fprintf(ctx->fp,
4802         ".LSFDE1:\n"
4803         "\t.long .LEFDE1-.LASFDE1\n"
4804         ".LASFDE1:\n"
4805         "\t.long .Lframe0\n"
4806         "\t.long lj_vm_ffi_call\n"
4807         "\t.long %d\n"
4808         "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
4809         "\t.byte 0x8e\n\t.uleb128 2\n"
4810         "\t.byte 0xd\n\t.uleb128 0xe\n"
4811         "\t.align 2\n"
4812         ".LEFDE1:\n\n", (int)ctx->codesz - fcofs);
4813 #endif
4814     fprintf(ctx->fp, "\t.section .eh_frame,\"a\",@progbits\n");
4815     fprintf(ctx->fp,
4816         ".Lframe1:\n"
4817         "\t.long .LECIE1-.LSCIE1\n"
4818         ".LSCIE1:\n"
4819         "\t.long 0\n"
4820         "\t.byte 0x1\n"
4821         "\t.string \"zPR\"\n"
4822         "\t.uleb128 0x1\n"
4823         "\t.sleb128 -4\n"
4824         "\t.byte 65\n"
4825         "\t.uleb128 6\n"                        /* augmentation length */
4826         "\t.byte 0x1b\n"                        /* pcrel|sdata4 */
4827         "\t.long lj_err_unwind_dwarf-.\n"
4828         "\t.byte 0x1b\n"                        /* pcrel|sdata4 */
4829         "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
4830         "\t.align 2\n"
4831         ".LECIE1:\n\n");
4832     fprintf(ctx->fp,
4833         ".LSFDE2:\n"
4834         "\t.long .LEFDE2-.LASFDE2\n"
4835         ".LASFDE2:\n"
4836         "\t.long .LASFDE2-.Lframe1\n"
4837         "\t.long .Lbegin-.\n"
4838         "\t.long %d\n"
4839         "\t.uleb128 0\n"                        /* augmentation length */
4840         "\t.byte 0xe\n\t.uleb128 %d\n"
4841         "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
4842         "\t.byte 0x5\n\t.uleb128 70\n\t.uleb128 55\n",
4843         fcofs, CFRAME_SIZE);
4844     for (i = 14; i <= 31; i++)
4845       fprintf(ctx->fp,
4846         "\t.byte %d\n\t.uleb128 %d\n"
4847         "\t.byte %d\n\t.uleb128 %d\n",
4848         0x80+i, 37+(31-i), 0x80+32+i, 2+2*(31-i));
4849     fprintf(ctx->fp,
4850         "\t.align 2\n"
4851         ".LEFDE2:\n\n");
4852 #if LJ_HASFFI
4853     fprintf(ctx->fp,
4854         ".Lframe2:\n"
4855         "\t.long .LECIE2-.LSCIE2\n"
4856         ".LSCIE2:\n"
4857         "\t.long 0\n"
4858         "\t.byte 0x1\n"
4859         "\t.string \"zR\"\n"
4860         "\t.uleb128 0x1\n"
4861         "\t.sleb128 -4\n"
4862         "\t.byte 65\n"
4863         "\t.uleb128 1\n"                        /* augmentation length */
4864         "\t.byte 0x1b\n"                        /* pcrel|sdata4 */
4865         "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
4866         "\t.align 2\n"
4867         ".LECIE2:\n\n");
4868     fprintf(ctx->fp,
4869         ".LSFDE3:\n"
4870         "\t.long .LEFDE3-.LASFDE3\n"
4871         ".LASFDE3:\n"
4872         "\t.long .LASFDE3-.Lframe2\n"
4873         "\t.long lj_vm_ffi_call-.\n"
4874         "\t.long %d\n"
4875         "\t.uleb128 0\n"                        /* augmentation length */
4876         "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
4877         "\t.byte 0x8e\n\t.uleb128 2\n"
4878         "\t.byte 0xd\n\t.uleb128 0xe\n"
4879         "\t.align 2\n"
4880         ".LEFDE3:\n\n", (int)ctx->codesz - fcofs);
4881 #endif
4882     break;
4883   default:
4884     break;
4885   }
4886 }
4887