cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckStructHasMember)
  11 include(CheckCCompilerFlag)
  12
  13 include(CheckCompilerVersion)
  14 include(HandleLLVMStdlib)
  15
  16 if( UNIX AND NOT (BEOS OR HAIKU) )
  17   # Used by check_symbol_exists:
  18   list(APPEND CMAKE_REQUIRED_LIBRARIES "m")
  19 endif()
  20 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  21 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  22     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  23   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  24 endif()
  25
  26 # include checks
  27 check_include_file(dlfcn.h HAVE_DLFCN_H)
  28 check_include_file(errno.h HAVE_ERRNO_H)
  29 check_include_file(fcntl.h HAVE_FCNTL_H)
  30 check_include_file(link.h HAVE_LINK_H)
  31 check_include_file(malloc.h HAVE_MALLOC_H)
  32 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  33 if( NOT PURE_WINDOWS )
  34   check_include_file(pthread.h HAVE_PTHREAD_H)
  35 endif()
  36 check_include_file(signal.h HAVE_SIGNAL_H)
  37 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  38 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  39 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  40 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  41 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  42 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  43 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  44 check_include_file(termios.h HAVE_TERMIOS_H)
  45 check_include_file(unistd.h HAVE_UNISTD_H)
  46 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  47 check_include_file(zlib.h HAVE_ZLIB_H)
  48 check_include_file(fenv.h HAVE_FENV_H)
  49 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  50 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  51
  52 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  53 check_include_file(histedit.h HAVE_HISTEDIT_H)
  54 check_include_file(CrashReporterClient.h HAVE_CRASHREPORTERCLIENT_H)
  55 if(APPLE)
  56   include(CheckCSourceCompiles)
  57   CHECK_C_SOURCE_COMPILES("
  58      static const char *__crashreporter_info__ = 0;
  59      asm(\".desc ___crashreporter_info__, 0x10\");
  60      int main() { return 0; }"
  61     HAVE_CRASHREPORTER_INFO)
  62 endif()
  63
  64 if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  65   check_include_file(linux/magic.h HAVE_LINUX_MAGIC_H)
  66   if(NOT HAVE_LINUX_MAGIC_H)
  67     # older kernels use split files
  68     check_include_file(linux/nfs_fs.h HAVE_LINUX_NFS_FS_H)
  69     check_include_file(linux/smb.h HAVE_LINUX_SMB_H)
  70   endif()
  71 endif()
  72
  73 # library checks
  74 if( NOT PURE_WINDOWS )
  75   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  76   if (HAVE_LIBPTHREAD)
  77     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  78     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  79     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  80   else()
  81     # this could be Android
  82     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  83     if (PTHREAD_IN_LIBC)
  84       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  85       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  86       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  87     endif()
  88   endif()
  89   check_library_exists(dl dlopen "" HAVE_LIBDL)
  90   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
  91 endif()
  92
  93 # Check for libpfm.
  94 include(FindLibpfm)
  95
  96 if(HAVE_LIBPTHREAD)
  97   # We want to find pthreads library and at the moment we do want to
  98   # have it reported as '-l<lib>' instead of '-pthread'.
  99   # TODO: switch to -pthread once the rest of the build system can deal with it.
 100   set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 101   set(THREADS_HAVE_PTHREAD_ARG Off)
 102   find_package(Threads REQUIRED)
 103   set(LLVM_PTHREAD_LIB ${CMAKE_THREAD_LIBS_INIT})
 104 endif()
 105
 106 # Don't look for these libraries if we're using MSan, since uninstrumented third
 107 # party code may call MSan interceptors like strlen, leading to false positives.
 108 if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 109   set(HAVE_LIBZ 0)
 110   if(LLVM_ENABLE_ZLIB)
 111     foreach(library z zlib_static zlib)
 112       string(TOUPPER ${library} library_suffix)
 113       check_library_exists(${library} compress2 "" HAVE_LIBZ_${library_suffix})
 114       if(HAVE_LIBZ_${library_suffix})
 115         set(HAVE_LIBZ 1)
 116         set(ZLIB_LIBRARIES "${library}")
 117         break()
 118       endif()
 119     endforeach()
 120   endif()
 121
 122   # Don't look for these libraries on Windows.
 123   if (NOT PURE_WINDOWS)
 124     # Skip libedit if using ASan as it contains memory leaks.
 125     if (LLVM_ENABLE_LIBEDIT AND HAVE_HISTEDIT_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*")
 126       check_library_exists(edit el_init "" HAVE_LIBEDIT)
 127     else()
 128       set(HAVE_LIBEDIT 0)
 129     endif()
 130     if(LLVM_ENABLE_TERMINFO)
 131       set(HAVE_TERMINFO 0)
 132       foreach(library terminfo tinfo curses ncurses ncursesw)
 133         string(TOUPPER ${library} library_suffix)
 134         check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 135         if(HAVE_TERMINFO_${library_suffix})
 136           set(HAVE_TERMINFO 1)
 137           set(TERMINFO_LIBS "${library}")
 138           break()
 139         endif()
 140       endforeach()
 141     else()
 142       set(HAVE_TERMINFO 0)
 143     endif()
 144
 145     find_library(ICONV_LIBRARY_PATH NAMES iconv libiconv libiconv-2 c)
 146     set(LLVM_LIBXML2_ENABLED 0)
 147     set(LIBXML2_FOUND 0)
 148     if((LLVM_ENABLE_LIBXML2) AND ((CMAKE_SYSTEM_NAME MATCHES "Linux") AND (ICONV_LIBRARY_PATH) OR APPLE))
 149       find_package(LibXml2)
 150       if (LIBXML2_FOUND)
 151         set(LLVM_LIBXML2_ENABLED 1)
 152         if ((CMAKE_OSX_SYSROOT) AND (EXISTS ${CMAKE_OSX_SYSROOT}/${LIBXML2_INCLUDE_DIR}))
 153           include_directories(${CMAKE_OSX_SYSROOT}/${LIBXML2_INCLUDE_DIR})
 154         else()
 155           include_directories(${LIBXML2_INCLUDE_DIR})
 156         endif()
 157         set(LIBXML2_LIBS "xml2")
 158       endif()
 159     endif()
 160   endif()
 161 endif()
 162
 163 if (LLVM_ENABLE_LIBXML2 STREQUAL "FORCE_ON" AND NOT LLVM_LIBXML2_ENABLED)
 164   message(FATAL_ERROR "Failed to congifure libxml2")
 165 endif()
 166
 167 check_library_exists(xar xar_open "" HAVE_LIBXAR)
 168 if(HAVE_LIBXAR)
 169   set(XAR_LIB xar)
 170 endif()
 171
 172 # function checks
 173 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 174 find_package(Backtrace)
 175 set(HAVE_BACKTRACE ${Backtrace_FOUND})
 176 set(BACKTRACE_HEADER ${Backtrace_HEADER})
 177
 178 # Prevent check_symbol_exists from using API that is not supported for a given
 179 # deployment target.
 180 check_c_compiler_flag("-Werror=unguarded-availability-new" "C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW")
 181 if(C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW)
 182   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unguarded-availability-new")
 183 endif()
 184
 185 check_symbol_exists(_Unwind_Backtrace "unwind.h" HAVE__UNWIND_BACKTRACE)
 186 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 187 check_symbol_exists(sysconf unistd.h HAVE_SYSCONF)
 188 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 189 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 190 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 191 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 192 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 193 check_symbol_exists(posix_fallocate fcntl.h HAVE_POSIX_FALLOCATE)
 194 # AddressSanitizer conflicts with lib/Support/Unix/Signals.inc
 195 # Avoid sigaltstack on Apple platforms, where backtrace() cannot handle it
 196 # (rdar://7089625) and _Unwind_Backtrace is unusable because it cannot unwind
 197 # past the signal handler after an assertion failure (rdar://29866587).
 198 if( HAVE_SIGNAL_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*" AND NOT APPLE )
 199   check_symbol_exists(sigaltstack signal.h HAVE_SIGALTSTACK)
 200 endif()
 201 set(CMAKE_REQUIRED_DEFINITIONS "-D_LARGEFILE64_SOURCE")
 202 check_symbol_exists(lseek64 "sys/types.h;unistd.h" HAVE_LSEEK64)
 203 set(CMAKE_REQUIRED_DEFINITIONS "")
 204 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 205 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 206 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 207                     HAVE_MALLOC_ZONE_STATISTICS)
 208 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 209 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 210 check_symbol_exists(pread unistd.h HAVE_PREAD)
 211 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 212 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 213 check_symbol_exists(strerror string.h HAVE_STRERROR)
 214 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 215 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 216 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 217 if( PURE_WINDOWS )
 218   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 219
 220   check_function_exists(_alloca HAVE__ALLOCA)
 221   check_function_exists(__alloca HAVE___ALLOCA)
 222   check_function_exists(__chkstk HAVE___CHKSTK)
 223   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 224   check_function_exists(___chkstk HAVE____CHKSTK)
 225   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 226
 227   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 228   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 229   check_function_exists(__divdi3 HAVE___DIVDI3)
 230   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 231   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 232   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 233   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 234   check_function_exists(__moddi3 HAVE___MODDI3)
 235   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 236   check_function_exists(__umoddi3 HAVE___UMODDI3)
 237
 238   check_function_exists(__main HAVE___MAIN)
 239   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 240 endif()
 241 if( HAVE_DLFCN_H )
 242   if( HAVE_LIBDL )
 243     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 244   endif()
 245   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 246   check_symbol_exists(dladdr dlfcn.h HAVE_DLADDR)
 247   if( HAVE_LIBDL )
 248     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 249   endif()
 250 endif()
 251
 252 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec
 253     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC)
 254 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec
 255     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC)
 256
 257 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 258 if( LLVM_USING_GLIBC )
 259   add_definitions( -D_GNU_SOURCE )
 260   list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 261 endif()
 262 # This check requires _GNU_SOURCE
 263 check_symbol_exists(sched_getaffinity sched.h HAVE_SCHED_GETAFFINITY)
 264 check_symbol_exists(CPU_COUNT sched.h HAVE_CPU_COUNT)
 265 if (NOT PURE_WINDOWS)
 266   if (LLVM_PTHREAD_LIB)
 267     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 268   endif()
 269   check_symbol_exists(pthread_getname_np pthread.h HAVE_PTHREAD_GETNAME_NP)
 270   check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 271   if (LLVM_PTHREAD_LIB)
 272     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 273   endif()
 274 endif()
 275
 276 # available programs checks
 277 function(llvm_find_program name)
 278   string(TOUPPER ${name} NAME)
 279   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 280
 281   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 282   mark_as_advanced(LLVM_PATH_${NAME})
 283   if(LLVM_PATH_${NAME})
 284     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 285     mark_as_advanced(HAVE_${NAME})
 286   else(LLVM_PATH_${NAME})
 287     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 288   endif(LLVM_PATH_${NAME})
 289 endfunction()
 290
 291 if (LLVM_ENABLE_DOXYGEN)
 292   llvm_find_program(dot)
 293 endif ()
 294
 295 if( LLVM_ENABLE_FFI )
 296   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 297   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
 298     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 299     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 300   else()
 301     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 302     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
 303       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 304       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 305     endif()
 306   endif()
 307
 308   if( NOT FFI_HEADER )
 309     message(FATAL_ERROR "libffi includes are not found.")
 310   endif()
 311
 312   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 313   if( NOT FFI_LIBRARY_PATH )
 314     message(FATAL_ERROR "libffi is not found.")
 315   endif()
 316
 317   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 318   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 319   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 320   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 321   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 322 else()
 323   unset(HAVE_FFI_FFI_H CACHE)
 324   unset(HAVE_FFI_H CACHE)
 325   unset(HAVE_FFI_CALL CACHE)
 326 endif( LLVM_ENABLE_FFI )
 327
 328 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 329 include(CheckAtomic)
 330
 331 if( LLVM_ENABLE_PIC )
 332   set(ENABLE_PIC 1)
 333 else()
 334   set(ENABLE_PIC 0)
 335   check_cxx_compiler_flag("-fno-pie" SUPPORTS_NO_PIE_FLAG)
 336   if(SUPPORTS_NO_PIE_FLAG)
 337     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fno-pie")
 338   endif()
 339 endif()
 340
 341 check_cxx_compiler_flag("-Wvariadic-macros" SUPPORTS_VARIADIC_MACROS_FLAG)
 342 check_cxx_compiler_flag("-Wgnu-zero-variadic-macro-arguments"
 343                         SUPPORTS_GNU_ZERO_VARIADIC_MACRO_ARGUMENTS_FLAG)
 344
 345 set(USE_NO_MAYBE_UNINITIALIZED 0)
 346 set(USE_NO_UNINITIALIZED 0)
 347
 348 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 349 # false positives.
 350 if (CMAKE_COMPILER_IS_GNUCXX)
 351   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 352   if (HAS_MAYBE_UNINITIALIZED)
 353     set(USE_NO_MAYBE_UNINITIALIZED 1)
 354   else()
 355     # Only recent versions of gcc make the distinction between -Wuninitialized
 356     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 357     # turn off all uninitialized use warnings.
 358     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 359     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 360   endif()
 361 endif()
 362
 363 # By default, we target the host, but this can be overridden at CMake
 364 # invocation time.
 365 include(GetHostTriple)
 366 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 367
 368 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 369     "Host on which LLVM binaries will run")
 370
 371 # Determine the native architecture.
 372 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 373 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 374   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 375 endif ()
 376
 377 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 378   set(LLVM_NATIVE_ARCH X86)
 379 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 380   set(LLVM_NATIVE_ARCH X86)
 381 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 382   set(LLVM_NATIVE_ARCH X86)
 383 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 384   set(LLVM_NATIVE_ARCH X86)
 385 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 386   set(LLVM_NATIVE_ARCH Sparc)
 387 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 388   set(LLVM_NATIVE_ARCH PowerPC)
 389 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 390   set(LLVM_NATIVE_ARCH AArch64)
 391 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 392   set(LLVM_NATIVE_ARCH AArch64)
 393 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 394   set(LLVM_NATIVE_ARCH ARM)
 395 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 396   set(LLVM_NATIVE_ARCH Mips)
 397 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 398   set(LLVM_NATIVE_ARCH XCore)
 399 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 400   set(LLVM_NATIVE_ARCH MSP430)
 401 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 402   set(LLVM_NATIVE_ARCH Hexagon)
 403 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 404   set(LLVM_NATIVE_ARCH SystemZ)
 405 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
 406   set(LLVM_NATIVE_ARCH WebAssembly)
 407 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
 408   set(LLVM_NATIVE_ARCH WebAssembly)
 409 elseif (LLVM_NATIVE_ARCH MATCHES "riscv32")
 410   set(LLVM_NATIVE_ARCH RISCV)
 411 elseif (LLVM_NATIVE_ARCH MATCHES "riscv64")
 412   set(LLVM_NATIVE_ARCH RISCV)
 413 else ()
 414   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 415 endif ()
 416
 417 # If build targets includes "host", then replace with native architecture.
 418 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 419 if( NOT idx LESS 0 )
 420   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 421   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 422   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 423 endif()
 424
 425 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 426 if (NATIVE_ARCH_IDX EQUAL -1)
 427   message(STATUS
 428     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 429 else ()
 430   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 431   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 432   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 433   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 434   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 435
 436   # We don't have an ASM parser for all architectures yet.
 437   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 438     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 439   endif ()
 440
 441   # We don't have an disassembler for all architectures yet.
 442   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 443     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 444   endif ()
 445 endif ()
 446
 447 if( MSVC )
 448   set(SHLIBEXT ".lib")
 449   set(stricmp "_stricmp")
 450   set(strdup "_strdup")
 451
 452   # See if the DIA SDK is available and usable.
 453   set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK")
 454
 455   # Due to a bug in MSVC 2013's installation software, it is possible
 456   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 457   # install directory.  If this happens, the installation is corrupt
 458   # and there's nothing we can do.  It happens with enough frequency
 459   # though that we should handle it.  We do so by simply checking that
 460   # the DIA SDK folder exists.  Should this happen you will need to
 461   # uninstall VS 2012 and then re-install VS 2013.
 462   if (IS_DIRECTORY ${MSVC_DIA_SDK_DIR})
 463     set(HAVE_DIA_SDK 1)
 464   else()
 465     set(HAVE_DIA_SDK 0)
 466   endif()
 467
 468   option(LLVM_ENABLE_DIA_SDK "Use MSVC DIA SDK for debugging if available."
 469                              ${HAVE_DIA_SDK})
 470
 471   if(LLVM_ENABLE_DIA_SDK AND NOT HAVE_DIA_SDK)
 472     message(FATAL_ERROR "DIA SDK not found. If you have both VS 2012 and 2013 installed, you may need to uninstall the former and re-install the latter afterwards.")
 473   endif()
 474 else()
 475   set(LLVM_ENABLE_DIA_SDK 0)
 476 endif( MSVC )
 477
 478 # FIXME: Signal handler return type, currently hardcoded to 'void'
 479 set(RETSIGTYPE void)
 480
 481 if( LLVM_ENABLE_THREADS )
 482   # Check if threading primitives aren't supported on this platform
 483   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 484     set(LLVM_ENABLE_THREADS 0)
 485   endif()
 486 endif()
 487
 488 if( LLVM_ENABLE_THREADS )
 489   message(STATUS "Threads enabled.")
 490 else( LLVM_ENABLE_THREADS )
 491   message(STATUS "Threads disabled.")
 492 endif()
 493
 494 if (LLVM_ENABLE_ZLIB )
 495   # Check if zlib is available in the system.
 496   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 497     set(LLVM_ENABLE_ZLIB 0)
 498   endif()
 499 endif()
 500
 501 if (LLVM_ENABLE_DOXYGEN)
 502   message(STATUS "Doxygen enabled.")
 503   find_package(Doxygen REQUIRED)
 504
 505   if (DOXYGEN_FOUND)
 506     # If we find doxygen and we want to enable doxygen by default create a
 507     # global aggregate doxygen target for generating llvm and any/all
 508     # subprojects doxygen documentation.
 509     if (LLVM_BUILD_DOCS)
 510       add_custom_target(doxygen ALL)
 511     endif()
 512
 513     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 514     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 515       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
 516       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 517     endif()
 518   endif()
 519 else()
 520   message(STATUS "Doxygen disabled.")
 521 endif()
 522
 523 set(LLVM_BINDINGS "")
 524 find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 525 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 526   message(STATUS "Go bindings disabled.")
 527 else()
 528   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 529     message(STATUS "Go bindings disabled.")
 530   else()
 531     execute_process(COMMAND ${GO_EXECUTABLE} run ${PROJECT_SOURCE_DIR}/bindings/go/conftest.go
 532                     RESULT_VARIABLE GO_CONFTEST)
 533     if(GO_CONFTEST STREQUAL "0")
 534       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 535       message(STATUS "Go bindings enabled.")
 536     else()
 537       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 538     endif()
 539   endif()
 540 endif()
 541
 542 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
 543 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 544         "PATH to binutils/include containing plugin-api.h for gold plugin.")
 545
 546 if(CMAKE_HOST_APPLE AND APPLE)
 547   if(NOT CMAKE_XCRUN)
 548     find_program(CMAKE_XCRUN NAMES xcrun)
 549   endif()
 550   if(CMAKE_XCRUN)
 551     execute_process(COMMAND ${CMAKE_XCRUN} -find ld
 552       OUTPUT_VARIABLE LD64_EXECUTABLE
 553       OUTPUT_STRIP_TRAILING_WHITESPACE)
 554   else()
 555     find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
 556   endif()
 557
 558   if(LD64_EXECUTABLE)
 559     set(LD64_EXECUTABLE ${LD64_EXECUTABLE} CACHE PATH "ld64 executable")
 560     message(STATUS "Found ld64 - ${LD64_EXECUTABLE}")
 561   endif()
 562 endif()
 563
 564 # Keep the version requirements in sync with bindings/ocaml/README.txt.
 565 include(FindOCaml)
 566 include(AddOCaml)
 567 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 568   message(STATUS "OCaml bindings disabled.")
 569 else()
 570   find_package(OCaml)
 571   if( NOT OCAML_FOUND )
 572     message(STATUS "OCaml bindings disabled.")
 573   else()
 574     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 575       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 576     else()
 577       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
 578       if( HAVE_OCAML_CTYPES )
 579         message(STATUS "OCaml bindings enabled.")
 580         find_ocamlfind_package(oUnit VERSION 2 OPTIONAL)
 581         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 582
 583         set(LLVM_OCAML_INSTALL_PATH "${OCAML_STDLIB_PATH}" CACHE STRING
 584             "Install directory for LLVM OCaml packages")
 585       else()
 586         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
 587       endif()
 588     endif()
 589   endif()
 590 endif()
 591
 592 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")
 593
 594 function(find_python_module module)
 595   string(REPLACE "." "_" module_name ${module})
 596   string(TOUPPER ${module_name} module_upper)
 597   set(FOUND_VAR PY_${module_upper}_FOUND)
 598
 599   execute_process(COMMAND "${PYTHON_EXECUTABLE}" "-c" "import ${module}"
 600     RESULT_VARIABLE status
 601     ERROR_QUIET)
 602
 603   if(status)
 604     set(${FOUND_VAR} 0 PARENT_SCOPE)
 605     message(STATUS "Could NOT find Python module ${module}")
 606   else()
 607     set(${FOUND_VAR} 1 PARENT_SCOPE)
 608     message(STATUS "Found Python module ${module}")
 609   endif()
 610 endfunction()
 611
 612 set (PYTHON_MODULES
 613   pygments
 614   # Some systems still don't have pygments.lexers.c_cpp which was introduced in
 615   # version 2.0 in 2014...
 616   pygments.lexers.c_cpp
 617   yaml
 618   )
 619 foreach(module ${PYTHON_MODULES})
 620   find_python_module(${module})
 621 endforeach()
 622
 623 if(PY_PYGMENTS_FOUND AND PY_PYGMENTS_LEXERS_C_CPP_FOUND AND PY_YAML_FOUND)
 624   set (LLVM_HAVE_OPT_VIEWER_MODULES 1)
 625 else()
 626   set (LLVM_HAVE_OPT_VIEWER_MODULES 0)
 627 endif()