cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(CheckCompilerVersion)
  10 include(HandleLLVMStdlib)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13
  14 if(CMAKE_LINKER MATCHES "lld-link\.exe" OR (WIN32 AND LLVM_USE_LINKER STREQUAL "lld") OR LLVM_ENABLE_LLD)
  15   set(LINKER_IS_LLD_LINK TRUE)
  16 else()
  17   set(LINKER_IS_LLD_LINK FALSE)
  18 endif()
  19
  20 set(LLVM_ENABLE_LTO OFF CACHE STRING "Build LLVM with LTO. May be specified as Thin or Full to use a particular kind of LTO")
  21 string(TOUPPER "${LLVM_ENABLE_LTO}" uppercase_LLVM_ENABLE_LTO)
  22
  23 # Ninja Job Pool support
  24 # The following only works with the Ninja generator in CMake >= 3.0.
  25 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  26   "Define the maximum number of concurrent compilation jobs (Ninja only).")
  27 if(LLVM_PARALLEL_COMPILE_JOBS)
  28   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  29     message(WARNING "Job pooling is only available with Ninja generators.")
  30   else()
  31     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  32     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  33   endif()
  34 endif()
  35
  36 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  37   "Define the maximum number of concurrent link jobs (Ninja only).")
  38 if(CMAKE_MAKE_PROGRAM MATCHES "ninja")
  39   if(NOT LLVM_PARALLEL_LINK_JOBS AND uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
  40     message(STATUS "ThinLTO provides its own parallel linking - limiting parallel link jobs to 2.")
  41     set(LLVM_PARALLEL_LINK_JOBS "2")
  42   endif()
  43   if(LLVM_PARALLEL_LINK_JOBS)
  44     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  45     set(CMAKE_JOB_POOL_LINK link_job_pool)
  46   endif()
  47 elseif(LLVM_PARALLEL_LINK_JOBS)
  48   message(WARNING "Job pooling is only available with Ninja generators.")
  49 endif()
  50
  51 if( LLVM_ENABLE_ASSERTIONS )
  52   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  53   if( NOT MSVC )
  54     add_definitions( -D_DEBUG )
  55   endif()
  56   # On non-Debug builds cmake automatically defines NDEBUG, so we
  57   # explicitly undefine it:
  58   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  59     add_definitions( -UNDEBUG )
  60     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  61     foreach (flags_var_to_scrub
  62         CMAKE_CXX_FLAGS_RELEASE
  63         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  64         CMAKE_CXX_FLAGS_MINSIZEREL
  65         CMAKE_C_FLAGS_RELEASE
  66         CMAKE_C_FLAGS_RELWITHDEBINFO
  67         CMAKE_C_FLAGS_MINSIZEREL)
  68       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  69         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  70     endforeach()
  71   endif()
  72 endif()
  73
  74 if(LLVM_ENABLE_EXPENSIVE_CHECKS)
  75   add_definitions(-DEXPENSIVE_CHECKS)
  76   add_definitions(-D_GLIBCXX_DEBUG)
  77 endif()
  78
  79 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  80
  81 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  82   if( LLVM_ENABLE_ASSERTIONS )
  83     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  84   endif()
  85 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  86   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  87 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
  88   # We don't need to do anything special to turn off ABI breaking checks.
  89 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
  90   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
  91   # defined.
  92 else()
  93   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
  94 endif()
  95
  96 if( LLVM_REVERSE_ITERATION )
  97   set( LLVM_ENABLE_REVERSE_ITERATION 1 )
  98 endif()
  99
 100 if(WIN32)
 101   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 102   if(CYGWIN)
 103     set(LLVM_ON_WIN32 0)
 104     set(LLVM_ON_UNIX 1)
 105   else(CYGWIN)
 106     set(LLVM_ON_WIN32 1)
 107     set(LLVM_ON_UNIX 0)
 108   endif(CYGWIN)
 109 else(WIN32)
 110   if(FUCHSIA OR UNIX)
 111     set(LLVM_ON_WIN32 0)
 112     set(LLVM_ON_UNIX 1)
 113     if(APPLE OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 114       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 115     else()
 116       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 117     endif()
 118   else(FUCHSIA OR UNIX)
 119     MESSAGE(SEND_ERROR "Unable to determine platform")
 120   endif(FUCHSIA OR UNIX)
 121 endif(WIN32)
 122
 123 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 124 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 125
 126 # We use *.dylib rather than *.so on darwin.
 127 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 128
 129 if(APPLE)
 130   if(LLVM_ENABLE_LLD AND LLVM_ENABLE_LTO)
 131     message(FATAL_ERROR "lld does not support LTO on Darwin")
 132   endif()
 133   # Darwin-specific linker flags for loadable modules.
 134   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 135 endif()
 136
 137 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 138 # build might work on ELF but fail on MachO/COFF.
 139 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR CYGWIN OR
 140         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD" OR
 141         ${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD") AND
 142    NOT LLVM_USE_SANITIZER)
 143   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 144 endif()
 145
 146 # Pass -Wl,-z,nodelete. This makes sure our shared libraries are not unloaded
 147 # by dlclose(). We need that since the CLI API relies on cross-references
 148 # between global objects which became horribly broken when one of the libraries
 149 # is unloaded.
 150 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 151   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,nodelete")
 152   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-z,nodelete")
 153 endif()
 154
 155
 156 function(append value)
 157   foreach(variable ${ARGN})
 158     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 159   endforeach(variable)
 160 endfunction()
 161
 162 function(append_if condition value)
 163   if (${condition})
 164     foreach(variable ${ARGN})
 165       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 166     endforeach(variable)
 167   endif()
 168 endfunction()
 169
 170 macro(add_flag_if_supported flag name)
 171   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 172   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 173   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 174   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 175 endmacro()
 176
 177 function(add_flag_or_print_warning flag name)
 178   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 179   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 180   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 181     message(STATUS "Building with ${flag}")
 182     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 183     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 184     set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} ${flag}" PARENT_SCOPE)
 185   else()
 186     message(WARNING "${flag} is not supported.")
 187   endif()
 188 endfunction()
 189
 190 if( LLVM_ENABLE_LLD )
 191         if ( LLVM_USE_LINKER )
 192                 message(FATAL_ERROR "LLVM_ENABLE_LLD and LLVM_USE_LINKER can't be set at the same time")
 193         endif()
 194         set(LLVM_USE_LINKER "lld")
 195 endif()
 196
 197 if( LLVM_USE_LINKER )
 198   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 199   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fuse-ld=${LLVM_USE_LINKER}")
 200   check_cxx_source_compiles("int main() { return 0; }" CXX_SUPPORTS_CUSTOM_LINKER)
 201   if ( NOT CXX_SUPPORTS_CUSTOM_LINKER )
 202           message(FATAL_ERROR "Host compiler does not support '-fuse-ld=${LLVM_USE_LINKER}'")
 203   endif()
 204   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 205   append("-fuse-ld=${LLVM_USE_LINKER}"
 206     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 207 endif()
 208
 209 if( LLVM_ENABLE_PIC )
 210   if( XCODE )
 211     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 212     # know how to disable this, so just force ENABLE_PIC off for now.
 213     message(WARNING "-fPIC not supported with Xcode.")
 214   elseif( WIN32 OR CYGWIN)
 215     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 216   else()
 217     add_flag_or_print_warning("-fPIC" FPIC)
 218   endif()
 219 endif()
 220
 221 if(NOT WIN32 AND NOT CYGWIN)
 222   # MinGW warns if -fvisibility-inlines-hidden is used.
 223   check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 224   append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 225 endif()
 226
 227 if(CMAKE_SIZEOF_VOID_P EQUAL 8 AND MINGW)
 228   add_definitions( -D_FILE_OFFSET_BITS=64 )
 229 endif()
 230
 231 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 232   # TODO: support other platforms and toolchains.
 233   if( LLVM_BUILD_32_BITS )
 234     message(STATUS "Building 32 bits executables and libraries.")
 235     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 236     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -m32")
 237     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 238     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 239     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 240
 241     # FIXME: CMAKE_SIZEOF_VOID_P is still 8
 242     add_definitions(-D_LARGEFILE_SOURCE)
 243     add_definitions(-D_FILE_OFFSET_BITS=64)
 244   endif( LLVM_BUILD_32_BITS )
 245 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 246
 247 # If building on a GNU specific 32-bit system, make sure off_t is 64 bits
 248 # so that off_t can stored offset > 2GB.
 249 # Android until version N (API 24) doesn't support it.
 250 if (ANDROID AND (ANDROID_NATIVE_API_LEVEL LESS 24))
 251   set(LLVM_FORCE_SMALLFILE_FOR_ANDROID TRUE)
 252 endif()
 253 if( CMAKE_SIZEOF_VOID_P EQUAL 4 AND NOT LLVM_FORCE_SMALLFILE_FOR_ANDROID)
 254   # FIXME: It isn't handled in LLVM_BUILD_32_BITS.
 255   add_definitions( -D_LARGEFILE_SOURCE )
 256   add_definitions( -D_FILE_OFFSET_BITS=64 )
 257 endif()
 258
 259 if( XCODE )
 260   # For Xcode enable several build settings that correspond to
 261   # many warnings that are on by default in Clang but are
 262   # not enabled for historical reasons.  For versions of Xcode
 263   # that do not support these options they will simply
 264   # be ignored.
 265   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 266   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 267   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 268   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 269   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 270   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 271   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 272   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 273   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 274   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 275   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 276   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 277   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 278   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 279   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 280 endif()
 281
 282 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 283 # to use.
 284 if( MSVC_IDE )
 285   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 286     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 287   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 288     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 289       add_definitions( /MP )
 290     else()
 291       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 292       add_definitions( /MP${LLVM_COMPILER_JOBS} )
 293     endif()
 294   else()
 295     message(STATUS "Parallel compilation disabled")
 296   endif()
 297 endif()
 298
 299 # set stack reserved size to ~10MB
 300 if(MSVC)
 301   # CMake previously automatically set this value for MSVC builds, but the
 302   # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 303   # value (1 MB) which is not enough for us in tasks such as parsing recursive
 304   # C++ templates in Clang.
 305   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 306 elseif(MINGW) # FIXME: Also cygwin?
 307   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,16777216")
 308
 309   # Pass -mbig-obj to mingw gas on Win64. COFF has a 2**16 section limit, and
 310   # on Win64, every COMDAT function creates at least 3 sections: .text, .pdata,
 311   # and .xdata.
 312   if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 313     append("-Wa,-mbig-obj" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 314   endif()
 315 endif()
 316
 317 if( MSVC )
 318   if( CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.0 )
 319     # For MSVC 2013, disable iterator null pointer checking in debug mode,
 320     # especially so std::equal(nullptr, nullptr, nullptr) will not assert.
 321     add_definitions("-D_DEBUG_POINTER_IMPL=")
 322   endif()
 323
 324   include(ChooseMSVCCRT)
 325
 326   if( MSVC11 )
 327     add_definitions(-D_VARIADIC_MAX=10)
 328   endif()
 329
 330   # Add definitions that make MSVC much less annoying.
 331   add_definitions(
 332     # For some reason MS wants to deprecate a bunch of standard functions...
 333     -D_CRT_SECURE_NO_DEPRECATE
 334     -D_CRT_SECURE_NO_WARNINGS
 335     -D_CRT_NONSTDC_NO_DEPRECATE
 336     -D_CRT_NONSTDC_NO_WARNINGS
 337     -D_SCL_SECURE_NO_DEPRECATE
 338     -D_SCL_SECURE_NO_WARNINGS
 339     )
 340
 341   # Tell MSVC to use the Unicode version of the Win32 APIs instead of ANSI.
 342   add_definitions(
 343     -DUNICODE
 344     -D_UNICODE
 345   )
 346
 347   if (LLVM_ENABLE_WERROR)
 348     append("/WX" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 349   endif (LLVM_ENABLE_WERROR)
 350
 351   append("/Zc:inline" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 352
 353   # Allow users to request PDBs in release mode. CMake offeres the
 354   # RelWithDebInfo configuration, but it uses different optimization settings
 355   # (/Ob1 vs /Ob2 or -O2 vs -O3). LLVM provides this flag so that users can get
 356   # PDBs without changing codegen.
 357   option(LLVM_ENABLE_PDB OFF)
 358   if (LLVM_ENABLE_PDB AND uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
 359     append("/Zi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 360     # /DEBUG disables linker GC and ICF, but we want those in Release mode.
 361     append("/DEBUG /OPT:REF /OPT:ICF"
 362           CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS
 363           CMAKE_SHARED_LINKER_FLAGS)
 364   endif()
 365
 366   # /Zc:strictStrings is incompatible with VS12's (Visual Studio 2013's)
 367   # debug mode headers. Instead of only enabling them in VS2013's debug mode,
 368   # we'll just enable them for Visual Studio 2015 (VS 14, MSVC_VERSION 1900)
 369   # and up.
 370   if (NOT (MSVC_VERSION LESS 1900))
 371     # Disable string literal const->non-const type conversion.
 372     # "When specified, the compiler requires strict const-qualification
 373     # conformance for pointers initialized by using string literals."
 374     append("/Zc:strictStrings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 375   endif(NOT (MSVC_VERSION LESS 1900))
 376
 377   # "Generate Intrinsic Functions".
 378   append("/Oi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 379
 380   # "Enforce type conversion rules".
 381   append("/Zc:rvalueCast" CMAKE_CXX_FLAGS)
 382
 383   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND NOT LLVM_ENABLE_LTO)
 384     # clang-cl and cl by default produce non-deterministic binaries because
 385     # link.exe /incremental requires a timestamp in the .obj file.  clang-cl
 386     # has the flag /Brepro to force deterministic binaries. We want to pass that
 387     # whenever you're building with clang unless you're passing /incremental
 388     # or using LTO (/Brepro with LTO would result in a warning about the flag
 389     # being unused, because we're not generating object files).
 390     # This checks CMAKE_CXX_COMPILER_ID in addition to check_cxx_compiler_flag()
 391     # because cl.exe does not emit an error on flags it doesn't understand,
 392     # letting check_cxx_compiler_flag() claim it understands all flags.
 393     check_cxx_compiler_flag("/Brepro" SUPPORTS_BREPRO)
 394     if (SUPPORTS_BREPRO)
 395       # Check if /INCREMENTAL is passed to the linker and complain that it
 396       # won't work with /Brepro.
 397       string(TOUPPER "${CMAKE_EXE_LINKER_FLAGS}" upper_exe_flags)
 398       string(TOUPPER "${CMAKE_MODULE_LINKER_FLAGS}" upper_module_flags)
 399       string(TOUPPER "${CMAKE_SHARED_LINKER_FLAGS}" upper_shared_flags)
 400
 401       string(FIND "${upper_exe_flags} ${upper_module_flags} ${upper_shared_flags}"
 402         "/INCREMENTAL" linker_flag_idx)
 403
 404       if (${linker_flag_idx} GREATER -1)
 405         message(WARNING "/Brepro not compatible with /INCREMENTAL linking - builds will be non-deterministic")
 406       else()
 407         append("/Brepro" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 408       endif()
 409     endif()
 410   endif()
 411
 412 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 413   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 414   append_if(LLVM_ENABLE_WERROR "-Wno-error" CMAKE_REQUIRED_FLAGS)
 415   add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 416   add_flag_if_supported("-Werror=unguarded-availability-new" WERROR_UNGUARDED_AVAILABILITY_NEW)
 417   if (LLVM_ENABLE_CXX1Y)
 418     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 419     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 420   elseif(LLVM_ENABLE_CXX1Z)
 421     check_cxx_compiler_flag("-std=c++1z" CXX_SUPPORTS_CXX1Z)
 422     append_if(CXX_SUPPORTS_CXX1Z "-std=c++1z" CMAKE_CXX_FLAGS)
 423   else()
 424     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 425     if (CXX_SUPPORTS_CXX11)
 426       if (CYGWIN OR MINGW)
 427         # MinGW and Cygwin are a bit stricter and lack things like
 428         # 'strdup', 'stricmp', etc in c++11 mode.
 429         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 430       else()
 431         append("-std=c++11" CMAKE_CXX_FLAGS)
 432       endif()
 433     else()
 434       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 435     endif()
 436   endif()
 437   if (LLVM_ENABLE_MODULES)
 438     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 439     set(module_flags "-fmodules -fmodules-cache-path=${PROJECT_BINARY_DIR}/module.cache")
 440     if (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 441       # On Darwin -fmodules does not imply -fcxx-modules.
 442       set(module_flags "${module_flags} -fcxx-modules")
 443     endif()
 444     if (LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY)
 445       set(module_flags "${module_flags} -Xclang -fmodules-local-submodule-visibility")
 446     endif()
 447     if (LLVM_ENABLE_MODULE_DEBUGGING AND
 448         ((uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG") OR
 449          (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")))
 450       set(module_flags "${module_flags} -gmodules")
 451     endif()
 452     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${module_flags}")
 453
 454     # Check that we can build code with modules enabled, and that repeatedly
 455     # including <cassert> still manages to respect NDEBUG properly.
 456     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 457                                #include <cassert>
 458                                #define NDEBUG
 459                                #include <cassert>
 460                                int main() { assert(this code is not compiled); }"
 461                                CXX_SUPPORTS_MODULES)
 462     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 463     if (CXX_SUPPORTS_MODULES)
 464       append("${module_flags}" CMAKE_CXX_FLAGS)
 465     else()
 466       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 467     endif()
 468   endif(LLVM_ENABLE_MODULES)
 469 endif( MSVC )
 470
 471 if (MSVC)
 472   if (NOT CLANG_CL)
 473     set(msvc_warning_flags
 474       # Disabled warnings.
 475       -wd4141 # Suppress ''modifier' : used more than once' (because of __forceinline combined with inline)
 476       -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 477       -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 478       -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 479       -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 480       -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 481       -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 482       -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 483       -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 484       -wd4355 # Suppress ''this' : used in base member initializer list'
 485       -wd4456 # Suppress 'declaration of 'var' hides local variable'
 486       -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 487       -wd4458 # Suppress 'declaration of 'var' hides class member'
 488       -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 489       -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 490       -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 491       -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 492       -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 493       -wd4100 # Suppress 'unreferenced formal parameter'
 494       -wd4127 # Suppress 'conditional expression is constant'
 495       -wd4512 # Suppress 'assignment operator could not be generated'
 496       -wd4505 # Suppress 'unreferenced local function has been removed'
 497       -wd4610 # Suppress '<class> can never be instantiated'
 498       -wd4510 # Suppress 'default constructor could not be generated'
 499       -wd4702 # Suppress 'unreachable code'
 500       -wd4245 # Suppress 'signed/unsigned mismatch'
 501       -wd4706 # Suppress 'assignment within conditional expression'
 502       -wd4310 # Suppress 'cast truncates constant value'
 503       -wd4701 # Suppress 'potentially uninitialized local variable'
 504       -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 505       -wd4389 # Suppress 'signed/unsigned mismatch'
 506       -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 507       -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 508       -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 509       -wd4577 # Suppress 'noexcept used with no exception handling mode specified; termination on exception is not guaranteed'
 510       -wd4091 # Suppress 'typedef: ignored on left of '' when no variable is declared'
 511           # C4592 is disabled because of false positives in Visual Studio 2015
 512           # Update 1. Re-evaluate the usefulness of this diagnostic with Update 2.
 513       -wd4592 # Suppress ''var': symbol will be dynamically initialized (implementation limitation)
 514       -wd4319 # Suppress ''operator' : zero extending 'type' to 'type' of greater size'
 515
 516       # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
 517       # support the 'aligned' attribute in the way that clang sources requires (for
 518       # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
 519       # avoid unwanted alignment warnings.
 520       # When we switch to requiring a version of MSVC that supports the 'alignas'
 521       # specifier (MSVC 2015?) this warning can be re-enabled.
 522       -wd4324 # Suppress 'structure was padded due to __declspec(align())'
 523
 524       # Promoted warnings.
 525       -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 526
 527       # Promoted warnings to errors.
 528       -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 529       )
 530   endif(NOT CLANG_CL)
 531
 532   # Enable warnings
 533   if (LLVM_ENABLE_WARNINGS)
 534     # Put /W4 in front of all the -we flags. cl.exe doesn't care, but for
 535     # clang-cl having /W4 after the -we flags will re-enable the warnings
 536     # disabled by -we.
 537     set(msvc_warning_flags "/W4 ${msvc_warning_flags}")
 538     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in
 539     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
 540     # a command line warning and not a compiler warning, it cannot be suppressed except
 541     # by fixing the command line.
 542     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 543     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 544
 545     if (LLVM_ENABLE_PEDANTIC)
 546       # No MSVC equivalent available
 547     endif (LLVM_ENABLE_PEDANTIC)
 548   endif (LLVM_ENABLE_WARNINGS)
 549
 550   foreach(flag ${msvc_warning_flags})
 551     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 552   endforeach(flag)
 553 endif (MSVC)
 554
 555 if (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 556
 557   # Don't add -Wall for clang-cl, because it maps -Wall to -Weverything for
 558   # MSVC compatibility.  /W4 is added above instead.
 559   if (NOT CLANG_CL)
 560     append("-Wall" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 561   endif()
 562
 563   append("-Wextra -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 564   append("-Wcast-qual" CMAKE_CXX_FLAGS)
 565
 566   # Turn off missing field initializer warnings for gcc to avoid noise from
 567   # false positives with empty {}. Turn them on otherwise (they're off by
 568   # default for clang).
 569   check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 570   if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 571     if (CMAKE_COMPILER_IS_GNUCXX)
 572       append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 573     else()
 574       append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 575     endif()
 576   endif()
 577
 578   if (LLVM_ENABLE_PEDANTIC AND LLVM_COMPILER_IS_GCC_COMPATIBLE)
 579     append("-pedantic" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 580     append("-Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 581   endif()
 582
 583   add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 584   append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 585   append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 586
 587   # Disable -Wclass-memaccess, a C++-only warning from GCC 8 that fires on
 588   # LLVM's ADT classes.
 589   check_cxx_compiler_flag("-Wclass-memaccess" CXX_SUPPORTS_CLASS_MEMACCESS_FLAG)
 590   append_if(CXX_SUPPORTS_CLASS_MEMACCESS_FLAG "-Wno-class-memaccess" CMAKE_CXX_FLAGS)
 591
 592   # The LLVM libraries have no stable C++ API, so -Wnoexcept-type is not useful.
 593   check_cxx_compiler_flag("-Wnoexcept-type" CXX_SUPPORTS_NOEXCEPT_TYPE_FLAG)
 594   append_if(CXX_SUPPORTS_NOEXCEPT_TYPE_FLAG "-Wno-noexcept-type" CMAKE_CXX_FLAGS)
 595
 596   # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 597   # If it does, don't add it. So it won't be added on clang 3.4 and older.
 598   # This also catches cases when -Wnon-virtual-dtor isn't supported by
 599   # the compiler at all.  This flag is not activated for gcc since it will
 600   # incorrectly identify a protected non-virtual base when there is a friend
 601   # declaration. Don't activate this in general on Windows as this warning has
 602   # too many false positives on COM-style classes, which are destroyed with
 603   # Release() (PR32286).
 604   if (NOT CMAKE_COMPILER_IS_GNUCXX AND NOT WIN32)
 605     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 606     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 607     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 608                                class derived final : public base { public: ~derived();};
 609                                int main() { return 0; }"
 610                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 611     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 612     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 613               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 614   endif()
 615
 616   # Enable -Wdelete-non-virtual-dtor if available.
 617   add_flag_if_supported("-Wdelete-non-virtual-dtor" DELETE_NON_VIRTUAL_DTOR_FLAG)
 618
 619   # Check if -Wcomment is OK with an // comment ending with '\' if the next
 620   # line is also a // comment.
 621   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 622   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 623   CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 624                           C_WCOMMENT_ALLOWS_LINE_WRAP)
 625   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 626   if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 627     append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 628   endif()
 629
 630   # Enable -Wstring-conversion to catch misuse of string literals.
 631   add_flag_if_supported("-Wstring-conversion" STRING_CONVERSION_FLAG)
 632 endif (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 633
 634 if (LLVM_COMPILER_IS_GCC_COMPATIBLE AND NOT LLVM_ENABLE_WARNINGS)
 635   append("-w" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 636 endif()
 637
 638 macro(append_common_sanitizer_flags)
 639   if (NOT MSVC)
 640     # Append -fno-omit-frame-pointer and turn on debug info to get better
 641     # stack traces.
 642     add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 643     if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 644         NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 645       add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 646     endif()
 647     # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 648     if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND LLVM_OPTIMIZE_SANITIZED_BUILDS)
 649       add_flag_if_supported("-O1" O1)
 650     endif()
 651   elseif (CLANG_CL)
 652     # Keep frame pointers around.
 653     append("/Oy-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 654     if (LINKER_IS_LLD_LINK)
 655       # Use DWARF debug info with LLD.
 656       append("-gdwarf" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 657     else()
 658       # Enable codeview otherwise.
 659       append("/Z7" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 660     endif()
 661     # Always ask the linker to produce symbols with asan.
 662     append("-debug" CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 663   endif()
 664 endmacro()
 665
 666 # Turn on sanitizers if necessary.
 667 if(LLVM_USE_SANITIZER)
 668   if (LLVM_ON_UNIX)
 669     if (LLVM_USE_SANITIZER STREQUAL "Address")
 670       append_common_sanitizer_flags()
 671       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 672     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 673       append_common_sanitizer_flags()
 674       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 675       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 676         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 677       endif()
 678     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 679       append_common_sanitizer_flags()
 680       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 681               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 682     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 683       append_common_sanitizer_flags()
 684       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 685     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 686             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 687       append_common_sanitizer_flags()
 688       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 689               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 690     elseif (LLVM_USE_SANITIZER STREQUAL "Leaks")
 691       append_common_sanitizer_flags()
 692       append("-fsanitize=leak" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 693     else()
 694       message(FATAL_ERROR "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 695     endif()
 696   elseif(MSVC)
 697     if (LLVM_USE_SANITIZER STREQUAL "Address")
 698       append_common_sanitizer_flags()
 699       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 700     else()
 701       message(FATAL_ERROR "This sanitizer not yet supported in the MSVC environment: ${LLVM_USE_SANITIZER}")
 702     endif()
 703   else()
 704     message(FATAL_ERROR "LLVM_USE_SANITIZER is not supported on this platform.")
 705   endif()
 706   if (LLVM_USE_SANITIZER MATCHES "(Undefined;)?Address(;Undefined)?")
 707     add_flag_if_supported("-fsanitize-address-use-after-scope"
 708                           FSANITIZE_USE_AFTER_SCOPE_FLAG)
 709   endif()
 710   if (LLVM_USE_SANITIZE_COVERAGE)
 711     append("-fsanitize=fuzzer-no-link" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 712   endif()
 713   if (LLVM_USE_SANITIZER MATCHES ".*Undefined.*")
 714     set(BLACKLIST_FILE "${CMAKE_SOURCE_DIR}/utils/sanitizers/ubsan_blacklist.txt")
 715     if (EXISTS "${BLACKLIST_FILE}")
 716       append("-fsanitize-blacklist=${BLACKLIST_FILE}"
 717              CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 718     endif()
 719   endif()
 720 endif()
 721
 722 # Turn on -gsplit-dwarf if requested
 723 if(LLVM_USE_SPLIT_DWARF)
 724   add_definitions("-gsplit-dwarf")
 725 endif()
 726
 727 add_definitions( -D__STDC_CONSTANT_MACROS )
 728 add_definitions( -D__STDC_FORMAT_MACROS )
 729 add_definitions( -D__STDC_LIMIT_MACROS )
 730
 731 # clang and gcc don't default-print colored diagnostics when invoked from Ninja.
 732 if (UNIX AND
 733     CMAKE_GENERATOR STREQUAL "Ninja" AND
 734     (CMAKE_CXX_COMPILER_ID MATCHES "Clang" OR
 735      (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND
 736       NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.9))))
 737   append("-fdiagnostics-color" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 738 endif()
 739
 740 # lld doesn't print colored diagnostics when invoked from Ninja
 741 if (UNIX AND CMAKE_GENERATOR STREQUAL "Ninja")
 742   include(CheckLinkerFlag)
 743   check_linker_flag("-Wl,--color-diagnostics" LINKER_SUPPORTS_COLOR_DIAGNOSTICS)
 744   append_if(LINKER_SUPPORTS_COLOR_DIAGNOSTICS "-Wl,--color-diagnostics"
 745     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 746 endif()
 747
 748 # Add flags for add_dead_strip().
 749 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 750 # But MinSizeRel seems to add that automatically, so maybe disable these
 751 # flags instead if LLVM_NO_DEAD_STRIP is set.
 752 if(NOT CYGWIN AND NOT WIN32)
 753   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
 754      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 755     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 756     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 757       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 758       # Doing so will break sanitizers.
 759       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 760     endif()
 761     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 762   endif()
 763 endif()
 764
 765 if(MSVC)
 766   # Remove flags here, for exceptions and RTTI.
 767   # Each target property or source property should be responsible to control
 768   # them.
 769   # CL.EXE complains to override flags like "/GR /GR-".
 770   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 771   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 772 endif()
 773
 774 # Provide public options to globally control RTTI and EH
 775 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 776 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 777 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 778   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 779 endif()
 780
 781 option(LLVM_ENABLE_IR_PGO "Build LLVM and tools with IR PGO instrumentation (deprecated)" Off)
 782 mark_as_advanced(LLVM_ENABLE_IR_PGO)
 783
 784 set(LLVM_BUILD_INSTRUMENTED OFF CACHE STRING "Build LLVM and tools with PGO instrumentation. May be specified as IR or Frontend")
 785 mark_as_advanced(LLVM_BUILD_INSTRUMENTED)
 786 string(TOUPPER "${LLVM_BUILD_INSTRUMENTED}" uppercase_LLVM_BUILD_INSTRUMENTED)
 787
 788 if (LLVM_BUILD_INSTRUMENTED)
 789   if (LLVM_ENABLE_IR_PGO OR uppercase_LLVM_BUILD_INSTRUMENTED STREQUAL "IR")
 790     append("-fprofile-generate='${LLVM_PROFILE_DATA_DIR}'"
 791       CMAKE_CXX_FLAGS
 792       CMAKE_C_FLAGS
 793       CMAKE_EXE_LINKER_FLAGS
 794       CMAKE_SHARED_LINKER_FLAGS)
 795   else()
 796     append("-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}'"
 797       CMAKE_CXX_FLAGS
 798       CMAKE_C_FLAGS
 799       CMAKE_EXE_LINKER_FLAGS
 800       CMAKE_SHARED_LINKER_FLAGS)
 801   endif()
 802 endif()
 803
 804 option(LLVM_BUILD_INSTRUMENTED_COVERAGE "Build LLVM and tools with Code Coverage instrumentation" Off)
 805 mark_as_advanced(LLVM_BUILD_INSTRUMENTED_COVERAGE)
 806 append_if(LLVM_BUILD_INSTRUMENTED_COVERAGE "-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}' -fcoverage-mapping"
 807   CMAKE_CXX_FLAGS
 808   CMAKE_C_FLAGS
 809   CMAKE_EXE_LINKER_FLAGS
 810   CMAKE_SHARED_LINKER_FLAGS)
 811
 812 if (LLVM_BUILD_INSTRUMENTED AND LLVM_BUILD_INSTRUMENTED_COVERAGE)
 813   message(FATAL_ERROR "LLVM_BUILD_INSTRUMENTED and LLVM_BUILD_INSTRUMENTED_COVERAGE cannot both be specified")
 814 endif()
 815
 816 if(LLVM_ENABLE_LTO AND LLVM_ON_WIN32 AND NOT LINKER_IS_LLD_LINK)
 817   message(FATAL_ERROR "When compiling for Windows, LLVM_ENABLE_LTO requires using lld as the linker (point CMAKE_LINKER at lld-link.exe)")
 818 endif()
 819 if(uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
 820   append("-flto=thin" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 821   if(NOT LINKER_IS_LLD_LINK)
 822     append("-flto=thin" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 823   endif()
 824   # If the linker supports it, enable the lto cache. This improves initial build
 825   # time a little since we re-link a lot of the same objects, and significantly
 826   # improves incremental build time.
 827   # FIXME: We should move all this logic into the clang driver.
 828   if(APPLE)
 829     append("-Wl,-cache_path_lto,${PROJECT_BINARY_DIR}/lto.cache"
 830            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 831   elseif(UNIX AND LLVM_USE_LINKER STREQUAL "lld")
 832     append("-Wl,--thinlto-cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 833            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 834   elseif(LLVM_USE_LINKER STREQUAL "gold")
 835     append("-Wl,--plugin-opt,cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 836            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 837   endif()
 838 elseif(uppercase_LLVM_ENABLE_LTO STREQUAL "FULL")
 839   append("-flto=full" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 840   if(NOT LINKER_IS_LLD_LINK)
 841     append("-flto=full" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 842   endif()
 843 elseif(LLVM_ENABLE_LTO)
 844   append("-flto" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 845   if(NOT LINKER_IS_LLD_LINK)
 846     append("-flto" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 847   endif()
 848 endif()
 849
 850 # This option makes utils/extract_symbols.py be used to determine the list of
 851 # symbols to export from LLVM tools. This is necessary when using MSVC if you
 852 # want to allow plugins, though note that the plugin has to explicitly link
 853 # against (exactly one) tool so we can't unilaterally turn on
 854 # LLVM_ENABLE_PLUGINS when it's enabled.
 855 option(LLVM_EXPORT_SYMBOLS_FOR_PLUGINS "Export symbols from LLVM tools so that plugins can import them" OFF)
 856 if(BUILD_SHARED_LIBS AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 857   message(FATAL_ERROR "BUILD_SHARED_LIBS not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 858 endif()
 859 if(LLVM_LINK_LLVM_DYLIB AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 860   message(FATAL_ERROR "LLVM_LINK_LLVM_DYLIB not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 861 endif()
 862
 863 # Plugin support
 864 # FIXME: Make this configurable.
 865 if(WIN32 OR CYGWIN)
 866   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 867     set(LLVM_ENABLE_PLUGINS ON)
 868   else()
 869     set(LLVM_ENABLE_PLUGINS OFF)
 870   endif()
 871 else()
 872   set(LLVM_ENABLE_PLUGINS ON)
 873 endif()
 874
 875 # By default we should enable LLVM_ENABLE_IDE only for multi-configuration
 876 # generators. This option disables optional build system features that make IDEs
 877 # less usable.
 878 set(LLVM_ENABLE_IDE_default OFF)
 879 if (CMAKE_CONFIGURATION_TYPES)
 880   set(LLVM_ENABLE_IDE_default ON)
 881 endif()
 882 option(LLVM_ENABLE_IDE
 883        "Disable optional build system features that cause problems for IDE generators"
 884        ${LLVM_ENABLE_IDE_default})
 885 if (CMAKE_CONFIGURATION_TYPES AND NOT LLVM_ENABLE_IDE)
 886   message(WARNING "Disabling LLVM_ENABLE_IDE on multi-configuration generators is not recommended.")
 887 endif()
 888
 889 function(get_compile_definitions)
 890   get_directory_property(top_dir_definitions DIRECTORY ${CMAKE_SOURCE_DIR} COMPILE_DEFINITIONS)
 891   foreach(definition ${top_dir_definitions})
 892     if(DEFINED result)
 893       string(APPEND result " -D${definition}")
 894     else()
 895       set(result "-D${definition}")
 896     endif()
 897   endforeach()
 898   set(LLVM_DEFINITIONS "${result}" PARENT_SCOPE)
 899 endfunction()
 900 get_compile_definitions()
 901
 902 option(LLVM_FORCE_ENABLE_STATS "Enable statistics collection for builds that wouldn't normally enable it" OFF)