arch/arm/mm/proc-v7-2level.S

   1 /*
   2  * arch/arm/mm/proc-v7-2level.S
   3  *
   4  * Copyright (C) 2001 Deep Blue Solutions Ltd.
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #define TTB_S           (1 << 1)
  12 #define TTB_RGN_NC      (0 << 3)
  13 #define TTB_RGN_OC_WBWA (1 << 3)
  14 #define TTB_RGN_OC_WT   (2 << 3)
  15 #define TTB_RGN_OC_WB   (3 << 3)
  16 #define TTB_NOS         (1 << 5)
  17 #define TTB_IRGN_NC     ((0 << 0) | (0 << 6))
  18 #define TTB_IRGN_WBWA   ((0 << 0) | (1 << 6))
  19 #define TTB_IRGN_WT     ((1 << 0) | (0 << 6))
  20 #define TTB_IRGN_WB     ((1 << 0) | (1 << 6))
  21
  22 /* PTWs cacheable, inner WB not shareable, outer WB not shareable */
  23 #define TTB_FLAGS_UP    TTB_IRGN_WB|TTB_RGN_OC_WB
  24 #define PMD_FLAGS_UP    PMD_SECT_WB
  25
  26 /* PTWs cacheable, inner WBWA shareable, outer WBWA not shareable */
  27 #define TTB_FLAGS_SMP   TTB_IRGN_WBWA|TTB_S|TTB_NOS|TTB_RGN_OC_WBWA
  28 #define PMD_FLAGS_SMP   PMD_SECT_WBWA|PMD_SECT_S
  29
  30 /*
  31  *      cpu_v7_switch_mm(pgd_phys, tsk)
  32  *
  33  *      Set the translation table base pointer to be pgd_phys
  34  *
  35  *      - pgd_phys - physical address of new TTB
  36  *
  37  *      It is assumed that:
  38  *      - we are not using split page tables
  39  */
  40 ENTRY(cpu_v7_switch_mm)
  41 #ifdef CONFIG_MMU
  42         mov     r2, #0
  43         ldr     r1, [r1, #MM_CONTEXT_ID]        @ get mm->context.id
  44         ALT_SMP(orr     r0, r0, #TTB_FLAGS_SMP)
  45         ALT_UP(orr      r0, r0, #TTB_FLAGS_UP)
  46 #ifdef CONFIG_ARM_ERRATA_430973
  47         mcr     p15, 0, r2, c7, c5, 6           @ flush BTAC/BTB
  48 #endif
  49         mrc     p15, 0, r2, c2, c0, 1           @ load TTB 1
  50         mcr     p15, 0, r2, c2, c0, 0           @ into TTB 0
  51         isb
  52 #ifdef CONFIG_ARM_ERRATA_754322
  53         dsb
  54 #endif
  55         mcr     p15, 0, r1, c13, c0, 1          @ set context ID
  56         isb
  57         mcr     p15, 0, r0, c2, c0, 0           @ set TTB 0
  58         isb
  59 #endif
  60         mov     pc, lr
  61 ENDPROC(cpu_v7_switch_mm)
  62
  63 /*
  64  *      cpu_v7_set_pte_ext(ptep, pte)
  65  *
  66  *      Set a level 2 translation table entry.
  67  *
  68  *      - ptep  - pointer to level 2 translation table entry
  69  *                (hardware version is stored at +2048 bytes)
  70  *      - pte   - PTE value to store
  71  *      - ext   - value for extended PTE bits
  72  */
  73 ENTRY(cpu_v7_set_pte_ext)
  74 #ifdef CONFIG_MMU
  75         str     r1, [r0]                        @ linux version
  76
  77         bic     r3, r1, #0x000003f0
  78         bic     r3, r3, #PTE_TYPE_MASK
  79         orr     r3, r3, r2
  80         orr     r3, r3, #PTE_EXT_AP0 | 2
  81
  82         tst     r1, #1 << 4
  83         orrne   r3, r3, #PTE_EXT_TEX(1)
  84
  85         eor     r1, r1, #L_PTE_DIRTY
  86         tst     r1, #L_PTE_RDONLY | L_PTE_DIRTY
  87         orrne   r3, r3, #PTE_EXT_APX
  88
  89         tst     r1, #L_PTE_USER
  90         orrne   r3, r3, #PTE_EXT_AP1
  91 #ifdef CONFIG_CPU_USE_DOMAINS
  92         @ allow kernel read/write access to read-only user pages
  93         tstne   r3, #PTE_EXT_APX
  94         bicne   r3, r3, #PTE_EXT_APX | PTE_EXT_AP0
  95 #endif
  96
  97         tst     r1, #L_PTE_XN
  98         orrne   r3, r3, #PTE_EXT_XN
  99
 100         tst     r1, #L_PTE_YOUNG
 101         tstne   r1, #L_PTE_PRESENT
 102         moveq   r3, #0
 103
 104  ARM(   str     r3, [r0, #2048]! )
 105  THUMB( add     r0, r0, #2048 )
 106  THUMB( str     r3, [r0] )
 107         mcr     p15, 0, r0, c7, c10, 1          @ flush_pte
 108 #endif
 109         mov     pc, lr
 110 ENDPROC(cpu_v7_set_pte_ext)
 111
 112         /*
 113          * Memory region attributes with SCTLR.TRE=1
 114          *
 115          *   n = TEX[0],C,B
 116          *   TR = PRRR[2n+1:2n]         - memory type
 117          *   IR = NMRR[2n+1:2n]         - inner cacheable property
 118          *   OR = NMRR[2n+17:2n+16]     - outer cacheable property
 119          *
 120          *                      n       TR      IR      OR
 121          *   UNCACHED           000     00
 122          *   BUFFERABLE         001     10      00      00
 123          *   WRITETHROUGH       010     10      10      10
 124          *   WRITEBACK          011     10      11      11
 125          *   reserved           110
 126          *   WRITEALLOC         111     10      01      01
 127          *   DEV_SHARED         100     01
 128          *   DEV_NONSHARED      100     01
 129          *   DEV_WC             001     10
 130          *   DEV_CACHED         011     10
 131          *
 132          * Other attributes:
 133          *
 134          *   DS0 = PRRR[16] = 0         - device shareable property
 135          *   DS1 = PRRR[17] = 1         - device shareable property
 136          *   NS0 = PRRR[18] = 0         - normal shareable property
 137          *   NS1 = PRRR[19] = 1         - normal shareable property
 138          *   NOS = PRRR[24+n] = 1       - not outer shareable
 139          */
 140 .equ    PRRR,   0xff0a81a8
 141 .equ    NMRR,   0x40e040e0
 142
 143         /*
 144          * Macro for setting up the TTBRx and TTBCR registers.
 145          * - \ttb0 and \ttb1 updated with the corresponding flags.
 146          */
 147         .macro  v7_ttb_setup, zero, ttbr0, ttbr1, tmp
 148         mcr     p15, 0, \zero, c2, c0, 2        @ TTB control register
 149         ALT_SMP(orr     \ttbr0, \ttbr0, #TTB_FLAGS_SMP)
 150         ALT_UP(orr      \ttbr0, \ttbr0, #TTB_FLAGS_UP)
 151         ALT_SMP(orr     \ttbr1, \ttbr1, #TTB_FLAGS_SMP)
 152         ALT_UP(orr      \ttbr1, \ttbr1, #TTB_FLAGS_UP)
 153         mcr     p15, 0, \ttbr1, c2, c0, 1       @ load TTB1
 154         .endm
 155
 156         __CPUINIT
 157
 158         /*   AT
 159          *  TFR   EV X F   I D LR    S
 160          * .EEE ..EE PUI. .T.T 4RVI ZWRS BLDP WCAM
 161          * rxxx rrxx xxx0 0101 xxxx xxxx x111 xxxx < forced
 162          *    1    0 110       0011 1100 .111 1101 < we want
 163          */
 164         .align  2
 165         .type   v7_crval, #object
 166 v7_crval:
 167         crval   clear=0x0120c302, mmuset=0x10c03c7d, ucset=0x00c01c7c
 168
 169         .previous