CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM C CXX ASM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  36     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  37   else()
  38     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  39     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  40   endif()
  41 endif()
  42
  43 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  44   "Define the maximum number of concurrent link jobs.")
  45 if(LLVM_PARALLEL_LINK_JOBS)
  46   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  47     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  48   else()
  49     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  50     set(CMAKE_JOB_POOL_LINK link_job_pool)
  51   endif()
  52 endif()
  53
  54 # Add path for custom modules
  55 set(CMAKE_MODULE_PATH
  56   ${CMAKE_MODULE_PATH}
  57   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  58   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  59   )
  60
  61 set(LLVM_VERSION_MAJOR 3)
  62 set(LLVM_VERSION_MINOR 8)
  63 set(LLVM_VERSION_PATCH 0)
  64 set(LLVM_VERSION_SUFFIX svn)
  65
  66 if (NOT PACKAGE_VERSION)
  67   set(PACKAGE_VERSION
  68     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  69 endif()
  70
  71 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  72
  73 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  74
  75 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  76 if ( LLVM_USE_FOLDERS )
  77   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  78 endif()
  79
  80 include(VersionFromVCS)
  81
  82 option(LLVM_APPEND_VC_REV
  83   "Append the version control system revision id to LLVM version" OFF)
  84
  85 if( LLVM_APPEND_VC_REV )
  86   add_version_info_from_vcs(PACKAGE_VERSION)
  87 endif()
  88
  89 set(PACKAGE_NAME LLVM)
  90 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  91 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  92
  93 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  94   "Default URL where bug reports are to be submitted.")
  95
  96 # Configure CPack.
  97 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  98 set(CPACK_PACKAGE_VENDOR "LLVM")
  99 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 100 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 101 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 102 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 103 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 104 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 105 if(WIN32 AND NOT UNIX)
 106   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 107   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 108   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 109   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 110   set(CPACK_NSIS_MODIFY_PATH "ON")
 111   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 112   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 113     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 114   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 115     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 116   if( CMAKE_CL_64 )
 117     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 118   endif()
 119 endif()
 120 include(CPack)
 121
 122 # Sanity check our source directory to make sure that we are not trying to
 123 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 124 # sure that we don't have any stray generated files lying around in the tree
 125 # (which would end up getting picked up by header search, instead of the correct
 126 # versions).
 127 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 128   message(FATAL_ERROR "In-source builds are not allowed.
 129 CMake would overwrite the makefiles distributed with LLVM.
 130 Please create a directory and run cmake from there, passing the path
 131 to this source directory as the last argument.
 132 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 133 Please delete them.")
 134 endif()
 135 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 136   file(GLOB_RECURSE
 137     tablegenned_files_on_include_dir
 138     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 139   file(GLOB_RECURSE
 140     tablegenned_files_on_lib_dir
 141     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 142   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 143     message(FATAL_ERROR "Apparently there is a previous in-source build,
 144 probably as the result of running `configure' and `make' on
 145 ${CMAKE_CURRENT_SOURCE_DIR}.
 146 This may cause problems. The suspicious files are:
 147 ${tablegenned_files_on_lib_dir}
 148 ${tablegenned_files_on_include_dir}
 149 Please clean the source directory.")
 150   endif()
 151 endif()
 152
 153 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 154
 155 if (CMAKE_BUILD_TYPE AND
 156     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 157   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 158 endif()
 159
 160 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 161
 162 # They are used as destination of target generators.
 163 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 164 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 165 if(WIN32 OR CYGWIN)
 166   # DLL platform -- put DLLs into bin.
 167   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 168 else()
 169   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 170 endif()
 171
 172 # Each of them corresponds to llvm-config's.
 173 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 174 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 175 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 176 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 177 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 178
 179 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 180 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 181
 182 set(LLVM_ALL_TARGETS
 183   AArch64
 184   AMDGPU
 185   ARM
 186   BPF
 187   CppBackend
 188   Hexagon
 189   Mips
 190   MSP430
 191   NVPTX
 192   PowerPC
 193   Sparc
 194   SystemZ
 195   X86
 196   XCore
 197   )
 198
 199 # List of targets with JIT support:
 200 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 201
 202 set(LLVM_TARGETS_TO_BUILD "all"
 203     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 204
 205 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 206   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 207
 208 option(BUILD_SHARED_LIBS
 209   "Build all libraries as shared libraries instead of static" OFF)
 210
 211 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 212 if(LLVM_ENABLE_TIMESTAMPS)
 213   set(ENABLE_TIMESTAMPS 1)
 214 endif()
 215
 216 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 217 if(LLVM_ENABLE_BACKTRACES)
 218   set(ENABLE_BACKTRACES 1)
 219 endif()
 220
 221 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 222 if(LLVM_ENABLE_CRASH_OVERRIDES)
 223   set(ENABLE_CRASH_OVERRIDES 1)
 224 endif()
 225
 226 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 227 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 228 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 229
 230 set(LLVM_TARGET_ARCH "host"
 231   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 232
 233 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 234
 235 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 236
 237 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 238
 239 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 240   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 241 endif()
 242
 243 set(LLVM_TARGETS_TO_BUILD
 244    ${LLVM_TARGETS_TO_BUILD}
 245    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 246 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 247
 248 include(AddLLVMDefinitions)
 249
 250 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 251 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 252 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 253 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 254 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 255 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 256 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 257 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 258
 259 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 260   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 261 else()
 262   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 263 endif()
 264
 265 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 266   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 267
 268 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 269        "Set to ON to force using an old, unsupported host toolchain." OFF)
 270
 271 option(LLVM_USE_INTEL_JITEVENTS
 272   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 273   OFF)
 274
 275 if( LLVM_USE_INTEL_JITEVENTS )
 276   # Verify we are on a supported platform
 277   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 278     message(FATAL_ERROR
 279       "Intel JIT API support is available on Linux and Windows only.")
 280   endif()
 281 endif( LLVM_USE_INTEL_JITEVENTS )
 282
 283 option(LLVM_USE_OPROFILE
 284   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 285
 286 # If enabled, verify we are on a platform that supports oprofile.
 287 if( LLVM_USE_OPROFILE )
 288   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 289     message(FATAL_ERROR "OProfile support is available on Linux only.")
 290   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 291 endif( LLVM_USE_OPROFILE )
 292
 293 set(LLVM_USE_SANITIZER "" CACHE STRING
 294   "Define the sanitizer used to build binaries and tests.")
 295
 296 option(LLVM_USE_SPLIT_DWARF
 297   "Use -gsplit-dwarf when compiling llvm." OFF)
 298
 299 option(WITH_POLLY "Build LLVM with Polly" ON)
 300 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 301
 302 # Define an option controlling whether we should build for 32-bit on 64-bit
 303 # platforms, where supported.
 304 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 305   # TODO: support other platforms and toolchains.
 306   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 307 endif()
 308
 309 # Define the default arguments to use with 'lit', and an option for the user to
 310 # override.
 311 set(LIT_ARGS_DEFAULT "-sv")
 312 if (MSVC_IDE OR XCODE)
 313   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 314 endif()
 315 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 316
 317 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 318 if( WIN32 AND NOT CYGWIN )
 319   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 320 endif()
 321
 322 # Define options to control the inclusion and default build behavior for
 323 # components which may not strictly be necessary (tools, examples, and tests).
 324 #
 325 # This is primarily to support building smaller or faster project files.
 326 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 327 option(LLVM_BUILD_TOOLS
 328   "Build the LLVM tools. If OFF, just generate build targets." ON)
 329
 330 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 331
 332 option(LLVM_BUILD_RUNTIME
 333   "Build the LLVM runtime libraries." ON)
 334 option(LLVM_BUILD_EXAMPLES
 335   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 336 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 337
 338 option(LLVM_BUILD_TESTS
 339   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 340 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 341 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 342
 343 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 344 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 345 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 346 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 347
 348 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 349   "Build compiler-rt as an external project." OFF)
 350
 351 # You can configure which libraries from LLVM you want to include in the
 352 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 353 # list of LLVM components. All component names handled by llvm-config are valid.
 354 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 355   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 356     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 357 endif()
 358 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 359 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_LINK_LLVM_DYLIB})
 360 option(LLVM_DYLIB_EXPORT_ALL "Export all symbols from libLLVM.dylib (default is C API only" ${LLVM_LINK_LLVM_DYLIB})
 361 set(LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT ON)
 362 if (LLVM_LINK_LLVM_DYLIB)
 363   set(LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT OFF)
 364 endif()
 365 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ${LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT})
 366 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 367   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 368 endif()
 369
 370 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 371 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 372   set(LLVM_USE_HOST_TOOLS ON)
 373 endif()
 374
 375 # All options referred to from HandleLLVMOptions have to be specified
 376 # BEFORE this include, otherwise options will not be correctly set on
 377 # first cmake run
 378 include(config-ix)
 379
 380 # By default, we target the host, but this can be overridden at CMake
 381 # invocation time.
 382 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 383   "Default target for which LLVM will generate code." )
 384 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 385
 386 include(HandleLLVMOptions)
 387
 388 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 389 # FIXME: We should support systems with only Python 3, but that requires work
 390 # on LLDB.
 391 set(Python_ADDITIONAL_VERSIONS 2.7)
 392 include(FindPythonInterp)
 393 if( NOT PYTHONINTERP_FOUND )
 394   message(FATAL_ERROR
 395 "Unable to find Python interpreter, required for builds and testing.
 396
 397 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 398 endif()
 399
 400 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 401   message(FATAL_ERROR "Python 2.7 or newer is required")
 402 endif()
 403
 404 ######
 405 # LLVMBuild Integration
 406 #
 407 # We use llvm-build to generate all the data required by the CMake based
 408 # build system in one swoop:
 409 #
 410 #  - We generate a file (a CMake fragment) in the object root which contains
 411 #    all the definitions that are required by CMake.
 412 #
 413 #  - We generate the library table used by llvm-config.
 414 #
 415 #  - We generate the dependencies for the CMake fragment, so that we will
 416 #    automatically reconfigure outselves.
 417
 418 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 419 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 420   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 421 set(LLVMBUILDCMAKEFRAG
 422   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 423
 424 # Create the list of optional components that are enabled
 425 if (LLVM_USE_INTEL_JITEVENTS)
 426   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 427 endif (LLVM_USE_INTEL_JITEVENTS)
 428 if (LLVM_USE_OPROFILE)
 429   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 430 endif (LLVM_USE_OPROFILE)
 431
 432 message(STATUS "Constructing LLVMBuild project information")
 433 execute_process(
 434   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 435             --native-target "${LLVM_NATIVE_ARCH}"
 436             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 437             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 438             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 439             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 440             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 441             ERROR_VARIABLE LLVMBUILDERRORS
 442             OUTPUT_STRIP_TRAILING_WHITESPACE
 443             ERROR_STRIP_TRAILING_WHITESPACE
 444   RESULT_VARIABLE LLVMBUILDRESULT)
 445
 446 # On Win32, CMake doesn't properly handle piping the default output/error
 447 # streams into the GUI console. So, we explicitly catch and report them.
 448 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 449   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 450 endif()
 451 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 452   message(FATAL_ERROR
 453     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 454 endif()
 455
 456 # Include the generated CMake fragment. This will define properties from the
 457 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 458 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 459 # files change.
 460 include(${LLVMBUILDCMAKEFRAG})
 461
 462 ######
 463
 464 # Configure all of the various header file fragments LLVM uses which depend on
 465 # configuration variables.
 466 set(LLVM_ENUM_TARGETS "")
 467 set(LLVM_ENUM_ASM_PRINTERS "")
 468 set(LLVM_ENUM_ASM_PARSERS "")
 469 set(LLVM_ENUM_DISASSEMBLERS "")
 470 foreach(t ${LLVM_TARGETS_TO_BUILD})
 471   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 472
 473   list(FIND LLVM_ALL_TARGETS ${t} idx)
 474   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 475   if( idx LESS 0 AND idy LESS 0 )
 476     message(FATAL_ERROR "The target `${t}' does not exist.
 477     It should be one of\n${LLVM_ALL_TARGETS}")
 478   else()
 479     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 480   endif()
 481
 482   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 483   if( asmp_file )
 484     set(LLVM_ENUM_ASM_PRINTERS
 485       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 486   endif()
 487   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 488     set(LLVM_ENUM_ASM_PARSERS
 489       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 490   endif()
 491   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 492     set(LLVM_ENUM_DISASSEMBLERS
 493       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 494   endif()
 495 endforeach(t)
 496
 497 # Produce the target definition files, which provide a way for clients to easily
 498 # include various classes of targets.
 499 configure_file(
 500   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 501   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 502   )
 503 configure_file(
 504   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 505   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 506   )
 507 configure_file(
 508   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 509   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 510   )
 511 configure_file(
 512   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 513   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 514   )
 515
 516 # Configure the three LLVM configuration header files.
 517 configure_file(
 518   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 519   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 520 configure_file(
 521   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 522   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 523 configure_file(
 524   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 525   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 526
 527 # They are not referenced. See set_output_directory().
 528 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 529 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 530 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 531
 532 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 533 if (APPLE)
 534   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 535   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 536 else(UNIX)
 537   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 538     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 539     if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 540       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 541       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 542     endif()
 543   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 544 endif()
 545
 546 if(APPLE AND DARWIN_LTO_LIBRARY)
 547   set(CMAKE_EXE_LINKER_FLAGS
 548     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 549   set(CMAKE_SHARED_LINKER_FLAGS
 550     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 551   set(CMAKE_MODULE_LINKER_FLAGS
 552     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 553 endif()
 554
 555 # Work around a broken bfd ld behavior. When linking a binary with a
 556 # foo.so library, it will try to find any library that foo.so uses and
 557 # check its symbols. This is wasteful (the check was done when foo.so
 558 # was created) and can fail since it is not the dynamic linker and
 559 # doesn't know how to handle search paths correctly.
 560 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 561   set(CMAKE_EXE_LINKER_FLAGS
 562       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 563 endif()
 564
 565 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 566
 567 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 568
 569 # when crosscompiling import the executable targets from a file
 570 if(LLVM_USE_HOST_TOOLS)
 571   include(CrossCompile)
 572 endif(LLVM_USE_HOST_TOOLS)
 573 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 574 # Dummy use to avoid CMake Wraning: Manually-specified variables were not used
 575 # (this is a variable that CrossCompile sets on recursive invocations)
 576 endif()
 577
 578 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 579   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 580   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 581   include_directories("/usr/local/include")
 582   link_directories("/usr/local/lib")
 583 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 584
 585 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 586    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 587 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 588
 589 # Make sure we don't get -rdynamic in every binary. For those that need it,
 590 # use export_executable_symbols(target).
 591 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 592
 593 include(AddLLVM)
 594 include(TableGen)
 595
 596 if( MINGW )
 597   # People report that -O3 is unreliable on MinGW. The traditional
 598   # build also uses -O2 for that reason:
 599   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 600 endif()
 601
 602 # Put this before tblgen. Else we have a circular dependence.
 603 add_subdirectory(lib/Support)
 604 add_subdirectory(lib/TableGen)
 605
 606 add_subdirectory(utils/TableGen)
 607
 608 add_subdirectory(include/llvm)
 609
 610 add_subdirectory(lib)
 611
 612 if( LLVM_INCLUDE_UTILS )
 613   add_subdirectory(utils/FileCheck)
 614   add_subdirectory(utils/PerfectShuffle)
 615   add_subdirectory(utils/count)
 616   add_subdirectory(utils/not)
 617   add_subdirectory(utils/llvm-lit)
 618   add_subdirectory(utils/yaml-bench)
 619 else()
 620   if ( LLVM_INCLUDE_TESTS )
 621     message(FATAL_ERROR "Including tests when not building utils will not work.
 622     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 623   endif()
 624 endif()
 625
 626 if(LLVM_INCLUDE_TESTS)
 627   add_subdirectory(utils/unittest)
 628 endif()
 629
 630 foreach( binding ${LLVM_BINDINGS_LIST} )
 631   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 632     add_subdirectory(bindings/${binding})
 633   endif()
 634 endforeach()
 635
 636 add_subdirectory(projects)
 637
 638 if(WITH_POLLY)
 639   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 640     set(WITH_POLLY OFF)
 641   endif()
 642 endif(WITH_POLLY)
 643
 644 if( LLVM_INCLUDE_TOOLS )
 645   add_subdirectory(tools)
 646 endif()
 647
 648 if( LLVM_INCLUDE_EXAMPLES )
 649   add_subdirectory(examples)
 650 endif()
 651
 652 if( LLVM_INCLUDE_TESTS )
 653   add_subdirectory(test)
 654   add_subdirectory(unittests)
 655   if (MSVC)
 656     # This utility is used to prevent crashing tests from calling Dr. Watson on
 657     # Windows.
 658     add_subdirectory(utils/KillTheDoctor)
 659   endif()
 660
 661   # Add a global check rule now that all subdirectories have been traversed
 662   # and we know the total set of lit testsuites.
 663   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 664   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 665   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 666   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 667   add_lit_target(check-all
 668     "Running all regression tests"
 669     ${LLVM_LIT_TESTSUITES}
 670     PARAMS ${LLVM_LIT_PARAMS}
 671     DEPENDS ${LLVM_LIT_DEPENDS}
 672     ARGS ${LLVM_LIT_EXTRA_ARGS}
 673     )
 674 endif()
 675
 676 if (LLVM_INCLUDE_DOCS)
 677   add_subdirectory(docs)
 678 endif()
 679
 680 add_subdirectory(cmake/modules)
 681
 682 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 683   install(DIRECTORY include/llvm include/llvm-c
 684     DESTINATION include
 685     COMPONENT llvm-headers
 686     FILES_MATCHING
 687     PATTERN "*.def"
 688     PATTERN "*.h"
 689     PATTERN "*.td"
 690     PATTERN "*.inc"
 691     PATTERN "LICENSE.TXT"
 692     PATTERN ".svn" EXCLUDE
 693     )
 694
 695   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 696     DESTINATION include
 697     COMPONENT llvm-headers
 698     FILES_MATCHING
 699     PATTERN "*.def"
 700     PATTERN "*.h"
 701     PATTERN "*.gen"
 702     PATTERN "*.inc"
 703     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 704     PATTERN "CMakeFiles" EXCLUDE
 705     PATTERN "config.h" EXCLUDE
 706     PATTERN ".svn" EXCLUDE
 707     )
 708
 709   if (NOT CMAKE_CONFIGURATION_TYPES)
 710     add_custom_target(installhdrs
 711                       DEPENDS ${name}
 712                       COMMAND "${CMAKE_COMMAND}"
 713                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 714                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 715   endif()
 716 endif()