CMakeLists.txt

   1 #  Copyright (c) 2008 Peter Kuemmel
   2 #  Copyright (c) 2008 Mauro Iazzi
   3 #  Copyright (c) 2011 Michal Kottman
   4 #
   5 #  Permission is hereby granted, free of charge, to any person
   6 #  obtaining a copy of this software and associated documentation
   7 #  files (the "Software"), to deal in the Software without
   8 #  restriction, including without limitation the rights to use,
   9 #  copy, modify, merge, publish, distribute, sublicense, and/or sell
  10 #  copies of the Software, and to permit persons to whom the
  11 #  Software is furnished to do so, subject to the following
  12 #  conditions:
  13 #
  14 #  The above copyright notice and this permission notice shall be
  15 #  included in all copies or substantial portions of the Software.
  16 #
  17 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18 #  EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  19 #  OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  20 #  NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  21 #  HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  22 #  WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  23 #  FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  24 #  OTHER DEALINGS IN THE SOFTWARE.
  25
  26 cmake_minimum_required(VERSION 2.6)
  27
  28 project(lqt)
  29
  30
  31 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/bin)
  32 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/lib)
  33 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/lib)
  34
  35 find_package(Qt4 REQUIRED)
  36 set(QT_USE_QTCORE 1)
  37 set(QT_USE_QTGUI 1)
  38 set(QT_USE_QTNETWORK 1)
  39 set(QT_USE_QTWEBKIT 1)
  40 set(QT_USE_QTOPENGL 1)
  41 set(QT_USE_QTSCRIPT 1)
  42 set(QT_USE_QTSVG 1)
  43 set(QT_USE_QTUITOOLS 1)
  44 set(QT_USE_QTXML 1)
  45 set(QT_USE_QTSQL 1)
  46 set(QT_USE_QTXMLPATTERNS 1)
  47 include(${QT_USE_FILE})
  48
  49 if(noqt)
  50         set(QT_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/test)
  51         #set(nomerge TRUE)
  52 endif()
  53
  54 find_package(Lua51 REQUIRED)
  55 find_program(LUA_CMD NAMES luajit lua lua5.1 lua51)
  56
  57 if(MSVC)
  58         set(CMAKE_SUPPRESS_REGENERATION TRUE)
  59         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -DLUA_BUILD_AS_DLL /bigobj)
  60         set(CMAKE_DEBUG_POSTFIX)
  61 endif()
  62
  63 if(MINGW)
  64         set(CMAKE_SHARED_LINKER_FLAGS "-Wl,-add-stdcall-alias")
  65 endif()
  66
  67 add_subdirectory(cpptoxml)
  68
  69 function(build_qt_lib_binding BINDING_HEADER)
  70
  71         string(TOLOWER ${BINDING_HEADER} BINDING_NAME)
  72
  73         # hardcoded in generator.lua
  74         set (LQT_GEN_DIR ${CMAKE_BINARY_DIR}/${BINDING_NAME}_src)
  75         file(MAKE_DIRECTORY ${LQT_GEN_DIR})
  76
  77         set (BINDING_SRC ${LQT_GEN_DIR}/${BINDING_NAME}_merged_build.cpp)
  78         set_source_files_properties(${BINDING_SRC} PROPERTIES  GENERATED TRUE)
  79
  80         if (UNIX)
  81                 set (PP_CONFIG ${CMAKE_SOURCE_DIR}/cpptoxml/parser/rpp/pp-qt-configuration)
  82         else()
  83                 set (PP_CONFIG ${CMAKE_SOURCE_DIR}/cpptoxml/parser/rpp/pp-qt-configuration-win)
  84         endif()
  85
  86         if(NOT REUSE_FILES)
  87                 set (GEN_XML ${LQT_GEN_DIR}/${BINDING_NAME}.xml)
  88                 add_custom_target(generate_${BINDING_NAME}_xml
  89                                                         COMMAND cpptoxml
  90                                                                 ${BINDING_HEADER}
  91                                                                 -C ${PP_CONFIG}
  92                                                                 -Q ${QT_INCLUDE_DIR}
  93                                                                 -o ${GEN_XML}
  94                                                         COMMENT "Generating XML: running cpptoxml on ${BINDING_NAME} "
  95                                                         VERBATIM)
  96
  97                 math(EXPR MAX ${ARGC}-1)
  98                 if(MAX)
  99                         foreach(I RANGE 1 ${MAX})
 100                                 string(TOLOWER ${ARGV${I}} DEPNAME)
 101                                 set(${BINDING_NAME}_TYPES ${${BINDING_NAME}_TYPES} -t ${DEPNAME}_src/${DEPNAME}_types.lua)
 102                                 set(${BINDING_NAME}_DEPENDS ${${BINDING_NAME}_DEPENDS} generate_${DEPNAME}_cpp)
 103                         endforeach()
 104                 endif()
 105
 106                 add_custom_target(generate_${BINDING_NAME}_cpp
 107                                                         COMMAND ${LUA_CMD}
 108                                                                 "${CMAKE_SOURCE_DIR}/generator/generator.lua"
 109                                                                 ${GEN_XML}
 110                                                                 -i ${BINDING_HEADER} -i lqt_qt.hpp
 111                                                                 -n ${BINDING_NAME}
 112                                                                 -t ${CMAKE_SOURCE_DIR}/generator/qtypes.lua
 113                                                                 ${${BINDING_NAME}_TYPES}
 114                                                                 -f ${CMAKE_SOURCE_DIR}/generator/qt_internal.lua
 115                                                         COMMENT "Generating binding code with Lua"
 116                                                         VERBATIM)
 117         else()
 118                 add_custom_target(generate_${BINDING_NAME}_xml  COMMAND
 119                                                         COMMENT "Reusing old XML on ${BINDING_NAME} "
 120                                                         VERBATIM)
 121                 add_custom_target(generate_${BINDING_NAME}_cpp
 122                                                         COMMENT "Reusing old binding code with Lua"
 123                                                         VERBATIM)
 124         endif()
 125
 126         set(COMMON COMMON_${BINDING_NAME})
 127         file(GLOB ${COMMON}_SRC ${CMAKE_SOURCE_DIR}/common/*.cpp)
 128         file(GLOB ${COMMON}_HPP ${CMAKE_SOURCE_DIR}/common/*.hpp)
 129
 130
 131         set(${BINDING_NAME}_GENERATED ${LQT_GEN_DIR}/${BINDING_NAME}_enum.cpp
 132                                                                         ${LQT_GEN_DIR}/${BINDING_NAME}_meta.cpp
 133                                                                         ${LQT_GEN_DIR}/${BINDING_NAME}_slot.cpp)
 134         set_source_files_properties(${${BINDING_NAME}_GENERATED} PROPERTIES GENERATED TRUE)
 135
 136         if(nomerge)
 137                 #TODO fix this build process:
 138                 #       1. cmake ../lqt -Dnomerge=1
 139                 #       2. make -> will generate cpp files but they are not part of the Makefile (GLOB was at 1.)
 140                 #       3. cmake ../lqt -Dnomerge=1 -> GLOB now finds the generated cpp files
 141                 #       4. make
 142                 file(GLOB BINDING_SRC ${LQT_GEN_DIR}/*.cpp)
 143                 set(${COMMON}_SRC)
 144                 list(REMOVE_ITEM BINDING_SRC ${LQT_GEN_DIR}/${BINDING_NAME}_merged_build.cpp)
 145         else()
 146                 set(${COMMON}_SRC ${${COMMON}_SRC}      ${${BINDING_NAME}_GENERATED})
 147         endif()
 148
 149         qt4_wrap_cpp(${COMMON}_MOC ${LQT_GEN_DIR}/${BINDING_NAME}_slot.hpp)
 150
 151         include_directories(${CMAKE_SOURCE_DIR}/common ${LUA_INCLUDE_DIR} ${QT_INCLUDES})
 152
 153         add_library(${BINDING_NAME} MODULE ${BINDING_SRC}
 154                                                                                         ${${COMMON}_SRC}
 155                                                                                         ${${COMMON}_HPP}
 156                                                                                         ${${COMMON}_MOC})
 157
 158         target_link_libraries(${BINDING_NAME} ${QT_LIBRARIES} ${LUA_LIBRARIES})
 159         set_target_properties(${BINDING_NAME} PROPERTIES PREFIX "" COMPILE_DEFINITIONS "MODULE_${BINDING_NAME}")
 160
 161         if(LQT_BUILDIN_CPPTOXML)
 162                 add_dependencies(generate_${BINDING_NAME}_xml  cpptoxml)
 163         endif()
 164
 165         add_dependencies(generate_${BINDING_NAME}_cpp  generate_${BINDING_NAME}_xml ${${BINDING_NAME}_DEPENDS})
 166         add_dependencies(${BINDING_NAME} generate_${BINDING_NAME}_cpp)
 167 endfunction()
 168
 169 if(noqt)
 170         include_directories(${CMAKE_CURRENT_SOURCE_DIR}/test/noqt)
 171         build_qt_lib_binding(noqt)
 172 else()
 173         build_qt_lib_binding(QtCore)
 174         build_qt_lib_binding(QtNetwork QtCore)
 175         build_qt_lib_binding(QtGui QtNetwork QtCore)
 176         build_qt_lib_binding(QtScript QtGui QtNetwork QtCore)
 177         build_qt_lib_binding(QtOpenGL QtGui QtNetwork QtCore)
 178         build_qt_lib_binding(QtSvg QtScript QtGui QtNetwork QtCore)
 179         build_qt_lib_binding(QtXml QtSvg QtScript QtGui QtNetwork QtCore)
 180         build_qt_lib_binding(QtXmlPatterns QtCore QtXml)
 181         build_qt_lib_binding(QtUiTools QtCore QtGui QtXml)
 182         build_qt_lib_binding(QtWebKit QtXmlPatterns QtSvg QtScript QtOpenGL QtGui QtNetwork QtCore QtXml)
 183         build_qt_lib_binding(QtSql QtCore)
 184         # TODO
 185         #build_qt_lib_binding(QtScriptTools) # 4.5 only
 186         #build_qt_lib_binding(Phonon)
 187 endif()
 188
 189
 190
 191
 192
 193
 194