CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(POLICY CMP0077)
  15   cmake_policy(SET CMP0077 NEW)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 10)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  37   message(WARNING "Visual Studio generators use the x86 host compiler by "
  38                   "default, even for 64-bit targets. This can result in linker "
  39                   "instability and out of memory errors. To use the 64-bit "
  40                   "host compiler, pass -Thost=x64 on the CMake command line.")
  41 endif()
  42
  43 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  44   # Some CMake features like object libraries get confused if you don't
  45   # explicitly specify an architecture setting with the Xcode generator.
  46   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  47 endif()
  48
  49 project(LLVM
  50   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  51   LANGUAGES C CXX ASM)
  52
  53 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  54   message(STATUS "No build type selected, default to Debug")
  55   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  56 endif()
  57
  58 # Side-by-side subprojects layout: automatically set the
  59 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
  60 # This allows an easy way of setting up a build directory for llvm and another
  61 # one for llvm+clang+... using the same sources.
  62 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
  63 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
  64         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
  65 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
  66   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
  67 endif()
  68
  69 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
  70 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
  71 # several reasons:
  72 #
  73 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
  74 # source of truth for which projects to build. This means we will ignore user
  75 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
  76 # them.
  77 #
  78 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
  79 # non-empty list but now the user wishes to disable building all other projects
  80 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
  81 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
  82 # building all the projects that were previously enabled.
  83 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
  84 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
  85
  86 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
  87   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
  88   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
  89     string(TOUPPER "${proj}" upper_proj)
  90     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
  91     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
  92       message(STATUS "${proj} project is enabled")
  93       set(SHOULD_ENABLE_PROJECT TRUE)
  94       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
  95       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
  96         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
  97       endif()
  98       set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE STRING "")
  99     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 100       message(STATUS "${proj} project is enabled")
 101       set(SHOULD_ENABLE_PROJECT TRUE)
 102     else()
 103       message(STATUS "${proj} project is disabled")
 104       set(SHOULD_ENABLE_PROJECT FALSE)
 105     endif()
 106     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 107     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 108     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 109     # we should deprecate allowing users to set these variables by turning them
 110     # into normal CMake variables rather than cache variables.
 111     set(LLVM_TOOL_${upper_proj}_BUILD
 112       ${SHOULD_ENABLE_PROJECT}
 113       CACHE
 114       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 115     )
 116   endforeach()
 117 endif()
 118 unset(SHOULD_ENABLE_PROJECT)
 119
 120 # Build llvm with ccache if the package is present
 121 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 122 if(LLVM_CCACHE_BUILD)
 123   find_program(CCACHE_PROGRAM ccache)
 124   if(CCACHE_PROGRAM)
 125       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 126       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 127       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 128           CACHE STRING "Parameters to pass through to ccache")
 129
 130       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 131       if (LLVM_CCACHE_MAXSIZE)
 132         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 133       endif()
 134       if (LLVM_CCACHE_DIR)
 135         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 136       endif()
 137       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 138   else()
 139     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 140   endif()
 141 endif()
 142
 143 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 144
 145 # Some features of the LLVM build may be disallowed when dependency debugging is
 146 # enabled. In particular you cannot use ccache because we want to force compile
 147 # operations to always happen.
 148 if(LLVM_DEPENDENCY_DEBUGGING)
 149   if(NOT CMAKE_HOST_APPLE)
 150     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 151   endif()
 152   if(LLVM_CCACHE_BUILD)
 153     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 154   endif()
 155 endif()
 156
 157 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 158 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 159 if(LLVM_ENABLE_GISEL_COV)
 160   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 161 endif()
 162
 163 # Add path for custom modules
 164 set(CMAKE_MODULE_PATH
 165   ${CMAKE_MODULE_PATH}
 166   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 167   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 168   )
 169
 170 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 171 # for use by clang_complete, YouCompleteMe, etc.
 172 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 173
 174 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 175   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 176
 177 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 178
 179 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 180
 181 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 182 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 183 # the installation by default. See llvm.org/PR31905.
 184 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 185
 186 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 187 if ( LLVM_USE_FOLDERS )
 188   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 189 endif()
 190
 191 include(VersionFromVCS)
 192
 193 option(LLVM_APPEND_VC_REV
 194   "Embed the version control system revision in LLVM" ON)
 195
 196 set(PACKAGE_NAME LLVM)
 197 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 198 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 199
 200 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 201   "Default URL where bug reports are to be submitted.")
 202
 203 # Configure CPack.
 204 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 205 set(CPACK_PACKAGE_VENDOR "LLVM")
 206 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 207 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 208 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 209 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 210 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 211 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 212 if(WIN32 AND NOT UNIX)
 213   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 214   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 215   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 216   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 217   set(CPACK_NSIS_MODIFY_PATH "ON")
 218   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 219   if( CMAKE_CL_64 )
 220     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 221   endif()
 222 endif()
 223 include(CPack)
 224
 225 # Sanity check our source directory to make sure that we are not trying to
 226 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 227 # sure that we don't have any stray generated files lying around in the tree
 228 # (which would end up getting picked up by header search, instead of the correct
 229 # versions).
 230 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 231   message(FATAL_ERROR "In-source builds are not allowed.
 232 Please create a directory and run cmake from there, passing the path
 233 to this source directory as the last argument.
 234 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 235 Please delete them.")
 236 endif()
 237
 238 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 239
 240 if (CMAKE_BUILD_TYPE AND
 241     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 242   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 243 endif()
 244
 245 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 246
 247 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 248 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 249
 250 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 251     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 252 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 253
 254 # They are used as destination of target generators.
 255 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 256 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 257 if(WIN32 OR CYGWIN)
 258   # DLL platform -- put DLLs into bin.
 259   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 260 else()
 261   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 262 endif()
 263
 264 # Each of them corresponds to llvm-config's.
 265 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 266 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 267 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 268 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 269 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 270
 271 # Note: LLVM_CMAKE_PATH does not include generated files
 272 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 273 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 274 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 275
 276 # List of all targets to be built by default:
 277 set(LLVM_ALL_TARGETS
 278   AArch64
 279   AMDGPU
 280   ARM
 281   BPF
 282   Hexagon
 283   Lanai
 284   Mips
 285   MSP430
 286   NVPTX
 287   PowerPC
 288   RISCV
 289   Sparc
 290   SystemZ
 291   WebAssembly
 292   X86
 293   XCore
 294   )
 295
 296 # List of targets with JIT support:
 297 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 298
 299 set(LLVM_TARGETS_TO_BUILD "all"
 300     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 301
 302 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 303   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 304
 305 option(BUILD_SHARED_LIBS
 306   "Build all libraries as shared libraries instead of static" OFF)
 307
 308 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 309 if(LLVM_ENABLE_BACKTRACES)
 310   set(ENABLE_BACKTRACES 1)
 311 endif()
 312
 313 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 314
 315 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 316 if(LLVM_ENABLE_CRASH_OVERRIDES)
 317   set(ENABLE_CRASH_OVERRIDES 1)
 318 endif()
 319
 320 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 321
 322 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 323 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 324 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 325
 326 set(LLVM_TARGET_ARCH "host"
 327   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 328
 329 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 330
 331 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 332
 333 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 334
 335 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 336
 337 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 338
 339 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 340
 341 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 342
 343 find_package(Z3 4.7.1)
 344
 345 if (LLVM_Z3_INSTALL_DIR)
 346   if (NOT Z3_FOUND)
 347     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 348   endif()
 349 endif()
 350
 351 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 352
 353 option(LLVM_ENABLE_Z3_SOLVER
 354   "Enable Support for the Z3 constraint solver in LLVM."
 355   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 356 )
 357
 358 if (LLVM_ENABLE_Z3_SOLVER)
 359   if (NOT Z3_FOUND)
 360     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 361   endif()
 362
 363   set(LLVM_WITH_Z3 1)
 364 endif()
 365
 366 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 367   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 368 endif()
 369
 370 set(LLVM_TARGETS_TO_BUILD
 371    ${LLVM_TARGETS_TO_BUILD}
 372    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 373 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 374
 375 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 376 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 377 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 378 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 379   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 380   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 381 else()
 382   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 383   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 384 endif()
 385 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 386 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 387 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 388 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 389
 390 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 391
 392 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 393   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 394 else()
 395   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 396 endif()
 397
 398 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 399
 400 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 401   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 402
 403 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 404        "Set to ON to force using an old, unsupported host toolchain." OFF)
 405
 406 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 407        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 408
 409 option(LLVM_USE_INTEL_JITEVENTS
 410   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 411   OFF)
 412
 413 if( LLVM_USE_INTEL_JITEVENTS )
 414   # Verify we are on a supported platform
 415   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 416     message(FATAL_ERROR
 417       "Intel JIT API support is available on Linux and Windows only.")
 418   endif()
 419 endif( LLVM_USE_INTEL_JITEVENTS )
 420
 421 option(LLVM_USE_OPROFILE
 422   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 423
 424 option(LLVM_EXTERNALIZE_DEBUGINFO
 425   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 426
 427 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 428   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 429
 430 # If enabled, verify we are on a platform that supports oprofile.
 431 if( LLVM_USE_OPROFILE )
 432   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 433     message(FATAL_ERROR "OProfile support is available on Linux only.")
 434   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 435 endif( LLVM_USE_OPROFILE )
 436
 437 option(LLVM_USE_PERF
 438   "Use perf JIT interface to inform perf about JIT code" OFF)
 439
 440 # If enabled, verify we are on a platform that supports perf.
 441 if( LLVM_USE_PERF )
 442   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 443     message(FATAL_ERROR "perf support is available on Linux only.")
 444   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 445 endif( LLVM_USE_PERF )
 446
 447 set(LLVM_USE_SANITIZER "" CACHE STRING
 448   "Define the sanitizer used to build binaries and tests.")
 449 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 450 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 451   "Path to fuzzing library for linking with fuzz targets")
 452
 453 option(LLVM_USE_SPLIT_DWARF
 454   "Use -gsplit-dwarf when compiling llvm." OFF)
 455
 456 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 457 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 458
 459 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 460   set(POLLY_IN_TREE TRUE)
 461 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 462   set(POLLY_IN_TREE TRUE)
 463 else()
 464   set(POLLY_IN_TREE FALSE)
 465 endif()
 466
 467 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 468   set(WITH_POLLY ON)
 469 else()
 470   set(WITH_POLLY OFF)
 471 endif()
 472
 473 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 474   set(LINK_POLLY_INTO_TOOLS ON)
 475 else()
 476   set(LINK_POLLY_INTO_TOOLS OFF)
 477 endif()
 478
 479 # Define an option controlling whether we should build for 32-bit on 64-bit
 480 # platforms, where supported.
 481 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 482   # TODO: support other platforms and toolchains.
 483   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 484 endif()
 485
 486 # Define the default arguments to use with 'lit', and an option for the user to
 487 # override.
 488 set(LIT_ARGS_DEFAULT "-sv")
 489 if (MSVC_IDE OR XCODE)
 490   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 491 endif()
 492 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 493
 494 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 495 if( WIN32 AND NOT CYGWIN )
 496   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 497 endif()
 498
 499 # Define options to control the inclusion and default build behavior for
 500 # components which may not strictly be necessary (tools, examples, and tests).
 501 #
 502 # This is primarily to support building smaller or faster project files.
 503 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 504 option(LLVM_BUILD_TOOLS
 505   "Build the LLVM tools. If OFF, just generate build targets." ON)
 506
 507 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 508 option(LLVM_BUILD_UTILS
 509   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 510
 511 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 512 option(LLVM_BUILD_RUNTIMES
 513   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 514
 515 option(LLVM_BUILD_RUNTIME
 516   "Build the LLVM runtime libraries." ON)
 517 option(LLVM_BUILD_EXAMPLES
 518   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 519 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 520
 521 option(LLVM_BUILD_TESTS
 522   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 523 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 524 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 525
 526 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 527 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 528 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 529
 530 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 531 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 532 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 533 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 534 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 535 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 536
 537 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 538     CACHE STRING "Doxygen-generated HTML documentation install directory")
 539 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 540     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 541
 542 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 543   "Build compiler-rt as an external project." OFF)
 544
 545 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 546   "Show target and host info when tools are invoked with --version." ON)
 547
 548 # You can configure which libraries from LLVM you want to include in the
 549 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 550 # list of LLVM components. All component names handled by llvm-config are valid.
 551 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 552   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 553     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 554 endif()
 555 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 556 if(MSVC)
 557   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 558 else()
 559   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 560 endif()
 561 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 562 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 563   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 564 endif()
 565 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 566
 567 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 568 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 569   set(LLVM_USE_HOST_TOOLS ON)
 570 endif()
 571
 572 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 573   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 574 else()
 575   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 576 endif()
 577
 578 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 579     LLVM_ENABLE_IR_PGO)
 580   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 581     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 582     # for spining disks. Anything higher may only help on slower mediums.
 583     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 584   endif()
 585   if(NOT LLVM_PROFILE_FILE_PATTERN)
 586     if(NOT LLVM_PROFILE_DATA_DIR)
 587       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 588     endif()
 589                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 590   endif()
 591   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 592     if(NOT LLVM_CSPROFILE_DATA_DIR)
 593       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 594     endif()
 595     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 596   endif()
 597 endif()
 598
 599 if (LLVM_BUILD_STATIC)
 600   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 601 endif()
 602
 603 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 604 if(CMAKE_HOST_APPLE AND APPLE)
 605   include(UseLibtool)
 606 endif()
 607
 608 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 609 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 610 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 611
 612 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 613   "Enable per-target runtimes directory")
 614
 615 # All options referred to from HandleLLVMOptions have to be specified
 616 # BEFORE this include, otherwise options will not be correctly set on
 617 # first cmake run
 618 include(config-ix)
 619
 620 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 621   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 622 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 623
 624 # By default, we target the host, but this can be overridden at CMake
 625 # invocation time.
 626 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 627   "Default target for which LLVM will generate code." )
 628 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 629 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 630 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 631
 632 if(WIN32 OR CYGWIN)
 633   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 634     set(LLVM_ENABLE_PLUGINS_default ON)
 635   else()
 636     set(LLVM_ENABLE_PLUGINS_default OFF)
 637   endif()
 638 else()
 639   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 640 endif()
 641 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 642
 643 include(HandleLLVMOptions)
 644
 645 include(FindPythonInterp)
 646 if( NOT PYTHONINTERP_FOUND )
 647   message(FATAL_ERROR
 648 "Unable to find Python interpreter, required for builds and testing.
 649
 650 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 651 endif()
 652
 653 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 654   message(FATAL_ERROR "Python 2.7 or newer is required")
 655 endif()
 656
 657 ######
 658 # LLVMBuild Integration
 659 #
 660 # We use llvm-build to generate all the data required by the CMake based
 661 # build system in one swoop:
 662 #
 663 #  - We generate a file (a CMake fragment) in the object root which contains
 664 #    all the definitions that are required by CMake.
 665 #
 666 #  - We generate the library table used by llvm-config.
 667 #
 668 #  - We generate the dependencies for the CMake fragment, so that we will
 669 #    automatically reconfigure ourselves.
 670
 671 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 672 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 673   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 674 set(LLVMBUILDCMAKEFRAG
 675   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 676
 677 # Create the list of optional components that are enabled
 678 if (LLVM_USE_INTEL_JITEVENTS)
 679   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 680 endif (LLVM_USE_INTEL_JITEVENTS)
 681 if (LLVM_USE_OPROFILE)
 682   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 683 endif (LLVM_USE_OPROFILE)
 684 if (LLVM_USE_PERF)
 685   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 686 endif (LLVM_USE_PERF)
 687
 688 message(STATUS "Constructing LLVMBuild project information")
 689 execute_process(
 690   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 691             --native-target "${LLVM_NATIVE_ARCH}"
 692             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 693             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 694             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 695             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 696             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 697             ERROR_VARIABLE LLVMBUILDERRORS
 698             OUTPUT_STRIP_TRAILING_WHITESPACE
 699             ERROR_STRIP_TRAILING_WHITESPACE
 700   RESULT_VARIABLE LLVMBUILDRESULT)
 701
 702 # On Win32, CMake doesn't properly handle piping the default output/error
 703 # streams into the GUI console. So, we explicitly catch and report them.
 704 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 705   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 706 endif()
 707 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 708   message(FATAL_ERROR
 709     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 710 endif()
 711
 712 # Include the generated CMake fragment. This will define properties from the
 713 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 714 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 715 # files change.
 716 include(${LLVMBUILDCMAKEFRAG})
 717
 718 ######
 719
 720 # Configure all of the various header file fragments LLVM uses which depend on
 721 # configuration variables.
 722 set(LLVM_ENUM_TARGETS "")
 723 set(LLVM_ENUM_ASM_PRINTERS "")
 724 set(LLVM_ENUM_ASM_PARSERS "")
 725 set(LLVM_ENUM_DISASSEMBLERS "")
 726 foreach(t ${LLVM_TARGETS_TO_BUILD})
 727   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 728
 729   list(FIND LLVM_ALL_TARGETS ${t} idx)
 730   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 731   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 732   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 733   # this test just makes sure that any experimental targets were passed via
 734   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 735   if( idx LESS 0 AND idy LESS 0 )
 736     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 737       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 738   else()
 739     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 740   endif()
 741
 742   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 743   if( asmp_file )
 744     set(LLVM_ENUM_ASM_PRINTERS
 745       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 746   endif()
 747   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 748     set(LLVM_ENUM_ASM_PARSERS
 749       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 750   endif()
 751   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 752     set(LLVM_ENUM_DISASSEMBLERS
 753       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 754   endif()
 755 endforeach(t)
 756
 757 # Produce the target definition files, which provide a way for clients to easily
 758 # include various classes of targets.
 759 configure_file(
 760   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 761   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 762   )
 763 configure_file(
 764   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 765   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 766   )
 767 configure_file(
 768   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 769   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 770   )
 771 configure_file(
 772   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 773   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 774   )
 775
 776 # Configure the three LLVM configuration header files.
 777 configure_file(
 778   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 779   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 780 configure_file(
 781   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 782   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 783 configure_file(
 784   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 785   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 786
 787 # Add target for generating source rpm package.
 788 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 789     CACHE FILEPATH ".spec file to use for srpm generation")
 790 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 791 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 792
 793 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 794 string(LENGTH "${revision}" revision_length)
 795 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 796   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 797 else()
 798   set(LLVM_RPM_SPEC_REVISION "${revision}")
 799 endif()
 800
 801 configure_file(
 802   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 803   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 804
 805 add_custom_target(srpm
 806   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 807   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 808 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 809
 810
 811 # They are not referenced. See set_output_directory().
 812 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 813 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 814 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 815
 816 if(APPLE AND DARWIN_LTO_LIBRARY)
 817   set(CMAKE_EXE_LINKER_FLAGS
 818     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 819   set(CMAKE_SHARED_LINKER_FLAGS
 820     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 821   set(CMAKE_MODULE_LINKER_FLAGS
 822     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 823 endif()
 824
 825 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
 826 # break things. In this case we need to enable the large-file API as well.
 827 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 828           add_definitions("-D_XOPEN_SOURCE=700")
 829           add_definitions("-D_LARGE_FILE_API")
 830 endif()
 831
 832 # Work around a broken bfd ld behavior. When linking a binary with a
 833 # foo.so library, it will try to find any library that foo.so uses and
 834 # check its symbols. This is wasteful (the check was done when foo.so
 835 # was created) and can fail since it is not the dynamic linker and
 836 # doesn't know how to handle search paths correctly.
 837 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 838   set(CMAKE_EXE_LINKER_FLAGS
 839       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 840 endif()
 841
 842 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 843
 844 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 845
 846 # when crosscompiling import the executable targets from a file
 847 if(LLVM_USE_HOST_TOOLS)
 848   include(CrossCompile)
 849   llvm_create_cross_target(LLVM NATIVE "" Release)
 850 endif(LLVM_USE_HOST_TOOLS)
 851 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 852 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 853 # (this is a variable that CrossCompile sets on recursive invocations)
 854 endif()
 855
 856 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 857   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 858   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 859   include_directories(SYSTEM "/usr/local/include")
 860   link_directories("/usr/local/lib")
 861 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 862
 863 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 864    # special hack for Solaris to handle crazy system sys/regset.h
 865    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 866 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 867
 868 # Make sure we don't get -rdynamic in every binary. For those that need it,
 869 # use export_executable_symbols(target).
 870 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 871
 872 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 873   "Profiling data file to use when compiling in order to improve runtime performance.")
 874
 875 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 876   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 877     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 878   else()
 879     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 880   endif()
 881 endif()
 882
 883 include(AddLLVM)
 884 include(TableGen)
 885
 886 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 887   # People report that -O3 is unreliable on MinGW. The traditional
 888   # build also uses -O2 for that reason:
 889   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 890 endif()
 891
 892 # Put this before tblgen. Else we have a circular dependence.
 893 add_subdirectory(lib/Demangle)
 894 add_subdirectory(lib/Support)
 895 add_subdirectory(lib/TableGen)
 896
 897 add_subdirectory(utils/TableGen)
 898
 899 add_subdirectory(include/llvm)
 900
 901 add_subdirectory(lib)
 902
 903 if( LLVM_INCLUDE_UTILS )
 904   add_subdirectory(utils/FileCheck)
 905   add_subdirectory(utils/PerfectShuffle)
 906   add_subdirectory(utils/count)
 907   add_subdirectory(utils/not)
 908   add_subdirectory(utils/yaml-bench)
 909 else()
 910   if ( LLVM_INCLUDE_TESTS )
 911     message(FATAL_ERROR "Including tests when not building utils will not work.
 912     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 913   endif()
 914 endif()
 915
 916 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 917 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 918   add_subdirectory(utils/LLVMVisualizers)
 919 endif()
 920
 921 foreach( binding ${LLVM_BINDINGS_LIST} )
 922   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 923     add_subdirectory(bindings/${binding})
 924   endif()
 925 endforeach()
 926
 927 add_subdirectory(projects)
 928
 929 if( LLVM_INCLUDE_TOOLS )
 930   add_subdirectory(tools)
 931 endif()
 932
 933 if( LLVM_INCLUDE_RUNTIMES )
 934   add_subdirectory(runtimes)
 935 endif()
 936
 937 if( LLVM_INCLUDE_EXAMPLES )
 938   add_subdirectory(examples)
 939 endif()
 940
 941 if( LLVM_INCLUDE_TESTS )
 942   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 943     include(LLVMExternalProjectUtils)
 944     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 945       USE_TOOLCHAIN
 946       EXCLUDE_FROM_ALL
 947       NO_INSTALL
 948       ALWAYS_CLEAN)
 949   endif()
 950   add_subdirectory(utils/lit)
 951   add_subdirectory(test)
 952   add_subdirectory(unittests)
 953   if( LLVM_INCLUDE_UTILS )
 954     add_subdirectory(utils/unittest)
 955   endif()
 956
 957   if (WIN32)
 958     # This utility is used to prevent crashing tests from calling Dr. Watson on
 959     # Windows.
 960     add_subdirectory(utils/KillTheDoctor)
 961   endif()
 962
 963   # Add a global check rule now that all subdirectories have been traversed
 964   # and we know the total set of lit testsuites.
 965   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 966   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 967   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 968   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 969   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 970                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 971   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 972                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 973   add_lit_target(check-all
 974     "Running all regression tests"
 975     ${LLVM_LIT_TESTSUITES}
 976     PARAMS ${LLVM_LIT_PARAMS}
 977     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 978     ARGS ${LLVM_LIT_EXTRA_ARGS}
 979     )
 980   if(TARGET check-runtimes)
 981     add_dependencies(check-all check-runtimes)
 982   endif()
 983   add_custom_target(test-depends
 984                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 985   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 986 endif()
 987
 988 if (LLVM_INCLUDE_DOCS)
 989   add_subdirectory(docs)
 990 endif()
 991
 992 add_subdirectory(cmake/modules)
 993
 994 # Do this last so that all lit targets have already been created.
 995 if (LLVM_INCLUDE_UTILS)
 996   add_subdirectory(utils/llvm-lit)
 997 endif()
 998
 999 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1000   install(DIRECTORY include/llvm include/llvm-c
1001     DESTINATION include
1002     COMPONENT llvm-headers
1003     FILES_MATCHING
1004     PATTERN "*.def"
1005     PATTERN "*.h"
1006     PATTERN "*.td"
1007     PATTERN "*.inc"
1008     PATTERN "LICENSE.TXT"
1009     PATTERN ".svn" EXCLUDE
1010     )
1011
1012   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1013     DESTINATION include
1014     COMPONENT llvm-headers
1015     FILES_MATCHING
1016     PATTERN "*.def"
1017     PATTERN "*.h"
1018     PATTERN "*.gen"
1019     PATTERN "*.inc"
1020     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1021     PATTERN "CMakeFiles" EXCLUDE
1022     PATTERN "config.h" EXCLUDE
1023     PATTERN ".svn" EXCLUDE
1024     )
1025
1026   if (LLVM_INSTALL_MODULEMAPS)
1027     install(DIRECTORY include/llvm include/llvm-c
1028             DESTINATION include
1029             COMPONENT llvm-headers
1030             FILES_MATCHING
1031             PATTERN "module.modulemap"
1032             )
1033     install(FILES include/llvm/module.install.modulemap
1034             DESTINATION include/llvm
1035             COMPONENT llvm-headers
1036             RENAME "module.extern.modulemap"
1037             )
1038   endif(LLVM_INSTALL_MODULEMAPS)
1039
1040   # Installing the headers needs to depend on generating any public
1041   # tablegen'd headers.
1042   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1043   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1044
1045   if (NOT LLVM_ENABLE_IDE)
1046     add_llvm_install_targets(install-llvm-headers
1047                              DEPENDS llvm-headers
1048                              COMPONENT llvm-headers)
1049   endif()
1050
1051   # Custom target to install all libraries.
1052   add_custom_target(llvm-libraries)
1053   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1054
1055   if (NOT LLVM_ENABLE_IDE)
1056     add_llvm_install_targets(install-llvm-libraries
1057                              DEPENDS llvm-libraries
1058                              COMPONENT llvm-libraries)
1059   endif()
1060
1061   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1062   if(LLVM_LIBS)
1063     list(REMOVE_DUPLICATES LLVM_LIBS)
1064     foreach(lib ${LLVM_LIBS})
1065       add_dependencies(llvm-libraries ${lib})
1066       if (NOT LLVM_ENABLE_IDE)
1067         add_dependencies(install-llvm-libraries install-${lib})
1068       endif()
1069     endforeach()
1070   endif()
1071 endif()
1072
1073 # This must be at the end of the LLVM root CMakeLists file because it must run
1074 # after all targets are created.
1075 include(LLVMDistributionSupport)
1076 llvm_distribution_add_targets()
1077
1078 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1079 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1080   include(InstallRequiredSystemLibraries)
1081 endif()
1082
1083 if (LLVM_INCLUDE_BENCHMARKS)
1084   # Override benchmark defaults so that when the library itself is updated these
1085   # modifications are not lost.
1086   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1087   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1088   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1089   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1090   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1091   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1092   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1093
1094   add_subdirectory(utils/benchmark)
1095   add_subdirectory(benchmarks)
1096 endif()