CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(POLICY CMP0077)
  15   cmake_policy(SET CMP0077 NEW)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 10)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  37   message(WARNING "Visual Studio generators use the x86 host compiler by "
  38                   "default, even for 64-bit targets. This can result in linker "
  39                   "instability and out of memory errors. To use the 64-bit "
  40                   "host compiler, pass -Thost=x64 on the CMake command line.")
  41 endif()
  42
  43 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  44   # Some CMake features like object libraries get confused if you don't
  45   # explicitly specify an architecture setting with the Xcode generator.
  46   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  47 endif()
  48
  49 project(LLVM
  50   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  51   LANGUAGES C CXX ASM)
  52
  53 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  54   message(STATUS "No build type selected, default to Debug")
  55   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  56 endif()
  57
  58 # Side-by-side subprojects layout: automatically set the
  59 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
  60 # This allows an easy way of setting up a build directory for llvm and another
  61 # one for llvm+clang+... using the same sources.
  62 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
  63 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
  64         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
  65 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
  66   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
  67 endif()
  68
  69 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
  70 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
  71 # several reasons:
  72 #
  73 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
  74 # source of truth for which projects to build. This means we will ignore user
  75 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
  76 # them.
  77 #
  78 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
  79 # non-empty list but now the user wishes to disable building all other projects
  80 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
  81 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
  82 # building all the projects that were previously enabled.
  83 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
  84 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
  85
  86 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
  87   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
  88   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
  89     string(TOUPPER "${proj}" upper_proj)
  90     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
  91     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
  92       message(STATUS "${proj} project is enabled")
  93       set(SHOULD_ENABLE_PROJECT TRUE)
  94       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
  95       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
  96         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
  97       endif()
  98       if( LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR STREQUAL "" )
  99         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "" FORCE)
 100       else()
 101         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "")
 102       endif()
 103     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 104       message(STATUS "${proj} project is enabled")
 105       set(SHOULD_ENABLE_PROJECT TRUE)
 106     else()
 107       message(STATUS "${proj} project is disabled")
 108       set(SHOULD_ENABLE_PROJECT FALSE)
 109     endif()
 110     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 111     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 112     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 113     # we should deprecate allowing users to set these variables by turning them
 114     # into normal CMake variables rather than cache variables.
 115     set(LLVM_TOOL_${upper_proj}_BUILD
 116       ${SHOULD_ENABLE_PROJECT}
 117       CACHE
 118       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 119     )
 120   endforeach()
 121 endif()
 122 unset(SHOULD_ENABLE_PROJECT)
 123
 124 # Build llvm with ccache if the package is present
 125 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 126 if(LLVM_CCACHE_BUILD)
 127   find_program(CCACHE_PROGRAM ccache)
 128   if(CCACHE_PROGRAM)
 129       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 130       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 131       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 132           CACHE STRING "Parameters to pass through to ccache")
 133
 134       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 135       if (LLVM_CCACHE_MAXSIZE)
 136         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 137       endif()
 138       if (LLVM_CCACHE_DIR)
 139         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 140       endif()
 141       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 142   else()
 143     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 144   endif()
 145 endif()
 146
 147 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 148
 149 # Some features of the LLVM build may be disallowed when dependency debugging is
 150 # enabled. In particular you cannot use ccache because we want to force compile
 151 # operations to always happen.
 152 if(LLVM_DEPENDENCY_DEBUGGING)
 153   if(NOT CMAKE_HOST_APPLE)
 154     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 155   endif()
 156   if(LLVM_CCACHE_BUILD)
 157     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 158   endif()
 159 endif()
 160
 161 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 162 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 163 if(LLVM_ENABLE_GISEL_COV)
 164   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 165 endif()
 166
 167 # Add path for custom modules
 168 set(CMAKE_MODULE_PATH
 169   ${CMAKE_MODULE_PATH}
 170   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 171   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 172   )
 173
 174 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 175 # for use by clang_complete, YouCompleteMe, etc.
 176 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 177
 178 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 179   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 180
 181 option(LLVM_INSTALL_CCTOOLS_SYMLINKS
 182   "Install symlinks from the cctools tool names to the corresponding LLVM tools." OFF)
 183
 184 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 185
 186 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 187
 188 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 189 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 190 # the installation by default. See llvm.org/PR31905.
 191 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 192
 193 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 194 if ( LLVM_USE_FOLDERS )
 195   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 196 endif()
 197
 198 include(VersionFromVCS)
 199
 200 option(LLVM_APPEND_VC_REV
 201   "Embed the version control system revision in LLVM" ON)
 202
 203 set(PACKAGE_NAME LLVM)
 204 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 205 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 206
 207 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 208   "Default URL where bug reports are to be submitted.")
 209
 210 # Configure CPack.
 211 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 212 set(CPACK_PACKAGE_VENDOR "LLVM")
 213 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 214 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 215 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 216 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 217 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 218 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 219 if(WIN32 AND NOT UNIX)
 220   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 221   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 222   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 223   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 224   set(CPACK_NSIS_MODIFY_PATH "ON")
 225   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 226   if( CMAKE_CL_64 )
 227     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 228   endif()
 229 endif()
 230 include(CPack)
 231
 232 # Sanity check our source directory to make sure that we are not trying to
 233 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 234 # sure that we don't have any stray generated files lying around in the tree
 235 # (which would end up getting picked up by header search, instead of the correct
 236 # versions).
 237 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 238   message(FATAL_ERROR "In-source builds are not allowed.
 239 Please create a directory and run cmake from there, passing the path
 240 to this source directory as the last argument.
 241 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 242 Please delete them.")
 243 endif()
 244
 245 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 246
 247 if (CMAKE_BUILD_TYPE AND
 248     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 249   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 250 endif()
 251
 252 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 253
 254 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 255 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 256
 257 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 258     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 259 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 260
 261 # They are used as destination of target generators.
 262 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 263 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 264 if(WIN32 OR CYGWIN)
 265   # DLL platform -- put DLLs into bin.
 266   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 267 else()
 268   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 269 endif()
 270
 271 # Each of them corresponds to llvm-config's.
 272 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 273 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 274 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 275 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 276 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 277
 278 # Note: LLVM_CMAKE_PATH does not include generated files
 279 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 280 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 281 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 282
 283 # List of all targets to be built by default:
 284 set(LLVM_ALL_TARGETS
 285   AArch64
 286   AMDGPU
 287   ARM
 288   BPF
 289   Hexagon
 290   Lanai
 291   Mips
 292   MSP430
 293   NVPTX
 294   PowerPC
 295   RISCV
 296   Sparc
 297   SystemZ
 298   WebAssembly
 299   X86
 300   XCore
 301   )
 302
 303 # List of targets with JIT support:
 304 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 305
 306 set(LLVM_TARGETS_TO_BUILD "all"
 307     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 308
 309 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 310   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 311
 312 option(BUILD_SHARED_LIBS
 313   "Build all libraries as shared libraries instead of static" OFF)
 314
 315 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 316 if(LLVM_ENABLE_BACKTRACES)
 317   set(ENABLE_BACKTRACES 1)
 318 endif()
 319
 320 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 321
 322 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 323 if(LLVM_ENABLE_CRASH_OVERRIDES)
 324   set(ENABLE_CRASH_OVERRIDES 1)
 325 endif()
 326
 327 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 328
 329 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 330 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 331 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 332
 333 set(LLVM_TARGET_ARCH "host"
 334   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 335
 336 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 337
 338 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 339
 340 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 341
 342 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 343
 344 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 345
 346 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 347
 348 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 349
 350 find_package(Z3 4.7.1)
 351
 352 if (LLVM_Z3_INSTALL_DIR)
 353   if (NOT Z3_FOUND)
 354     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 355   endif()
 356 endif()
 357
 358 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 359
 360 option(LLVM_ENABLE_Z3_SOLVER
 361   "Enable Support for the Z3 constraint solver in LLVM."
 362   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 363 )
 364
 365 if (LLVM_ENABLE_Z3_SOLVER)
 366   if (NOT Z3_FOUND)
 367     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 368   endif()
 369
 370   set(LLVM_WITH_Z3 1)
 371 endif()
 372
 373 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 374   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 375 endif()
 376
 377 set(LLVM_TARGETS_TO_BUILD
 378    ${LLVM_TARGETS_TO_BUILD}
 379    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 380 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 381
 382 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 383 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 384 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 385 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 386   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 387   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 388 else()
 389   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 390   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 391 endif()
 392 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 393 option(LLVM_STATIC_LINK_CXX_STDLIB "Statically link the standard library." OFF)
 394 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 395 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 396 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 397
 398 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 399
 400 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 401   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 402 else()
 403   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 404 endif()
 405
 406 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 407
 408 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 409   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 410
 411 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 412        "Set to ON to force using an old, unsupported host toolchain." OFF)
 413
 414 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 415        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 416
 417 option(LLVM_USE_INTEL_JITEVENTS
 418   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 419   OFF)
 420
 421 if( LLVM_USE_INTEL_JITEVENTS )
 422   # Verify we are on a supported platform
 423   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 424     message(FATAL_ERROR
 425       "Intel JIT API support is available on Linux and Windows only.")
 426   endif()
 427 endif( LLVM_USE_INTEL_JITEVENTS )
 428
 429 option(LLVM_USE_OPROFILE
 430   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 431
 432 option(LLVM_EXTERNALIZE_DEBUGINFO
 433   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 434
 435 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 436   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 437
 438 # If enabled, verify we are on a platform that supports oprofile.
 439 if( LLVM_USE_OPROFILE )
 440   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 441     message(FATAL_ERROR "OProfile support is available on Linux only.")
 442   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 443 endif( LLVM_USE_OPROFILE )
 444
 445 option(LLVM_USE_PERF
 446   "Use perf JIT interface to inform perf about JIT code" OFF)
 447
 448 # If enabled, verify we are on a platform that supports perf.
 449 if( LLVM_USE_PERF )
 450   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 451     message(FATAL_ERROR "perf support is available on Linux only.")
 452   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 453 endif( LLVM_USE_PERF )
 454
 455 set(LLVM_USE_SANITIZER "" CACHE STRING
 456   "Define the sanitizer used to build binaries and tests.")
 457 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 458 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 459   "Path to fuzzing library for linking with fuzz targets")
 460
 461 option(LLVM_USE_SPLIT_DWARF
 462   "Use -gsplit-dwarf when compiling llvm." OFF)
 463
 464 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 465 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 466
 467 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 468   set(POLLY_IN_TREE TRUE)
 469 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 470   set(POLLY_IN_TREE TRUE)
 471 else()
 472   set(POLLY_IN_TREE FALSE)
 473 endif()
 474
 475 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 476   set(WITH_POLLY ON)
 477 else()
 478   set(WITH_POLLY OFF)
 479 endif()
 480
 481 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 482   set(LINK_POLLY_INTO_TOOLS ON)
 483 else()
 484   set(LINK_POLLY_INTO_TOOLS OFF)
 485 endif()
 486
 487 # Define an option controlling whether we should build for 32-bit on 64-bit
 488 # platforms, where supported.
 489 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 490   # TODO: support other platforms and toolchains.
 491   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 492 endif()
 493
 494 # Define the default arguments to use with 'lit', and an option for the user to
 495 # override.
 496 set(LIT_ARGS_DEFAULT "-sv")
 497 if (MSVC_IDE OR XCODE)
 498   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 499 endif()
 500 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 501
 502 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 503 if( WIN32 AND NOT CYGWIN )
 504   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 505 endif()
 506
 507 # Define options to control the inclusion and default build behavior for
 508 # components which may not strictly be necessary (tools, examples, and tests).
 509 #
 510 # This is primarily to support building smaller or faster project files.
 511 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 512 option(LLVM_BUILD_TOOLS
 513   "Build the LLVM tools. If OFF, just generate build targets." ON)
 514
 515 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 516 option(LLVM_BUILD_UTILS
 517   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 518
 519 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 520 option(LLVM_BUILD_RUNTIMES
 521   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 522
 523 option(LLVM_BUILD_RUNTIME
 524   "Build the LLVM runtime libraries." ON)
 525 option(LLVM_BUILD_EXAMPLES
 526   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 527 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 528
 529 option(LLVM_BUILD_TESTS
 530   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 531 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 532 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 533
 534 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 535 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 536 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 537
 538 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 539 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 540 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 541 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 542 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 543 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 544
 545 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 546     CACHE STRING "Doxygen-generated HTML documentation install directory")
 547 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 548     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 549
 550 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 551   "Build compiler-rt as an external project." OFF)
 552
 553 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 554   "Show target and host info when tools are invoked with --version." ON)
 555
 556 # You can configure which libraries from LLVM you want to include in the
 557 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 558 # list of LLVM components. All component names handled by llvm-config are valid.
 559 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 560   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 561     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 562 endif()
 563 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 564 if(MSVC)
 565   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 566 else()
 567   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 568 endif()
 569 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 570 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 571   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 572 endif()
 573 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 574
 575 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 576 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 577   set(LLVM_USE_HOST_TOOLS ON)
 578 endif()
 579
 580 if (MSVC_IDE)
 581   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 582 endif()
 583
 584 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 585     LLVM_ENABLE_IR_PGO)
 586   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 587     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 588     # for spining disks. Anything higher may only help on slower mediums.
 589     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 590   endif()
 591   if(NOT LLVM_PROFILE_FILE_PATTERN)
 592     if(NOT LLVM_PROFILE_DATA_DIR)
 593       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 594     endif()
 595                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 596   endif()
 597   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 598     if(NOT LLVM_CSPROFILE_DATA_DIR)
 599       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 600     endif()
 601     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 602   endif()
 603 endif()
 604
 605 if (LLVM_BUILD_STATIC)
 606   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 607 endif()
 608
 609 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 610 if(CMAKE_HOST_APPLE AND APPLE)
 611   include(UseLibtool)
 612 endif()
 613
 614 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 615 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 616 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 617
 618 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 619   "Enable per-target runtimes directory")
 620
 621 # All options referred to from HandleLLVMOptions have to be specified
 622 # BEFORE this include, otherwise options will not be correctly set on
 623 # first cmake run
 624 include(config-ix)
 625
 626 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 627   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 628 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 629
 630 # By default, we target the host, but this can be overridden at CMake
 631 # invocation time.
 632 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 633   "Default target for which LLVM will generate code." )
 634 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 635 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 636 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 637
 638 if(WIN32 OR CYGWIN)
 639   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 640     set(LLVM_ENABLE_PLUGINS_default ON)
 641   else()
 642     set(LLVM_ENABLE_PLUGINS_default OFF)
 643   endif()
 644 else()
 645   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 646 endif()
 647 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 648
 649 include(HandleLLVMOptions)
 650
 651 include(FindPythonInterp)
 652 if( NOT PYTHONINTERP_FOUND )
 653   message(FATAL_ERROR
 654 "Unable to find Python interpreter, required for builds and testing.
 655
 656 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 657 endif()
 658
 659 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 660   message(FATAL_ERROR "Python 2.7 or newer is required")
 661 endif()
 662
 663 ######
 664 # LLVMBuild Integration
 665 #
 666 # We use llvm-build to generate all the data required by the CMake based
 667 # build system in one swoop:
 668 #
 669 #  - We generate a file (a CMake fragment) in the object root which contains
 670 #    all the definitions that are required by CMake.
 671 #
 672 #  - We generate the library table used by llvm-config.
 673 #
 674 #  - We generate the dependencies for the CMake fragment, so that we will
 675 #    automatically reconfigure ourselves.
 676
 677 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 678 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 679   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 680 set(LLVMBUILDCMAKEFRAG
 681   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 682
 683 # Create the list of optional components that are enabled
 684 if (LLVM_USE_INTEL_JITEVENTS)
 685   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 686 endif (LLVM_USE_INTEL_JITEVENTS)
 687 if (LLVM_USE_OPROFILE)
 688   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 689 endif (LLVM_USE_OPROFILE)
 690 if (LLVM_USE_PERF)
 691   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 692 endif (LLVM_USE_PERF)
 693
 694 message(STATUS "Constructing LLVMBuild project information")
 695 execute_process(
 696   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 697             --native-target "${LLVM_NATIVE_ARCH}"
 698             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 699             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 700             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 701             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 702             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 703             ERROR_VARIABLE LLVMBUILDERRORS
 704             OUTPUT_STRIP_TRAILING_WHITESPACE
 705             ERROR_STRIP_TRAILING_WHITESPACE
 706   RESULT_VARIABLE LLVMBUILDRESULT)
 707
 708 # On Win32, CMake doesn't properly handle piping the default output/error
 709 # streams into the GUI console. So, we explicitly catch and report them.
 710 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 711   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 712 endif()
 713 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 714   message(FATAL_ERROR
 715     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 716 endif()
 717
 718 # Include the generated CMake fragment. This will define properties from the
 719 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 720 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 721 # files change.
 722 include(${LLVMBUILDCMAKEFRAG})
 723
 724 ######
 725
 726 # Configure all of the various header file fragments LLVM uses which depend on
 727 # configuration variables.
 728 set(LLVM_ENUM_TARGETS "")
 729 set(LLVM_ENUM_ASM_PRINTERS "")
 730 set(LLVM_ENUM_ASM_PARSERS "")
 731 set(LLVM_ENUM_DISASSEMBLERS "")
 732 foreach(t ${LLVM_TARGETS_TO_BUILD})
 733   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 734
 735   list(FIND LLVM_ALL_TARGETS ${t} idx)
 736   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 737   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 738   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 739   # this test just makes sure that any experimental targets were passed via
 740   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 741   if( idx LESS 0 AND idy LESS 0 )
 742     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 743       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 744   else()
 745     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 746   endif()
 747
 748   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 749   if( asmp_file )
 750     set(LLVM_ENUM_ASM_PRINTERS
 751       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 752   endif()
 753   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 754     set(LLVM_ENUM_ASM_PARSERS
 755       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 756   endif()
 757   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 758     set(LLVM_ENUM_DISASSEMBLERS
 759       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 760   endif()
 761 endforeach(t)
 762
 763 # Produce the target definition files, which provide a way for clients to easily
 764 # include various classes of targets.
 765 configure_file(
 766   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 767   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 768   )
 769 configure_file(
 770   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 771   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 772   )
 773 configure_file(
 774   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 775   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 776   )
 777 configure_file(
 778   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 779   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 780   )
 781
 782 # Configure the three LLVM configuration header files.
 783 configure_file(
 784   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 785   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 786 configure_file(
 787   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 788   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 789 configure_file(
 790   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 791   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 792
 793 # Add target for generating source rpm package.
 794 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 795     CACHE FILEPATH ".spec file to use for srpm generation")
 796 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 797 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 798
 799 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 800 string(LENGTH "${revision}" revision_length)
 801 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 802   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 803 else()
 804   set(LLVM_RPM_SPEC_REVISION "${revision}")
 805 endif()
 806
 807 configure_file(
 808   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 809   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 810
 811 add_custom_target(srpm
 812   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 813   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 814 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 815
 816
 817 # They are not referenced. See set_output_directory().
 818 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 819 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 820 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 821
 822 if(APPLE AND DARWIN_LTO_LIBRARY)
 823   set(CMAKE_EXE_LINKER_FLAGS
 824     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 825   set(CMAKE_SHARED_LINKER_FLAGS
 826     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 827   set(CMAKE_MODULE_LINKER_FLAGS
 828     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 829 endif()
 830
 831 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
 832 # break things. In this case we need to enable the large-file API as well.
 833 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 834           add_definitions("-D_XOPEN_SOURCE=700")
 835           add_definitions("-D_LARGE_FILE_API")
 836 endif()
 837
 838 # Build with _FILE_OFFSET_BITS=64 on Solaris to match g++ >= 9.
 839 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 840           add_definitions("-D_FILE_OFFSET_BITS=64")
 841 endif()
 842
 843 # Work around a broken bfd ld behavior. When linking a binary with a
 844 # foo.so library, it will try to find any library that foo.so uses and
 845 # check its symbols. This is wasteful (the check was done when foo.so
 846 # was created) and can fail since it is not the dynamic linker and
 847 # doesn't know how to handle search paths correctly.
 848 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 849   set(CMAKE_EXE_LINKER_FLAGS
 850       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 851 endif()
 852
 853 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 854
 855 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 856
 857 # when crosscompiling import the executable targets from a file
 858 if(LLVM_USE_HOST_TOOLS)
 859   include(CrossCompile)
 860   llvm_create_cross_target(LLVM NATIVE "" Release)
 861 endif(LLVM_USE_HOST_TOOLS)
 862 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 863 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 864 # (this is a variable that CrossCompile sets on recursive invocations)
 865 endif()
 866
 867 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 868   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 869   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 870   include_directories(SYSTEM "/usr/local/include")
 871   link_directories("/usr/local/lib")
 872 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 873
 874 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 875    # special hack for Solaris to handle crazy system sys/regset.h
 876    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 877 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 878
 879 # Make sure we don't get -rdynamic in every binary. For those that need it,
 880 # use export_executable_symbols(target).
 881 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 882
 883 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 884   "Profiling data file to use when compiling in order to improve runtime performance.")
 885
 886 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 887   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 888     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 889   else()
 890     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 891   endif()
 892 endif()
 893
 894 include(AddLLVM)
 895 include(TableGen)
 896
 897 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 898   # People report that -O3 is unreliable on MinGW. The traditional
 899   # build also uses -O2 for that reason:
 900   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 901 endif()
 902
 903 # Put this before tblgen. Else we have a circular dependence.
 904 add_subdirectory(lib/Demangle)
 905 add_subdirectory(lib/Support)
 906 add_subdirectory(lib/TableGen)
 907
 908 add_subdirectory(utils/TableGen)
 909
 910 add_subdirectory(include/llvm)
 911
 912 add_subdirectory(lib)
 913
 914 if( LLVM_INCLUDE_UTILS )
 915   add_subdirectory(utils/FileCheck)
 916   add_subdirectory(utils/PerfectShuffle)
 917   add_subdirectory(utils/count)
 918   add_subdirectory(utils/not)
 919   add_subdirectory(utils/yaml-bench)
 920 else()
 921   if ( LLVM_INCLUDE_TESTS )
 922     message(FATAL_ERROR "Including tests when not building utils will not work.
 923     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 924   endif()
 925 endif()
 926
 927 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 928 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 929   add_subdirectory(utils/LLVMVisualizers)
 930 endif()
 931
 932 foreach( binding ${LLVM_BINDINGS_LIST} )
 933   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 934     add_subdirectory(bindings/${binding})
 935   endif()
 936 endforeach()
 937
 938 add_subdirectory(projects)
 939
 940 if( LLVM_INCLUDE_TOOLS )
 941   add_subdirectory(tools)
 942 endif()
 943
 944 if( LLVM_INCLUDE_RUNTIMES )
 945   add_subdirectory(runtimes)
 946 endif()
 947
 948 if( LLVM_INCLUDE_EXAMPLES )
 949   add_subdirectory(examples)
 950 endif()
 951
 952 if( LLVM_INCLUDE_TESTS )
 953   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 954     include(LLVMExternalProjectUtils)
 955     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 956       USE_TOOLCHAIN
 957       EXCLUDE_FROM_ALL
 958       NO_INSTALL
 959       ALWAYS_CLEAN)
 960   endif()
 961   add_subdirectory(utils/lit)
 962   add_subdirectory(test)
 963   add_subdirectory(unittests)
 964   if( LLVM_INCLUDE_UTILS )
 965     add_subdirectory(utils/unittest)
 966   endif()
 967
 968   if (WIN32)
 969     # This utility is used to prevent crashing tests from calling Dr. Watson on
 970     # Windows.
 971     add_subdirectory(utils/KillTheDoctor)
 972   endif()
 973
 974   # Add a global check rule now that all subdirectories have been traversed
 975   # and we know the total set of lit testsuites.
 976   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 977   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 978   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 979   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 980   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 981                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 982   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 983                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 984   add_lit_target(check-all
 985     "Running all regression tests"
 986     ${LLVM_LIT_TESTSUITES}
 987     PARAMS ${LLVM_LIT_PARAMS}
 988     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 989     ARGS ${LLVM_LIT_EXTRA_ARGS}
 990     )
 991   if(TARGET check-runtimes)
 992     add_dependencies(check-all check-runtimes)
 993   endif()
 994   add_custom_target(test-depends
 995                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 996   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 997 endif()
 998
 999 if (LLVM_INCLUDE_DOCS)
1000   add_subdirectory(docs)
1001 endif()
1002
1003 add_subdirectory(cmake/modules)
1004
1005 # Do this last so that all lit targets have already been created.
1006 if (LLVM_INCLUDE_UTILS)
1007   add_subdirectory(utils/llvm-lit)
1008 endif()
1009
1010 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1011   install(DIRECTORY include/llvm include/llvm-c
1012     DESTINATION include
1013     COMPONENT llvm-headers
1014     FILES_MATCHING
1015     PATTERN "*.def"
1016     PATTERN "*.h"
1017     PATTERN "*.td"
1018     PATTERN "*.inc"
1019     PATTERN "LICENSE.TXT"
1020     PATTERN ".svn" EXCLUDE
1021     )
1022
1023   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1024     DESTINATION include
1025     COMPONENT llvm-headers
1026     FILES_MATCHING
1027     PATTERN "*.def"
1028     PATTERN "*.h"
1029     PATTERN "*.gen"
1030     PATTERN "*.inc"
1031     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1032     PATTERN "CMakeFiles" EXCLUDE
1033     PATTERN "config.h" EXCLUDE
1034     PATTERN ".svn" EXCLUDE
1035     )
1036
1037   if (LLVM_INSTALL_MODULEMAPS)
1038     install(DIRECTORY include/llvm include/llvm-c
1039             DESTINATION include
1040             COMPONENT llvm-headers
1041             FILES_MATCHING
1042             PATTERN "module.modulemap"
1043             )
1044     install(FILES include/llvm/module.install.modulemap
1045             DESTINATION include/llvm
1046             COMPONENT llvm-headers
1047             RENAME "module.extern.modulemap"
1048             )
1049   endif(LLVM_INSTALL_MODULEMAPS)
1050
1051   # Installing the headers needs to depend on generating any public
1052   # tablegen'd headers.
1053   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1054   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1055
1056   if (NOT LLVM_ENABLE_IDE)
1057     add_llvm_install_targets(install-llvm-headers
1058                              DEPENDS llvm-headers
1059                              COMPONENT llvm-headers)
1060   endif()
1061
1062   # Custom target to install all libraries.
1063   add_custom_target(llvm-libraries)
1064   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1065
1066   if (NOT LLVM_ENABLE_IDE)
1067     add_llvm_install_targets(install-llvm-libraries
1068                              DEPENDS llvm-libraries
1069                              COMPONENT llvm-libraries)
1070   endif()
1071
1072   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1073   if(LLVM_LIBS)
1074     list(REMOVE_DUPLICATES LLVM_LIBS)
1075     foreach(lib ${LLVM_LIBS})
1076       add_dependencies(llvm-libraries ${lib})
1077       if (NOT LLVM_ENABLE_IDE)
1078         add_dependencies(install-llvm-libraries install-${lib})
1079       endif()
1080     endforeach()
1081   endif()
1082 endif()
1083
1084 # This must be at the end of the LLVM root CMakeLists file because it must run
1085 # after all targets are created.
1086 include(LLVMDistributionSupport)
1087 llvm_distribution_add_targets()
1088
1089 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1090 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1091   include(InstallRequiredSystemLibraries)
1092 endif()
1093
1094 if (LLVM_INCLUDE_BENCHMARKS)
1095   # Override benchmark defaults so that when the library itself is updated these
1096   # modifications are not lost.
1097   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1098   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1099   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1100   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1101   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1102   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1103   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1104
1105   add_subdirectory(utils/benchmark)
1106   add_subdirectory(benchmarks)
1107 endif()