arch/x86/boot/compressed/head_32.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24         .text
  25
  26 #include <linux/linkage.h>
  27 #include <asm/segment.h>
  28 #include <asm/page_types.h>
  29 #include <asm/boot.h>
  30 #include <asm/asm-offsets.h>
  31
  32         .section ".text.head","ax",@progbits
  33 ENTRY(startup_32)
  34         cld
  35         /*
  36          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
  37          * us to not reload segments
  38          */
  39         testb   $(1<<6), BP_loadflags(%esi)
  40         jnz     1f
  41
  42         cli
  43         movl    $__BOOT_DS, %eax
  44         movl    %eax, %ds
  45         movl    %eax, %es
  46         movl    %eax, %fs
  47         movl    %eax, %gs
  48         movl    %eax, %ss
  49 1:
  50
  51 /*
  52  * Calculate the delta between where we were compiled to run
  53  * at and where we were actually loaded at.  This can only be done
  54  * with a short local call on x86.  Nothing  else will tell us what
  55  * address we are running at.  The reserved chunk of the real-mode
  56  * data at 0x1e4 (defined as a scratch field) are used as the stack
  57  * for this calculation. Only 4 bytes are needed.
  58  */
  59         leal    (BP_scratch+4)(%esi), %esp
  60         call    1f
  61 1:      popl    %ebp
  62         subl    $1b, %ebp
  63
  64 /*
  65  * %ebp contains the address we are loaded at by the boot loader and %ebx
  66  * contains the address where we should move the kernel image temporarily
  67  * for safe in-place decompression.
  68  */
  69
  70 #ifdef CONFIG_RELOCATABLE
  71         movl    %ebp, %ebx
  72         addl    $(CONFIG_PHYSICAL_ALIGN - 1), %ebx
  73         andl    $(~(CONFIG_PHYSICAL_ALIGN - 1)), %ebx
  74 #else
  75         movl    $LOAD_PHYSICAL_ADDR, %ebx
  76 #endif
  77
  78         /* Replace the compressed data size with the uncompressed size */
  79         subl    input_len(%ebp), %ebx
  80         movl    output_len(%ebp), %eax
  81         addl    %eax, %ebx
  82         /* Add 8 bytes for every 32K input block */
  83         shrl    $12, %eax
  84         addl    %eax, %ebx
  85         /* Add 32K + 18 bytes of extra slack */
  86         addl    $(32768 + 18), %ebx
  87         /* Align on a 4K boundary */
  88         addl    $4095, %ebx
  89         andl    $~4095, %ebx
  90
  91 /*
  92  * Copy the compressed kernel to the end of our buffer
  93  * where decompression in place becomes safe.
  94  */
  95         pushl   %esi
  96         leal    _ebss(%ebp), %esi
  97         leal    _ebss(%ebx), %edi
  98         movl    $(_ebss - startup_32), %ecx
  99         std
 100         rep     movsb
 101         cld
 102         popl    %esi
 103
 104 /*
 105  * Compute the kernel start address.
 106  */
 107 #ifdef CONFIG_RELOCATABLE
 108         addl    $(CONFIG_PHYSICAL_ALIGN - 1), %ebp
 109         andl    $(~(CONFIG_PHYSICAL_ALIGN - 1)), %ebp
 110 #else
 111         movl    $LOAD_PHYSICAL_ADDR, %ebp
 112 #endif
 113
 114 /*
 115  * Jump to the relocated address.
 116  */
 117         leal    relocated(%ebx), %eax
 118         jmp     *%eax
 119 ENDPROC(startup_32)
 120
 121         .text
 122 relocated:
 123
 124 /*
 125  * Clear BSS
 126  */
 127         xorl    %eax, %eax
 128         leal    _edata(%ebx), %edi
 129         leal    _ebss(%ebx), %ecx
 130         subl    %edi, %ecx
 131         cld
 132         rep     stosb
 133
 134 /*
 135  * Setup the stack for the decompressor
 136  */
 137         leal    boot_stack_end(%ebx), %esp
 138
 139 /*
 140  * Do the decompression, and jump to the new kernel..
 141  */
 142         movl    output_len(%ebx), %eax
 143         pushl   %eax
 144                                 /* push arguments for decompress_kernel: */
 145         pushl   %ebp            /* output address */
 146         movl    input_len(%ebx), %eax
 147         pushl   %eax            /* input_len */
 148         leal    input_data(%ebx), %eax
 149         pushl   %eax            /* input_data */
 150         leal    boot_heap(%ebx), %eax
 151         pushl   %eax            /* heap area */
 152         pushl   %esi            /* real mode pointer */
 153         call    decompress_kernel
 154         addl    $20, %esp
 155         popl    %ecx
 156
 157 #if CONFIG_RELOCATABLE
 158 /*
 159  * Find the address of the relocations.
 160  */
 161         movl    %ebp, %edi
 162         addl    %ecx, %edi
 163
 164 /*
 165  * Calculate the delta between where vmlinux was compiled to run
 166  * and where it was actually loaded.
 167  */
 168         movl    %ebp, %ebx
 169         subl    $LOAD_PHYSICAL_ADDR, %ebx
 170         jz      2f      /* Nothing to be done if loaded at compiled addr. */
 171 /*
 172  * Process relocations.
 173  */
 174
 175 1:      subl    $4, %edi
 176         movl    (%edi), %ecx
 177         testl   %ecx, %ecx
 178         jz      2f
 179         addl    %ebx, -__PAGE_OFFSET(%ebx, %ecx)
 180         jmp     1b
 181 2:
 182 #endif
 183
 184 /*
 185  * Jump to the decompressed kernel.
 186  */
 187         xorl    %ebx, %ebx
 188         jmp     *%ebp
 189
 190 /*
 191  * Stack and heap for uncompression
 192  */
 193         .bss
 194         .balign 4
 195 boot_heap:
 196         .fill BOOT_HEAP_SIZE, 1, 0
 197 boot_stack:
 198         .fill BOOT_STACK_SIZE, 1, 0
 199 boot_stack_end: