arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <mach/entry-macro.S>
  14 #include <asm/unwind.h>
  15
  16 #include "entry-header.S"
  17
  18
  19         .align  5
  20 /*
  21  * This is the fast syscall return path.  We do as little as
  22  * possible here, and this includes saving r0 back into the SVC
  23  * stack.
  24  */
  25 ret_fast_syscall:
  26  UNWIND(.fnstart        )
  27  UNWIND(.cantunwind     )
  28         disable_irq                             @ disable interrupts
  29         ldr     r1, [tsk, #TI_FLAGS]
  30         tst     r1, #_TIF_WORK_MASK
  31         bne     fast_work_pending
  32
  33         /* perform architecture specific actions before user return */
  34         arch_ret_to_user r1, lr
  35
  36         @ fast_restore_user_regs
  37         ldr     r1, [sp, #S_OFF + S_PSR]        @ get calling cpsr
  38         ldr     lr, [sp, #S_OFF + S_PC]!        @ get pc
  39         msr     spsr_cxsf, r1                   @ save in spsr_svc
  40         ldmdb   sp, {r1 - lr}^                  @ get calling r1 - lr
  41         mov     r0, r0
  42         add     sp, sp, #S_FRAME_SIZE - S_PC
  43         movs    pc, lr                          @ return & move spsr_svc into cpsr
  44  UNWIND(.fnend          )
  45
  46 /*
  47  * Ok, we need to do extra processing, enter the slow path.
  48  */
  49 fast_work_pending:
  50         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  51 work_pending:
  52         tst     r1, #_TIF_NEED_RESCHED
  53         bne     work_resched
  54         tst     r1, #_TIF_SIGPENDING
  55         beq     no_work_pending
  56         mov     r0, sp                          @ 'regs'
  57         mov     r2, why                         @ 'syscall'
  58         bl      do_notify_resume
  59         b       ret_slow_syscall                @ Check work again
  60
  61 work_resched:
  62         bl      schedule
  63 /*
  64  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  65  */
  66 ENTRY(ret_to_user)
  67 ret_slow_syscall:
  68         disable_irq                             @ disable interrupts
  69         ldr     r1, [tsk, #TI_FLAGS]
  70         tst     r1, #_TIF_WORK_MASK
  71         bne     work_pending
  72 no_work_pending:
  73         /* perform architecture specific actions before user return */
  74         arch_ret_to_user r1, lr
  75
  76         @ slow_restore_user_regs
  77         ldr     r1, [sp, #S_PSR]                @ get calling cpsr
  78         ldr     lr, [sp, #S_PC]!                @ get pc
  79         msr     spsr_cxsf, r1                   @ save in spsr_svc
  80         ldmdb   sp, {r0 - lr}^                  @ get calling r0 - lr
  81         mov     r0, r0
  82         add     sp, sp, #S_FRAME_SIZE - S_PC
  83         movs    pc, lr                          @ return & move spsr_svc into cpsr
  84 ENDPROC(ret_to_user)
  85
  86 /*
  87  * This is how we return from a fork.
  88  */
  89 ENTRY(ret_from_fork)
  90         bl      schedule_tail
  91         get_thread_info tsk
  92         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  93         mov     why, #1
  94         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  95         beq     ret_slow_syscall
  96         mov     r1, sp
  97         mov     r0, #1                          @ trace exit [IP = 1]
  98         bl      syscall_trace
  99         b       ret_slow_syscall
 100 ENDPROC(ret_from_fork)
 101
 102         .equ NR_syscalls,0
 103 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
 104 #include "calls.S"
 105 #undef CALL
 106 #define CALL(x) .long x
 107
 108 #ifdef CONFIG_FUNCTION_TRACER
 109 #ifdef CONFIG_DYNAMIC_FTRACE
 110 ENTRY(mcount)
 111         stmdb sp!, {r0-r3, lr}
 112         mov r0, lr
 113         sub r0, r0, #MCOUNT_INSN_SIZE
 114
 115         .globl mcount_call
 116 mcount_call:
 117         bl ftrace_stub
 118         ldr lr, [fp, #-4]                       @ restore lr
 119         ldmia sp!, {r0-r3, pc}
 120
 121 ENTRY(ftrace_caller)
 122         stmdb sp!, {r0-r3, lr}
 123         ldr r1, [fp, #-4]
 124         mov r0, lr
 125         sub r0, r0, #MCOUNT_INSN_SIZE
 126
 127         .globl ftrace_call
 128 ftrace_call:
 129         bl ftrace_stub
 130         ldr lr, [fp, #-4]                       @ restore lr
 131         ldmia sp!, {r0-r3, pc}
 132
 133 #else
 134
 135 ENTRY(__gnu_mcount_nc)
 136         stmdb sp!, {r0-r3, lr}
 137         ldr r0, =ftrace_trace_function
 138         ldr r2, [r0]
 139         adr r0, ftrace_stub
 140         cmp r0, r2
 141         bne gnu_trace
 142         ldmia sp!, {r0-r3, ip, lr}
 143         bx ip
 144
 145 gnu_trace:
 146         ldr r1, [sp, #20]                       @ lr of instrumented routine
 147         mov r0, lr
 148         sub r0, r0, #MCOUNT_INSN_SIZE
 149         mov lr, pc
 150         mov pc, r2
 151         ldmia sp!, {r0-r3, ip, lr}
 152         bx ip
 153
 154 ENTRY(mcount)
 155         stmdb sp!, {r0-r3, lr}
 156         ldr r0, =ftrace_trace_function
 157         ldr r2, [r0]
 158         adr r0, ftrace_stub
 159         cmp r0, r2
 160         bne trace
 161         ldr lr, [fp, #-4]                       @ restore lr
 162         ldmia sp!, {r0-r3, pc}
 163
 164 trace:
 165         ldr r1, [fp, #-4]                       @ lr of instrumented routine
 166         mov r0, lr
 167         sub r0, r0, #MCOUNT_INSN_SIZE
 168         mov lr, pc
 169         mov pc, r2
 170         mov lr, r1                              @ restore lr
 171         ldmia sp!, {r0-r3, pc}
 172
 173 #endif /* CONFIG_DYNAMIC_FTRACE */
 174
 175         .globl ftrace_stub
 176 ftrace_stub:
 177         mov pc, lr
 178
 179 #endif /* CONFIG_FUNCTION_TRACER */
 180
 181 /*=============================================================================
 182  * SWI handler
 183  *-----------------------------------------------------------------------------
 184  */
 185
 186         /* If we're optimising for StrongARM the resulting code won't
 187            run on an ARM7 and we can save a couple of instructions.
 188                                                                 --pb */
 189 #ifdef CONFIG_CPU_ARM710
 190 #define A710(code...) code
 191 .Larm710bug:
 192         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 193         mov     r0, r0
 194         add     sp, sp, #S_FRAME_SIZE
 195         subs    pc, lr, #4
 196 #else
 197 #define A710(code...)
 198 #endif
 199
 200         .align  5
 201 ENTRY(vector_swi)
 202         sub     sp, sp, #S_FRAME_SIZE
 203         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 204         add     r8, sp, #S_PC
 205         stmdb   r8, {sp, lr}^                   @ Calling sp, lr
 206         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 207         str     lr, [sp, #S_PC]                 @ Save calling PC
 208         str     r8, [sp, #S_PSR]                @ Save CPSR
 209         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 210         zero_fp
 211
 212         /*
 213          * Get the system call number.
 214          */
 215
 216 #if defined(CONFIG_OABI_COMPAT)
 217
 218         /*
 219          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 220          * value to determine if it is an EABI or an old ABI call.
 221          */
 222 #ifdef CONFIG_ARM_THUMB
 223         tst     r8, #PSR_T_BIT
 224         movne   r10, #0                         @ no thumb OABI emulation
 225         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 226 #else
 227         ldr     r10, [lr, #-4]                  @ get SWI instruction
 228   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
 229   A710( teq     ip, #0x0f000000                                         )
 230   A710( bne     .Larm710bug                                             )
 231 #endif
 232 #ifdef CONFIG_CPU_ENDIAN_BE8
 233         rev     r10, r10                        @ little endian instruction
 234 #endif
 235
 236 #elif defined(CONFIG_AEABI)
 237
 238         /*
 239          * Pure EABI user space always put syscall number into scno (r7).
 240          */
 241   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
 242   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
 243   A710( teq     ip, #0x0f000000                                         )
 244   A710( bne     .Larm710bug                                             )
 245
 246 #elif defined(CONFIG_ARM_THUMB)
 247
 248         /* Legacy ABI only, possibly thumb mode. */
 249         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 250         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 251         ldreq   scno, [lr, #-4]
 252
 253 #else
 254
 255         /* Legacy ABI only. */
 256         ldr     scno, [lr, #-4]                 @ get SWI instruction
 257   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
 258   A710( teq     ip, #0x0f000000                                         )
 259   A710( bne     .Larm710bug                                             )
 260
 261 #endif
 262
 263 #ifdef CONFIG_ALIGNMENT_TRAP
 264         ldr     ip, __cr_alignment
 265         ldr     ip, [ip]
 266         mcr     p15, 0, ip, c1, c0              @ update control register
 267 #endif
 268         enable_irq
 269
 270         get_thread_info tsk
 271         adr     tbl, sys_call_table             @ load syscall table pointer
 272         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
 273
 274 #if defined(CONFIG_OABI_COMPAT)
 275         /*
 276          * If the swi argument is zero, this is an EABI call and we do nothing.
 277          *
 278          * If this is an old ABI call, get the syscall number into scno and
 279          * get the old ABI syscall table address.
 280          */
 281         bics    r10, r10, #0xff000000
 282         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 283         ldrne   tbl, =sys_oabi_call_table
 284 #elif !defined(CONFIG_AEABI)
 285         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 286         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 287 #endif
 288
 289         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 290         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
 291         bne     __sys_trace
 292
 293         cmp     scno, #NR_syscalls              @ check upper syscall limit
 294         adr     lr, ret_fast_syscall            @ return address
 295         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 296
 297         add     r1, sp, #S_OFF
 298 2:      mov     why, #0                         @ no longer a real syscall
 299         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 300         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 301         bcs     arm_syscall
 302         b       sys_ni_syscall                  @ not private func
 303 ENDPROC(vector_swi)
 304
 305         /*
 306          * This is the really slow path.  We're going to be doing
 307          * context switches, and waiting for our parent to respond.
 308          */
 309 __sys_trace:
 310         mov     r2, scno
 311         add     r1, sp, #S_OFF
 312         mov     r0, #0                          @ trace entry [IP = 0]
 313         bl      syscall_trace
 314
 315         adr     lr, __sys_trace_return          @ return address
 316         mov     scno, r0                        @ syscall number (possibly new)
 317         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 318         cmp     scno, #NR_syscalls              @ check upper syscall limit
 319         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 320         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 321         b       2b
 322
 323 __sys_trace_return:
 324         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 325         mov     r2, scno
 326         mov     r1, sp
 327         mov     r0, #1                          @ trace exit [IP = 1]
 328         bl      syscall_trace
 329         b       ret_slow_syscall
 330
 331         .align  5
 332 #ifdef CONFIG_ALIGNMENT_TRAP
 333         .type   __cr_alignment, #object
 334 __cr_alignment:
 335         .word   cr_alignment
 336 #endif
 337         .ltorg
 338
 339 /*
 340  * This is the syscall table declaration for native ABI syscalls.
 341  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 342  */
 343 #define ABI(native, compat) native
 344 #ifdef CONFIG_AEABI
 345 #define OBSOLETE(syscall) sys_ni_syscall
 346 #else
 347 #define OBSOLETE(syscall) syscall
 348 #endif
 349
 350         .type   sys_call_table, #object
 351 ENTRY(sys_call_table)
 352 #include "calls.S"
 353 #undef ABI
 354 #undef OBSOLETE
 355
 356 /*============================================================================
 357  * Special system call wrappers
 358  */
 359 @ r0 = syscall number
 360 @ r8 = syscall table
 361 sys_syscall:
 362                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 363                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 364                 cmpne   scno, #NR_syscalls      @ check range
 365                 stmloia sp, {r5, r6}            @ shuffle args
 366                 movlo   r0, r1
 367                 movlo   r1, r2
 368                 movlo   r2, r3
 369                 movlo   r3, r4
 370                 ldrlo   pc, [tbl, scno, lsl #2]
 371                 b       sys_ni_syscall
 372 ENDPROC(sys_syscall)
 373
 374 sys_fork_wrapper:
 375                 add     r0, sp, #S_OFF
 376                 b       sys_fork
 377 ENDPROC(sys_fork_wrapper)
 378
 379 sys_vfork_wrapper:
 380                 add     r0, sp, #S_OFF
 381                 b       sys_vfork
 382 ENDPROC(sys_vfork_wrapper)
 383
 384 sys_execve_wrapper:
 385                 add     r3, sp, #S_OFF
 386                 b       sys_execve
 387 ENDPROC(sys_execve_wrapper)
 388
 389 sys_clone_wrapper:
 390                 add     ip, sp, #S_OFF
 391                 str     ip, [sp, #4]
 392                 b       sys_clone
 393 ENDPROC(sys_clone_wrapper)
 394
 395 sys_sigsuspend_wrapper:
 396                 add     r3, sp, #S_OFF
 397                 b       sys_sigsuspend
 398 ENDPROC(sys_sigsuspend_wrapper)
 399
 400 sys_rt_sigsuspend_wrapper:
 401                 add     r2, sp, #S_OFF
 402                 b       sys_rt_sigsuspend
 403 ENDPROC(sys_rt_sigsuspend_wrapper)
 404
 405 sys_sigreturn_wrapper:
 406                 add     r0, sp, #S_OFF
 407                 b       sys_sigreturn
 408 ENDPROC(sys_sigreturn_wrapper)
 409
 410 sys_rt_sigreturn_wrapper:
 411                 add     r0, sp, #S_OFF
 412                 b       sys_rt_sigreturn
 413 ENDPROC(sys_rt_sigreturn_wrapper)
 414
 415 sys_sigaltstack_wrapper:
 416                 ldr     r2, [sp, #S_OFF + S_SP]
 417                 b       do_sigaltstack
 418 ENDPROC(sys_sigaltstack_wrapper)
 419
 420 sys_statfs64_wrapper:
 421                 teq     r1, #88
 422                 moveq   r1, #84
 423                 b       sys_statfs64
 424 ENDPROC(sys_statfs64_wrapper)
 425
 426 sys_fstatfs64_wrapper:
 427                 teq     r1, #88
 428                 moveq   r1, #84
 429                 b       sys_fstatfs64
 430 ENDPROC(sys_fstatfs64_wrapper)
 431
 432 /*
 433  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 434  * offset, we return EINVAL.
 435  */
 436 sys_mmap2:
 437 #if PAGE_SHIFT > 12
 438                 tst     r5, #PGOFF_MASK
 439                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 440                 streq   r5, [sp, #4]
 441                 beq     do_mmap2
 442                 mov     r0, #-EINVAL
 443                 mov     pc, lr
 444 #else
 445                 str     r5, [sp, #4]
 446                 b       do_mmap2
 447 #endif
 448 ENDPROC(sys_mmap2)
 449
 450 ENTRY(pabort_ifar)
 451                 mrc     p15, 0, r0, cr6, cr0, 2
 452 ENTRY(pabort_noifar)
 453                 mov     pc, lr
 454 ENDPROC(pabort_ifar)
 455 ENDPROC(pabort_noifar)
 456
 457 #ifdef CONFIG_OABI_COMPAT
 458
 459 /*
 460  * These are syscalls with argument register differences
 461  */
 462
 463 sys_oabi_pread64:
 464                 stmia   sp, {r3, r4}
 465                 b       sys_pread64
 466 ENDPROC(sys_oabi_pread64)
 467
 468 sys_oabi_pwrite64:
 469                 stmia   sp, {r3, r4}
 470                 b       sys_pwrite64
 471 ENDPROC(sys_oabi_pwrite64)
 472
 473 sys_oabi_truncate64:
 474                 mov     r3, r2
 475                 mov     r2, r1
 476                 b       sys_truncate64
 477 ENDPROC(sys_oabi_truncate64)
 478
 479 sys_oabi_ftruncate64:
 480                 mov     r3, r2
 481                 mov     r2, r1
 482                 b       sys_ftruncate64
 483 ENDPROC(sys_oabi_ftruncate64)
 484
 485 sys_oabi_readahead:
 486                 str     r3, [sp]
 487                 mov     r3, r2
 488                 mov     r2, r1
 489                 b       sys_readahead
 490 ENDPROC(sys_oabi_readahead)
 491
 492 /*
 493  * Let's declare a second syscall table for old ABI binaries
 494  * using the compatibility syscall entries.
 495  */
 496 #define ABI(native, compat) compat
 497 #define OBSOLETE(syscall) syscall
 498
 499         .type   sys_oabi_call_table, #object
 500 ENTRY(sys_oabi_call_table)
 501 #include "calls.S"
 502 #undef ABI
 503 #undef OBSOLETE
 504
 505 #endif
 506