scripts/kconfig/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #define LKC_DIRECT_LINK
  15 #include "lkc.h"
  16
  17 #include "zconf.hash.c"
  18
  19 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  20
  21 #define PRINTD          0x0001
  22 #define DEBUG_PARSE     0x0002
  23
  24 int cdebug = PRINTD;
  25
  26 extern int zconflex(void);
  27 static void zconfprint(const char *err, ...);
  28 static void zconferror(const char *err);
  29 static bool zconf_endtoken(int token, int starttoken, int endtoken);
  30
  31 struct symbol *symbol_hash[257];
  32
  33 static struct menu *current_menu, *current_entry;
  34
  35 #define YYERROR_VERBOSE
  36 %}
  37 %expect 40
  38
  39 %union
  40 {
  41         int token;
  42         char *string;
  43         struct symbol *symbol;
  44         struct expr *expr;
  45         struct menu *menu;
  46         struct kconf_id *id;
  47 }
  48
  49 %token <id>T_MAINMENU
  50 %token <id>T_MENU
  51 %token <id>T_ENDMENU
  52 %token <id>T_SOURCE
  53 %token <id>T_CHOICE
  54 %token <id>T_ENDCHOICE
  55 %token <id>T_COMMENT
  56 %token <id>T_CONFIG
  57 %token <id>T_MENUCONFIG
  58 %token <id>T_HELP
  59 %token <string> T_HELPTEXT
  60 %token <id>T_IF
  61 %token <id>T_ENDIF
  62 %token <id>T_DEPENDS
  63 %token <id>T_REQUIRES
  64 %token <id>T_OPTIONAL
  65 %token <id>T_PROMPT
  66 %token <id>T_TYPE
  67 %token <id>T_DEFAULT
  68 %token <id>T_SELECT
  69 %token <id>T_RANGE
  70 %token <id>T_ON
  71 %token <string> T_WORD
  72 %token <string> T_WORD_QUOTE
  73 %token T_UNEQUAL
  74 %token T_CLOSE_PAREN
  75 %token T_OPEN_PAREN
  76 %token T_EOL
  77 %token T_EOF
  78
  79 %left T_OR
  80 %left T_AND
  81 %left T_EQUAL T_UNEQUAL
  82 %nonassoc T_NOT
  83
  84 %type <string> prompt
  85 %type <string> source
  86 %type <symbol> symbol
  87 %type <expr> expr
  88 %type <expr> if_expr
  89 %type <token> end
  90
  91 %%
  92 input:    /* empty */
  93         | input block
  94 ;
  95
  96 block:    common_block
  97         | choice_stmt
  98         | menu_stmt
  99         | T_MAINMENU prompt nl_or_eof
 100         | T_ENDMENU             { zconfprint("unexpected 'endmenu' statement"); }
 101         | T_ENDIF               { zconfprint("unexpected 'endif' statement"); }
 102         | T_ENDCHOICE           { zconfprint("unexpected 'endchoice' statement"); }
 103         | error nl_or_eof       { zconfprint("syntax error"); yyerrok; }
 104 ;
 105
 106 common_block:
 107           if_stmt
 108         | comment_stmt
 109         | config_stmt
 110         | menuconfig_stmt
 111         | source_stmt
 112         | nl_or_eof
 113 ;
 114
 115
 116 /* config/menuconfig entry */
 117
 118 config_entry_start: T_CONFIG T_WORD T_EOL
 119 {
 120         struct symbol *sym = sym_lookup($2, 0);
 121         sym->flags |= SYMBOL_OPTIONAL;
 122         menu_add_entry(sym);
 123         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2);
 124 };
 125
 126 config_stmt: config_entry_start config_option_list
 127 {
 128         menu_end_entry();
 129         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 130 };
 131
 132 menuconfig_entry_start: T_MENUCONFIG T_WORD T_EOL
 133 {
 134         struct symbol *sym = sym_lookup($2, 0);
 135         sym->flags |= SYMBOL_OPTIONAL;
 136         menu_add_entry(sym);
 137         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2);
 138 };
 139
 140 menuconfig_stmt: menuconfig_entry_start config_option_list
 141 {
 142         if (current_entry->prompt)
 143                 current_entry->prompt->type = P_MENU;
 144         else
 145                 zconfprint("warning: menuconfig statement without prompt");
 146         menu_end_entry();
 147         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 148 };
 149
 150 config_option_list:
 151           /* empty */
 152         | config_option_list config_option
 153         | config_option_list depends
 154         | config_option_list help
 155         | config_option_list T_EOL
 156 ;
 157
 158 config_option: T_TYPE prompt_stmt_opt T_EOL
 159 {
 160         menu_set_type($1->stype);
 161         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 162                 zconf_curname(), zconf_lineno(),
 163                 $1->stype);
 164 };
 165
 166 config_option: T_PROMPT prompt if_expr T_EOL
 167 {
 168         menu_add_prompt(P_PROMPT, $2, $3);
 169         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 170 };
 171
 172 config_option: T_DEFAULT expr if_expr T_EOL
 173 {
 174         menu_add_expr(P_DEFAULT, $2, $3);
 175         if ($1->stype != S_UNKNOWN)
 176                 menu_set_type($1->stype);
 177         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 178                 zconf_curname(), zconf_lineno(),
 179                 $1->stype);
 180 };
 181
 182 config_option: T_SELECT T_WORD if_expr T_EOL
 183 {
 184         menu_add_symbol(P_SELECT, sym_lookup($2, 0), $3);
 185         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 186 };
 187
 188 config_option: T_RANGE symbol symbol if_expr T_EOL
 189 {
 190         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 191         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 192 };
 193
 194 /* choice entry */
 195
 196 choice: T_CHOICE T_EOL
 197 {
 198         struct symbol *sym = sym_lookup(NULL, 0);
 199         sym->flags |= SYMBOL_CHOICE;
 200         menu_add_entry(sym);
 201         menu_add_expr(P_CHOICE, NULL, NULL);
 202         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 203 };
 204
 205 choice_entry: choice choice_option_list
 206 {
 207         menu_end_entry();
 208         menu_add_menu();
 209 };
 210
 211 choice_end: end
 212 {
 213         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 214                 menu_end_menu();
 215                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 216         }
 217 };
 218
 219 choice_stmt:
 220           choice_entry choice_block choice_end
 221         | choice_entry choice_block
 222 {
 223         printf("%s:%d: missing 'endchoice' for this 'choice' statement\n", current_menu->file->name, current_menu->lineno);
 224         zconfnerrs++;
 225 };
 226
 227 choice_option_list:
 228           /* empty */
 229         | choice_option_list choice_option
 230         | choice_option_list depends
 231         | choice_option_list help
 232         | choice_option_list T_EOL
 233 ;
 234
 235 choice_option: T_PROMPT prompt if_expr T_EOL
 236 {
 237         menu_add_prompt(P_PROMPT, $2, $3);
 238         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 239 };
 240
 241 choice_option: T_TYPE prompt_stmt_opt T_EOL
 242 {
 243         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 244                 menu_set_type($1->stype);
 245                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 246                         zconf_curname(), zconf_lineno(),
 247                         $1->stype);
 248         } else
 249                 YYERROR;
 250 };
 251
 252 choice_option: T_OPTIONAL T_EOL
 253 {
 254         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 255         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 256 };
 257
 258 choice_option: T_DEFAULT T_WORD if_expr T_EOL
 259 {
 260         if ($1->stype == S_UNKNOWN) {
 261                 menu_add_symbol(P_DEFAULT, sym_lookup($2, 0), $3);
 262                 printd(DEBUG_PARSE, "%s:%d:default\n",
 263                         zconf_curname(), zconf_lineno());
 264         } else
 265                 YYERROR;
 266 };
 267
 268 choice_block:
 269           /* empty */
 270         | choice_block common_block
 271 ;
 272
 273 /* if entry */
 274
 275 if: T_IF expr T_EOL
 276 {
 277         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 278         menu_add_entry(NULL);
 279         menu_add_dep($2);
 280         menu_end_entry();
 281         menu_add_menu();
 282 };
 283
 284 if_end: end
 285 {
 286         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 287                 menu_end_menu();
 288                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 289         }
 290 };
 291
 292 if_stmt:
 293           if if_block if_end
 294         | if if_block
 295 {
 296         printf("%s:%d: missing 'endif' for this 'if' statement\n", current_menu->file->name, current_menu->lineno);
 297         zconfnerrs++;
 298 };
 299
 300 if_block:
 301           /* empty */
 302         | if_block common_block
 303         | if_block menu_stmt
 304         | if_block choice_stmt
 305 ;
 306
 307 /* menu entry */
 308
 309 menu: T_MENU prompt T_EOL
 310 {
 311         menu_add_entry(NULL);
 312         menu_add_prompt(P_MENU, $2, NULL);
 313         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 314 };
 315
 316 menu_entry: menu depends_list
 317 {
 318         menu_end_entry();
 319         menu_add_menu();
 320 };
 321
 322 menu_end: end
 323 {
 324         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 325                 menu_end_menu();
 326                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 327         }
 328 };
 329
 330 menu_stmt:
 331           menu_entry menu_block menu_end
 332         | menu_entry menu_block
 333 {
 334         printf("%s:%d: missing 'endmenu' for this 'menu' statement\n", current_menu->file->name, current_menu->lineno);
 335         zconfnerrs++;
 336 };
 337
 338 menu_block:
 339           /* empty */
 340         | menu_block common_block
 341         | menu_block menu_stmt
 342         | menu_block choice_stmt
 343         | menu_block error T_EOL                { zconfprint("invalid menu option"); yyerrok; }
 344 ;
 345
 346 source: T_SOURCE prompt T_EOL
 347 {
 348         $$ = $2;
 349         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 350 };
 351
 352 source_stmt: source
 353 {
 354         zconf_nextfile($1);
 355 };
 356
 357 /* comment entry */
 358
 359 comment: T_COMMENT prompt T_EOL
 360 {
 361         menu_add_entry(NULL);
 362         menu_add_prompt(P_COMMENT, $2, NULL);
 363         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 364 };
 365
 366 comment_stmt: comment depends_list
 367 {
 368         menu_end_entry();
 369 };
 370
 371 /* help option */
 372
 373 help_start: T_HELP T_EOL
 374 {
 375         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 376         zconf_starthelp();
 377 };
 378
 379 help: help_start T_HELPTEXT
 380 {
 381         current_entry->sym->help = $2;
 382 };
 383
 384 /* depends option */
 385
 386 depends_list:     /* empty */
 387                 | depends_list depends
 388                 | depends_list T_EOL
 389 ;
 390
 391 depends: T_DEPENDS T_ON expr T_EOL
 392 {
 393         menu_add_dep($3);
 394         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 395 }
 396         | T_DEPENDS expr T_EOL
 397 {
 398         menu_add_dep($2);
 399         printd(DEBUG_PARSE, "%s:%d:depends\n", zconf_curname(), zconf_lineno());
 400 }
 401         | T_REQUIRES expr T_EOL
 402 {
 403         menu_add_dep($2);
 404         printd(DEBUG_PARSE, "%s:%d:requires\n", zconf_curname(), zconf_lineno());
 405 };
 406
 407 /* prompt statement */
 408
 409 prompt_stmt_opt:
 410           /* empty */
 411         | prompt if_expr
 412 {
 413         menu_add_prompt(P_PROMPT, $1, $2);
 414 };
 415
 416 prompt:   T_WORD
 417         | T_WORD_QUOTE
 418 ;
 419
 420 end:      T_ENDMENU nl_or_eof   { $$ = T_ENDMENU; }
 421         | T_ENDCHOICE nl_or_eof { $$ = T_ENDCHOICE; }
 422         | T_ENDIF nl_or_eof     { $$ = T_ENDIF; }
 423 ;
 424
 425 nl_or_eof:
 426         T_EOL | T_EOF;
 427
 428 if_expr:  /* empty */                   { $$ = NULL; }
 429         | T_IF expr                     { $$ = $2; }
 430 ;
 431
 432 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 433         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 434         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 435         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 436         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 437         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 438         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 439 ;
 440
 441 symbol:   T_WORD        { $$ = sym_lookup($1, 0); free($1); }
 442         | T_WORD_QUOTE  { $$ = sym_lookup($1, 1); free($1); }
 443 ;
 444
 445 %%
 446
 447 void conf_parse(const char *name)
 448 {
 449         struct symbol *sym;
 450         int i;
 451
 452         zconf_initscan(name);
 453
 454         sym_init();
 455         menu_init();
 456         modules_sym = sym_lookup("MODULES", 0);
 457         rootmenu.prompt = menu_add_prompt(P_MENU, "Linux Kernel Configuration", NULL);
 458
 459         //zconfdebug = 1;
 460         zconfparse();
 461         if (zconfnerrs)
 462                 exit(1);
 463         menu_finalize(&rootmenu);
 464         for_all_symbols(i, sym) {
 465                 sym_check_deps(sym);
 466         }
 467
 468         sym_change_count = 1;
 469 }
 470
 471 const char *zconf_tokenname(int token)
 472 {
 473         switch (token) {
 474         case T_MENU:            return "menu";
 475         case T_ENDMENU:         return "endmenu";
 476         case T_CHOICE:          return "choice";
 477         case T_ENDCHOICE:       return "endchoice";
 478         case T_IF:              return "if";
 479         case T_ENDIF:           return "endif";
 480         }
 481         return "<token>";
 482 }
 483
 484 static bool zconf_endtoken(int token, int starttoken, int endtoken)
 485 {
 486         if (token != endtoken) {
 487                 zconfprint("unexpected '%s' within %s block", zconf_tokenname(token), zconf_tokenname(starttoken));
 488                 zconfnerrs++;
 489                 return false;
 490         }
 491         if (current_menu->file != current_file) {
 492                 zconfprint("'%s' in different file than '%s'", zconf_tokenname(token), zconf_tokenname(starttoken));
 493                 zconfprint("location of the '%s'", zconf_tokenname(starttoken));
 494                 zconfnerrs++;
 495                 return false;
 496         }
 497         return true;
 498 }
 499
 500 static void zconfprint(const char *err, ...)
 501 {
 502         va_list ap;
 503
 504         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno() + 1);
 505         va_start(ap, err);
 506         vfprintf(stderr, err, ap);
 507         va_end(ap);
 508         fprintf(stderr, "\n");
 509 }
 510
 511 static void zconferror(const char *err)
 512 {
 513         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 514 }
 515
 516 void print_quoted_string(FILE *out, const char *str)
 517 {
 518         const char *p;
 519         int len;
 520
 521         putc('"', out);
 522         while ((p = strchr(str, '"'))) {
 523                 len = p - str;
 524                 if (len)
 525                         fprintf(out, "%.*s", len, str);
 526                 fputs("\\\"", out);
 527                 str = p + 1;
 528         }
 529         fputs(str, out);
 530         putc('"', out);
 531 }
 532
 533 void print_symbol(FILE *out, struct menu *menu)
 534 {
 535         struct symbol *sym = menu->sym;
 536         struct property *prop;
 537
 538         if (sym_is_choice(sym))
 539                 fprintf(out, "choice\n");
 540         else
 541                 fprintf(out, "config %s\n", sym->name);
 542         switch (sym->type) {
 543         case S_BOOLEAN:
 544                 fputs("  boolean\n", out);
 545                 break;
 546         case S_TRISTATE:
 547                 fputs("  tristate\n", out);
 548                 break;
 549         case S_STRING:
 550                 fputs("  string\n", out);
 551                 break;
 552         case S_INT:
 553                 fputs("  integer\n", out);
 554                 break;
 555         case S_HEX:
 556                 fputs("  hex\n", out);
 557                 break;
 558         default:
 559                 fputs("  ???\n", out);
 560                 break;
 561         }
 562         for (prop = sym->prop; prop; prop = prop->next) {
 563                 if (prop->menu != menu)
 564                         continue;
 565                 switch (prop->type) {
 566                 case P_PROMPT:
 567                         fputs("  prompt ", out);
 568                         print_quoted_string(out, prop->text);
 569                         if (!expr_is_yes(prop->visible.expr)) {
 570                                 fputs(" if ", out);
 571                                 expr_fprint(prop->visible.expr, out);
 572                         }
 573                         fputc('\n', out);
 574                         break;
 575                 case P_DEFAULT:
 576                         fputs( "  default ", out);
 577                         expr_fprint(prop->expr, out);
 578                         if (!expr_is_yes(prop->visible.expr)) {
 579                                 fputs(" if ", out);
 580                                 expr_fprint(prop->visible.expr, out);
 581                         }
 582                         fputc('\n', out);
 583                         break;
 584                 case P_CHOICE:
 585                         fputs("  #choice value\n", out);
 586                         break;
 587                 default:
 588                         fprintf(out, "  unknown prop %d!\n", prop->type);
 589                         break;
 590                 }
 591         }
 592         if (sym->help) {
 593                 int len = strlen(sym->help);
 594                 while (sym->help[--len] == '\n')
 595                         sym->help[len] = 0;
 596                 fprintf(out, "  help\n%s\n", sym->help);
 597         }
 598         fputc('\n', out);
 599 }
 600
 601 void zconfdump(FILE *out)
 602 {
 603         struct property *prop;
 604         struct symbol *sym;
 605         struct menu *menu;
 606
 607         menu = rootmenu.list;
 608         while (menu) {
 609                 if ((sym = menu->sym))
 610                         print_symbol(out, menu);
 611                 else if ((prop = menu->prompt)) {
 612                         switch (prop->type) {
 613                         case P_COMMENT:
 614                                 fputs("\ncomment ", out);
 615                                 print_quoted_string(out, prop->text);
 616                                 fputs("\n", out);
 617                                 break;
 618                         case P_MENU:
 619                                 fputs("\nmenu ", out);
 620                                 print_quoted_string(out, prop->text);
 621                                 fputs("\n", out);
 622                                 break;
 623                         default:
 624                                 ;
 625                         }
 626                         if (!expr_is_yes(prop->visible.expr)) {
 627                                 fputs("  depends ", out);
 628                                 expr_fprint(prop->visible.expr, out);
 629                                 fputc('\n', out);
 630                         }
 631                         fputs("\n", out);
 632                 }
 633
 634                 if (menu->list)
 635                         menu = menu->list;
 636                 else if (menu->next)
 637                         menu = menu->next;
 638                 else while ((menu = menu->parent)) {
 639                         if (menu->prompt && menu->prompt->type == P_MENU)
 640                                 fputs("\nendmenu\n", out);
 641                         if (menu->next) {
 642                                 menu = menu->next;
 643                                 break;
 644                         }
 645                 }
 646         }
 647 }
 648
 649 #include "lex.zconf.c"
 650 #include "util.c"
 651 #include "confdata.c"
 652 #include "expr.c"
 653 #include "symbol.c"
 654 #include "menu.c"