arch/sh/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka and Paul Mundt
   4  */
   5 #ifdef CONFIG_SUPERH64
   6 #define LOAD_OFFSET     CONFIG_PAGE_OFFSET
   7 OUTPUT_ARCH(sh:sh5)
   8 #else
   9 #define LOAD_OFFSET     0
  10 OUTPUT_ARCH(sh)
  11 #endif
  12
  13 #include <asm/thread_info.h>
  14 #include <asm/cache.h>
  15 #include <asm/vmlinux.lds.h>
  16
  17 #if defined(CONFIG_32BIT) && !defined(CONFIG_PMB_LEGACY)
  18 #define MEMORY_OFFSET   0
  19 #else
  20 #define MEMORY_OFFSET   (CONFIG_MEMORY_START & 0x1fffffff)
  21 #endif
  22
  23 ENTRY(_start)
  24 SECTIONS
  25 {
  26         . = CONFIG_PAGE_OFFSET + MEMORY_OFFSET + CONFIG_ZERO_PAGE_OFFSET;
  27
  28         _text = .;              /* Text and read-only data */
  29
  30         .empty_zero_page : AT(ADDR(.empty_zero_page) - LOAD_OFFSET) {
  31                 *(.empty_zero_page)
  32         } = 0
  33
  34         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  35                 HEAD_TEXT
  36                 TEXT_TEXT
  37
  38 #ifdef CONFIG_SUPERH64
  39                 *(.text64)
  40                 *(.text..SHmedia32)
  41 #endif
  42
  43                 SCHED_TEXT
  44                 LOCK_TEXT
  45                 KPROBES_TEXT
  46                 IRQENTRY_TEXT
  47                 *(.fixup)
  48                 *(.gnu.warning)
  49                 _etext = .;             /* End of text section */
  50         } = 0x0009
  51
  52         EXCEPTION_TABLE(16)
  53
  54         NOTES
  55         RO_DATA(PAGE_SIZE)
  56         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  57
  58         _edata = .;                     /* End of data section */
  59
  60         DWARF_EH_FRAME
  61
  62         . = ALIGN(PAGE_SIZE);           /* Init code and data */
  63         __init_begin = .;
  64         INIT_TEXT_SECTION(PAGE_SIZE)
  65         INIT_DATA_SECTION(16)
  66
  67         . = ALIGN(4);
  68         .machvec.init : AT(ADDR(.machvec.init) - LOAD_OFFSET) {
  69                 __machvec_start = .;
  70                 *(.machvec.init)
  71                 __machvec_end = .;
  72         }
  73
  74         PERCPU(PAGE_SIZE)
  75
  76         /*
  77          * .exit.text is discarded at runtime, not link time, to deal with
  78          * references from __bug_table
  79          */
  80         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { EXIT_TEXT }
  81         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { EXIT_DATA }
  82
  83         . = ALIGN(PAGE_SIZE);
  84         __init_end = .;
  85         BSS_SECTION(0, PAGE_SIZE, 4)
  86         _ebss = .;                      /* uClinux MTD sucks */
  87         _end = . ;
  88
  89         STABS_DEBUG
  90         DWARF_DEBUG
  91
  92         DISCARDS
  93 }