arch/x86/boot/compressed/head_64.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24 .code32
  25 .text
  26
  27 #include <linux/linkage.h>
  28 #include <asm/segment.h>
  29 #include <asm/pgtable.h>
  30 #include <asm/page.h>
  31 #include <asm/boot.h>
  32 #include <asm/msr.h>
  33 #include <asm/asm-offsets.h>
  34
  35 .section ".text.head"
  36         .code32
  37         .globl startup_32
  38
  39 startup_32:
  40         cld
  41         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  42          * us to not reload segments */
  43         testb $(1<<6), BP_loadflags(%esi)
  44         jnz 1f
  45
  46         cli
  47         movl    $(__KERNEL_DS), %eax
  48         movl    %eax, %ds
  49         movl    %eax, %es
  50         movl    %eax, %ss
  51 1:
  52
  53 /* Calculate the delta between where we were compiled to run
  54  * at and where we were actually loaded at.  This can only be done
  55  * with a short local call on x86.  Nothing  else will tell us what
  56  * address we are running at.  The reserved chunk of the real-mode
  57  * data at 0x1e4 (defined as a scratch field) are used as the stack
  58  * for this calculation. Only 4 bytes are needed.
  59  */
  60         leal    (0x1e4+4)(%esi), %esp
  61         call    1f
  62 1:      popl    %ebp
  63         subl    $1b, %ebp
  64
  65 /* setup a stack and make sure cpu supports long mode. */
  66         movl    $boot_stack_end, %eax
  67         addl    %ebp, %eax
  68         movl    %eax, %esp
  69
  70         call    verify_cpu
  71         testl   %eax, %eax
  72         jnz     no_longmode
  73
  74 /* Compute the delta between where we were compiled to run at
  75  * and where the code will actually run at.
  76  */
  77 /* %ebp contains the address we are loaded at by the boot loader and %ebx
  78  * contains the address where we should move the kernel image temporarily
  79  * for safe in-place decompression.
  80  */
  81
  82 #ifdef CONFIG_RELOCATABLE
  83         movl    %ebp, %ebx
  84         addl    $(PMD_PAGE_SIZE -1), %ebx
  85         andl    $PMD_PAGE_MASK, %ebx
  86 #else
  87         movl    $CONFIG_PHYSICAL_START, %ebx
  88 #endif
  89
  90         /* Replace the compressed data size with the uncompressed size */
  91         subl    input_len(%ebp), %ebx
  92         movl    output_len(%ebp), %eax
  93         addl    %eax, %ebx
  94         /* Add 8 bytes for every 32K input block */
  95         shrl    $12, %eax
  96         addl    %eax, %ebx
  97         /* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
  98         addl    $(32768 + 18 + 4095), %ebx
  99         andl    $~4095, %ebx
 100
 101 /*
 102  * Prepare for entering 64 bit mode
 103  */
 104
 105         /* Load new GDT with the 64bit segments using 32bit descriptor */
 106         leal    gdt(%ebp), %eax
 107         movl    %eax, gdt+2(%ebp)
 108         lgdt    gdt(%ebp)
 109
 110         /* Enable PAE mode */
 111         xorl    %eax, %eax
 112         orl     $(1 << 5), %eax
 113         movl    %eax, %cr4
 114
 115  /*
 116   * Build early 4G boot pagetable
 117   */
 118         /* Initialize Page tables to 0*/
 119         leal    pgtable(%ebx), %edi
 120         xorl    %eax, %eax
 121         movl    $((4096*6)/4), %ecx
 122         rep     stosl
 123
 124         /* Build Level 4 */
 125         leal    pgtable + 0(%ebx), %edi
 126         leal    0x1007 (%edi), %eax
 127         movl    %eax, 0(%edi)
 128
 129         /* Build Level 3 */
 130         leal    pgtable + 0x1000(%ebx), %edi
 131         leal    0x1007(%edi), %eax
 132         movl    $4, %ecx
 133 1:      movl    %eax, 0x00(%edi)
 134         addl    $0x00001000, %eax
 135         addl    $8, %edi
 136         decl    %ecx
 137         jnz     1b
 138
 139         /* Build Level 2 */
 140         leal    pgtable + 0x2000(%ebx), %edi
 141         movl    $0x00000183, %eax
 142         movl    $2048, %ecx
 143 1:      movl    %eax, 0(%edi)
 144         addl    $0x00200000, %eax
 145         addl    $8, %edi
 146         decl    %ecx
 147         jnz     1b
 148
 149         /* Enable the boot page tables */
 150         leal    pgtable(%ebx), %eax
 151         movl    %eax, %cr3
 152
 153         /* Enable Long mode in EFER (Extended Feature Enable Register) */
 154         movl    $MSR_EFER, %ecx
 155         rdmsr
 156         btsl    $_EFER_LME, %eax
 157         wrmsr
 158
 159         /* Setup for the jump to 64bit mode
 160          *
 161          * When the jump is performend we will be in long mode but
 162          * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
 163          * (and in turn EFER.LMA = 1).  To jump into 64bit mode we use
 164          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 165          * We place all of the values on our mini stack so lret can
 166          * used to perform that far jump.
 167          */
 168         pushl   $__KERNEL_CS
 169         leal    startup_64(%ebp), %eax
 170         pushl   %eax
 171
 172         /* Enter paged protected Mode, activating Long Mode */
 173         movl    $0x80000001, %eax /* Enable Paging and Protected mode */
 174         movl    %eax, %cr0
 175
 176         /* Jump from 32bit compatibility mode into 64bit mode. */
 177         lret
 178
 179 no_longmode:
 180         /* This isn't an x86-64 CPU so hang */
 181 1:
 182         hlt
 183         jmp     1b
 184
 185 #include "../../kernel/verify_cpu_64.S"
 186
 187         /* Be careful here startup_64 needs to be at a predictable
 188          * address so I can export it in an ELF header.  Bootloaders
 189          * should look at the ELF header to find this address, as
 190          * it may change in the future.
 191          */
 192         .code64
 193         .org 0x200
 194 ENTRY(startup_64)
 195         /* We come here either from startup_32 or directly from a
 196          * 64bit bootloader.  If we come here from a bootloader we depend on
 197          * an identity mapped page table being provied that maps our
 198          * entire text+data+bss and hopefully all of memory.
 199          */
 200
 201         /* Setup data segments. */
 202         xorl    %eax, %eax
 203         movl    %eax, %ds
 204         movl    %eax, %es
 205         movl    %eax, %ss
 206         movl    %eax, %fs
 207         movl    %eax, %gs
 208         lldt    %ax
 209         movl    $0x20, %eax
 210         ltr     %ax
 211
 212         /* Compute the decompressed kernel start address.  It is where
 213          * we were loaded at aligned to a 2M boundary. %rbp contains the
 214          * decompressed kernel start address.
 215          *
 216          * If it is a relocatable kernel then decompress and run the kernel
 217          * from load address aligned to 2MB addr, otherwise decompress and
 218          * run the kernel from CONFIG_PHYSICAL_START
 219          */
 220
 221         /* Start with the delta to where the kernel will run at. */
 222 #ifdef CONFIG_RELOCATABLE
 223         leaq    startup_32(%rip) /* - $startup_32 */, %rbp
 224         addq    $(PMD_PAGE_SIZE - 1), %rbp
 225         andq    $PMD_PAGE_MASK, %rbp
 226         movq    %rbp, %rbx
 227 #else
 228         movq    $CONFIG_PHYSICAL_START, %rbp
 229         movq    %rbp, %rbx
 230 #endif
 231
 232         /* Replace the compressed data size with the uncompressed size */
 233         movl    input_len(%rip), %eax
 234         subq    %rax, %rbx
 235         movl    output_len(%rip), %eax
 236         addq    %rax, %rbx
 237         /* Add 8 bytes for every 32K input block */
 238         shrq    $12, %rax
 239         addq    %rax, %rbx
 240         /* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
 241         addq    $(32768 + 18 + 4095), %rbx
 242         andq    $~4095, %rbx
 243
 244 /* Copy the compressed kernel to the end of our buffer
 245  * where decompression in place becomes safe.
 246  */
 247         leaq    _end_before_pgt(%rip), %r8
 248         leaq    _end_before_pgt(%rbx), %r9
 249         movq    $_end_before_pgt /* - $startup_32 */, %rcx
 250 1:      subq    $8, %r8
 251         subq    $8, %r9
 252         movq    0(%r8), %rax
 253         movq    %rax, 0(%r9)
 254         subq    $8, %rcx
 255         jnz     1b
 256
 257 /*
 258  * Jump to the relocated address.
 259  */
 260         leaq    relocated(%rbx), %rax
 261         jmp     *%rax
 262
 263 .section ".text"
 264 relocated:
 265
 266 /*
 267  * Clear BSS
 268  */
 269         xorq    %rax, %rax
 270         leaq    _edata(%rbx), %rdi
 271         leaq    _end_before_pgt(%rbx), %rcx
 272         subq    %rdi, %rcx
 273         cld
 274         rep
 275         stosb
 276
 277         /* Setup the stack */
 278         leaq    boot_stack_end(%rip), %rsp
 279
 280         /* zero EFLAGS after setting rsp */
 281         pushq   $0
 282         popfq
 283
 284 /*
 285  * Do the decompression, and jump to the new kernel..
 286  */
 287         pushq   %rsi                    # Save the real mode argument
 288         movq    %rsi, %rdi              # real mode address
 289         leaq    boot_heap(%rip), %rsi   # malloc area for uncompression
 290         leaq    input_data(%rip), %rdx  # input_data
 291         movl    input_len(%rip), %eax
 292         movq    %rax, %rcx              # input_len
 293         movq    %rbp, %r8               # output
 294         call    decompress_kernel
 295         popq    %rsi
 296
 297
 298 /*
 299  * Jump to the decompressed kernel.
 300  */
 301         jmp     *%rbp
 302
 303         .data
 304 gdt:
 305         .word   gdt_end - gdt
 306         .long   gdt
 307         .word   0
 308         .quad   0x0000000000000000      /* NULL descriptor */
 309         .quad   0x00af9a000000ffff      /* __KERNEL_CS */
 310         .quad   0x00cf92000000ffff      /* __KERNEL_DS */
 311         .quad   0x0080890000000000      /* TS descriptor */
 312         .quad   0x0000000000000000      /* TS continued */
 313 gdt_end:
 314
 315 .bss
 316 /* Stack and heap for uncompression */
 317 .balign 4
 318 boot_heap:
 319         .fill BOOT_HEAP_SIZE, 1, 0
 320 boot_stack:
 321         .fill BOOT_STACK_SIZE, 1, 0
 322 boot_stack_end: