arch/x86/boot/compressed/head_64.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  linux/boot/head.S
   4  *
   5  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   6  */
   7
   8 /*
   9  *  head.S contains the 32-bit startup code.
  10  *
  11  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  12  * the page directory will exist. The startup code will be overwritten by
  13  * the page directory. [According to comments etc elsewhere on a compressed
  14  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  15  *
  16  * Page 0 is deliberately kept safe, since System Management Mode code in
  17  * laptops may need to access the BIOS data stored there.  This is also
  18  * useful for future device drivers that either access the BIOS via VM86
  19  * mode.
  20  */
  21
  22 /*
  23  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  24  */
  25         .code32
  26         .text
  27
  28 #include <linux/init.h>
  29 #include <linux/linkage.h>
  30 #include <asm/segment.h>
  31 #include <asm/boot.h>
  32 #include <asm/msr.h>
  33 #include <asm/processor-flags.h>
  34 #include <asm/asm-offsets.h>
  35 #include <asm/bootparam.h>
  36 #include "pgtable.h"
  37
  38 /*
  39  * Locally defined symbols should be marked hidden:
  40  */
  41         .hidden _bss
  42         .hidden _ebss
  43         .hidden _got
  44         .hidden _egot
  45
  46         __HEAD
  47         .code32
  48 ENTRY(startup_32)
  49         /*
  50          * 32bit entry is 0 and it is ABI so immutable!
  51          * If we come here directly from a bootloader,
  52          * kernel(text+data+bss+brk) ramdisk, zero_page, command line
  53          * all need to be under the 4G limit.
  54          */
  55         cld
  56         /*
  57          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
  58          * us to not reload segments
  59          */
  60         testb $KEEP_SEGMENTS, BP_loadflags(%esi)
  61         jnz 1f
  62
  63         cli
  64         movl    $(__BOOT_DS), %eax
  65         movl    %eax, %ds
  66         movl    %eax, %es
  67         movl    %eax, %ss
  68 1:
  69
  70 /*
  71  * Calculate the delta between where we were compiled to run
  72  * at and where we were actually loaded at.  This can only be done
  73  * with a short local call on x86.  Nothing  else will tell us what
  74  * address we are running at.  The reserved chunk of the real-mode
  75  * data at 0x1e4 (defined as a scratch field) are used as the stack
  76  * for this calculation. Only 4 bytes are needed.
  77  */
  78         leal    (BP_scratch+4)(%esi), %esp
  79         call    1f
  80 1:      popl    %ebp
  81         subl    $1b, %ebp
  82
  83 /* setup a stack and make sure cpu supports long mode. */
  84         movl    $boot_stack_end, %eax
  85         addl    %ebp, %eax
  86         movl    %eax, %esp
  87
  88         call    verify_cpu
  89         testl   %eax, %eax
  90         jnz     no_longmode
  91
  92 /*
  93  * Compute the delta between where we were compiled to run at
  94  * and where the code will actually run at.
  95  *
  96  * %ebp contains the address we are loaded at by the boot loader and %ebx
  97  * contains the address where we should move the kernel image temporarily
  98  * for safe in-place decompression.
  99  */
 100
 101 #ifdef CONFIG_RELOCATABLE
 102         movl    %ebp, %ebx
 103         movl    BP_kernel_alignment(%esi), %eax
 104         decl    %eax
 105         addl    %eax, %ebx
 106         notl    %eax
 107         andl    %eax, %ebx
 108         cmpl    $LOAD_PHYSICAL_ADDR, %ebx
 109         jge     1f
 110 #endif
 111         movl    $LOAD_PHYSICAL_ADDR, %ebx
 112 1:
 113
 114         /* Target address to relocate to for decompression */
 115         movl    BP_init_size(%esi), %eax
 116         subl    $_end, %eax
 117         addl    %eax, %ebx
 118
 119 /*
 120  * Prepare for entering 64 bit mode
 121  */
 122
 123         /* Load new GDT with the 64bit segments using 32bit descriptor */
 124         addl    %ebp, gdt+2(%ebp)
 125         lgdt    gdt(%ebp)
 126
 127         /* Enable PAE mode */
 128         movl    %cr4, %eax
 129         orl     $X86_CR4_PAE, %eax
 130         movl    %eax, %cr4
 131
 132  /*
 133   * Build early 4G boot pagetable
 134   */
 135         /*
 136          * If SEV is active then set the encryption mask in the page tables.
 137          * This will insure that when the kernel is copied and decompressed
 138          * it will be done so encrypted.
 139          */
 140         call    get_sev_encryption_bit
 141         xorl    %edx, %edx
 142         testl   %eax, %eax
 143         jz      1f
 144         subl    $32, %eax       /* Encryption bit is always above bit 31 */
 145         bts     %eax, %edx      /* Set encryption mask for page tables */
 146 1:
 147
 148         /* Initialize Page tables to 0 */
 149         leal    pgtable(%ebx), %edi
 150         xorl    %eax, %eax
 151         movl    $(BOOT_INIT_PGT_SIZE/4), %ecx
 152         rep     stosl
 153
 154         /* Build Level 4 */
 155         leal    pgtable + 0(%ebx), %edi
 156         leal    0x1007 (%edi), %eax
 157         movl    %eax, 0(%edi)
 158         addl    %edx, 4(%edi)
 159
 160         /* Build Level 3 */
 161         leal    pgtable + 0x1000(%ebx), %edi
 162         leal    0x1007(%edi), %eax
 163         movl    $4, %ecx
 164 1:      movl    %eax, 0x00(%edi)
 165         addl    %edx, 0x04(%edi)
 166         addl    $0x00001000, %eax
 167         addl    $8, %edi
 168         decl    %ecx
 169         jnz     1b
 170
 171         /* Build Level 2 */
 172         leal    pgtable + 0x2000(%ebx), %edi
 173         movl    $0x00000183, %eax
 174         movl    $2048, %ecx
 175 1:      movl    %eax, 0(%edi)
 176         addl    %edx, 4(%edi)
 177         addl    $0x00200000, %eax
 178         addl    $8, %edi
 179         decl    %ecx
 180         jnz     1b
 181
 182         /* Enable the boot page tables */
 183         leal    pgtable(%ebx), %eax
 184         movl    %eax, %cr3
 185
 186         /* Enable Long mode in EFER (Extended Feature Enable Register) */
 187         movl    $MSR_EFER, %ecx
 188         rdmsr
 189         btsl    $_EFER_LME, %eax
 190         wrmsr
 191
 192         /* After gdt is loaded */
 193         xorl    %eax, %eax
 194         lldt    %ax
 195         movl    $__BOOT_TSS, %eax
 196         ltr     %ax
 197
 198         /*
 199          * Setup for the jump to 64bit mode
 200          *
 201          * When the jump is performend we will be in long mode but
 202          * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
 203          * (and in turn EFER.LMA = 1).  To jump into 64bit mode we use
 204          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 205          * We place all of the values on our mini stack so lret can
 206          * used to perform that far jump.
 207          */
 208         pushl   $__KERNEL_CS
 209         leal    startup_64(%ebp), %eax
 210 #ifdef CONFIG_EFI_MIXED
 211         movl    efi32_config(%ebp), %ebx
 212         cmp     $0, %ebx
 213         jz      1f
 214         leal    handover_entry(%ebp), %eax
 215 1:
 216 #endif
 217         pushl   %eax
 218
 219         /* Enter paged protected Mode, activating Long Mode */
 220         movl    $(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */
 221         movl    %eax, %cr0
 222
 223         /* Jump from 32bit compatibility mode into 64bit mode. */
 224         lret
 225 ENDPROC(startup_32)
 226
 227 #ifdef CONFIG_EFI_MIXED
 228         .org 0x190
 229 ENTRY(efi32_stub_entry)
 230         add     $0x4, %esp              /* Discard return address */
 231         popl    %ecx
 232         popl    %edx
 233         popl    %esi
 234
 235         leal    (BP_scratch+4)(%esi), %esp
 236         call    1f
 237 1:      pop     %ebp
 238         subl    $1b, %ebp
 239
 240         movl    %ecx, efi32_config(%ebp)
 241         movl    %edx, efi32_config+8(%ebp)
 242         sgdtl   efi32_boot_gdt(%ebp)
 243
 244         leal    efi32_config(%ebp), %eax
 245         movl    %eax, efi_config(%ebp)
 246
 247         jmp     startup_32
 248 ENDPROC(efi32_stub_entry)
 249 #endif
 250
 251         .code64
 252         .org 0x200
 253 ENTRY(startup_64)
 254         /*
 255          * 64bit entry is 0x200 and it is ABI so immutable!
 256          * We come here either from startup_32 or directly from a
 257          * 64bit bootloader.
 258          * If we come here from a bootloader, kernel(text+data+bss+brk),
 259          * ramdisk, zero_page, command line could be above 4G.
 260          * We depend on an identity mapped page table being provided
 261          * that maps our entire kernel(text+data+bss+brk), zero page
 262          * and command line.
 263          */
 264
 265         /* Setup data segments. */
 266         xorl    %eax, %eax
 267         movl    %eax, %ds
 268         movl    %eax, %es
 269         movl    %eax, %ss
 270         movl    %eax, %fs
 271         movl    %eax, %gs
 272
 273         /*
 274          * Compute the decompressed kernel start address.  It is where
 275          * we were loaded at aligned to a 2M boundary. %rbp contains the
 276          * decompressed kernel start address.
 277          *
 278          * If it is a relocatable kernel then decompress and run the kernel
 279          * from load address aligned to 2MB addr, otherwise decompress and
 280          * run the kernel from LOAD_PHYSICAL_ADDR
 281          *
 282          * We cannot rely on the calculation done in 32-bit mode, since we
 283          * may have been invoked via the 64-bit entry point.
 284          */
 285
 286         /* Start with the delta to where the kernel will run at. */
 287 #ifdef CONFIG_RELOCATABLE
 288         leaq    startup_32(%rip) /* - $startup_32 */, %rbp
 289         movl    BP_kernel_alignment(%rsi), %eax
 290         decl    %eax
 291         addq    %rax, %rbp
 292         notq    %rax
 293         andq    %rax, %rbp
 294         cmpq    $LOAD_PHYSICAL_ADDR, %rbp
 295         jge     1f
 296 #endif
 297         movq    $LOAD_PHYSICAL_ADDR, %rbp
 298 1:
 299
 300         /* Target address to relocate to for decompression */
 301         movl    BP_init_size(%rsi), %ebx
 302         subl    $_end, %ebx
 303         addq    %rbp, %rbx
 304
 305         /* Set up the stack */
 306         leaq    boot_stack_end(%rbx), %rsp
 307
 308         /*
 309          * At this point we are in long mode with 4-level paging enabled,
 310          * but we want to enable 5-level paging.
 311          *
 312          * The problem is that we cannot do it directly. Setting LA57 in
 313          * long mode would trigger #GP. So we need to switch off long mode
 314          * first.
 315          */
 316
 317         /* Make sure we have GDT with 32-bit code segment */
 318         leaq    gdt(%rip), %rax
 319         movq    %rax, gdt64+2(%rip)
 320         lgdt    gdt64(%rip)
 321
 322         /*
 323          * paging_prepare() sets up the trampoline and checks if we need to
 324          * enable 5-level paging.
 325          *
 326          * Address of the trampoline is returned in RAX.
 327          * Non zero RDX on return means we need to enable 5-level paging.
 328          *
 329          * RSI holds real mode data and needs to be preserved across
 330          * this function call.
 331          */
 332         pushq   %rsi
 333         call    paging_prepare
 334         popq    %rsi
 335
 336         /* Save the trampoline address in RCX */
 337         movq    %rax, %rcx
 338
 339         /* Check if we need to enable 5-level paging */
 340         cmpq    $0, %rdx
 341         jz      lvl5
 342
 343         /* Clear additional page table */
 344         leaq    lvl5_pgtable(%rbx), %rdi
 345         xorq    %rax, %rax
 346         movq    $(PAGE_SIZE/8), %rcx
 347         rep     stosq
 348
 349         /*
 350          * Setup current CR3 as the first and only entry in a new top level
 351          * page table.
 352          */
 353         movq    %cr3, %rdi
 354         leaq    0x7 (%rdi), %rax
 355         movq    %rax, lvl5_pgtable(%rbx)
 356
 357         /* Switch to compatibility mode (CS.L = 0 CS.D = 1) via far return */
 358         pushq   $__KERNEL32_CS
 359         leaq    compatible_mode(%rip), %rax
 360         pushq   %rax
 361         lretq
 362 lvl5:
 363         /* Restore the stack, the 32-bit trampoline uses its own stack */
 364         leaq    boot_stack_end(%rbx), %rsp
 365
 366         /*
 367          * cleanup_trampoline() would restore trampoline memory.
 368          *
 369          * RSI holds real mode data and needs to be preserved across
 370          * this function call.
 371          */
 372         pushq   %rsi
 373         call    cleanup_trampoline
 374         popq    %rsi
 375
 376         /* Zero EFLAGS */
 377         pushq   $0
 378         popfq
 379
 380 /*
 381  * Copy the compressed kernel to the end of our buffer
 382  * where decompression in place becomes safe.
 383  */
 384         pushq   %rsi
 385         leaq    (_bss-8)(%rip), %rsi
 386         leaq    (_bss-8)(%rbx), %rdi
 387         movq    $_bss /* - $startup_32 */, %rcx
 388         shrq    $3, %rcx
 389         std
 390         rep     movsq
 391         cld
 392         popq    %rsi
 393
 394 /*
 395  * Jump to the relocated address.
 396  */
 397         leaq    relocated(%rbx), %rax
 398         jmp     *%rax
 399
 400 #ifdef CONFIG_EFI_STUB
 401
 402 /* The entry point for the PE/COFF executable is efi_pe_entry. */
 403 ENTRY(efi_pe_entry)
 404         movq    %rcx, efi64_config(%rip)        /* Handle */
 405         movq    %rdx, efi64_config+8(%rip) /* EFI System table pointer */
 406
 407         leaq    efi64_config(%rip), %rax
 408         movq    %rax, efi_config(%rip)
 409
 410         call    1f
 411 1:      popq    %rbp
 412         subq    $1b, %rbp
 413
 414         /*
 415          * Relocate efi_config->call().
 416          */
 417         addq    %rbp, efi64_config+40(%rip)
 418
 419         movq    %rax, %rdi
 420         call    make_boot_params
 421         cmpq    $0,%rax
 422         je      fail
 423         mov     %rax, %rsi
 424         leaq    startup_32(%rip), %rax
 425         movl    %eax, BP_code32_start(%rsi)
 426         jmp     2f              /* Skip the relocation */
 427
 428 handover_entry:
 429         call    1f
 430 1:      popq    %rbp
 431         subq    $1b, %rbp
 432
 433         /*
 434          * Relocate efi_config->call().
 435          */
 436         movq    efi_config(%rip), %rax
 437         addq    %rbp, 40(%rax)
 438 2:
 439         movq    efi_config(%rip), %rdi
 440         call    efi_main
 441         movq    %rax,%rsi
 442         cmpq    $0,%rax
 443         jne     2f
 444 fail:
 445         /* EFI init failed, so hang. */
 446         hlt
 447         jmp     fail
 448 2:
 449         movl    BP_code32_start(%esi), %eax
 450         leaq    startup_64(%rax), %rax
 451         jmp     *%rax
 452 ENDPROC(efi_pe_entry)
 453
 454         .org 0x390
 455 ENTRY(efi64_stub_entry)
 456         movq    %rdi, efi64_config(%rip)        /* Handle */
 457         movq    %rsi, efi64_config+8(%rip) /* EFI System table pointer */
 458
 459         leaq    efi64_config(%rip), %rax
 460         movq    %rax, efi_config(%rip)
 461
 462         movq    %rdx, %rsi
 463         jmp     handover_entry
 464 ENDPROC(efi64_stub_entry)
 465 #endif
 466
 467         .text
 468 relocated:
 469
 470 /*
 471  * Clear BSS (stack is currently empty)
 472  */
 473         xorl    %eax, %eax
 474         leaq    _bss(%rip), %rdi
 475         leaq    _ebss(%rip), %rcx
 476         subq    %rdi, %rcx
 477         shrq    $3, %rcx
 478         rep     stosq
 479
 480 /*
 481  * Adjust our own GOT
 482  */
 483         leaq    _got(%rip), %rdx
 484         leaq    _egot(%rip), %rcx
 485 1:
 486         cmpq    %rcx, %rdx
 487         jae     2f
 488         addq    %rbx, (%rdx)
 489         addq    $8, %rdx
 490         jmp     1b
 491 2:
 492
 493 /*
 494  * Do the extraction, and jump to the new kernel..
 495  */
 496         pushq   %rsi                    /* Save the real mode argument */
 497         movq    %rsi, %rdi              /* real mode address */
 498         leaq    boot_heap(%rip), %rsi   /* malloc area for uncompression */
 499         leaq    input_data(%rip), %rdx  /* input_data */
 500         movl    $z_input_len, %ecx      /* input_len */
 501         movq    %rbp, %r8               /* output target address */
 502         movq    $z_output_len, %r9      /* decompressed length, end of relocs */
 503         call    extract_kernel          /* returns kernel location in %rax */
 504         popq    %rsi
 505
 506 /*
 507  * Jump to the decompressed kernel.
 508  */
 509         jmp     *%rax
 510
 511         .code32
 512 ENTRY(trampoline_32bit_src)
 513 compatible_mode:
 514         /* Set up data and stack segments */
 515         movl    $__KERNEL_DS, %eax
 516         movl    %eax, %ds
 517         movl    %eax, %ss
 518
 519         /* Set up new stack */
 520         leal    TRAMPOLINE_32BIT_STACK_END(%ecx), %esp
 521
 522         /* Disable paging */
 523         movl    %cr0, %eax
 524         btrl    $X86_CR0_PG_BIT, %eax
 525         movl    %eax, %cr0
 526
 527         /* Point CR3 to 5-level paging */
 528         leal    lvl5_pgtable(%ebx), %eax
 529         movl    %eax, %cr3
 530
 531         /* Enable PAE and LA57 mode */
 532         movl    %cr4, %eax
 533         orl     $(X86_CR4_PAE | X86_CR4_LA57), %eax
 534         movl    %eax, %cr4
 535
 536         /* Calculate address we are running at */
 537         call    1f
 538 1:      popl    %edi
 539         subl    $1b, %edi
 540
 541         /* Prepare stack for far return to Long Mode */
 542         pushl   $__KERNEL_CS
 543         leal    lvl5(%edi), %eax
 544         push    %eax
 545
 546         /* Enable paging back */
 547         movl    $(X86_CR0_PG | X86_CR0_PE), %eax
 548         movl    %eax, %cr0
 549
 550         lret
 551
 552 no_longmode:
 553         /* This isn't an x86-64 CPU so hang */
 554 1:
 555         hlt
 556         jmp     1b
 557
 558 #include "../../kernel/verify_cpu.S"
 559
 560         .data
 561 gdt64:
 562         .word   gdt_end - gdt
 563         .long   0
 564         .word   0
 565         .quad   0
 566 gdt:
 567         .word   gdt_end - gdt
 568         .long   gdt
 569         .word   0
 570         .quad   0x00cf9a000000ffff      /* __KERNEL32_CS */
 571         .quad   0x00af9a000000ffff      /* __KERNEL_CS */
 572         .quad   0x00cf92000000ffff      /* __KERNEL_DS */
 573         .quad   0x0080890000000000      /* TS descriptor */
 574         .quad   0x0000000000000000      /* TS continued */
 575 gdt_end:
 576
 577 #ifdef CONFIG_EFI_STUB
 578 efi_config:
 579         .quad   0
 580
 581 #ifdef CONFIG_EFI_MIXED
 582         .global efi32_config
 583 efi32_config:
 584         .fill   5,8,0
 585         .quad   efi64_thunk
 586         .byte   0
 587 #endif
 588
 589         .global efi64_config
 590 efi64_config:
 591         .fill   5,8,0
 592         .quad   efi_call
 593         .byte   1
 594 #endif /* CONFIG_EFI_STUB */
 595
 596 /*
 597  * Stack and heap for uncompression
 598  */
 599         .bss
 600         .balign 4
 601 boot_heap:
 602         .fill BOOT_HEAP_SIZE, 1, 0
 603 boot_stack:
 604         .fill BOOT_STACK_SIZE, 1, 0
 605 boot_stack_end:
 606
 607 /*
 608  * Space for page tables (not in .bss so not zeroed)
 609  */
 610         .section ".pgtable","a",@nobits
 611         .balign 4096
 612 pgtable:
 613         .fill BOOT_PGT_SIZE, 1, 0
 614 lvl5_pgtable:
 615         .fill PAGE_SIZE, 1, 0