arch/xtensa/kernel/head.S

   1 /*
   2  * arch/xtensa/kernel/head.S
   3  *
   4  * Xtensa Processor startup code.
   5  *
   6  * This file is subject to the terms and conditions of the GNU General Public
   7  * License.  See the file "COPYING" in the main directory of this archive
   8  * for more details.
   9  *
  10  * Copyright (C) 2001 - 2008 Tensilica Inc.
  11  *
  12  * Chris Zankel <chris@zankel.net>
  13  * Marc Gauthier <marc@tensilica.com, marc@alumni.uwaterloo.ca>
  14  * Joe Taylor <joe@tensilica.com, joetylr@yahoo.com>
  15  * Kevin Chea
  16  */
  17
  18 #include <asm/processor.h>
  19 #include <asm/page.h>
  20 #include <asm/cacheasm.h>
  21 #include <asm/initialize_mmu.h>
  22
  23 #include <linux/init.h>
  24 #include <linux/linkage.h>
  25
  26 /*
  27  * This module contains the entry code for kernel images. It performs the
  28  * minimal setup needed to call the generic C routines.
  29  *
  30  * Prerequisites:
  31  *
  32  * - The kernel image has been loaded to the actual address where it was
  33  *   compiled to.
  34  * - a2 contains either 0 or a pointer to a list of boot parameters.
  35  *   (see setup.c for more details)
  36  *
  37  */
  38
  39 /*
  40  *  _start
  41  *
  42  *  The bootloader passes a pointer to a list of boot parameters in a2.
  43  */
  44
  45         /* The first bytes of the kernel image must be an instruction, so we
  46          * manually allocate and define the literal constant we need for a jx
  47          * instruction.
  48          */
  49
  50         __HEAD
  51 ENTRY(_start)
  52
  53         _j      2f
  54         .align  4
  55 1:      .word   _startup
  56 2:      l32r    a0, 1b
  57         jx      a0
  58
  59 ENDPROC(_start)
  60
  61         .section .init.text, "ax"
  62
  63 ENTRY(_startup)
  64
  65         /* Disable interrupts and exceptions. */
  66
  67         movi    a0, LOCKLEVEL
  68         wsr     a0, ps
  69
  70         /* Preserve the pointer to the boot parameter list in EXCSAVE_1 */
  71
  72         wsr     a2, excsave1
  73
  74         /* Start with a fresh windowbase and windowstart.  */
  75
  76         movi    a1, 1
  77         movi    a0, 0
  78         wsr     a1, windowstart
  79         wsr     a0, windowbase
  80         rsync
  81
  82         /* Set a0 to 0 for the remaining initialization. */
  83
  84         movi    a0, 0
  85
  86         /* Clear debugging registers. */
  87
  88 #if XCHAL_HAVE_DEBUG
  89 #if XCHAL_NUM_IBREAK > 0
  90         wsr     a0, ibreakenable
  91 #endif
  92         wsr     a0, icount
  93         movi    a1, 15
  94         wsr     a0, icountlevel
  95
  96         .set    _index, 0
  97         .rept   XCHAL_NUM_DBREAK - 1
  98         wsr     a0, SREG_DBREAKC + _index
  99         .set    _index, _index + 1
 100         .endr
 101 #endif
 102
 103         /* Clear CCOUNT (not really necessary, but nice) */
 104
 105         wsr     a0, ccount      # not really necessary, but nice
 106
 107         /* Disable zero-loops. */
 108
 109 #if XCHAL_HAVE_LOOPS
 110         wsr     a0, lcount
 111 #endif
 112
 113         /* Disable all timers. */
 114
 115         .set    _index, 0
 116         .rept   XCHAL_NUM_TIMERS
 117         wsr     a0, SREG_CCOMPARE + _index
 118         .set    _index, _index + 1
 119         .endr
 120
 121         /* Interrupt initialization. */
 122
 123         movi    a2, XCHAL_INTTYPE_MASK_SOFTWARE | XCHAL_INTTYPE_MASK_EXTERN_EDGE
 124         wsr     a0, intenable
 125         wsr     a2, intclear
 126
 127         /* Disable coprocessors. */
 128
 129 #if XCHAL_HAVE_CP
 130         wsr     a0, cpenable
 131 #endif
 132
 133         /* Set PS.INTLEVEL=LOCKLEVEL, PS.WOE=0, kernel stack, PS.EXCM=0
 134          *
 135          * Note: PS.EXCM must be cleared before using any loop
 136          *       instructions; otherwise, they are silently disabled, and
 137          *       at most one iteration of the loop is executed.
 138          */
 139
 140         movi    a1, LOCKLEVEL
 141         wsr     a1, ps
 142         rsync
 143
 144         /*  Initialize the caches.
 145          *  a2, a3 are just working registers (clobbered).
 146          */
 147
 148 #if XCHAL_DCACHE_LINE_LOCKABLE
 149         ___unlock_dcache_all a2 a3
 150 #endif
 151
 152 #if XCHAL_ICACHE_LINE_LOCKABLE
 153         ___unlock_icache_all a2 a3
 154 #endif
 155
 156         ___invalidate_dcache_all a2 a3
 157         ___invalidate_icache_all a2 a3
 158
 159         isync
 160
 161         initialize_mmu
 162
 163         /* Unpack data sections
 164          *
 165          * The linker script used to build the Linux kernel image
 166          * creates a table located at __boot_reloc_table_start
 167          * that contans the information what data needs to be unpacked.
 168          *
 169          * Uses a2-a7.
 170          */
 171
 172         movi    a2, __boot_reloc_table_start
 173         movi    a3, __boot_reloc_table_end
 174
 175 1:      beq     a2, a3, 3f      # no more entries?
 176         l32i    a4, a2, 0       # start destination (in RAM)
 177         l32i    a5, a2, 4       # end desination (in RAM)
 178         l32i    a6, a2, 8       # start source (in ROM)
 179         addi    a2, a2, 12      # next entry
 180         beq     a4, a5, 1b      # skip, empty entry
 181         beq     a4, a6, 1b      # skip, source and dest. are the same
 182
 183 2:      l32i    a7, a6, 0       # load word
 184         addi    a6, a6, 4
 185         s32i    a7, a4, 0       # store word
 186         addi    a4, a4, 4
 187         bltu    a4, a5, 2b
 188         j       1b
 189
 190 3:
 191         /* All code and initialized data segments have been copied.
 192          * Now clear the BSS segment.
 193          */
 194
 195         movi    a2, __bss_start # start of BSS
 196         movi    a3, __bss_stop  # end of BSS
 197
 198         __loopt a2, a3, a4, 2
 199         s32i    a0, a2, 0
 200         __endla a2, a4, 4
 201
 202 #if XCHAL_DCACHE_IS_WRITEBACK
 203
 204         /* After unpacking, flush the writeback cache to memory so the
 205          * instructions/data are available.
 206          */
 207
 208         ___flush_dcache_all a2 a3
 209 #endif
 210
 211         /* Setup stack and enable window exceptions (keep irqs disabled) */
 212
 213         movi    a1, init_thread_union
 214         addi    a1, a1, KERNEL_STACK_SIZE
 215
 216         movi    a2, (1 << PS_WOE_BIT) | LOCKLEVEL
 217                                         # WOE=1, INTLEVEL=LOCKLEVEL, UM=0
 218         wsr     a2, ps                  # (enable reg-windows; progmode stack)
 219         rsync
 220
 221         /* Set up EXCSAVE[DEBUGLEVEL] to point to the Debug Exception Handler.*/
 222
 223         movi    a2, debug_exception
 224         wsr     a2, SREG_EXCSAVE + XCHAL_DEBUGLEVEL
 225
 226         /* Set up EXCSAVE[1] to point to the exc_table. */
 227
 228         movi    a6, exc_table
 229         xsr     a6, excsave1
 230
 231         /* init_arch kick-starts the linux kernel */
 232
 233         movi    a4, init_arch
 234         callx4  a4
 235
 236         movi    a4, start_kernel
 237         callx4  a4
 238
 239 should_never_return:
 240         j       should_never_return
 241
 242 ENDPROC(_startup)
 243
 244 /*
 245  * BSS section
 246  */
 247
 248 __PAGE_ALIGNED_BSS
 249 #ifdef CONFIG_MMU
 250 ENTRY(swapper_pg_dir)
 251         .fill   PAGE_SIZE, 1, 0
 252 END(swapper_pg_dir)
 253 #endif
 254 ENTRY(empty_zero_page)
 255         .fill   PAGE_SIZE, 1, 0
 256 END(empty_zero_page)