CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0022)
   6   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
   7 endif()
   8
   9 if (POLICY CMP0051)
  10   # CMake 3.1 and higher include generator expressions of the form
  11   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  12   # stripped everywhere that access the SOURCES property, so we just
  13   # defer to the OLD behavior of not including generator expressions
  14   # in the output for now.
  15   cmake_policy(SET CMP0051 OLD)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 4)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (POLICY CMP0048)
  32   cmake_policy(SET CMP0048 NEW)
  33   set(cmake_3_0_PROJ_VERSION
  34     VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH})
  35   set(cmake_3_0_LANGUAGES LANGUAGES)
  36 endif()
  37
  38 if (NOT PACKAGE_VERSION)
  39   set(PACKAGE_VERSION
  40     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  41 endif()
  42
  43 project(LLVM
  44   ${cmake_3_0_PROJ_VERSION}
  45   ${cmake_3_0_LANGUAGES}
  46   C CXX ASM)
  47
  48 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  49   message(STATUS "No build type selected, default to Debug")
  50   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)")
  51 endif()
  52
  53 # This should only apply if you are both on an Apple host, and targeting Apple.
  54 if(CMAKE_HOST_APPLE AND APPLE)
  55   if(NOT CMAKE_XCRUN)
  56     find_program(CMAKE_XCRUN NAMES xcrun)
  57   endif()
  58   if(CMAKE_XCRUN)
  59     execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  60       OUTPUT_VARIABLE CMAKE_LIBTOOL
  61       OUTPUT_STRIP_TRAILING_WHITESPACE)
  62   endif()
  63
  64   if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  65     find_program(CMAKE_LIBTOOL NAMES libtool)
  66   endif()
  67
  68   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  69   if(CMAKE_LIBTOOL)
  70     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  71     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  72     foreach(lang ${languages})
  73       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  74         "${CMAKE_LIBTOOL} -static -o <TARGET> <LINK_FLAGS> <OBJECTS> ")
  75     endforeach()
  76   endif()
  77
  78   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  79   if(DYLD_LIBRARY_PATH)
  80     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  81     foreach(lang ${languages})
  82       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
  83         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
  84              "${dyld_envar} ${cmd}")
  85       endforeach()
  86       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  87         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
  88     endforeach()
  89   endif()
  90 endif()
  91
  92 # The following only works with the Ninja generator in CMake >= 3.0.
  93 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  94   "Define the maximum number of concurrent compilation jobs.")
  95 if(LLVM_PARALLEL_COMPILE_JOBS)
  96   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  97     message(WARNING "Job pooling is only available with Ninja generators.")
  98   else()
  99     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
 100     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
 101   endif()
 102 endif()
 103
 104 # Build llvm with ccache if the package is present
 105 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 106 if(LLVM_CCACHE_BUILD)
 107   find_program(CCACHE_PROGRAM ccache)
 108   if(CCACHE_PROGRAM)
 109       set(LLVM_CCACHE_SIZE "" CACHE STRING "Size of ccache")
 110       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 111       set(CCACHE_PROGRAM "CCACHE_CPP2=yes CCACHE_HASHDIR=yes ${CCACHE_PROGRAM}")
 112       if (LLVM_CCACHE_SIZE)
 113         set(CCACHE_PROGRAM "CCACHE_SIZE=${LLVM_CCACHE_SIZE} ${CCACHE_PROGRAM}")
 114       endif()
 115       if (LLVM_CCACHE_DIR)
 116         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 117       endif()
 118       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 119   else()
 120     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 121   endif()
 122 endif()
 123
 124 option(LLVM_BUILD_GLOBAL_ISEL "Experimental: Build GlobalISel" OFF)
 125 if(LLVM_BUILD_GLOBAL_ISEL)
 126   add_definitions(-DLLVM_BUILD_GLOBAL_ISEL)
 127 endif()
 128
 129 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
 130   "Define the maximum number of concurrent link jobs.")
 131 if(LLVM_PARALLEL_LINK_JOBS)
 132   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
 133     message(WARNING "Job pooling is only available with Ninja generators.")
 134   else()
 135     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
 136     set(CMAKE_JOB_POOL_LINK link_job_pool)
 137   endif()
 138 endif()
 139
 140 # Add path for custom modules
 141 set(CMAKE_MODULE_PATH
 142   ${CMAKE_MODULE_PATH}
 143   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 144   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 145   )
 146
 147 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 148 # for use by clang_complete, YouCompleteMe, etc.
 149 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 150
 151 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 152
 153 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 154
 155 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 156 if ( LLVM_USE_FOLDERS )
 157   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 158 endif()
 159
 160 include(VersionFromVCS)
 161
 162 option(LLVM_APPEND_VC_REV
 163   "Append the version control system revision id to LLVM version" OFF)
 164
 165 if( LLVM_APPEND_VC_REV )
 166   add_version_info_from_vcs(PACKAGE_VERSION)
 167 endif()
 168
 169 set(PACKAGE_NAME LLVM)
 170 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 171 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 172
 173 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 174   "Default URL where bug reports are to be submitted.")
 175
 176 # Configure CPack.
 177 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 178 set(CPACK_PACKAGE_VENDOR "LLVM")
 179 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 180 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 181 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 182 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 183 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 184 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 185 if(WIN32 AND NOT UNIX)
 186   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 187   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 188   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 189   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 190   set(CPACK_NSIS_MODIFY_PATH "ON")
 191   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 192   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 193     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 194   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 195     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 196   if( CMAKE_CL_64 )
 197     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 198   endif()
 199 endif()
 200 include(CPack)
 201
 202 # Sanity check our source directory to make sure that we are not trying to
 203 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 204 # sure that we don't have any stray generated files lying around in the tree
 205 # (which would end up getting picked up by header search, instead of the correct
 206 # versions).
 207 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 208   message(FATAL_ERROR "In-source builds are not allowed.
 209 CMake would overwrite the makefiles distributed with LLVM.
 210 Please create a directory and run cmake from there, passing the path
 211 to this source directory as the last argument.
 212 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 213 Please delete them.")
 214 endif()
 215 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 216   file(GLOB_RECURSE
 217     tablegenned_files_on_include_dir
 218     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 219   file(GLOB_RECURSE
 220     tablegenned_files_on_lib_dir
 221     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 222   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 223     message(FATAL_ERROR "Apparently there is a previous in-source build,
 224 probably as the result of running `configure' and `make' on
 225 ${CMAKE_CURRENT_SOURCE_DIR}.
 226 This may cause problems. The suspicious files are:
 227 ${tablegenned_files_on_lib_dir}
 228 ${tablegenned_files_on_include_dir}
 229 Please clean the source directory.")
 230   endif()
 231 endif()
 232
 233 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 234
 235 if (CMAKE_BUILD_TYPE AND
 236     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 237   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 238 endif()
 239
 240 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 241
 242 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 243 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 244
 245 # They are used as destination of target generators.
 246 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 247 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 248 if(WIN32 OR CYGWIN)
 249   # DLL platform -- put DLLs into bin.
 250   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 251 else()
 252   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 253 endif()
 254
 255 # Each of them corresponds to llvm-config's.
 256 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 257 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 258 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 259 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 260 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 261
 262 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 263 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 264
 265 set(LLVM_ALL_TARGETS
 266   AArch64
 267   AMDGPU
 268   ARM
 269   BPF
 270   Hexagon
 271   Lanai
 272   Mips
 273   MSP430
 274   NVPTX
 275   PowerPC
 276   Sparc
 277   SystemZ
 278   X86
 279   XCore
 280   )
 281
 282 # List of targets with JIT support:
 283 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 284
 285 set(LLVM_TARGETS_TO_BUILD "all"
 286     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 287
 288 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 289   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 290
 291 option(BUILD_SHARED_LIBS
 292   "Build all libraries as shared libraries instead of static" OFF)
 293
 294 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 295 if(LLVM_ENABLE_BACKTRACES)
 296   set(ENABLE_BACKTRACES 1)
 297 endif()
 298
 299 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 300 if(LLVM_ENABLE_CRASH_OVERRIDES)
 301   set(ENABLE_CRASH_OVERRIDES 1)
 302 endif()
 303
 304 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 305 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 306 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 307
 308 set(LLVM_TARGET_ARCH "host"
 309   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 310
 311 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 312
 313 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 314
 315 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 316
 317 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 318   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 319 endif()
 320
 321 set(LLVM_TARGETS_TO_BUILD
 322    ${LLVM_TARGETS_TO_BUILD}
 323    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 324 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 325
 326 include(AddLLVMDefinitions)
 327
 328 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 329 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 330 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 331 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 332   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 333   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 334 else()
 335   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 336   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 337 endif()
 338 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 339 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 340 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 341 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 342 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 343
 344 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 345   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 346 else()
 347   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 348 endif()
 349
 350 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 351
 352 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 353   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 354
 355 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 356        "Set to ON to force using an old, unsupported host toolchain." OFF)
 357
 358 option(LLVM_USE_INTEL_JITEVENTS
 359   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 360   OFF)
 361
 362 if( LLVM_USE_INTEL_JITEVENTS )
 363   # Verify we are on a supported platform
 364   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 365     message(FATAL_ERROR
 366       "Intel JIT API support is available on Linux and Windows only.")
 367   endif()
 368 endif( LLVM_USE_INTEL_JITEVENTS )
 369
 370 option(LLVM_USE_OPROFILE
 371   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 372
 373 option(LLVM_EXTERNALIZE_DEBUGINFO
 374   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 375
 376 # If enabled, verify we are on a platform that supports oprofile.
 377 if( LLVM_USE_OPROFILE )
 378   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 379     message(FATAL_ERROR "OProfile support is available on Linux only.")
 380   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 381 endif( LLVM_USE_OPROFILE )
 382
 383 set(LLVM_USE_SANITIZER "" CACHE STRING
 384   "Define the sanitizer used to build binaries and tests.")
 385
 386 option(LLVM_USE_SPLIT_DWARF
 387   "Use -gsplit-dwarf when compiling llvm." OFF)
 388
 389 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 390 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 391
 392 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 393   set(POLLY_IN_TREE TRUE)
 394 else()
 395   set(POLLY_IN_TREE FALSE)
 396 endif()
 397
 398 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 399   set(WITH_POLLY ON)
 400 else()
 401   set(WITH_POLLY OFF)
 402 endif()
 403
 404 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 405   set(LINK_POLLY_INTO_TOOLS ON)
 406 else()
 407   set(LINK_POLLY_INTO_TOOLS OFF)
 408 endif()
 409
 410 # Define an option controlling whether we should build for 32-bit on 64-bit
 411 # platforms, where supported.
 412 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 413   # TODO: support other platforms and toolchains.
 414   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 415 endif()
 416
 417 # Define the default arguments to use with 'lit', and an option for the user to
 418 # override.
 419 set(LIT_ARGS_DEFAULT "-sv")
 420 if (MSVC_IDE OR XCODE)
 421   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 422 endif()
 423 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 424
 425 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 426 if( WIN32 AND NOT CYGWIN )
 427   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 428 endif()
 429
 430 # Define options to control the inclusion and default build behavior for
 431 # components which may not strictly be necessary (tools, examples, and tests).
 432 #
 433 # This is primarily to support building smaller or faster project files.
 434 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 435 option(LLVM_BUILD_TOOLS
 436   "Build the LLVM tools. If OFF, just generate build targets." ON)
 437
 438 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 439 option(LLVM_BUILD_UTILS
 440   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 441
 442 option(LLVM_BUILD_RUNTIME
 443   "Build the LLVM runtime libraries." ON)
 444 option(LLVM_BUILD_EXAMPLES
 445   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 446 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 447
 448 option(LLVM_BUILD_TESTS
 449   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 450 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 451 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 452
 453 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 454 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 455 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 456 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 457 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 458
 459 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 460   "Build compiler-rt as an external project." OFF)
 461
 462 # You can configure which libraries from LLVM you want to include in the
 463 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 464 # list of LLVM components. All component names handled by llvm-config are valid.
 465 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 466   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 467     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 468 endif()
 469 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 470 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 471 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 472 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 473   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 474 endif()
 475 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 476
 477 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 478 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 479   set(LLVM_USE_HOST_TOOLS ON)
 480 endif()
 481
 482 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 483   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 484 else()
 485   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 486 endif()
 487
 488 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE)
 489   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 490     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 491     # for spining disks. Anything higher may only help on slower mediums.
 492     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 493   endif()
 494   if(NOT LLVM_PROFILE_FILE_PATTERN)
 495     if(NOT LLVM_PROFILE_DATA_DIR)
 496       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 497     else()
 498       file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 499     endif()
 500   endif()
 501 endif()
 502
 503 # All options referred to from HandleLLVMOptions have to be specified
 504 # BEFORE this include, otherwise options will not be correctly set on
 505 # first cmake run
 506 include(config-ix)
 507
 508 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 509   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 510 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 511
 512 # By default, we target the host, but this can be overridden at CMake
 513 # invocation time.
 514 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 515   "Default target for which LLVM will generate code." )
 516 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 517
 518 include(HandleLLVMOptions)
 519
 520 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 521 # FIXME: We should support systems with only Python 3, but that requires work
 522 # on LLDB.
 523 set(Python_ADDITIONAL_VERSIONS 2.7)
 524 include(FindPythonInterp)
 525 if( NOT PYTHONINTERP_FOUND )
 526   message(FATAL_ERROR
 527 "Unable to find Python interpreter, required for builds and testing.
 528
 529 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 530 endif()
 531
 532 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 533   message(FATAL_ERROR "Python 2.7 or newer is required")
 534 endif()
 535
 536 ######
 537 # LLVMBuild Integration
 538 #
 539 # We use llvm-build to generate all the data required by the CMake based
 540 # build system in one swoop:
 541 #
 542 #  - We generate a file (a CMake fragment) in the object root which contains
 543 #    all the definitions that are required by CMake.
 544 #
 545 #  - We generate the library table used by llvm-config.
 546 #
 547 #  - We generate the dependencies for the CMake fragment, so that we will
 548 #    automatically reconfigure outselves.
 549
 550 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 551 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 552   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 553 set(LLVMBUILDCMAKEFRAG
 554   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 555
 556 # Create the list of optional components that are enabled
 557 if (LLVM_USE_INTEL_JITEVENTS)
 558   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 559 endif (LLVM_USE_INTEL_JITEVENTS)
 560 if (LLVM_USE_OPROFILE)
 561   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 562 endif (LLVM_USE_OPROFILE)
 563
 564 message(STATUS "Constructing LLVMBuild project information")
 565 execute_process(
 566   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 567             --native-target "${LLVM_NATIVE_ARCH}"
 568             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 569             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 570             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 571             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 572             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 573             ERROR_VARIABLE LLVMBUILDERRORS
 574             OUTPUT_STRIP_TRAILING_WHITESPACE
 575             ERROR_STRIP_TRAILING_WHITESPACE
 576   RESULT_VARIABLE LLVMBUILDRESULT)
 577
 578 # On Win32, CMake doesn't properly handle piping the default output/error
 579 # streams into the GUI console. So, we explicitly catch and report them.
 580 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 581   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 582 endif()
 583 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 584   message(FATAL_ERROR
 585     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 586 endif()
 587
 588 # Include the generated CMake fragment. This will define properties from the
 589 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 590 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 591 # files change.
 592 include(${LLVMBUILDCMAKEFRAG})
 593
 594 ######
 595
 596 # Configure all of the various header file fragments LLVM uses which depend on
 597 # configuration variables.
 598 set(LLVM_ENUM_TARGETS "")
 599 set(LLVM_ENUM_ASM_PRINTERS "")
 600 set(LLVM_ENUM_ASM_PARSERS "")
 601 set(LLVM_ENUM_DISASSEMBLERS "")
 602 foreach(t ${LLVM_TARGETS_TO_BUILD})
 603   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 604
 605   list(FIND LLVM_ALL_TARGETS ${t} idx)
 606   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 607   if( idx LESS 0 AND idy LESS 0 )
 608     message(FATAL_ERROR "The target `${t}' does not exist.
 609     It should be one of\n${LLVM_ALL_TARGETS}")
 610   else()
 611     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 612   endif()
 613
 614   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 615   if( asmp_file )
 616     set(LLVM_ENUM_ASM_PRINTERS
 617       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 618   endif()
 619   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 620     set(LLVM_ENUM_ASM_PARSERS
 621       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 622   endif()
 623   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 624     set(LLVM_ENUM_DISASSEMBLERS
 625       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 626   endif()
 627 endforeach(t)
 628
 629 # Produce the target definition files, which provide a way for clients to easily
 630 # include various classes of targets.
 631 configure_file(
 632   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 633   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 634   )
 635 configure_file(
 636   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 637   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 638   )
 639 configure_file(
 640   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 641   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 642   )
 643 configure_file(
 644   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 645   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 646   )
 647
 648 # Configure the three LLVM configuration header files.
 649 configure_file(
 650   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 651   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 652 configure_file(
 653   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 654   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 655 configure_file(
 656   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 657   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 658
 659 # They are not referenced. See set_output_directory().
 660 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 661 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 662 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 663
 664 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 665 if (APPLE)
 666   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 667   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 668 else(UNIX)
 669   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 670     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 671     if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 672       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 673       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 674     endif()
 675   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 676 endif()
 677
 678 if(APPLE AND DARWIN_LTO_LIBRARY)
 679   set(CMAKE_EXE_LINKER_FLAGS
 680     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 681   set(CMAKE_SHARED_LINKER_FLAGS
 682     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 683   set(CMAKE_MODULE_LINKER_FLAGS
 684     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 685 endif()
 686
 687 # Work around a broken bfd ld behavior. When linking a binary with a
 688 # foo.so library, it will try to find any library that foo.so uses and
 689 # check its symbols. This is wasteful (the check was done when foo.so
 690 # was created) and can fail since it is not the dynamic linker and
 691 # doesn't know how to handle search paths correctly.
 692 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 693   set(CMAKE_EXE_LINKER_FLAGS
 694       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 695 endif()
 696
 697 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 698
 699 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 700
 701 # when crosscompiling import the executable targets from a file
 702 if(LLVM_USE_HOST_TOOLS)
 703   include(CrossCompile)
 704 endif(LLVM_USE_HOST_TOOLS)
 705 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 706 # Dummy use to avoid CMake Wraning: Manually-specified variables were not used
 707 # (this is a variable that CrossCompile sets on recursive invocations)
 708 endif()
 709
 710 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 711   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 712   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 713   include_directories("/usr/local/include")
 714   link_directories("/usr/local/lib")
 715 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 716
 717 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 718    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 719 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 720
 721 # Make sure we don't get -rdynamic in every binary. For those that need it,
 722 # use export_executable_symbols(target).
 723 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 724
 725 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 726   "Profiling data file to use when compiling in order to improve runtime performance.")
 727
 728 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 729   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 730     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 731   else()
 732     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 733   endif()
 734 endif()
 735
 736 include(AddLLVM)
 737 include(TableGen)
 738
 739 if( MINGW )
 740   # People report that -O3 is unreliable on MinGW. The traditional
 741   # build also uses -O2 for that reason:
 742   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 743 endif()
 744
 745 # Put this before tblgen. Else we have a circular dependence.
 746 add_subdirectory(lib/Demangle)
 747 add_subdirectory(lib/Support)
 748 add_subdirectory(lib/TableGen)
 749
 750 add_subdirectory(utils/TableGen)
 751
 752 # Force target to be built as soon as possible. Clang modules builds depend
 753 # header-wise on it as they ship all headers from the umbrella folders. Building
 754 # an entire module might include header, which depends on intrinsics_gen. This
 755 # should be right after LLVMSupport and LLVMTableGen otherwise we introduce a
 756 # circular dependence.
 757 if (LLVM_ENABLE_MODULES)
 758   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 759 endif(LLVM_ENABLE_MODULES)
 760
 761 add_subdirectory(include/llvm)
 762
 763 add_subdirectory(lib)
 764
 765 if( LLVM_INCLUDE_UTILS )
 766   add_subdirectory(utils/FileCheck)
 767   add_subdirectory(utils/PerfectShuffle)
 768   add_subdirectory(utils/count)
 769   add_subdirectory(utils/not)
 770   add_subdirectory(utils/llvm-lit)
 771   add_subdirectory(utils/yaml-bench)
 772   add_subdirectory(utils/unittest)
 773 else()
 774   if ( LLVM_INCLUDE_TESTS )
 775     message(FATAL_ERROR "Including tests when not building utils will not work.
 776     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 777   endif()
 778 endif()
 779
 780 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 781 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 782   add_subdirectory(utils/LLVMVisualizers)
 783 endif()
 784
 785 foreach( binding ${LLVM_BINDINGS_LIST} )
 786   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 787     add_subdirectory(bindings/${binding})
 788   endif()
 789 endforeach()
 790
 791 add_subdirectory(projects)
 792
 793 if( LLVM_INCLUDE_TOOLS )
 794   add_subdirectory(tools)
 795 endif()
 796
 797 add_subdirectory(runtimes)
 798
 799 if( LLVM_INCLUDE_EXAMPLES )
 800   add_subdirectory(examples)
 801 endif()
 802
 803 if( LLVM_INCLUDE_TESTS )
 804   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 805     include(LLVMExternalProjectUtils)
 806     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 807       USE_TOOLCHAIN
 808       EXCLUDE_FROM_ALL
 809       NO_INSTALL
 810       ALWAYS_CLEAN)
 811   endif()
 812   add_subdirectory(test)
 813   add_subdirectory(unittests)
 814   if (MSVC)
 815     # This utility is used to prevent crashing tests from calling Dr. Watson on
 816     # Windows.
 817     add_subdirectory(utils/KillTheDoctor)
 818   endif()
 819
 820   # Add a global check rule now that all subdirectories have been traversed
 821   # and we know the total set of lit testsuites.
 822   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 823   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 824   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 825   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 826   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 827                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 828   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 829                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 830   add_lit_target(check-all
 831     "Running all regression tests"
 832     ${LLVM_LIT_TESTSUITES}
 833     PARAMS ${LLVM_LIT_PARAMS}
 834     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 835     ARGS ${LLVM_LIT_EXTRA_ARGS}
 836     )
 837   if(TARGET check-runtimes)
 838     add_dependencies(check-all check-runtimes)
 839   endif()
 840   add_custom_target(test-depends
 841                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 842   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 843 endif()
 844
 845 if (LLVM_INCLUDE_DOCS)
 846   add_subdirectory(docs)
 847 endif()
 848
 849 add_subdirectory(cmake/modules)
 850
 851 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 852   install(DIRECTORY include/llvm include/llvm-c
 853     DESTINATION include
 854     COMPONENT llvm-headers
 855     FILES_MATCHING
 856     PATTERN "*.def"
 857     PATTERN "*.h"
 858     PATTERN "*.td"
 859     PATTERN "*.inc"
 860     PATTERN "LICENSE.TXT"
 861     PATTERN ".svn" EXCLUDE
 862     )
 863
 864   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 865     DESTINATION include
 866     COMPONENT llvm-headers
 867     FILES_MATCHING
 868     PATTERN "*.def"
 869     PATTERN "*.h"
 870     PATTERN "*.gen"
 871     PATTERN "*.inc"
 872     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 873     PATTERN "CMakeFiles" EXCLUDE
 874     PATTERN "config.h" EXCLUDE
 875     PATTERN ".svn" EXCLUDE
 876     )
 877
 878   if (NOT CMAKE_CONFIGURATION_TYPES)
 879     add_custom_target(installhdrs
 880                       DEPENDS ${name}
 881                       COMMAND "${CMAKE_COMMAND}"
 882                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 883                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 884   endif()
 885 endif()
 886
 887 # This must be at the end of the LLVM root CMakeLists file because it must run
 888 # after all targets are created.
 889 if(LLVM_DISTRIBUTION_COMPONENTS)
 890   if(CMAKE_CONFIGURATION_TYPES)
 891     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 892   endif()
 893
 894   add_custom_target(distribution)
 895   add_custom_target(install-distribution)
 896   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
 897     if(TARGET ${target})
 898       add_dependencies(distribution ${target})
 899     else()
 900       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have a target")
 901     endif()
 902
 903     if(TARGET install-${target})
 904       add_dependencies(install-distribution install-${target})
 905     else()
 906       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have an install target")
 907     endif()
 908   endforeach()
 909 endif()