autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.9svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl Disable the build of polly, even if it is checked out into tools/polly.
 125 AC_ARG_ENABLE(polly,
 126               AS_HELP_STRING([--enable-polly],
 127                              [Use polly if available (default is YES)]),,
 128                              enableval=default)
 129 case "$enableval" in
 130   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 131   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 132   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 133   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 134 esac
 135
 136
 137 dnl Check if polly is checked out into tools/polly and configure it if
 138 dnl available.
 139 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 140   AC_SUBST(LLVM_HAS_POLLY,1)
 141   AC_CONFIG_SUBDIRS([tools/polly])
 142 fi
 143
 144 dnl===-----------------------------------------------------------------------===
 145 dnl===
 146 dnl=== SECTION 2: Architecture, target, and host checks
 147 dnl===
 148 dnl===-----------------------------------------------------------------------===
 149
 150 dnl Check the target for which we're compiling and the host that will do the
 151 dnl compilations. This will tell us which LLVM compiler will be used for
 152 dnl compiling SSA into object code. This needs to be done early because
 153 dnl following tests depend on it.
 154 AC_CANONICAL_TARGET
 155
 156 dnl Determine the platform type and cache its value. This helps us configure
 157 dnl the System library to the correct build platform.
 158 AC_CACHE_CHECK([type of operating system we're going to host on],
 159                [llvm_cv_os_type],
 160 [case $host in
 161   *-*-aix*)
 162     llvm_cv_link_all_option="-Wl,--whole-archive"
 163     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 164     llvm_cv_os_type="AIX"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-irix*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="IRIX"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-cygwin*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="Cygwin"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-darwin*)
 177     llvm_cv_link_all_option="-Wl,-all_load"
 178     llvm_cv_no_link_all_option="-Wl,-noall_load"
 179     llvm_cv_os_type="Darwin"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-minix*)
 182     llvm_cv_link_all_option="-Wl,-all_load"
 183     llvm_cv_no_link_all_option="-Wl,-noall_load"
 184     llvm_cv_os_type="Minix"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-freebsd*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="FreeBSD"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-openbsd*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="OpenBSD"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-netbsd*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="NetBSD"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-dragonfly*)
 202     llvm_cv_link_all_option="-Wl,--whole-archive"
 203     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 204     llvm_cv_os_type="DragonFly"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-hpux*)
 207     llvm_cv_link_all_option="-Wl,--whole-archive"
 208     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 209     llvm_cv_os_type="HP-UX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-interix*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Interix"
 215     llvm_cv_platform_type="Unix" ;;
 216   *-*-linux*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="Linux"
 220     llvm_cv_platform_type="Unix" ;;
 221   *-*-solaris*)
 222     llvm_cv_link_all_option="-Wl,-z,allextract"
 223     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 224     llvm_cv_os_type="SunOS"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-*-auroraux*)
 227     llvm_cv_link_all_option="-Wl,-z,allextract"
 228     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 229     llvm_cv_os_type="AuroraUX"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-win32*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Win32"
 235     llvm_cv_platform_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="MingW"
 240     llvm_cv_platform_type="Win32" ;;
 241   *-*-haiku*)
 242     llvm_cv_link_all_option="-Wl,--whole-archive"
 243     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 244     llvm_cv_os_type="Haiku"
 245     llvm_cv_platform_type="Unix" ;;
 246   *-unknown-eabi*)
 247     llvm_cv_link_all_option="-Wl,--whole-archive"
 248     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 249     llvm_cv_os_type="Freestanding"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-unknown-elf*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="Freestanding"
 255     llvm_cv_platform_type="Unix" ;;
 256   *)
 257     llvm_cv_link_all_option=""
 258     llvm_cv_no_link_all_option=""
 259     llvm_cv_os_type="Unknown"
 260     llvm_cv_platform_type="Unknown" ;;
 261 esac])
 262
 263 AC_CACHE_CHECK([type of operating system we're going to target],
 264                [llvm_cv_target_os_type],
 265 [case $target in
 266   *-*-aix*)
 267     llvm_cv_target_os_type="AIX" ;;
 268   *-*-irix*)
 269     llvm_cv_target_os_type="IRIX" ;;
 270   *-*-cygwin*)
 271     llvm_cv_target_os_type="Cygwin" ;;
 272   *-*-darwin*)
 273     llvm_cv_target_os_type="Darwin" ;;
 274   *-*-minix*)
 275     llvm_cv_target_os_type="Minix" ;;
 276   *-*-freebsd*)
 277     llvm_cv_target_os_type="FreeBSD" ;;
 278   *-*-openbsd*)
 279     llvm_cv_target_os_type="OpenBSD" ;;
 280   *-*-netbsd*)
 281     llvm_cv_target_os_type="NetBSD" ;;
 282   *-*-dragonfly*)
 283     llvm_cv_target_os_type="DragonFly" ;;
 284   *-*-hpux*)
 285     llvm_cv_target_os_type="HP-UX" ;;
 286   *-*-interix*)
 287     llvm_cv_target_os_type="Interix" ;;
 288   *-*-linux*)
 289     llvm_cv_target_os_type="Linux" ;;
 290   *-*-solaris*)
 291     llvm_cv_target_os_type="SunOS" ;;
 292   *-*-auroraux*)
 293     llvm_cv_target_os_type="AuroraUX" ;;
 294   *-*-win32*)
 295     llvm_cv_target_os_type="Win32" ;;
 296   *-*-mingw*)
 297     llvm_cv_target_os_type="MingW" ;;
 298   *-*-haiku*)
 299     llvm_cv_target_os_type="Haiku" ;;
 300   *-unknown-eabi*)
 301     llvm_cv_target_os_type="Freestanding" ;;
 302   *)
 303     llvm_cv_target_os_type="Unknown" ;;
 304 esac])
 305
 306 dnl Make sure we aren't attempting to configure for an unknown system
 307 if test "$llvm_cv_os_type" = "Unknown" ; then
 308   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 309 fi
 310
 311 dnl Set the "OS" Makefile variable based on the platform type so the
 312 dnl makefile can configure itself to specific build hosts
 313 AC_SUBST(OS,$llvm_cv_os_type)
 314 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 315 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 316
 317 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 318 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 319 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 320
 321 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 322 dnl This is used by lib/Support to determine the basic kind of implementation
 323 dnl to use.
 324 case $llvm_cv_platform_type in
 325   Unix)
 326     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 327     AC_SUBST(LLVM_ON_UNIX,[1])
 328     AC_SUBST(LLVM_ON_WIN32,[0])
 329     ;;
 330   Win32)
 331     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 332     AC_SUBST(LLVM_ON_UNIX,[0])
 333     AC_SUBST(LLVM_ON_WIN32,[1])
 334     ;;
 335 esac
 336
 337 dnl Determine what our target architecture is and configure accordingly.
 338 dnl This will allow Makefiles to make a distinction between the hardware and
 339 dnl the OS.
 340 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 341 [case $target in
 342   i?86-*)                 llvm_cv_target_arch="x86" ;;
 343   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 344   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 345   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 346   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 347   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 348   mips-*)                 llvm_cv_target_arch="Mips" ;;
 349   xcore-*)                llvm_cv_target_arch="XCore" ;;
 350   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 351   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 352   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 353   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 354   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 355   *)                      llvm_cv_target_arch="Unknown" ;;
 356 esac])
 357
 358 if test "$llvm_cv_target_arch" = "Unknown" ; then
 359   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 360 fi
 361
 362 # Determine the LLVM native architecture for the target
 363 case "$llvm_cv_target_arch" in
 364     x86)     LLVM_NATIVE_ARCH="X86" ;;
 365     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 366     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 367 esac
 368
 369 dnl Define a substitution, ARCH, for the target architecture
 370 AC_SUBST(ARCH,$llvm_cv_target_arch)
 371
 372 dnl Check for the endianness of the target
 373 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 374
 375 dnl Check for build platform executable suffix if we're crosscompiling
 376 if test "$cross_compiling" = yes; then
 377   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 378   AC_BUILD_EXEEXT
 379   ac_build_prefix=${build_alias}-
 380   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 381   if test -z "$BUILD_CXX"; then
 382      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 383      if test -z "$BUILD_CXX"; then
 384        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 385      fi
 386   fi
 387 else
 388   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 389 fi
 390
 391 dnl Check to see if there's a .svn or .git directory indicating that this
 392 dnl build is being done from a checkout. This sets up several defaults for
 393 dnl the command line switches. When we build with a checkout directory,
 394 dnl we get a debug with assertions turned on. Without, we assume a source
 395 dnl release and we get an optimized build without assertions.
 396 dnl See --enable-optimized and --enable-assertions below
 397 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 398   cvsbuild="yes"
 399   optimize="no"
 400   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 401 else
 402   cvsbuild="no"
 403   optimize="yes"
 404 fi
 405
 406 dnl===-----------------------------------------------------------------------===
 407 dnl===
 408 dnl=== SECTION 3: Command line arguments for the configure script.
 409 dnl===
 410 dnl===-----------------------------------------------------------------------===
 411
 412 dnl --enable-optimized : check whether they want to do an optimized build:
 413 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 414  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 415 if test ${enableval} = "no" ; then
 416   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 417 else
 418   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 419 fi
 420
 421 dnl --enable-profiling : check whether they want to do a profile build:
 422 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 423  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 424 if test ${enableval} = "no" ; then
 425   AC_SUBST(ENABLE_PROFILING,[[]])
 426 else
 427   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 428 fi
 429
 430 dnl --enable-assertions : check whether they want to turn on assertions or not:
 431 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 432   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 433 if test ${enableval} = "yes" ; then
 434   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 435 else
 436   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 437 fi
 438
 439 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 440 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 441   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 442 if test ${enableval} = "yes" ; then
 443   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 444   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 445 else
 446   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 447   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 448 fi
 449
 450 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 451 AC_ARG_ENABLE(debug-runtime,
 452    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 453 if test ${enableval} = "no" ; then
 454   AC_SUBST(DEBUG_RUNTIME,[[]])
 455 else
 456   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 457 fi
 458
 459 dnl --enable-debug-symbols : should even optimized compiler libraries
 460 dnl have debug symbols?
 461 AC_ARG_ENABLE(debug-symbols,
 462    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 463 if test ${enableval} = "no" ; then
 464   AC_SUBST(DEBUG_SYMBOLS,[[]])
 465 else
 466   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 467 fi
 468
 469 dnl --enable-jit: check whether they want to enable the jit
 470 AC_ARG_ENABLE(jit,
 471   AS_HELP_STRING(--enable-jit,
 472                  [Enable Just In Time Compiling (default is YES)]),,
 473   enableval=default)
 474 if test ${enableval} = "no"
 475 then
 476   AC_SUBST(JIT,[[]])
 477 else
 478   case "$llvm_cv_target_arch" in
 479     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 480     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 481     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 482     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 483     Alpha)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 484     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 485     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 486     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 487     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 488     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 489     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 490     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 491     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 492     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 493   esac
 494 fi
 495
 496 dnl Allow enablement of building and installing docs
 497 AC_ARG_ENABLE(docs,
 498               AS_HELP_STRING([--enable-docs],
 499                              [Build documents (default is YES)]),,
 500                              enableval=default)
 501 case "$enableval" in
 502   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 503   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 504   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 505   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 506 esac
 507
 508 dnl Allow enablement of doxygen generated documentation
 509 AC_ARG_ENABLE(doxygen,
 510               AS_HELP_STRING([--enable-doxygen],
 511                              [Build doxygen documentation (default is NO)]),,
 512                              enableval=default)
 513 case "$enableval" in
 514   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 515   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 516   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 517   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 518 esac
 519
 520 dnl Allow disablement of threads
 521 AC_ARG_ENABLE(threads,
 522               AS_HELP_STRING([--enable-threads],
 523                              [Use threads if available (default is YES)]),,
 524                              enableval=default)
 525 case "$enableval" in
 526   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 527   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 528   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 529   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 530 esac
 531 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 532
 533 dnl Allow building without position independent code
 534 AC_ARG_ENABLE(pic,
 535   AS_HELP_STRING([--enable-pic],
 536                  [Build LLVM with Position Independent Code (default is YES)]),,
 537                  enableval=default)
 538 case "$enableval" in
 539   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 540   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 541   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 542   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 543 esac
 544 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 545                    [Define if position independent code is enabled])
 546
 547 dnl Allow building a shared library and linking tools against it.
 548 AC_ARG_ENABLE(shared,
 549   AS_HELP_STRING([--enable-shared],
 550                  [Build a shared library and link tools against it (default is NO)]),,
 551                  enableval=default)
 552 case "$enableval" in
 553   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 554   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 555   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 556   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 557 esac
 558
 559 dnl Enable embedding timestamp information into build.
 560 AC_ARG_ENABLE(timestamps,
 561   AS_HELP_STRING([--enable-timestamps],
 562                  [Enable embedding timestamp information in build (default is YES)]),,
 563                  enableval=default)
 564 case "$enableval" in
 565   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 566   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 567   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 568   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 569 esac
 570 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 571                    [Define if timestamp information (e.g., __DATE___) is allowed])
 572
 573 dnl Allow specific targets to be specified for building (or not)
 574 TARGETS_TO_BUILD=""
 575 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 576     [Build specific host targets: all or target1,target2,... Valid targets are:
 577      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 578      xcore, msp430, systemz, blackfin, ptx, cbe, and cpp (default=all)]),,
 579     enableval=all)
 580 if test "$enableval" = host-only ; then
 581   enableval=host
 582 fi
 583 case "$enableval" in
 584   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 SystemZ Blackfin CBackend CppBackend MBlaze PTX" ;;
 585   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 586       case "$a_target" in
 587         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 588         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 589         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 590         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 591         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 592         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 593         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 594         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 595         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 596         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 597         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 598         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 599         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 600         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 601         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 602         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 603         host) case "$llvm_cv_target_arch" in
 604             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 605             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 606             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 607             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 608             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 609             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 610             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 611             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 612             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 613             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 614             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 615             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 616             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 617             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 618             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 619           esac ;;
 620         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 621       esac
 622   done
 623   ;;
 624 esac
 625 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 626
 627 # Determine whether we are building LLVM support for the native architecture.
 628 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 629 for a_target in $TARGETS_TO_BUILD; do
 630   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 631     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 632       [LLVM architecture name for the native architecture, if available])
 633     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 634     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 635     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 636     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 637       [LLVM name for the native Target init function, if available])
 638     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 639       [LLVM name for the native TargetInfo init function, if available])
 640     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 641       [LLVM name for the native AsmPrinter init function, if available])
 642   fi
 643 done
 644
 645 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 646 # target feature def files.
 647 LLVM_ENUM_TARGETS=""
 648 LLVM_ENUM_ASM_PRINTERS=""
 649 LLVM_ENUM_ASM_PARSERS=""
 650 LLVM_ENUM_DISASSEMBLERS=""
 651 for target_to_build in $TARGETS_TO_BUILD; do
 652   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 653   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 654     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 655   fi
 656   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 657     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 658   fi
 659   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 660     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 661   fi
 662 done
 663 AC_SUBST(LLVM_ENUM_TARGETS)
 664 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 665 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 666 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 667
 668 dnl Prevent the CBackend from using printf("%a") for floating point so older
 669 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 670 dnl can still compile the CBE's output
 671 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 672   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 673   enableval=default)
 674 case "$enableval" in
 675   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 676   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 677   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 678   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 679 esac
 680 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 681                    [Define if CBE is enabled for printf %a output])
 682
 683 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 684 AC_ARG_WITH(llvmgccdir,
 685   AS_HELP_STRING([--with-llvmgccdir],
 686     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 687     withval=default)
 688 case "$withval" in
 689   default) WITH_LLVMGCCDIR=default ;;
 690   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 691   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 692 esac
 693
 694 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 695 AC_ARG_WITH(llvmgcc,
 696   AS_HELP_STRING([--with-llvmgcc],
 697     [Specify location of llvm-gcc driver (default searches PATH)]),
 698     LLVMGCC=$with_llvmgcc
 699       WITH_LLVMGCCDIR="",)
 700
 701 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 702 AC_ARG_WITH(llvmgxx,
 703   AS_HELP_STRING([--with-llvmgxx],
 704     [Specify location of llvm-g++ driver (default searches PATH)]),
 705     LLVMGXX=$with_llvmgxx
 706     WITH_LLVMGCCDIR="",)
 707
 708 if test -n "$LLVMGCC"; then
 709    LLVMGCCCOMMAND="$LLVMGCC"
 710 fi
 711
 712 if test -n "$LLVMGXX"; then
 713    LLVMGXXCOMMAND="$LLVMGXX"
 714 fi
 715
 716 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 717    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 718 fi
 719
 720 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 721    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 722 fi
 723
 724 dnl Allow a specific Clang compiler to be used with this LLVM config.
 725 AC_ARG_WITH(clang,
 726   AS_HELP_STRING([--with-clang],
 727     [Specify location of clang compiler (default is --with-built-clang)]),
 728     [],[with_clang=default])
 729
 730 dnl Enable use of the built Clang.
 731 AC_ARG_WITH(built-clang,
 732   AS_HELP_STRING([--with-built-clang],
 733     [Use the compiled Clang as the LLVM compiler (default=check)]),
 734     [],[with_built_clang=check])
 735
 736 dnl Select the Clang compiler option.
 737 dnl
 738 dnl If --with-clang is given, always honor that; otherwise honor
 739 dnl --with-built-clang, or check if we have the clang sources.
 740 AC_MSG_CHECKING([clang compiler])
 741 WITH_CLANGPATH=""
 742 WITH_BUILT_CLANG=0
 743 if test "$with_clang" != "default"; then
 744    WITH_CLANGPATH="$with_clang"
 745    if ! test -x "$WITH_CLANGPATH"; then
 746      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 747    fi
 748 elif test "$with_built_clang" = "yes"; then
 749    WITH_BUILT_CLANG=1
 750 elif test "$with_built_clang" = "no"; then
 751    WITH_BUILT_CLANG=0
 752 else
 753    if test "$with_built_clang" != "check"; then
 754       AC_MSG_ERROR([invalid value for --with-built-clang.])
 755    fi
 756
 757    if test -f ${srcdir}/tools/clang/README.txt; then
 758      WITH_BUILT_CLANG=1
 759    fi
 760 fi
 761
 762 if ! test -z "$WITH_CLANGPATH"; then
 763    AC_MSG_RESULT([$WITH_CLANGPATH])
 764    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 765 elif test "$WITH_BUILT_CLANG" = "1"; then
 766    AC_MSG_RESULT([built])
 767 else
 768    AC_MSG_RESULT([none])
 769 fi
 770 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 771 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 772 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 773
 774 dnl Override the option to use for optimized builds.
 775 AC_ARG_WITH(optimize-option,
 776   AS_HELP_STRING([--with-optimize-option],
 777                  [Select the compiler options to use for optimized builds]),,
 778                  withval=default)
 779 AC_MSG_CHECKING([optimization flags])
 780 case "$withval" in
 781   default)
 782     case "$llvm_cv_os_type" in
 783     FreeBSD) optimize_option=-O2 ;;
 784     MingW) optimize_option=-O2 ;;
 785     *)     optimize_option=-O3 ;;
 786     esac ;;
 787   *) optimize_option="$withval" ;;
 788 esac
 789 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 790 AC_MSG_RESULT([$optimize_option])
 791
 792 dnl Specify extra build options
 793 AC_ARG_WITH(extra-options,
 794   AS_HELP_STRING([--with-extra-options],
 795                  [Specify additional options to compile LLVM with]),,
 796                  withval=default)
 797 case "$withval" in
 798   default) EXTRA_OPTIONS= ;;
 799   *) EXTRA_OPTIONS=$withval ;;
 800 esac
 801 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 802
 803 dnl Allow specific bindings to be specified for building (or not)
 804 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 805     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 806     enableval=default)
 807 BINDINGS_TO_BUILD=""
 808 case "$enableval" in
 809   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 810   all ) BINDINGS_TO_BUILD="ocaml" ;;
 811   none | no) BINDINGS_TO_BUILD="" ;;
 812   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 813       case "$a_binding" in
 814         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 815         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 816       esac
 817   done
 818   ;;
 819 esac
 820
 821 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 822 dnl script for bindings/ocaml/configure, except that its auto value depends on
 823 dnl OCAMLC, which is found here to support tests.
 824 AC_ARG_WITH([ocaml-libdir],
 825   [AS_HELP_STRING([--with-ocaml-libdir],
 826     [Specify install location for ocaml bindings (default is stdlib)])],
 827   [],
 828   [withval=auto])
 829 case "$withval" in
 830   auto) with_ocaml_libdir="$withval" ;;
 831   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 832   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 833 esac
 834
 835 AC_ARG_WITH(clang-resource-dir,
 836   AS_HELP_STRING([--with-clang-resource-dir],
 837     [Relative directory from the Clang binary for resource files]),,
 838     withval="")
 839 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 840                    [Relative directory for resource files])
 841
 842 AC_ARG_WITH(c-include-dirs,
 843   AS_HELP_STRING([--with-c-include-dirs],
 844     [Colon separated list of directories clang will search for headers]),,
 845     withval="")
 846 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 847                    [Directories clang will search for headers])
 848
 849 AC_ARG_WITH(cxx-include-root,
 850   AS_HELP_STRING([--with-cxx-include-root],
 851     [Directory with the libstdc++ headers.]),,
 852     withval="")
 853 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 854                    [Directory with the libstdc++ headers.])
 855
 856 AC_ARG_WITH(cxx-include-arch,
 857   AS_HELP_STRING([--with-cxx-include-arch],
 858     [Architecture of the libstdc++ headers.]),,
 859     withval="")
 860 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 861                    [Arch the libstdc++ headers.])
 862
 863 AC_ARG_WITH(cxx-include-32bit-dir,
 864   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 865     [32 bit multilib dir.]),,
 866     withval="")
 867 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 868                    [32 bit multilib directory.])
 869
 870 AC_ARG_WITH(cxx-include-64bit-dir,
 871   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 872     [64 bit multilib directory.]),,
 873     withval="")
 874 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 875                    [64 bit multilib directory.])
 876
 877 dnl Allow linking of LLVM with GPLv3 binutils code.
 878 AC_ARG_WITH(binutils-include,
 879   AS_HELP_STRING([--with-binutils-include],
 880     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 881   withval=default)
 882 case "$withval" in
 883   default) WITH_BINUTILS_INCDIR=default ;;
 884   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 885   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 886 esac
 887 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 888   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 889   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 890      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 891      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 892   fi
 893 fi
 894
 895 dnl --enable-libffi : check whether the user wants to turn off libffi:
 896 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 897   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 898   [case "$enableval" in
 899     yes) llvm_cv_enable_libffi="yes" ;;
 900     no)  llvm_cv_enable_libffi="no"  ;;
 901     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 902   esac],
 903   llvm_cv_enable_libffi=no)
 904
 905 dnl===-----------------------------------------------------------------------===
 906 dnl===
 907 dnl=== SECTION 4: Check for programs we need and that they are the right version
 908 dnl===
 909 dnl===-----------------------------------------------------------------------===
 910
 911 dnl Check for compilation tools
 912 AC_PROG_CPP
 913 AC_PROG_CC(gcc)
 914 AC_PROG_CXX(g++)
 915
 916 AC_PROG_NM
 917 AC_SUBST(NM)
 918
 919 dnl Check for the tools that the makefiles require
 920 AC_CHECK_GNU_MAKE
 921 AC_PROG_LN_S
 922 AC_PATH_PROG(CMP, [cmp], [cmp])
 923 AC_PATH_PROG(CP, [cp], [cp])
 924 AC_PATH_PROG(DATE, [date], [date])
 925 AC_PATH_PROG(FIND, [find], [find])
 926 AC_PATH_PROG(GREP, [grep], [grep])
 927 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 928 AC_PATH_PROG(MV,   [mv],   [mv])
 929 AC_PROG_RANLIB
 930 AC_CHECK_TOOL(AR, ar, false)
 931 AC_PATH_PROG(RM,   [rm],   [rm])
 932 AC_PATH_PROG(SED,  [sed],  [sed])
 933 AC_PATH_PROG(TAR,  [tar],  [gtar])
 934 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 935
 936 dnl Looking for misc. graph plotting software
 937 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 938 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 939   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 940   dnl If we're targeting for mingw we should emit windows paths, not msys
 941   if test "$llvm_cv_os_type" = "MingW" ; then
 942     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 943   fi
 944   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 945    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 946 fi
 947 AC_PATH_PROG(DOT, [dot], [echo dot])
 948 if test "$DOT" != "echo dot" ; then
 949   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 950   dnl If we're targeting for mingw we should emit windows paths, not msys
 951   if test "$llvm_cv_os_type" = "MingW" ; then
 952     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 953   fi
 954   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 955    [Define to path to dot program if found or 'echo dot' otherwise])
 956 fi
 957 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 958 if test "$FDP" != "echo fdp" ; then
 959   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 960   dnl If we're targeting for mingw we should emit windows paths, not msys
 961   if test "$llvm_cv_os_type" = "MingW" ; then
 962     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 963   fi
 964   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 965    [Define to path to fdp program if found or 'echo fdp' otherwise])
 966 fi
 967 AC_PATH_PROG(NEATO, [neato], [echo neato])
 968 if test "$NEATO" != "echo neato" ; then
 969   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 970   dnl If we're targeting for mingw we should emit windows paths, not msys
 971   if test "$llvm_cv_os_type" = "MingW" ; then
 972     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 973   fi
 974   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 975    [Define to path to neato program if found or 'echo neato' otherwise])
 976 fi
 977 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 978 if test "$TWOPI" != "echo twopi" ; then
 979   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 980   dnl If we're targeting for mingw we should emit windows paths, not msys
 981   if test "$llvm_cv_os_type" = "MingW" ; then
 982     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 983   fi
 984   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 985    [Define to path to twopi program if found or 'echo twopi' otherwise])
 986 fi
 987 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 988 if test "$CIRCO" != "echo circo" ; then
 989   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 990   dnl If we're targeting for mingw we should emit windows paths, not msys
 991   if test "$llvm_cv_os_type" = "MingW" ; then
 992     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 993   fi
 994   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 995    [Define to path to circo program if found or 'echo circo' otherwise])
 996 fi
 997 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 998 if test "$GV" != "echo gv" ; then
 999   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1000   dnl If we're targeting for mingw we should emit windows paths, not msys
