listview.ml

   1 open Utils;;
   2 open Glutils;;
   3 open Config;;
   4
   5 let scrollph y maxy =
   6   let sh = float (maxy + state.winh) /. float state.winh in
   7   let sh = float state.winh /. sh in
   8   let sh = max sh (float conf.scrollh) in
   9
  10   let percent = float y /. float maxy in
  11   let position = (float state.winh -. sh) *. percent in
  12
  13   let position =
  14     if position +. sh > float state.winh
  15     then float state.winh -. sh
  16     else position
  17   in
  18   position, sh;
  19 ;;
  20
  21 let isbirdseye = function
  22   | Birdseye _ -> true
  23   | Textentry _ | View | LinkNav _ -> false
  24 ;;
  25
  26 let istextentry = function
  27   | Textentry _ -> true
  28   | Birdseye _ | View | LinkNav _ -> false
  29 ;;
  30
  31 let vscrollw () =
  32   if state.uioh#alwaysscrolly || ((conf.scrollb land scrollbvv != 0)
  33                                   && (state.maxy > state.winh))
  34   then conf.scrollbw
  35   else 0
  36 ;;
  37
  38 let vscrollhit x =
  39   if conf.leftscroll
  40   then x < vscrollw ()
  41   else x > state.winw - vscrollw ()
  42 ;;
  43
  44 let firstof first active =
  45   if first > active || abs (first - active) > fstate.maxrows - 1
  46   then max 0 (active - (fstate.maxrows/2))
  47   else first
  48 ;;
  49
  50 let calcfirst first active =
  51   if active > first
  52   then
  53     let rows = active - first in
  54     if rows > fstate.maxrows then active - fstate.maxrows else first
  55   else active
  56 ;;
  57
  58 let enttext () =
  59   let len = String.length state.text in
  60   let x0 = if conf.leftscroll then vscrollw () else 0 in
  61   let drawstring s =
  62     let hscrollh =
  63       match state.mode with
  64       | Textentry _ | View | LinkNav _ ->
  65          let h, _, _ = state.uioh#scrollpw in
  66          h
  67       | Birdseye _ -> 0
  68     in
  69     let rect x w =
  70       filledrect
  71         x      (float (state.winh - (fstate.fontsize + 4) - hscrollh))
  72         (x+.w) (float (state.winh - hscrollh))
  73     in
  74
  75     let w = float (state.winw - 1 - vscrollw ()) in
  76     if state.progress >= 0.0 && state.progress < 1.0
  77     then (
  78       GlDraw.color (0.3, 0.3, 0.3);
  79       let w1 = w *. state.progress in
  80       rect (float x0) w1;
  81       GlDraw.color (0.0, 0.0, 0.0);
  82       rect (float x0+.w1) (float x0+.w-.w1)
  83     )
  84     else (
  85       GlDraw.color (0.0, 0.0, 0.0);
  86       rect (float x0) w;
  87     );
  88
  89     GlDraw.color (1.0, 1.0, 1.0);
  90     drawstring
  91       fstate.fontsize
  92       (if conf.leftscroll then x0 + 2 else x0 + if len > 0 then 8 else 2)
  93       (state.winh - hscrollh - 5) s;
  94   in
  95   let s =
  96     match state.mode with
  97     | Textentry ((prefix, text, _, _, _, _), _) ->
  98        let s =
  99          if len > 0
 100          then Printf.sprintf "%s%s_ [%s]" prefix text state.text
 101          else Printf.sprintf "%s%s_"  prefix text
 102        in
 103        s
 104
 105     | Birdseye _ | View | LinkNav _ -> state.text
 106   in
 107   let s =
 108     if state.newerrmsgs
 109     then (
 110       if not (istextentry state.mode) && state.uioh#eformsgs
 111       then
 112         let s1 = "(press 'e' to review error messasges)" in
 113         if nonemptystr s then s ^ " " ^ s1 else s1
 114       else s
 115     )
 116     else s
 117   in
 118   if nonemptystr s
 119   then drawstring s
 120 ;;
 121
 122 let textentrykeyboard
 123       key mask ((c, text, opthist, onkey, ondone, cancelonempty), onleave) =
 124   state.text <- E.s;
 125   let enttext te =
 126     state.mode <- Textentry (te, onleave);
 127     enttext ();
 128     postRedisplay "textentrykeyboard enttext";
 129   in
 130   let histaction cmd =
 131     match opthist with
 132     | None -> ()
 133     | Some (action, _) ->
 134        state.mode <- Textentry (
 135                          (c, action cmd, opthist,
 136                           onkey, ondone, cancelonempty),
 137                          onleave);
 138        postRedisplay "textentry histaction"
 139   in
 140   let open Keys in
 141   let kt = Wsi.kc2kt key in
 142   match [@warning "-4"] kt with
 143   | Backspace ->
 144      if emptystr text && cancelonempty
 145      then (
 146        onleave Cancel;
 147        postRedisplay "textentrykeyboard after cancel";
 148      )
 149      else
 150        let s = withoutlastutf8 text in
 151        enttext (c, s, opthist, onkey, ondone, cancelonempty)
 152
 153   | Enter ->
 154      ondone text;
 155      onleave Confirm;
 156      postRedisplay "textentrykeyboard after confirm"
 157
 158   | Up   -> histaction HCprev
 159   | Down -> histaction HCnext
 160   | Home -> histaction HCfirst
 161   | End  -> histaction HClast
 162
 163   | Escape ->
 164      if emptystr text
 165      then (
 166        begin match opthist with
 167        | None -> ()
 168        | Some (_, onhistcancel) -> onhistcancel ()
 169        end;
 170        onleave Cancel;
 171        state.text <- E.s;
 172        postRedisplay "textentrykeyboard after cancel2"
 173      )
 174      else enttext (c, E.s, opthist, onkey, ondone, cancelonempty)
 175
 176   | Delete -> ()
 177
 178   | Insert when Wsi.withshift mask ->
 179      let s = getcmdoutput (fun s ->
 180                  prerr_endline ("error pasting: " ^ s)) conf.pastecmd in
 181      enttext (c, s, opthist, onkey, ondone, cancelonempty)
 182
 183   | Code _ | Ascii _ ->
 184      begin match onkey text kt with
 185      | TEdone text ->
 186         ondone text;
 187         onleave Confirm;
 188         postRedisplay "textentrykeyboard after confirm2";
 189
 190      | TEcont text ->
 191         enttext (c, text, opthist, onkey, ondone, cancelonempty);
 192
 193      | TEstop ->
 194         onleave Cancel;
 195         postRedisplay "textentrykeyboard after cancel3";
 196
 197      | TEswitch te ->
 198         state.mode <- Textentry (te, onleave);
 199         postRedisplay "textentrykeyboard switch";
 200      end
 201   | _ -> vlog "unhandled key"
 202 ;;
 203
 204 class type lvsource =
 205   object
 206     method getitemcount : int
 207     method getitem : int -> (string * int)
 208     method hasaction : int -> bool
 209     method exit : uioh:uioh ->
 210                   cancel:bool ->
 211                   active:int ->
 212                   first:int ->
 213                   pan:int ->
 214                   uioh option
 215     method getactive : int
 216     method getfirst : int
 217     method getpan : int
 218     method getminfo : (int * int) array
 219   end;;
 220
 221 class virtual lvsourcebase =
 222         object
 223           val mutable m_active = 0
 224           val mutable m_first = 0
 225           val mutable m_pan = 0
 226           method getactive = m_active
 227           method getfirst = m_first
 228           method getpan = m_pan
 229           method getminfo : (int * int) array = E.a
 230         end;;
 231
 232 let coe s = (s :> uioh);;
 233
 234 class listview ~zebra ~helpmode ~(source:lvsource) ~trusted ~modehash =
 235 object (self)
 236   val m_pan = source#getpan
 237   val m_first = source#getfirst
 238   val m_active = source#getactive
 239   val m_qsearch = E.s
 240   val m_prev_uioh = state.uioh
 241
 242   method private elemunder y =
 243     if y < 0
 244     then None
 245     else
 246       let n = y / (fstate.fontsize+1) in
 247       if m_first + n < source#getitemcount
 248       then (
 249         if source#hasaction (m_first + n)
 250         then Some (m_first + n)
 251         else None
 252       )
 253       else None
 254
 255   method display =
 256     Gl.enable `blend;
 257     GlFunc.blend_func ~src:`src_alpha ~dst:`one_minus_src_alpha;
 258     GlDraw.color (0., 0., 0.) ~alpha:0.85;
 259     filledrect 0. 0. (float state.winw) (float state.winh);
 260     GlDraw.color (1., 1., 1.);
 261     Gl.enable `texture_2d;
 262     let fs = fstate.fontsize in
 263     let nfs = fs + 1 in
 264     let hw = state.winw/3 in
 265     let ww = fstate.wwidth in
 266     let tabw = 17.0*.ww in
 267     let itemcount = source#getitemcount in
 268     let minfo = source#getminfo in
 269     if conf.leftscroll
 270     then (
 271       GlMat.push ();
 272       GlMat.translate ~x:(float conf.scrollbw) ();
 273     );
 274     let x0 = 0.0 and x1 = float (state.winw - conf.scrollbw - 1) in
 275     let rec loop row =
 276       if not ((row - m_first) > fstate.maxrows)
 277       then (
 278         if row >= 0 && row < itemcount
 279         then (
 280           let (s, level) = source#getitem row in
 281           let y = (row - m_first) * nfs in
 282           let x = 5.0 +. (float (level + m_pan)) *. ww in
 283           if helpmode
 284           then GlDraw.color
 285                  (let c = if row land 1 = 0 then 1.0 else 0.92 in (c,c,c));
 286
 287           if row = m_active
 288           then (
 289             Gl.disable `texture_2d;
 290             let alpha = if source#hasaction row then 0.9 else 0.3 in
 291             GlDraw.color (1., 1., 1.) ~alpha;
 292             linerect (x0 +. 1.) (float (y + 1)) (x1) (float (y + fs + 3));
 293             Gl.enable `texture_2d;
 294           );
 295           let c =
 296             if zebra && row land 1 = 1
 297             then 0.8
 298             else 1.0
 299           in
 300           GlDraw.color (c,c,c);
 301           let drawtabularstring s =
 302             let drawstr x s =
 303               let x' = truncate (x0 +. x) in
 304               let s1, s2 = splitatchar s '\000' in
 305               if emptystr s2
 306               then drawstring1 fs x' (y+nfs) s
 307               else
 308                 let rec e s =
 309                   if emptystr s
 310                   then s
 311                   else
 312                     let s' = withoutlastutf8 s in
 313                     let s = s' ^ Utf8syms.ellipsis in
 314                     let w = measurestr fs s in
 315                     if float x' +. w +. ww < float (hw + x')
 316                     then s
 317                     else e s'
 318                 in
 319                 let s1 =
 320                   if float x' +. ww +. measurestr fs s1 > float (hw + x')
 321                   then e s1
 322                   else s1
 323                 in
 324                 ignore (drawstring1 fs x' (y+nfs) s1);
 325                 drawstring1 fs (hw + x') (y+nfs) s2
 326             in
 327             if trusted
 328             then
 329               let x = if helpmode && row > 0 then x +. ww else x in
 330               let s1, s2 = splitatchar s '\t' in
 331               if nonemptystr s2
 332               then
 333                 let nx = drawstr x s1 in
 334                 let sw = nx -. x in
 335                 let x = x +. (max tabw sw) in
 336                 drawstr x s2
 337               else
 338                 let len = String.length s - 2 in
 339                 if len > 0 && s.[0] = '\xc2' && s.[1] = '\xb7'
 340                 then
 341                   let s = String.sub s 2 len in
 342                   let x = if not helpmode then x +. ww else x in
 343                   GlDraw.color (1.2, 1.2, 1.2);
 344                   let vinc = drawstring1 (fs+fs/4)
 345                                          (truncate (x -. ww)) (y+nfs) s in
 346                   GlDraw.color (1., 1., 1.);
 347                   vinc +. (float fs *. 0.8)
 348                 else drawstr x s
 349             else drawstr x s
 350           in
 351           ignore (drawtabularstring s);
 352           loop (row+1)
 353         )
 354       )
 355     in
 356     loop m_first;
 357     GlDraw.color (1.0, 1.0, 1.0) ~alpha:0.5;
 358     let xadj = 5.0 in
 359     let rec loop row =
 360       if (row - m_first) <= fstate.maxrows
 361       then
 362         if row >= 0 && row < itemcount
 363         then
 364           let (s, level) = source#getitem row in
 365           let pos0 = Ne.index s '\000' in
 366           let y = (row - m_first) * nfs in
 367           let x = float (level + m_pan) *. ww in
 368           let (first, last) = minfo.(row) in
 369           let prefix =
 370             if pos0 > 0 && first > pos0
 371             then String.sub s (pos0+1) (first-pos0-1)
 372             else String.sub s 0 first
 373           in
 374           let suffix = String.sub s first (last - first) in
 375           let w1 = measurestr fstate.fontsize prefix in
 376           let w2 = measurestr fstate.fontsize suffix in
 377           let x = x +. if conf.leftscroll then xadj else 5.0 in
 378           let x = if pos0 > 0 && first > pos0 then x +. float hw else x in
 379           let x0 = x +. w1
 380           and y0 = float (y+2) in
 381           let x1 = x0 +. w2
 382           and y1 = float (y+fs+3) in
 383           filledrect x0 y0 x1 y1;
 384           loop (row+1)
 385     in
 386     Gl.disable `texture_2d;
 387     if Array.length minfo > 0 then loop m_first;
 388     Gl.disable `blend;
 389     if conf.leftscroll
 390     then GlMat.pop ()
 391
 392   method updownlevel incr =
 393     let len = source#getitemcount in
 394     let curlevel =
 395       if m_active >= 0 && m_active < len
 396       then snd (source#getitem m_active)
 397       else -1
 398     in
 399     let rec flow i =
 400       if i = len then i-1 else if i = -1 then 0 else
 401         let _, l = source#getitem i in
 402         if l != curlevel then i else flow (i+incr)
 403     in
 404     let active = flow m_active in
 405     let first = calcfirst m_first active in
 406     postRedisplay "outline updownlevel";
 407     {< m_active = active; m_first = first >}
 408
 409   method private key1 key mask =
 410     let set1 active first qsearch =
 411       coe {< m_active = active; m_first = first; m_qsearch = qsearch >}
 412     in
 413     let search active pattern incr =
 414       let active = if active = -1 then m_first else active in
 415       let dosearch re =
 416         let rec loop n =
 417           if n >= 0 && n < source#getitemcount
 418           then (
 419             let s, _ = source#getitem n in
 420             match Str.search_forward re s 0 with
 421             | exception Not_found -> loop (n + incr)
 422             | _ -> Some n
 423           )
 424           else None
 425         in
 426         loop active
 427       in
 428       let qpat = Str.quote pattern in
 429       match Str.regexp_case_fold qpat with
 430       | s -> dosearch s
 431       | exception exn ->
 432          dolog "regexp_case_fold for `%S' failed: %S\n" qpat @@
 433            Printexc.to_string exn;
 434          None
 435     in
 436     let itemcount = source#getitemcount in
 437     let find start incr =
 438       let rec find i =
 439         if i = -1 || i = itemcount
 440         then -1
 441         else (
 442           if source#hasaction i
 443           then i
 444           else find (i + incr)
 445         )
 446       in
 447       find start
 448     in
 449     let set active first =
 450       let first = bound first 0 (itemcount - fstate.maxrows) in
 451       state.text <- E.s;
 452       coe {< m_active = active; m_first = first; m_qsearch = E.s >}
 453     in
 454     let navigate incr =
 455       let isvisible first n = n >= first && n - first <= fstate.maxrows in
 456       let active, first =
 457         let incr1 = if incr > 0 then 1 else -1 in
 458         if isvisible m_first m_active
 459         then
 460           let next =
 461             let next = m_active + incr in
 462             let next =
 463               if next < 0 || next >= itemcount
 464               then -1
 465               else find next incr1
 466             in
 467             if abs (m_active - next) > fstate.maxrows
 468             then -1
 469             else next
 470           in
 471           if next = -1
 472           then
 473             let first = m_first + incr in
 474             let first = bound first 0 (itemcount - fstate.maxrows) in
 475             let next =
 476               let next = m_active + incr in
 477               let next = bound next 0 (itemcount - 1) in
 478               find next ~-incr1
 479             in
 480             let active =
 481               if next = -1
 482               then m_active
 483               else (
 484                 if isvisible first next
 485                 then next
 486                 else m_active
 487               )
 488             in
 489             active, first
 490           else
 491             let first = min next m_first in
 492             let first =
 493               if abs (next - first) > fstate.maxrows
 494               then first + incr
 495               else first
 496             in
 497             next, first
 498         else
 499           let first = m_first + incr in
 500           let first = bound first 0 (itemcount - 1) in
 501           let active =
 502             let next = m_active + incr in
 503             let next = bound next 0 (itemcount - 1) in
 504             let next = find next incr1 in
 505             let active =
 506               if next = -1 || abs (m_active - first) > fstate.maxrows
 507               then (
 508                 let active = if m_active = -1 then next else m_active in
 509                 active
 510               )
 511               else next
 512             in
 513             if isvisible first active
 514             then active
 515             else -1
 516           in
 517           active, first
 518       in
 519       postRedisplay "listview navigate";
 520       set active first;
 521     in
 522     let open Keys in
 523     let kt = Wsi.kc2kt key in
 524     match [@warning "-4"] kt with
 525     | Ascii (('r'|'s') as c) when Wsi.withctrl mask ->
 526        let incr = if c = 'r' then -1 else 1 in
 527        let active, first =
 528          match search (m_active + incr) m_qsearch incr with
 529          | None ->
 530             state.text <- m_qsearch ^ " [not found]";
 531             m_active, m_first
 532          | Some active ->
 533             state.text <- m_qsearch;
 534             active, firstof m_first active
 535        in
 536        postRedisplay "listview ctrl-r/s";
 537        set1 active first m_qsearch;
 538
 539     | Insert when Wsi.withctrl mask ->
 540        if m_active >= 0 && m_active < source#getitemcount
 541        then (
 542          let s, _ = source#getitem m_active in
 543          selstring conf.selcmd s;
 544        );
 545        coe self
 546
 547     | Backspace ->
 548        if emptystr m_qsearch
 549        then coe self
 550        else (
 551          let qsearch = withoutlastutf8 m_qsearch in
 552          if emptystr qsearch
 553          then (
 554            state.text <- E.s;
 555            postRedisplay "listview empty qsearch";
 556            set1 m_active m_first E.s;
 557          )
 558          else
 559            let active, first =
 560              match search m_active qsearch ~-1 with
 561              | None ->
 562                 state.text <- qsearch ^ " [not found]";
 563                 m_active, m_first
 564              | Some active ->
 565                 state.text <- qsearch;
 566                 active, firstof m_first active
 567            in
 568            postRedisplay "listview backspace qsearch";
 569            set1 active first qsearch
 570        );
 571
 572     | Ascii _ | Code _ ->
 573        let utf8 =
 574          match [@warning "-8"] kt with
 575          | Ascii c -> String.make 1 c
 576          | Code code -> toutf8 code
 577        in
 578        let pattern = m_qsearch ^ utf8 in
 579        let active, first =
 580          match search m_active pattern 1 with
 581          | None ->
 582             state.text <- pattern ^ " [not found]";
 583             m_active, m_first
 584          | Some active ->
 585             state.text <- pattern;
 586             active, firstof m_first active
 587        in
 588        postRedisplay "listview qsearch add";
 589        set1 active first pattern;
 590
 591     | Escape ->
 592        state.text <- E.s;
 593        if emptystr m_qsearch
 594        then (
 595          postRedisplay "list view escape";
 596          (* XXX:
 597              let mx, my = state.mpos in
 598              updateunder mx my;
 599           *)
 600          getoptdef m_prev_uioh @@
 601            source#exit ~uioh:(coe self) ~cancel:true ~active:m_active
 602              ~first:m_first ~pan:m_pan
 603        )
 604        else (
 605          postRedisplay "list view kill qsearch";
 606          coe {< m_qsearch = E.s >}
 607        )
 608
 609     | Enter ->
 610        state.text <- E.s;
 611        let self = {< m_qsearch = E.s >} in
 612        let opt =
 613          postRedisplay "listview enter";
 614          let cancel = not (m_active >= 0 && m_active < source#getitemcount) in
 615          source#exit ~uioh:(coe self) ~cancel
 616                      ~active:m_active ~first:m_first ~pan:m_pan;
 617        in
 618        getoptdef m_prev_uioh opt
 619
 620     | Delete -> coe self
 621     | Up    -> navigate ~-1
 622     | Down  -> navigate 1
 623     | Prior -> navigate ~-(fstate.maxrows)
 624     | Next  -> navigate fstate.maxrows
 625
 626     | Right ->
 627        state.text <- E.s;
 628        postRedisplay "listview right";
 629        coe {< m_pan = m_pan - 1 >}
 630
 631     | Left ->
 632        state.text <- E.s;
 633        postRedisplay "listview left";
 634        coe {< m_pan = m_pan + 1 >}
 635
 636     | Home ->
 637        let active = find 0 1 in
 638        postRedisplay "listview home";
 639        set active 0;
 640
 641     | End ->
 642        let first = max 0 (itemcount - fstate.maxrows) in
 643        let active = find (itemcount - 1) ~-1 in
 644        postRedisplay "listview end";
 645        set active first;
 646
 647     | _ -> coe self
 648
 649   method key key mask =
 650     match state.mode with
 651     | Textentry te ->
 652        textentrykeyboard key mask te;
 653        coe self
 654     | Birdseye _ | View | LinkNav _ -> self#key1 key mask
 655
 656   method button button down x y _ =
 657     let opt =
 658       match button with
 659       | 1 when vscrollhit x ->
 660          postRedisplay "listview scroll";
 661          if down
 662          then
 663            let _, position, sh = self#scrollph in
 664            if y > truncate position && y < truncate (position +. sh)
 665            then (
 666              state.mstate <- Mscrolly;
 667              Some (coe self)
 668            )
 669            else
 670              let s = float (max 0 (y - conf.scrollh)) /. float state.winh in
 671              let first = truncate (s *. float source#getitemcount) in
 672              let first = min source#getitemcount first in
 673              Some (coe {< m_first = first; m_active = first >})
 674          else (
 675            state.mstate <- Mnone;
 676            Some (coe self);
 677          );
 678       | 1 when down ->
 679          begin match self#elemunder y with
 680          | Some n ->
 681             postRedisplay "listview click";
 682             source#exit ~uioh:(coe {< m_active = n >})
 683                         ~cancel:false ~active:n ~first:m_first ~pan:m_pan
 684          | _ ->
 685             Some (coe self)
 686          end
 687       | n when (n == 4 || n == 5) && not down ->
 688          let len = source#getitemcount in
 689          let first =
 690            if n = 5 && m_first + fstate.maxrows >= len
 691            then m_first
 692            else
 693              let first = m_first + (if n == 4 then -1 else 1) in
 694              bound first 0 (len - 1)
 695          in
 696          postRedisplay "listview wheel";
 697          Some (coe {< m_first = first >})
 698       | n when (n = 6 || n = 7) && not down ->
 699          let inc = if n = 7 then -1 else 1 in
 700          postRedisplay "listview hwheel";
 701          Some (coe {< m_pan = m_pan + inc >})
 702       | _ -> Some (coe self)
 703     in
 704     getoptdef m_prev_uioh opt
 705
 706   method multiclick _ x y = self#button 1 true x y
 707
 708   method motion _ y =
 709     match state.mstate with
 710     | Mscrolly ->
 711        let s = float (max 0 (y - conf.scrollh)) /. float state.winh in
 712        let first = truncate (s *. float source#getitemcount) in
 713        let first = min source#getitemcount first in
 714        postRedisplay "listview motion";
 715        coe {< m_first = first; m_active = first >}
 716     | Msel _
 717     | Mpan _
 718     | Mscrollx
 719     | Mzoom _
 720     | Mzoomrect _
 721     | Mnone -> coe self
 722
 723   method pmotion x y =
 724     if x < state.winw - conf.scrollbw
 725     then
 726       let n =
 727         match self#elemunder y with
 728         | None -> Wsi.setcursor Wsi.CURSOR_INHERIT; m_active
 729         | Some n -> Wsi.setcursor Wsi.CURSOR_INFO; n
 730       in
 731       let o =
 732         if n != m_active
 733         then (postRedisplay "listview pmotion"; {< m_active = n >})
 734         else self
 735       in
 736       coe o
 737     else (
 738       Wsi.setcursor Wsi.CURSOR_INHERIT;
 739       coe self
 740     )
 741
 742   method infochanged _ = ()
 743
 744   method scrollpw = (0, 0.0, 0.0)
 745   method scrollph =
 746     let nfs = fstate.fontsize + 1 in
 747     let y = m_first * nfs in
 748     let itemcount = source#getitemcount in
 749     let maxi = max 0 (itemcount - fstate.maxrows) in
 750     let maxy = maxi * nfs in
 751     let p, h = scrollph y maxy in
 752     conf.scrollbw, p, h
 753
 754   method modehash = modehash
 755   method eformsgs = false
 756   method alwaysscrolly = true
 757   method scroll _ dy =
 758     let self =
 759       if dy != 0 then begin
 760         let len = source#getitemcount in
 761         let first =
 762           if dy > 0 && m_first + fstate.maxrows >= len
 763           then m_first
 764           else
 765             let first = m_first + dy / 10 in
 766             bound first 0 (len - 1)
 767         in
 768         postRedisplay "listview wheel";
 769         {< m_first = first >}
 770       end else
 771         self
 772     in
 773     coe self
 774
 775   method zoom _ _ _ = ()
 776 end;;