arch/s390x/vmlinux.lds.S

   1 /*
   2  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   3  */
   4
   5 #include <asm-generic/vmlinux.lds.h>
   6
   7 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
   8 OUTPUT_ARCH(s390:64-bit)
   9 ENTRY(_start)
  10 jiffies = jiffies_64;
  11 SECTIONS
  12 {
  13   . = 0x00000000;
  14   _text = .;                    /* Text and read-only data */
  15   .text : {
  16         *(.text)
  17         *(.fixup)
  18         *(.gnu.warning)
  19         } = 0x0700
  20
  21   _etext = .;                   /* End of text section */
  22
  23   . = ALIGN(16);                /* Exception table */
  24   __start___ex_table = .;
  25   __ex_table : { *(__ex_table) }
  26   __stop___ex_table = .;
  27
  28   RODATA
  29
  30 #ifdef CONFIG_SHARED_KERNEL
  31   . = ALIGN(1048576);           /* VM shared segments are 1MB aligned */
  32
  33   _eshared = .;                 /* End of shareable data */
  34 #endif
  35
  36   .data : {                     /* Data */
  37         *(.data)
  38         CONSTRUCTORS
  39         }
  40
  41   . = ALIGN(4096);
  42   __nosave_begin = .;
  43   .data_nosave : { *(.data.nosave) }
  44   . = ALIGN(4096);
  45   __nosave_end = .;
  46
  47   . = ALIGN(4096);
  48   .data.page_aligned : { *(.data.idt) }
  49
  50   . = ALIGN(32);
  51   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  52
  53   _edata = .;                   /* End of data section */
  54
  55   . = ALIGN(8192);              /* init_task */
  56   .data.init_task : { *(.data.init_task) }
  57
  58   /* will be freed after init */
  59   . = ALIGN(4096);              /* Init code and data */
  60   __init_begin = .;
  61   .init.text : { *(.init.text) }
  62   .init.data : { *(.init.data) }
  63   . = ALIGN(256);
  64   __setup_start = .;
  65   .init.setup : { *(.init.setup) }
  66   __setup_end = .;
  67   __initcall_start = .;
  68   .initcall.init : {
  69         *(.initcall1.init)
  70         *(.initcall2.init)
  71         *(.initcall3.init)
  72         *(.initcall4.init)
  73         *(.initcall5.init)
  74         *(.initcall6.init)
  75         *(.initcall7.init)
  76   }
  77   __initcall_end = .;
  78   . = ALIGN(256);
  79   __initramfs_start = .;
  80   .init.ramfs : { *(.init.initramfs) }
  81   __initramfs_end = .;
  82   . = ALIGN(256);
  83   __per_cpu_start = .;
  84   .data.percpu  : { *(.data.percpu) }
  85   __per_cpu_end = .;
  86   . = ALIGN(4096);
  87   __init_end = .;
  88   /* freed after init ends here */
  89
  90   __bss_start = .;              /* BSS */
  91   .bss : { *(.bss) }
  92   __bss_stop = .;
  93
  94   _end = . ;
  95
  96   /* Sections to be discarded */
  97   /DISCARD/ : {
  98         *(.exit.text)
  99         *(.exit.data)
 100         *(.exitcall.exit)
 101         }
 102
 103   /* Stabs debugging sections.  */
 104   .stab 0 : { *(.stab) }
 105   .stabstr 0 : { *(.stabstr) }
 106   .stab.excl 0 : { *(.stab.excl) }
 107   .stab.exclstr 0 : { *(.stab.exclstr) }
 108   .stab.index 0 : { *(.stab.index) }
 109   .stab.indexstr 0 : { *(.stab.indexstr) }
 110   .comment 0 : { *(.comment) }
 111 }