arch/s390/kernel/head64.S

   1 /*
   2  * arch/s390/kernel/head64.S
   3  *
   4  * Copyright (C) IBM Corp. 1999,2006
   5  *
   6  *   Author(s): Hartmut Penner <hp@de.ibm.com>
   7  *              Martin Schwidefsky <schwidefsky@de.ibm.com>
   8  *              Rob van der Heij <rvdhei@iae.nl>
   9  *              Heiko Carstens <heiko.carstens@de.ibm.com>
  10  *
  11  */
  12
  13 #
  14 # startup-code at 0x10000, running in absolute addressing mode
  15 # this is called either by the ipl loader or directly by PSW restart
  16 # or linload or SALIPL
  17 #
  18         .org    0x10000
  19 startup:basr    %r13,0                  # get base
  20 .LPG0:  l       %r13,0f-.LPG0(%r13)
  21         b       0(%r13)
  22 0:      .long   startup_continue
  23
  24 #
  25 # params at 10400 (setup.h)
  26 #
  27         .org    PARMAREA
  28         .quad   0                       # IPL_DEVICE
  29         .quad   0                       # INITRD_START
  30         .quad   0                       # INITRD_SIZE
  31
  32         .org    COMMAND_LINE
  33         .byte   "root=/dev/ram0 ro"
  34         .byte   0
  35
  36         .org    0x11000
  37
  38 startup_continue:
  39         basr    %r13,0                  # get base
  40 .LPG1:  sll     %r13,1                  # remove high order bit
  41         srl     %r13,1
  42         lhi     %r1,1                   # mode 1 = esame
  43         mvi     __LC_AR_MODE_ID,1       # set esame flag
  44         slr     %r0,%r0                 # set cpuid to zero
  45         sigp    %r1,%r0,0x12            # switch to esame mode
  46         sam64                           # switch to 64 bit mode
  47         lctlg   %c0,%c15,.Lctl-.LPG1(%r13)      # load control registers
  48         lg      %r12,.Lparmaddr-.LPG1(%r13)     # pointer to parameter area
  49                                         # move IPL device to lowcore
  50         mvc     __LC_IPLDEV(4),IPL_DEVICE+4-PARMAREA(%r12)
  51 #
  52 # Setup stack
  53 #
  54         larl    %r15,init_thread_union
  55         lg      %r14,__TI_task(%r15)    # cache current in lowcore
  56         stg     %r14,__LC_CURRENT
  57         aghi    %r15,1<<(PAGE_SHIFT+THREAD_ORDER) # init_task_union + THREAD_SIZE
  58         stg     %r15,__LC_KERNEL_STACK  # set end of kernel stack
  59         aghi    %r15,-160
  60         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear backchain
  61 #
  62 # Save ipl parameters, clear bss memory, initialize storage key for kernel pages,
  63 # and create a kernel NSS if the SAVESYS= parm is defined
  64 #
  65         brasl   %r14,startup_init
  66                                         # set program check new psw mask
  67         mvc     __LC_PGM_NEW_PSW(8),.Lpcmsk-.LPG1(%r13)
  68         larl    %r1,.Lslowmemdetect     # set program check address
  69         stg     %r1,__LC_PGM_NEW_PSW+8
  70         lghi    %r1,0xc
  71         diag    %r0,%r1,0x260           # get memory size of virtual machine
  72         cgr     %r0,%r1                 # different? -> old detection routine
  73         jne     .Lslowmemdetect
  74         larl    %r3,ipl_flags
  75         llgt    %r3,0(%r3)
  76         chi     %r3,4                   # ipled from an kernel NSS
  77         je      .Lslowmemdetect
  78         aghi    %r1,1                   # size is one more than end
  79         larl    %r2,memory_chunk
  80         stg     %r1,8(%r2)              # store size of chunk
  81
  82 .Lslowmemdetect:
  83         l       %r2,.Lrcp-.LPG1(%r13)   # Read SCP forced command word
  84 .Lservicecall:
  85         stosm   .Lpmask-.LPG1(%r13),0x01        # authorize ext interrupts
  86
  87         stctg   %r0,%r0,.Lcr-.LPG1(%r13)        # get cr0
  88         la      %r1,0x200               # set bit 22
  89         og      %r1,.Lcr-.LPG1(%r13)    # or old cr0 with r1
  90         stg     %r1,.Lcr-.LPG1(%r13)
  91         lctlg   %r0,%r0,.Lcr-.LPG1(%r13)        # load modified cr0
  92
  93         mvc     __LC_EXT_NEW_PSW(8),.Lpcmsk-.LPG1(%r13) # set postcall psw
  94         larl    %r1,.Lsclph
  95         stg     %r1,__LC_EXT_NEW_PSW+8  # set handler
  96
  97         larl    %r4,.Lsccb              # %r4 is our index for sccb stuff
  98         lgr     %r1,%r4                 # our sccb
  99         .insn   rre,0xb2200000,%r2,%r1  # service call
 100         ipm     %r1
 101         srl     %r1,28                  # get cc code
 102         xr      %r3,%r3
 103         chi     %r1,3
 104         be      .Lfchunk-.LPG1(%r13)    # leave
 105         chi     %r1,2
 106         be      .Lservicecall-.LPG1(%r13)
 107         lpswe   .Lwaitsclp-.LPG1(%r13)
 108 .Lsclph:
 109         lh      %r1,.Lsccbr-.Lsccb(%r4)
 110         chi     %r1,0x10                # 0x0010 is the sucess code
 111         je      .Lprocsccb              # let's process the sccb
 112         chi     %r1,0x1f0
 113         bne     .Lfchunk-.LPG1(%r13)    # unhandled error code
 114         c       %r2,.Lrcp-.LPG1(%r13)   # Did we try Read SCP forced
 115         bne     .Lfchunk-.LPG1(%r13)    # if no, give up
 116         l       %r2,.Lrcp2-.LPG1(%r13)  # try with Read SCP
 117         b       .Lservicecall-.LPG1(%r13)
 118 .Lprocsccb:
 119         lghi    %r1,0
 120         icm     %r1,3,.Lscpincr1-.Lsccb(%r4)    # use this one if != 0
 121         jnz     .Lscnd
 122         lg      %r1,.Lscpincr2-.Lsccb(%r4)      # otherwise use this one
 123 .Lscnd:
 124         xr      %r3,%r3                 # same logic
 125         ic      %r3,.Lscpa1-.Lsccb(%r4)
 126         chi     %r3,0x00
 127         jne     .Lcompmem
 128         l       %r3,.Lscpa2-.Lsccb(%r4)
 129 .Lcompmem:
 130         mlgr    %r2,%r1                 # mem in MB on 128-bit
 131         l       %r1,.Lonemb-.LPG1(%r13)
 132         mlgr    %r2,%r1                 # mem size in bytes in %r3
 133         b       .Lfchunk-.LPG1(%r13)
 134
 135         .align  4
 136 .Lpmask:
 137         .byte   0
 138         .align  8
 139 .Lcr:
 140         .quad   0x00  # place holder for cr0
 141 .Lwaitsclp:
 142         .quad   0x0102000180000000,.Lsclph
 143 .Lrcp:
 144         .int    0x00120001 # Read SCP forced code
 145 .Lrcp2:
 146         .int    0x00020001 # Read SCP code
 147 .Lonemb:
 148         .int    0x100000
 149
 150 .Lfchunk:
 151
 152 #
 153 # find memory chunks.
 154 #
 155         larl    %r9,memory_chunk        # skip tprot loop if diag260
 156         lg      %r9,8(%r9)              # memory detection was successful
 157         ltgr    %r9,%r9
 158         jne     .Ldonemem
 159
 160         lgr     %r9,%r3                 # end of mem
 161         larl    %r1,.Lchkmem            # set program check address
 162         stg     %r1,__LC_PGM_NEW_PSW+8
 163         la      %r1,1                   # test in increments of 128KB
 164         sllg    %r1,%r1,17
 165         larl    %r3,memory_chunk
 166         slgr    %r4,%r4                 # set start of chunk to zero
 167         slgr    %r5,%r5                 # set end of chunk to zero
 168         slr     %r6,%r6                 # set access code to zero
 169         la      %r10,MEMORY_CHUNKS      # number of chunks
 170 .Lloop:
 171         tprot   0(%r5),0                # test protection of first byte
 172         ipm     %r7
 173         srl     %r7,28
 174         clr     %r6,%r7                 # compare cc with last access code
 175         je      .Lsame
 176         lghi    %r8,0                   # no program checks
 177         j       .Lsavchk
 178 .Lsame:
 179         algr    %r5,%r1                 # add 128KB to end of chunk
 180                                         # no need to check here,
 181         brc     12,.Lloop               # this is the same chunk
 182 .Lchkmem:                               # > 16EB or tprot got a program check
 183         lghi    %r8,1                   # set program check flag
 184 .Lsavchk:
 185         clgr    %r4,%r5                 # chunk size > 0?
 186         je      .Lchkloop
 187         stg     %r4,0(%r3)              # store start address of chunk
 188         lgr     %r0,%r5
 189         slgr    %r0,%r4
 190         stg     %r0,8(%r3)              # store size of chunk
 191         st      %r6,20(%r3)             # store type of chunk
 192         la      %r3,24(%r3)
 193         ahi     %r10,-1                 # update chunk number
 194 .Lchkloop:
 195         lr      %r6,%r7                 # set access code to last cc
 196         # we got an exception or we're starting a new
 197         # chunk , we must check if we should
 198         # still try to find valid memory (if we detected
 199         # the amount of available storage), and if we
 200         # have chunks left
 201         lghi    %r4,1
 202         sllg    %r4,%r4,31
 203         clgr    %r5,%r4
 204         je      .Lhsaskip
 205         xr      %r0, %r0
 206         clgr    %r0, %r9                # did we detect memory?
 207         je      .Ldonemem               # if not, leave
 208         chi     %r10, 0                 # do we have chunks left?
 209         je      .Ldonemem
 210 .Lhsaskip:
 211         chi     %r8,1                   # program check ?
 212         je      .Lpgmchk
 213         lgr     %r4,%r5                 # potential new chunk
 214         algr    %r5,%r1                 # add 128KB to end of chunk
 215         j       .Llpcnt
 216 .Lpgmchk:
 217         algr    %r5,%r1                 # add 128KB to end of chunk
 218         lgr     %r4,%r5                 # potential new chunk
 219 .Llpcnt:
 220         clgr    %r5,%r9                 # should we go on?
 221         jl      .Lloop
 222 .Ldonemem:
 223
 224         larl    %r12,machine_flags
 225 #
 226 # find out if we have the MVPG instruction
 227 #
 228         la      %r1,0f-.LPG1(%r13)      # set program check address
 229         stg     %r1,__LC_PGM_NEW_PSW+8
 230         sgr     %r0,%r0
 231         lghi    %r1,0
 232         lghi    %r2,0
 233         mvpg    %r1,%r2                 # test MVPG instruction
 234         oi      7(%r12),16              # set MVPG flag
 235 0:
 236
 237 #
 238 # find out if the diag 0x44 works in 64 bit mode
 239 #
 240         la      %r1,0f-.LPG1(%r13)      # set program check address
 241         stg     %r1,__LC_PGM_NEW_PSW+8
 242         diag    0,0,0x44                # test diag 0x44
 243         oi      7(%r12),32              # set diag44 flag
 244 0:
 245
 246 #
 247 # find out if we have the IDTE instruction
 248 #
 249         la      %r1,0f-.LPG1(%r13)      # set program check address
 250         stg     %r1,__LC_PGM_NEW_PSW+8
 251         .long   0xb2b10000              # store facility list
 252         tm      0xc8,0x08               # check bit for clearing-by-ASCE
 253         bno     0f-.LPG1(%r13)
 254         lhi     %r1,2094
 255         lhi     %r2,0
 256         .long   0xb98e2001
 257         oi      7(%r12),0x80            # set IDTE flag
 258 0:
 259
 260 #
 261 # find out if the diag 0x9c is available
 262 #
 263         la      %r1,0f-.LPG1(%r13)      # set program check address
 264         stg     %r1,__LC_PGM_NEW_PSW+8
 265         stap    __LC_CPUID+4            # store cpu address
 266         lh      %r1,__LC_CPUID+4
 267         diag    %r1,0,0x9c              # test diag 0x9c
 268         oi      6(%r12),1               # set diag9c flag
 269 0:
 270
 271 #
 272 # find out if we have the MVCOS instruction
 273 #
 274         la      %r1,0f-.LPG1(%r13)      # set program check address
 275         stg     %r1,__LC_PGM_NEW_PSW+8
 276         .short  0xc800                  # mvcos 0(%r0),0(%r0),%r0
 277         .short  0x0000
 278         .short  0x0000
 279 0:      tm      0x8f,0x13               # special-operation exception?
 280         bno     1f-.LPG1(%r13)          # if yes, MVCOS is present
 281         oi      6(%r12),2               # set MVCOS flag
 282 1:
 283
 284         lpswe   .Lentry-.LPG1(13)       # jump to _stext in primary-space,
 285                                         # virtual and never return ...
 286         .align  16
 287 .Lentry:.quad   0x0000000180000000,_stext
 288 .Lctl:  .quad   0x04b50002              # cr0: various things
 289         .quad   0                       # cr1: primary space segment table
 290         .quad   .Lduct                  # cr2: dispatchable unit control table
 291         .quad   0                       # cr3: instruction authorization
 292         .quad   0                       # cr4: instruction authorization
 293         .quad   0xffffffffffffffff      # cr5: primary-aste origin
 294         .quad   0                       # cr6:  I/O interrupts
 295         .quad   0                       # cr7:  secondary space segment table
 296         .quad   0                       # cr8:  access registers translation
 297         .quad   0                       # cr9:  tracing off
 298         .quad   0                       # cr10: tracing off
 299         .quad   0                       # cr11: tracing off
 300         .quad   0                       # cr12: tracing off
 301         .quad   0                       # cr13: home space segment table
 302         .quad   0xc0000000              # cr14: machine check handling off
 303         .quad   0                       # cr15: linkage stack operations
 304 .Lduct: .long   0,0,0,0,0,0,0,0
 305         .long   0,0,0,0,0,0,0,0
 306 .Lpcmsk:.quad   0x0000000180000000
 307 .L4malign:.quad 0xffffffffffc00000
 308 .Lscan2g:.quad  0x80000000 + 0x20000 - 8        # 2GB + 128K - 8
 309 .Lnop:  .long   0x07000700
 310 .Lparmaddr:
 311         .quad   PARMAREA
 312
 313         .globl  ipl_schib
 314 ipl_schib:
 315         .rept 13
 316         .long 0
 317         .endr
 318
 319         .globl  ipl_flags
 320 ipl_flags:
 321         .long   0
 322         .globl  ipl_devno
 323 ipl_devno:
 324         .word 0
 325
 326         .org    0x12000
 327 .globl s390_readinfo_sccb
 328 s390_readinfo_sccb:
 329 .Lsccb:
 330         .hword  0x1000                  # length, one page
 331         .byte   0x00,0x00,0x00
 332         .byte   0x80                    # variable response bit set
 333 .Lsccbr:
 334         .hword  0x00                    # response code
 335 .Lscpincr1:
 336         .hword  0x00
 337 .Lscpa1:
 338         .byte   0x00
 339         .fill   89,1,0
 340 .Lscpa2:
 341         .int    0x00
 342 .Lscpincr2:
 343         .quad   0x00
 344         .fill   3984,1,0
 345         .org    0x13000
 346
 347 #ifdef CONFIG_SHARED_KERNEL
 348         .org    0x100000
 349 #endif
 350
 351 #
 352 # startup-code, running in absolute addressing mode
 353 #
 354         .globl  _stext
 355 _stext: basr    %r13,0                  # get base
 356 .LPG3:
 357 # check control registers
 358         stctg   %c0,%c15,0(%r15)
 359         oi      6(%r15),0x40            # enable sigp emergency signal
 360         oi      4(%r15),0x10            # switch on low address proctection
 361         lctlg   %c0,%c15,0(%r15)
 362
 363         lam     0,15,.Laregs-.LPG3(%r13)        # load acrs needed by uaccess
 364         brasl   %r14,start_kernel       # go to C code
 365 #
 366 # We returned from start_kernel ?!? PANIK
 367 #
 368         basr    %r13,0
 369         lpswe   .Ldw-.(%r13)            # load disabled wait psw
 370
 371         .align  8
 372 .Ldw:   .quad   0x0002000180000000,0x0000000000000000
 373 .Laregs:.long   0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0