scripts/coccinelle/locks/mini_lock.cocci

   1 /// Find missing unlocks.  This semantic match considers the specific case
   2 /// where the unlock is missing from an if branch, and there is a lock
   3 /// before the if and an unlock after the if.  False positives are due to
   4 /// cases where the if branch represents a case where the function is
   5 /// supposed to exit with the lock held, or where there is some preceding
   6 /// function call that releases the lock.
   7 ///
   8 // Confidence: Moderate
   9 // Copyright: (C) 2010-2012 Nicolas Palix.  GPLv2.
  10 // Copyright: (C) 2010-2012 Julia Lawall, INRIA/LIP6.  GPLv2.
  11 // Copyright: (C) 2010-2012 Gilles Muller, INRIA/LiP6.  GPLv2.
  12 // URL: http://coccinelle.lip6.fr/
  13 // Comments:
  14 // Options: -no_includes -include_headers
  15
  16 virtual context
  17 virtual org
  18 virtual report
  19
  20 @prelocked@
  21 position p1,p;
  22 expression E1;
  23 @@
  24
  25 (
  26 mutex_lock@p1
  27 |
  28 mutex_trylock@p1
  29 |
  30 spin_lock@p1
  31 |
  32 spin_trylock@p1
  33 |
  34 read_lock@p1
  35 |
  36 read_trylock@p1
  37 |
  38 write_lock@p1
  39 |
  40 write_trylock@p1
  41 |
  42 read_lock_irq@p1
  43 |
  44 write_lock_irq@p1
  45 |
  46 read_lock_irqsave@p1
  47 |
  48 write_lock_irqsave@p1
  49 |
  50 spin_lock_irq@p1
  51 |
  52 spin_lock_irqsave@p1
  53 ) (E1@p,...);
  54
  55 @looped@
  56 position r;
  57 @@
  58
  59 for(...;...;...) { <+... return@r ...; ...+> }
  60
  61 @err exists@
  62 expression E1;
  63 position prelocked.p;
  64 position up != prelocked.p1;
  65 position r!=looped.r;
  66 identifier lock,unlock;
  67 @@
  68
  69 *lock(E1@p,...);
  70 <+... when != E1
  71 if (...) {
  72   ... when != E1
  73 *  return@r ...;
  74 }
  75 ...+>
  76 *unlock@up(E1,...);
  77
  78 @script:python depends on org@
  79 p << prelocked.p1;
  80 lock << err.lock;
  81 unlock << err.unlock;
  82 p2 << err.r;
  83 @@
  84
  85 cocci.print_main(lock,p)
  86 cocci.print_secs(unlock,p2)
  87
  88 @script:python depends on report@
  89 p << prelocked.p1;
  90 lock << err.lock;
  91 unlock << err.unlock;
  92 p2 << err.r;
  93 @@
  94
  95 msg = "preceding lock on line %s" % (p[0].line)
  96 coccilib.report.print_report(p2[0],msg)