cmake/config-ix.cmake

   1 include(CheckIncludeFile)
   2 include(CheckLibraryExists)
   3 include(CheckSymbolExists)
   4 include(CheckFunctionExists)
   5 include(CheckCXXSourceCompiles)
   6 include(TestBigEndian)
   7
   8 if( UNIX AND NOT BEOS )
   9   # Used by check_symbol_exists:
  10   set(CMAKE_REQUIRED_LIBRARIES m)
  11 endif()
  12
  13 # Helper macros and functions
  14 macro(add_cxx_include result files)
  15   set(${result} "")
  16   foreach (file_name ${files})
  17      set(${result} "${${result}}#include<${file_name}>\n")
  18   endforeach()
  19 endmacro(add_cxx_include files result)
  20
  21 function(check_type_exists type files variable)
  22   add_cxx_include(includes "${files}")
  23   CHECK_CXX_SOURCE_COMPILES("
  24     ${includes} ${type} typeVar;
  25     int main() {
  26         return 0;
  27     }
  28     " ${variable})
  29 endfunction()
  30
  31 # include checks
  32 check_include_file(argz.h HAVE_ARGZ_H)
  33 check_include_file(assert.h HAVE_ASSERT_H)
  34 check_include_file(dirent.h HAVE_DIRENT_H)
  35 check_include_file(dl.h HAVE_DL_H)
  36 check_include_file(dld.h HAVE_DLD_H)
  37 check_include_file(dlfcn.h HAVE_DLFCN_H)
  38 check_include_file(errno.h HAVE_ERRNO_H)
  39 check_include_file(execinfo.h HAVE_EXECINFO_H)
  40 check_include_file(fcntl.h HAVE_FCNTL_H)
  41 check_include_file(inttypes.h HAVE_INTTYPES_H)
  42 check_include_file(limits.h HAVE_LIMITS_H)
  43 check_include_file(link.h HAVE_LINK_H)
  44 check_include_file(malloc.h HAVE_MALLOC_H)
  45 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  46 check_include_file(memory.h HAVE_MEMORY_H)
  47 check_include_file(ndir.h HAVE_NDIR_H)
  48 if( NOT LLVM_ON_WIN32 )
  49   check_include_file(pthread.h HAVE_PTHREAD_H)
  50 endif()
  51 check_include_file(setjmp.h HAVE_SETJMP_H)
  52 check_include_file(signal.h HAVE_SIGNAL_H)
  53 check_include_file(stdint.h HAVE_STDINT_H)
  54 check_include_file(stdio.h HAVE_STDIO_H)
  55 check_include_file(stdlib.h HAVE_STDLIB_H)
  56 check_include_file(string.h HAVE_STRING_H)
  57 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  58 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  59 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  60 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  61 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  62 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  63 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  64 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  65 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  66 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  67 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  68 check_include_file(termios.h HAVE_TERMIOS_H)
  69 check_include_file(unistd.h HAVE_UNISTD_H)
  70 check_include_file(utime.h HAVE_UTIME_H)
  71 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  72 check_include_file(windows.h HAVE_WINDOWS_H)
  73 check_include_file(fenv.h HAVE_FENV_H)
  74
  75 # library checks
  76 if( NOT LLVM_ON_WIN32 )
  77   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  78   check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  79   check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  80   check_library_exists(dl dlopen "" HAVE_LIBDL)
  81 endif()
  82
  83 # function checks
  84 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  85 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  86 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  87 check_function_exists(isatty HAVE_ISATTY)
  88 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  89 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  90 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
  91 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  92 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  93 check_symbol_exists(ceilf math.h HAVE_CEILF)
  94 check_symbol_exists(floorf math.h HAVE_FLOORF)
  95 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
  96 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  97 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  98                     HAVE_MALLOC_ZONE_STATISTICS)
  99 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 100 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 101 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 102 if( NOT LLVM_ON_WIN32 )
 103   check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
 104 endif()
 105 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 106 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 107 check_symbol_exists(strerror string.h HAVE_STRERROR)
 108 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 109 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
 110 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 111
 112 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 113 if( LLVM_USING_GLIBC )
 114   add_llvm_definitions( -D_GNU_SOURCE )
 115 endif()
 116
 117 # Type checks
 118 check_type_exists(std::bidirectional_iterator<int,int> "iterator;iostream" HAVE_BI_ITERATOR)
 119 check_type_exists(std::iterator<int,int,int> iterator HAVE_STD_ITERATOR)
 120 check_type_exists(std::forward_iterator<int,int> iterator HAVE_FWD_ITERATOR)
 121
 122 set(headers "")
 123 if (HAVE_SYS_TYPES_H)
 124   set(headers ${headers} "sys/types.h")
 125 endif()
 126
 127 if (HAVE_INTTYPES_H)
 128   set(headers ${headers} "inttypes.h")
 129 endif()
 130
 131 if (HAVE_STDINT_H)
 132   set(headers ${headers} "stdint.h")
 133 endif()
 134
 135 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 136 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 137
 138 # available programs checks
 139 function(llvm_find_program name)
 140   string(TOUPPER ${name} NAME)
 141   find_program(LLVM_PATH_${NAME} ${name})
 142   mark_as_advanced(LLVM_PATH_${NAME})
 143   if(LLVM_PATH_${NAME})
 144     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 145     mark_as_advanced(HAVE_${NAME})
 146   else(LLVM_PATH_${NAME})
 147     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 148   endif(LLVM_PATH_${NAME})
 149 endfunction()
 150
 151 llvm_find_program(gv)
 152 llvm_find_program(circo)
 153 llvm_find_program(twopi)
 154 llvm_find_program(neato)
 155 llvm_find_program(fdp)
 156 llvm_find_program(dot)
 157 llvm_find_program(dotty)
 158
 159 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
 160 include(CheckAtomic)
 161
 162 include(CheckCXXCompilerFlag)
 163 # On windows all code is position-independent and mingw warns if -fPIC
 164 # is in the command-line.
 165 if( NOT WIN32 )
 166   check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
 167 endif()
 168
 169 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 170
 171 include(GetTargetTriple)
 172 get_target_triple(LLVM_HOSTTRIPLE)
 173
 174 # FIXME: We don't distinguish the target and the host. :(
 175 set(TARGET_TRIPLE "${LLVM_HOSTTRIPLE}")
 176
 177 # Determine the native architecture.
 178 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 179 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 180   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
 181 endif ()
 182
 183 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 184   set(LLVM_NATIVE_ARCH X86)
 185 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 186   set(LLVM_NATIVE_ARCH X86)
 187 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 188   set(LLVM_NATIVE_ARCH X86)
 189 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 190   set(LLVM_NATIVE_ARCH X86)
 191 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 192   set(LLVM_NATIVE_ARCH Sparc)
 193 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 194   set(LLVM_NATIVE_ARCH PowerPC)
 195 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 196   set(LLVM_NATIVE_ARCH Alpha)
 197 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 198   set(LLVM_NATIVE_ARCH ARM)
 199 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 200   set(LLVM_NATIVE_ARCH Mips)
 201 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 202   set(LLVM_NATIVE_ARCH XCore)
 203 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 204   set(LLVM_NATIVE_ARCH MSP430)
 205 else ()
 206   message(STATUS
 207     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 208   set(LLVM_NATIVE_ARCH)
 209 endif ()
 210
 211 if (LLVM_NATIVE_ARCH)
 212   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 213   if (NATIVE_ARCH_IDX EQUAL -1)
 214     message(STATUS
 215       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 216     set(LLVM_NATIVE_ARCH)
 217   else ()
 218     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 219     set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 220     set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 221     set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 222   endif ()
 223 endif()
 224
 225 if( MINGW )
 226   set(HAVE_LIBIMAGEHLP 1)
 227   set(HAVE_LIBPSAPI 1)
 228   # TODO: Check existence of libraries.
 229   #   include(CheckLibraryExists)
 230   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 231 endif( MINGW )
 232
 233 if( MSVC )
 234   set(error_t int)
 235   set(mode_t "unsigned short")
 236   set(LTDL_SHLIBPATH_VAR "PATH")
 237   set(LTDL_SYSSEARCHPATH "")
 238   set(LTDL_DLOPEN_DEPLIBS 1)
 239   set(SHLIBEXT ".lib")
 240   set(LTDL_OBJDIR "_libs")
 241   set(HAVE_STRTOLL 1)
 242   set(strtoll "_strtoi64")
 243   set(strtoull "_strtoui64")
 244   set(stricmp "_stricmp")
 245   set(strdup "_strdup")
 246 else( MSVC )
 247   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 248   set(LTDL_SYSSEARCHPATH "") # TODO
 249   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 250 endif( MSVC )
 251
 252 # FIXME: Signal handler return type, currently hardcoded to 'void'
 253 set(RETSIGTYPE void)
 254
 255 if( LLVM_ENABLE_THREADS )
 256   if( HAVE_PTHREAD_H OR WIN32 )
 257     set(ENABLE_THREADS 1)
 258   endif()
 259 endif()
 260
 261 if( ENABLE_THREADS )
 262   message(STATUS "Threads enabled.")
 263 else( ENABLE_THREADS )
 264   message(STATUS "Threads disabled.")
 265 endif()
 266
 267 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 268
 269 configure_file(
 270   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 271   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 272   )
 273
 274 configure_file(
 275   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 276   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h
 277   )
 278
 279 configure_file(
 280   ${LLVM_MAIN_INCLUDE_DIR}/llvm/System/DataTypes.h.cmake
 281   ${LLVM_BINARY_DIR}/include/llvm/System/DataTypes.h
 282   )
 283