arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 1;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(4);  /* R__ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.bootstrap.text)
  32         _stext = .;
  33         /* Then the rest */
  34         TEXT_TEXT
  35         SCHED_TEXT
  36         LOCK_TEXT
  37         KPROBES_TEXT
  38         *(.fixup)
  39         *(.gnu.warning)
  40         } :text = 0x9090
  41                                 /* out-of-line lock text */
  42   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  43
  44   _etext = .;                   /* End of text section */
  45
  46   . = ALIGN(16);                /* Exception table */
  47   __start___ex_table = .;
  48   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  49   __stop___ex_table = .;
  50
  51   NOTES :text :note
  52
  53   BUG_TABLE :text
  54
  55   RODATA
  56
  57   . = ALIGN(PAGE_SIZE);        /* Align data segment to page size boundary */
  58                                 /* Data */
  59   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  60         DATA_DATA
  61         CONSTRUCTORS
  62         } :data
  63
  64   _edata = .;                   /* End of data section */
  65
  66   . = ALIGN(PAGE_SIZE);
  67   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  68   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  69         *(.data.cacheline_aligned)
  70   }
  71   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  72   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  73         *(.data.read_mostly)
  74   }
  75
  76 #define VSYSCALL_ADDR (-10*1024*1024)
  77 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  78 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  79
  80 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  81 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  82
  83 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  84 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  85
  86   . = VSYSCALL_ADDR;
  87   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  88   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  89
  90   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  91   .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) }
  92   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  93   .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data))
  94                 { *(.vsyscall_gtod_data) }
  95   vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
  96
  97
  98   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1))
  99                 { *(.vsyscall_1) }
 100   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2))
 101                 { *(.vsyscall_2) }
 102
 103   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 104   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 105
 106   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 107   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 108   jiffies = VVIRT(.jiffies);
 109
 110   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3))
 111                 { *(.vsyscall_3) }
 112
 113   . = VSYSCALL_VIRT_ADDR + 4096;
 114
 115 #undef VSYSCALL_ADDR
 116 #undef VSYSCALL_PHYS_ADDR
 117 #undef VSYSCALL_VIRT_ADDR
 118 #undef VLOAD_OFFSET
 119 #undef VLOAD
 120 #undef VVIRT_OFFSET
 121 #undef VVIRT
 122
 123   . = ALIGN(8192);              /* init_task */
 124   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 125         *(.data.init_task)
 126   }:data.init
 127
 128   . = ALIGN(4096);
 129   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 130         *(.data.page_aligned)
 131   }
 132
 133   /* might get freed after init */
 134   . = ALIGN(4096);
 135   __smp_alt_begin = .;
 136   __smp_alt_instructions = .;
 137   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 138         *(.smp_altinstructions)
 139   }
 140   __smp_alt_instructions_end = .;
 141   . = ALIGN(8);
 142   __smp_locks = .;
 143   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 144         *(.smp_locks)
 145   }
 146   __smp_locks_end = .;
 147   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 148         *(.smp_altinstr_replacement)
 149   }
 150   . = ALIGN(4096);
 151   __smp_alt_end = .;
 152
 153   . = ALIGN(4096);              /* Init code and data */
 154   __init_begin = .;
 155   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 156         _sinittext = .;
 157         *(.init.text)
 158         _einittext = .;
 159   }
 160   __initdata_begin = .;
 161   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 162   __initdata_end = .;
 163   . = ALIGN(16);
 164   __setup_start = .;
 165   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 166   __setup_end = .;
 167   __initcall_start = .;
 168   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 169         INITCALLS
 170   }
 171   __initcall_end = .;
 172   __con_initcall_start = .;
 173   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 174         *(.con_initcall.init)
 175   }
 176   __con_initcall_end = .;
 177   SECURITY_INIT
 178   . = ALIGN(8);
 179   __alt_instructions = .;
 180   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 181         *(.altinstructions)
 182   }
 183   __alt_instructions_end = .;
 184   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 185         *(.altinstr_replacement)
 186   }
 187   /* .exit.text is discard at runtime, not link time, to deal with references
 188      from .altinstructions and .eh_frame */
 189   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 190   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 191
 192 #ifdef CONFIG_BLK_DEV_INITRD
 193   . = ALIGN(4096);
 194   __initramfs_start = .;
 195   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 196   __initramfs_end = .;
 197 #endif
 198
 199   PERCPU(4096)
 200
 201   . = ALIGN(4096);
 202   __init_end = .;
 203
 204   . = ALIGN(4096);
 205   __nosave_begin = .;
 206   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 207   . = ALIGN(4096);
 208   __nosave_end = .;
 209
 210   __bss_start = .;              /* BSS */
 211   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 212         *(.bss.page_aligned)
 213         *(.bss)
 214         }
 215   __bss_stop = .;
 216
 217   _end = . ;
 218
 219   /* Sections to be discarded */
 220   /DISCARD/ : {
 221         *(.exitcall.exit)
 222         *(.eh_frame)
 223         }
 224
 225   STABS_DEBUG
 226
 227   DWARF_DEBUG
 228 }