arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9 #include <asm/page.h>
  10
  11 #define PROC_INFO                                                       \
  12         VMLINUX_SYMBOL(__proc_info_begin) = .;                          \
  13         *(.proc.info.init)                                              \
  14         VMLINUX_SYMBOL(__proc_info_end) = .;
  15
  16 #ifdef CONFIG_HOTPLUG_CPU
  17 #define ARM_CPU_DISCARD(x)
  18 #define ARM_CPU_KEEP(x)         x
  19 #else
  20 #define ARM_CPU_DISCARD(x)      x
  21 #define ARM_CPU_KEEP(x)
  22 #endif
  23
  24 OUTPUT_ARCH(arm)
  25 ENTRY(stext)
  26
  27 #ifndef __ARMEB__
  28 jiffies = jiffies_64;
  29 #else
  30 jiffies = jiffies_64 + 4;
  31 #endif
  32
  33 SECTIONS
  34 {
  35 #ifdef CONFIG_XIP_KERNEL
  36         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  37 #else
  38         . = PAGE_OFFSET + TEXT_OFFSET;
  39 #endif
  40
  41         .init : {                       /* Init code and data           */
  42                 _stext = .;
  43                 _sinittext = .;
  44                         HEAD_TEXT
  45                         INIT_TEXT
  46                 _einittext = .;
  47                 ARM_CPU_DISCARD(PROC_INFO)
  48                 __arch_info_begin = .;
  49                         *(.arch.info.init)
  50                 __arch_info_end = .;
  51                 __tagtable_begin = .;
  52                         *(.taglist.init)
  53                 __tagtable_end = .;
  54 #ifdef CONFIG_SMP_ON_UP
  55                 __smpalt_begin = .;
  56                         *(.alt.smp.init)
  57                 __smpalt_end = .;
  58 #endif
  59
  60                 __pv_table_begin = .;
  61                         *(.pv_table)
  62                 __pv_table_end = .;
  63
  64                 INIT_SETUP(16)
  65
  66                 INIT_CALLS
  67                 CON_INITCALL
  68                 SECURITY_INITCALL
  69                 INIT_RAM_FS
  70
  71 #ifndef CONFIG_XIP_KERNEL
  72                 __init_begin = _stext;
  73                 INIT_DATA
  74 #endif
  75         }
  76
  77         PERCPU(PAGE_SIZE)
  78
  79 #ifndef CONFIG_XIP_KERNEL
  80         . = ALIGN(PAGE_SIZE);
  81         __init_end = .;
  82 #endif
  83
  84         /*
  85          * unwind exit sections must be discarded before the rest of the
  86          * unwind sections get included.
  87          */
  88         /DISCARD/ : {
  89                 *(.ARM.exidx.exit.text)
  90                 *(.ARM.extab.exit.text)
  91                 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
  92                 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
  93 #ifndef CONFIG_HOTPLUG
  94                 *(.ARM.exidx.devexit.text)
  95                 *(.ARM.extab.devexit.text)
  96 #endif
  97 #ifndef CONFIG_MMU
  98                 *(.fixup)
  99                 *(__ex_table)
 100 #endif
 101         }
 102
 103         .text : {                       /* Real text segment            */
 104                 _text = .;              /* Text and read-only data      */
 105                         __exception_text_start = .;
 106                         *(.exception.text)
 107                         __exception_text_end = .;
 108                         IRQENTRY_TEXT
 109                         TEXT_TEXT
 110                         SCHED_TEXT
 111                         LOCK_TEXT
 112                         KPROBES_TEXT
 113 #ifdef CONFIG_MMU
 114                         *(.fixup)
 115 #endif
 116                         *(.gnu.warning)
 117                         *(.rodata)
 118                         *(.rodata.*)
 119                         *(.glue_7)
 120                         *(.glue_7t)
 121                 . = ALIGN(4);
 122                 *(.got)                 /* Global offset table          */
 123                         ARM_CPU_KEEP(PROC_INFO)
 124         }
 125
 126         RO_DATA(PAGE_SIZE)
 127
 128 #ifdef CONFIG_ARM_UNWIND
 129         /*
 130          * Stack unwinding tables
 131          */
 132         . = ALIGN(8);
 133         .ARM.unwind_idx : {
 134                 __start_unwind_idx = .;
 135                 *(.ARM.exidx*)
 136                 __stop_unwind_idx = .;
 137         }
 138         .ARM.unwind_tab : {
 139                 __start_unwind_tab = .;
 140                 *(.ARM.extab*)
 141                 __stop_unwind_tab = .;
 142         }
 143 #endif
 144
 145         _etext = .;                     /* End of text and rodata section */
 146
 147 #ifdef CONFIG_XIP_KERNEL
 148         __data_loc = ALIGN(4);          /* location in binary */
 149         . = PAGE_OFFSET + TEXT_OFFSET;
 150 #else
 151         . = ALIGN(THREAD_SIZE);
 152         __data_loc = .;
 153 #endif
 154
 155         .data : AT(__data_loc) {
 156                 _data = .;              /* address in memory */
 157                 _sdata = .;
 158
 159                 /*
 160                  * first, the init task union, aligned
 161                  * to an 8192 byte boundary.
 162                  */
 163                 INIT_TASK_DATA(THREAD_SIZE)
 164
 165 #ifdef CONFIG_XIP_KERNEL
 166                 . = ALIGN(PAGE_SIZE);
 167                 __init_begin = .;
 168                 INIT_DATA
 169                 . = ALIGN(PAGE_SIZE);
 170                 __init_end = .;
 171 #endif
 172
 173                 NOSAVE_DATA
 174                 CACHELINE_ALIGNED_DATA(32)
 175                 READ_MOSTLY_DATA(32)
 176
 177                 /*
 178                  * The exception fixup table (might need resorting at runtime)
 179                  */
 180                 . = ALIGN(32);
 181                 __start___ex_table = .;
 182 #ifdef CONFIG_MMU
 183                 *(__ex_table)
 184 #endif
 185                 __stop___ex_table = .;
 186
 187                 /*
 188                  * and the usual data section
 189                  */
 190                 DATA_DATA
 191                 CONSTRUCTORS
 192
 193                 _edata = .;
 194         }
 195         _edata_loc = __data_loc + SIZEOF(.data);
 196
 197 #ifdef CONFIG_HAVE_TCM
 198         /*
 199          * We align everything to a page boundary so we can
 200          * free it after init has commenced and TCM contents have
 201          * been copied to its destination.
 202          */
 203         .tcm_start : {
 204                 . = ALIGN(PAGE_SIZE);
 205                 __tcm_start = .;
 206                 __itcm_start = .;
 207         }
 208
 209         /*
 210          * Link these to the ITCM RAM
 211          * Put VMA to the TCM address and LMA to the common RAM
 212          * and we'll upload the contents from RAM to TCM and free
 213          * the used RAM after that.
 214          */
 215         .text_itcm ITCM_OFFSET : AT(__itcm_start)
 216         {
 217                 __sitcm_text = .;
 218                 *(.tcm.text)
 219                 *(.tcm.rodata)
 220                 . = ALIGN(4);
 221                 __eitcm_text = .;
 222         }
 223
 224         /*
 225          * Reset the dot pointer, this is needed to create the
 226          * relative __dtcm_start below (to be used as extern in code).
 227          */
 228         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
 229
 230         .dtcm_start : {
 231                 __dtcm_start = .;
 232         }
 233
 234         /* TODO: add remainder of ITCM as well, that can be used for data! */
 235         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
 236         {
 237                 . = ALIGN(4);
 238                 __sdtcm_data = .;
 239                 *(.tcm.data)
 240                 . = ALIGN(4);
 241                 __edtcm_data = .;
 242         }
 243
 244         /* Reset the dot pointer or the linker gets confused */
 245         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
 246
 247         /* End marker for freeing TCM copy in linked object */
 248         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
 249                 . = ALIGN(PAGE_SIZE);
 250                 __tcm_end = .;
 251         }
 252 #endif
 253
 254         BSS_SECTION(0, 0, 0)
 255         _end = .;
 256
 257         STABS_DEBUG
 258         .comment 0 : { *(.comment) }
 259
 260         /* Default discards */
 261         DISCARDS
 262
 263 #ifndef CONFIG_SMP_ON_UP
 264         /DISCARD/ : {
 265                 *(.alt.smp.init)
 266         }
 267 #endif
 268 }
 269
 270 /*
 271  * These must never be empty
 272  * If you have to comment these two assert statements out, your
 273  * binutils is too old (for other reasons as well)
 274  */
 275 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 276 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")