1001   if test "$llvm_cv_os_type" = "MingW" ; then
1002     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1003   fi
1004   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1005    [Define to path to gv program if found or 'echo gv' otherwise])
1006 fi
1007 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1008 if test "$DOTTY" != "echo dotty" ; then
1009   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1010   dnl If we're targeting for mingw we should emit windows paths, not msys
1011   if test "$llvm_cv_os_type" = "MingW" ; then
1012     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1013   fi
1014   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1015    [Define to path to dotty program if found or 'echo dotty' otherwise])
1016 fi
1017 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1018 if test "$XDOT_PY" != "echo xdot.py" ; then
1019   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1020   dnl If we're targeting for mingw we should emit windows paths, not msys
1021   if test "$llvm_cv_os_type" = "MingW" ; then
1022     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1023   fi
1024   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1025    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1026 fi
1027
1028 dnl Look for a sufficiently recent version of Perl.
1029 LLVM_PROG_PERL([5.006])
1030 AC_SUBST(PERL)
1031 if test x"$PERL" = xnone; then
1032    AC_SUBST(HAVE_PERL,0)
1033    AC_MSG_ERROR([perl is required but was not found, please install it])
1034 else
1035    AC_SUBST(HAVE_PERL,1)
1036 fi
1037
1038 dnl Find the install program
1039 AC_PROG_INSTALL
1040 dnl Prepend src dir to install path dir if it's a relative path
1041 dnl This is a hack for installs that take place in something other
1042 dnl than the top level.
1043 case "$INSTALL" in
1044  [[\\/$]]* | ?:[[\\/]]* ) ;;
1045  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1046 esac
1047
1048 dnl Checks for documentation and testing tools that we can do without. If these
1049 dnl are not found then they are set to "true" which always succeeds but does
1050 dnl nothing. This just lets the build output show that we could have done
1051 dnl something if the tool was available.
1052 AC_PATH_PROG(BZIP2, [bzip2])
1053 AC_PATH_PROG(CAT, [cat])
1054 AC_PATH_PROG(DOXYGEN, [doxygen])
1055 AC_PATH_PROG(GROFF, [groff])
1056 AC_PATH_PROG(GZIP, [gzip])
1057 AC_PATH_PROG(POD2HTML, [pod2html])
1058 AC_PATH_PROG(POD2MAN, [pod2man])
1059 AC_PATH_PROG(PDFROFF, [pdfroff])
1060 AC_PATH_PROG(RUNTEST, [runtest])
1061 DJ_AC_PATH_TCLSH
1062 AC_PATH_PROG(ZIP, [zip])
1063 AC_PATH_PROGS(OCAMLC, [ocamlc])
1064 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1065 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1066 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1067 AC_PATH_PROGS(GAS, [gas as])
1068
1069 dnl Get the version of the linker in use.
1070 AC_LINK_GET_VERSION
1071
1072 dnl Determine whether the linker supports the -R option.
1073 AC_LINK_USE_R
1074
1075 dnl Determine whether the linker supports the -export-dynamic option.
1076 AC_LINK_EXPORT_DYNAMIC
1077
1078 dnl Determine whether the linker supports the --version-script option.
1079 AC_LINK_VERSION_SCRIPT
1080
1081 dnl Check for libtool and the library that has dlopen function (which must come
1082 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1083 dnl libtool).
1084 AC_LIBTOOL_DLOPEN
1085 AC_LIB_LTDL
1086
1087 if test "$WITH_LLVMGCCDIR" = "default" ; then
1088   LLVMGCC="llvm-gcc${EXEEXT}"
1089   LLVMGXX="llvm-g++${EXEEXT}"
1090   LLVMGCCCOMMAND="$LLVMGCC"
1091   LLVMGXXCOMMAND="$LLVMGXX"
1092   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1093   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1094   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1095   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1096 else
1097   if test -z "$LLVMGCC"; then
1098     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1099     LLVMGCCCOMMAND="$LLVMGCC"
1100   fi
1101   if test -z "$LLVMGXX"; then
1102     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1103     LLVMGXXCOMMAND="$LLVMGXX"
1104   fi
1105
1106   AC_SUBST(LLVMGCC,$LLVMGCC)
1107   AC_SUBST(LLVMGXX,$LLVMGXX)
1108   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1109   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1110 fi
1111
1112 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1113 dnl found, otherwise clang if available.
1114 AC_ARG_WITH(llvmcc,
1115   AS_HELP_STRING([--with-llvmcc=<name>],
1116     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1117     [],[with_llvmcc=check])
1118 AC_MSG_CHECKING([LLVM capable compiler])
1119 if test "$with_llvmcc" != "check"; then
1120    if (test "$with_llvmcc" != "llvm-gcc" &&
1121        test "$with_llvmcc" != "clang" &&
1122        test "$with_llvmcc" != "none"); then
1123       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1124    fi
1125    WITH_LLVMCC="$with_llvmcc"
1126 elif test -n "$LLVMGCC"; then
1127    WITH_LLVMCC=llvm-gcc
1128 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1129    WITH_LLVMCC=clang
1130 else
1131    WITH_LLVMCC=none
1132 fi
1133 AC_MSG_RESULT([$WITH_LLVMCC])
1134 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1135
1136 AC_MSG_CHECKING([tool compatibility])
1137
1138 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1139 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1140 dnl to support those options.
1141 dnl "icc" emits gcc signatures
1142 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1143 ICC=no
1144 IXX=no
1145 case $CC in
1146   icc*|icpc*)
1147     ICC=yes
1148     IXX=yes
1149     ;;
1150    *)
1151     ;;
1152 esac
1153
1154 if test "$GCC" != "yes" && test "$ICC" != "yes"
1155 then
1156   AC_MSG_ERROR([gcc|icc required but not found])
1157 fi
1158
1159 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1160 if test "$GXX" != "yes" && test "$IXX" != "yes"
1161 then
1162   AC_MSG_ERROR([g++|icc required but not found])
1163 fi
1164
1165 dnl Verify that GCC is version 3.0 or higher
1166 if test "$GCC" = "yes"
1167 then
1168   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1169 #error Unsupported GCC version
1170 #endif
1171 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1172 fi
1173
1174 dnl Check for GNU Make.  We use its extensions, so don't build without it
1175 if test -z "$llvm_cv_gnu_make_command"
1176 then
1177   AC_MSG_ERROR([GNU Make required but not found])
1178 fi
1179
1180 dnl Tool compatibility is okay if we make it here.
1181 AC_MSG_RESULT([ok])
1182
1183 dnl Check optional compiler flags.
1184 AC_MSG_CHECKING([optional compiler flags])
1185 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1186 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1187 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1188
1189 dnl===-----------------------------------------------------------------------===
1190 dnl===
1191 dnl=== SECTION 5: Check for libraries
1192 dnl===
1193 dnl===-----------------------------------------------------------------------===
1194
1195 AC_CHECK_LIB(m,sin)
1196 if test "$llvm_cv_os_type" = "MingW" ; then
1197   AC_CHECK_LIB(imagehlp, main)
1198   AC_CHECK_LIB(psapi, main)
1199 fi
1200
1201 dnl dlopen() is required for plugin support.
1202 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1203                [Define if dlopen() is available on this platform.]),
1204                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1205
1206 dnl libffi is optional; used to call external functions from the interpreter
1207 if test "$llvm_cv_enable_libffi" = "yes" ; then
1208   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1209                  [Define if libffi is available on this platform.]),
1210                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1211 fi
1212
1213 dnl mallinfo is optional; the code can compile (minus features) without it
1214 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1215                [Define if mallinfo() is available on this platform.]))
1216
1217 dnl pthread locking functions are optional - but llvm will not be thread-safe
1218 dnl without locks.
1219 if test "$ENABLE_THREADS" -eq 1 ; then
1220   AC_CHECK_LIB(pthread, pthread_mutex_init)
1221   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1222                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1223                            [Have pthread_mutex_lock]))
1224   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1225                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1226                  [Have pthread_rwlock_init]))
1227   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1228                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1229                  [Have pthread_getspecific]))
1230 fi
1231
1232 dnl Allow extra x86-disassembler library
1233 AC_ARG_WITH(udis86,
1234   AS_HELP_STRING([--with-udis86=<path>],
1235     [Use udis86 external x86 disassembler library]),
1236     [
1237       AC_SUBST(USE_UDIS86, [1])
1238       case "$withval" in
1239         /usr/lib|yes) ;;
1240         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1241       esac
1242       AC_CHECK_LIB(udis86, ud_init, [], [
1243         echo "Error! You need to have libudis86 around."
1244         exit -1
1245       ])
1246     ],
1247     AC_SUBST(USE_UDIS86, [0]))
1248 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1249                    [Define if use udis86 library])
1250
1251 dnl Allow OProfile support for JIT output.
1252 AC_ARG_WITH(oprofile,
1253   AS_HELP_STRING([--with-oprofile=<prefix>],
1254     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1255     [
1256       AC_SUBST(USE_OPROFILE, [1])
1257       case "$withval" in
1258         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1259         no) llvm_cv_oppath=
1260             AC_SUBST(USE_OPROFILE, [0]) ;;
1261         *) llvm_cv_oppath="${withval}/lib/oprofile"
1262            CPPFLAGS="-I${withval}/include";;
1263       esac
1264       if test -n "$llvm_cv_oppath" ; then
1265         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1266         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1267         dnl libbfd is not included properly in libopagent in some Debian
1268         dnl versions.  If libbfd isn't found at all, we assume opagent works
1269         dnl anyway.
1270         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1271         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1272           echo "Error! You need to have libopagent around."
1273           exit -1
1274         ])
1275         AC_CHECK_HEADER([opagent.h], [], [
1276           echo "Error! You need to have opagent.h around."
1277           exit -1
1278           ])
1279       fi
1280     ],
1281     [
1282       AC_SUBST(USE_OPROFILE, [0])
1283     ])
1284 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1285                    [Define if we have the oprofile JIT-support library])
1286
1287 dnl===-----------------------------------------------------------------------===
1288 dnl===
1289 dnl=== SECTION 6: Check for header files
1290 dnl===
1291 dnl===-----------------------------------------------------------------------===
1292
1293 dnl First, use autoconf provided macros for specific headers that we need
1294 dnl We don't check for ancient stuff or things that are guaranteed to be there
1295 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1296 dnl Generally we're looking for POSIX headers.
1297 AC_HEADER_DIRENT
1298 AC_HEADER_MMAP_ANONYMOUS
1299 AC_HEADER_STAT
1300 AC_HEADER_STDC
1301 AC_HEADER_SYS_WAIT
1302 AC_HEADER_TIME
1303
1304 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1305 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1306 AC_CHECK_HEADERS([utime.h windows.h])
1307 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1308 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1309 AC_CHECK_HEADERS([valgrind/valgrind.h])
1310 AC_CHECK_HEADERS([fenv.h])
1311 if test "$ENABLE_THREADS" -eq 1 ; then
1312   AC_CHECK_HEADERS(pthread.h,
1313                    AC_SUBST(HAVE_PTHREAD, 1),
1314                    AC_SUBST(HAVE_PTHREAD, 0))
1315 else
1316   AC_SUBST(HAVE_PTHREAD, 0)
1317 fi
1318
1319 dnl Try to find ffi.h.
1320 if test "$llvm_cv_enable_libffi" = "yes" ; then
1321   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1322 fi
1323
1324 dnl Try to find Darwin specific crash reporting library.
1325 AC_CHECK_HEADERS([CrashReporterClient.h])
1326
1327 dnl===-----------------------------------------------------------------------===
1328 dnl===
1329 dnl=== SECTION 7: Check for types and structures
1330 dnl===
1331 dnl===-----------------------------------------------------------------------===
1332
1333 AC_HUGE_VAL_CHECK
1334 AC_TYPE_PID_T
1335 AC_TYPE_SIZE_T
1336 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1337 AC_STRUCT_TM
1338 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1339 AC_CHECK_TYPES([uint64_t],,
1340          AC_CHECK_TYPES([u_int64_t],,
1341          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1342
1343 dnl===-----------------------------------------------------------------------===
1344 dnl===
1345 dnl=== SECTION 8: Check for specific functions needed
1346 dnl===
1347 dnl===-----------------------------------------------------------------------===
1348
1349 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1350 AC_CHECK_FUNCS([powf fmodf strtof round ])
1351 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1352 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1353 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1354 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1355 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1356 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1357 AC_C_PRINTF_A
1358 AC_FUNC_RAND48
1359
1360 dnl Check for variations in the Standard C++ library and STL. These macros are
1361 dnl provided by LLVM in the autoconf/m4 directory.
1362 AC_FUNC_ISNAN
1363 AC_FUNC_ISINF
1364
1365 dnl Check for mmap support.We also need to know if /dev/zero is required to
1366 dnl be opened for allocating RWX memory.
1367 dnl Make sure we aren't attempting to configure for an unknown system
1368 if test "$llvm_cv_platform_type" = "Unix" ; then
1369   AC_FUNC_MMAP
1370   AC_FUNC_MMAP_FILE
1371   AC_NEED_DEV_ZERO_FOR_MMAP
1372
1373   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1374   then
1375     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1376   fi
1377   if test "$ac_cv_func_mmap_file" = "no"
1378   then
1379     AC_MSG_WARN([mmap() of files required but not found])
1380   fi
1381 fi
1382
1383 dnl atomic builtins are required for threading support.
1384 AC_MSG_CHECKING(for GCC atomic builtins)
1385 dnl Since we'll be using these atomic builtins in C++ files we should test
1386 dnl the C++ compiler.
1387 AC_LANG_PUSH([C++])
1388 AC_LINK_IFELSE(
1389   AC_LANG_SOURCE(
1390     [[int main() {
1391         volatile unsigned long val = 1;
1392         __sync_synchronize();
1393         __sync_val_compare_and_swap(&val, 1, 0);
1394         __sync_add_and_fetch(&val, 1);
1395         __sync_sub_and_fetch(&val, 1);
1396         return 0;
1397       }
1398     ]]),
1399   AC_LANG_POP([C++])
1400   AC_MSG_RESULT(yes)
1401   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1402   AC_MSG_RESULT(no)
1403   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1404   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1405
1406 dnl===-----------------------------------------------------------------------===
1407 dnl===
1408 dnl=== SECTION 9: Additional checks, variables, etc.
1409 dnl===
1410 dnl===-----------------------------------------------------------------------===
1411
1412 dnl Handle 32-bit linux systems running a 64-bit kernel.
1413 dnl This has to come after section 4 because it invokes the compiler.
1414 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1415   AC_IS_LINUX_MIXED
1416   if test "$llvm_cv_linux_mixed" = "yes"; then
1417     llvm_cv_target_arch="x86"
1418     ARCH="x86"
1419   fi
1420 fi
1421
1422 dnl Check, whether __dso_handle is present
1423 AC_CHECK_FUNCS([__dso_handle])
1424
1425 dnl Check wether llvm-gcc is based on dragonegg
1426 AC_CACHE_CHECK([whether llvm-gcc is dragonegg],[llvm_cv_llvmgcc_dragonegg],
1427 [llvm_cv_llvmgcc_dragonegg="no"
1428 if test -n "$LLVMGCC" ; then
1429   cp /dev/null conftest.c
1430   $LLVMGCC -fplugin-arg-dragonegg-emit-ir -S -o - conftest.c > /dev/null 2>&1
1431   if test $? -eq 0 ; then
1432     llvm_cv_llvmgcc_dragonegg="yes"
1433   fi
1434   rm conftest.c
1435 fi])
1436
1437 dnl Set the flags needed to emit LLVM IR and to disable optimizations
1438 dnl in llvmgcc
1439 if test "$llvm_cv_llvmgcc_dragonegg" = "yes" ; then
1440   LLVMCC_EMITIR_FLAG="-fplugin-arg-dragonegg-emit-ir"
1441   LLVMCC_DISABLEOPT_FLAGS="-fplugin-arg-dragonegg-disable-llvm-optzns"
1442 else
1443   LLVMCC_EMITIR_FLAG="-emit-llvm"
1444   LLVMCC_DISABLEOPT_FLAGS="-mllvm -disable-llvm-optzns"
1445 fi
1446
1447 AC_SUBST(LLVMCC_EMITIR_FLAG)
1448
1449 dnl See if the llvm-gcc executable can compile to LLVM assembly
1450 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1451 [llvm_cv_llvmgcc_sanity="no"
1452 if test -n "$LLVMGCC" ; then
1453   cp /dev/null conftest.c
1454   $LLVMGCC "$LLVMCC_EMITIR_FLAG" -S -o - conftest.c | \
1455       grep 'target datalayout =' > /dev/null 2>&1
1456   if test $? -eq 0 ; then
1457     llvm_cv_llvmgcc_sanity="yes"
1458   fi
1459   rm conftest.c
1460 fi])
1461
1462 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1463 dnl Furthermore, add some information about the tools
1464 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1465   AC_MSG_CHECKING([llvm-gcc component support])
1466   llvmcc1path=`$LLVMGCC --print-prog-name=cc1`
1467   AC_SUBST(LLVMCC1,$llvmcc1path)
1468   llvmcc1pluspath=`$LLVMGCC --print-prog-name=cc1plus`
1469   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1470   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1471   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1472   llvmgcclangs=[`$LLVMGCC -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1473   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1474   AC_SUBST(LLVMGCC_DRAGONEGG,$llvm_cv_llvmgcc_dragonegg)
1475   AC_SUBST(LLVMCC_DISABLEOPT_FLAGS)
1476   AC_MSG_RESULT([ok])
1477 fi
1478
1479 dnl Propagate the shared library extension that the libltdl checks did to
1480 dnl the Makefiles so we can use it there too
1481 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1482
1483 dnl Propagate the run-time library path variable that the libltdl
1484 dnl checks found to the Makefiles so we can use it there too
1485 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1486
1487 # Translate the various configuration directories and other basic
1488 # information into substitutions that will end up in Makefile.config.in
1489 # that these configured values can be used by the makefiles
1490 if test "${prefix}" = "NONE" ; then
1491   prefix="/usr/local"
1492 fi
1493 eval LLVM_PREFIX="${prefix}";
1494 eval LLVM_BINDIR="${prefix}/bin";
1495 eval LLVM_LIBDIR="${prefix}/lib";
1496 eval LLVM_DATADIR="${prefix}/share/llvm";
1497 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1498 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1499 eval LLVM_INCLUDEDIR="${prefix}/include";
1500 eval LLVM_INFODIR="${prefix}/info";
1501 eval LLVM_MANDIR="${prefix}/man";
1502 LLVM_CONFIGTIME=`date`
1503 AC_SUBST(LLVM_PREFIX)
1504 AC_SUBST(LLVM_BINDIR)
1505 AC_SUBST(LLVM_LIBDIR)
1506 AC_SUBST(LLVM_DATADIR)
1507 AC_SUBST(LLVM_DOCSDIR)
1508 AC_SUBST(LLVM_ETCDIR)
1509 AC_SUBST(LLVM_INCLUDEDIR)
1510 AC_SUBST(LLVM_INFODIR)
1511 AC_SUBST(LLVM_MANDIR)
1512 AC_SUBST(LLVM_CONFIGTIME)
1513
1514 # Place the various directores into the config.h file as #defines so that we
1515 # can know about the installation paths within LLVM.
1516 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1517                    [Installation prefix directory])
1518 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1519                    [Installation directory for binary executables])
1520 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1521                    [Installation directory for libraries])
1522 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1523                    [Installation directory for data files])
1524 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1525                    [Installation directory for documentation])
1526 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1527                    [Installation directory for config files])
1528 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1529                    [Installation directory for include files])
1530 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1531                    [Installation directory for .info files])
1532 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1533                    [Installation directory for man pages])
1534 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1535                    [Time at which LLVM was configured])
1536 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1537                    [Host triple we were built on])
1538
1539 # Determine which bindings to build.
1540 if test "$BINDINGS_TO_BUILD" = auto ; then
1541   BINDINGS_TO_BUILD=""
1542   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1543     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1544   fi
1545 fi
1546 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1547
1548 # This isn't really configurey, but it avoids having to repeat the list in
1549 # other files.
1550 AC_SUBST(ALL_BINDINGS,ocaml)
1551
1552 # Do any work necessary to ensure that bindings have what they need.
1553 binding_prereqs_failed=0
1554 for a_binding in $BINDINGS_TO_BUILD ; do
1555   case "$a_binding" in
1556   ocaml)
1557     if test "x$OCAMLC" = x ; then
1558       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1559       binding_prereqs_failed=1
1560     fi
1561     if test "x$OCAMLDEP" = x ; then
1562       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1563       binding_prereqs_failed=1
1564     fi
1565     if test "x$OCAMLOPT" = x ; then
1566       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1567       dnl ocamlopt is optional!
1568     fi
1569     if test "x$with_ocaml_libdir" != xauto ; then
1570       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1571     else
1572       ocaml_stdlib="`"$OCAMLC" -where`"
1573       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1574       then
1575         # ocaml stdlib is beneath our prefix; use stdlib
1576         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1577       else
1578         # ocaml stdlib is outside our prefix; use libdir/ocaml
1579         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1580       fi
1581     fi
1582     ;;
1583   esac
1584 done
1585 if test "$binding_prereqs_failed" = 1 ; then
1586   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1587 fi
1588
1589 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1590 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1591
1592 dnl Determine linker rpath flag
1593 if test "$llvm_cv_link_use_r" = "yes" ; then
1594   RPATH="-Wl,-R"
1595 else
1596   RPATH="-Wl,-rpath"
1597 fi
1598 AC_SUBST(RPATH)
1599
1600 dnl Determine linker rdynamic flag
1601 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1602   RDYNAMIC="-Wl,-export-dynamic"
1603 else
1604   RDYNAMIC=""
1605 fi
1606 AC_SUBST(RDYNAMIC)
1607
1608 dnl===-----------------------------------------------------------------------===
1609 dnl===
1610 dnl=== SECTION 10: Specify the output files and generate it
1611 dnl===
1612 dnl===-----------------------------------------------------------------------===
1613
1614 dnl Configure header files
1615 dnl WARNING: dnl If you add or remove any of the following config headers, then
1616 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1617 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1618 dnl files can be updated automatically when their *.in sources change.
1619 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1620 AH_TOP([#ifndef CONFIG_H
1621 #define CONFIG_H])
1622 AH_BOTTOM([#endif])
1623
1624 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1625 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1626 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1627 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1628 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1629
1630 dnl Configure the makefile's configuration data
1631 AC_CONFIG_FILES([Makefile.config])
1632
1633 dnl Configure the RPM spec file for LLVM
1634 AC_CONFIG_FILES([llvm.spec])
1635
1636 dnl Configure llvmc's Base plugin
1637 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1638
1639 dnl Do the first stage of configuration for llvm-config.in.
1640 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1641
1642 dnl Do special configuration of Makefiles
1643 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1644 AC_CONFIG_MAKEFILE(Makefile)
1645 AC_CONFIG_MAKEFILE(Makefile.common)
1646 AC_CONFIG_MAKEFILE(examples/Makefile)
1647 AC_CONFIG_MAKEFILE(lib/Makefile)
1648 AC_CONFIG_MAKEFILE(runtime/Makefile)
1649 AC_CONFIG_MAKEFILE(test/Makefile)
1650 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1651 AC_CONFIG_MAKEFILE(unittests/Makefile)
1652 AC_CONFIG_MAKEFILE(tools/Makefile)
1653 AC_CONFIG_MAKEFILE(utils/Makefile)
1654 AC_CONFIG_MAKEFILE(projects/Makefile)
1655 AC_CONFIG_MAKEFILE(bindings/Makefile)
1656 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1657
1658 dnl Finally, crank out the output
1659 AC_OUTPUT