| blob | 7365a17a6a81560e97ffb54f6ce39eba2f04dff4 |
1 /*
2 * File: arch/blackfin/mach-common/entry.S
3 * Based on:
4 * Author: Linus Torvalds
5 *
6 * Created: ?
7 * Description: contains the system-call and fault low-level handling routines.
8 * This also contains the timer-interrupt handler, as well as all
9 * interrupts and faults that can result in a task-switch.
10 *
11 * Modified:
12 * Copyright 2004-2006 Analog Devices Inc.
13 *
14 * Bugs: Enter bugs at http://blackfin.uclinux.org/
15 *
16 * This program is free software; you can redistribute it and/or modify
17 * it under the terms of the GNU General Public License as published by
18 * the Free Software Foundation; either version 2 of the License, or
19 * (at your option) any later version.
20 *
21 * This program is distributed in the hope that it will be useful,
22 * but WITHOUT ANY WARRANTY; without even the implied warranty of
23 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
24 * GNU General Public License for more details.
25 *
26 * You should have received a copy of the GNU General Public License
27 * along with this program; if not, see the file COPYING, or write
28 * to the Free Software Foundation, Inc.,
29 * 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
30 */
32 /* NOTE: This code handles signal-recognition, which happens every time
33 * after a timer-interrupt and after each system call.
34 */
36 #include <linux/init.h>
37 #include <linux/linkage.h>
38 #include <linux/unistd.h>
39 #include <asm/blackfin.h>
40 #include <asm/errno.h>
41 #include <asm/fixed_code.h>
42 #include <asm/thread_info.h> /* TIF_NEED_RESCHED */
43 #include <asm/asm-offsets.h>
44 #include <asm/trace.h>
46 #include <asm/mach-common/context.S>
48 #if defined(CONFIG_BFIN_SCRATCH_REG_RETN)
49 # define EX_SCRATCH_REG RETN
50 #elif defined(CONFIG_BFIN_SCRATCH_REG_RETE)
51 # define EX_SCRATCH_REG RETE
52 #else
53 # define EX_SCRATCH_REG CYCLES
54 #endif
56 #ifdef CONFIG_EXCPT_IRQ_SYSC_L1
57 .section .l1.text
58 #else
59 .text
60 #endif
62 /* Slightly simplified and streamlined entry point for CPLB misses.
63 * This one does not lower the level to IRQ5, and thus can be used to
64 * patch up CPLB misses on the kernel stack.
65 */
66 #if ANOMALY_05000261
67 #define _ex_dviol _ex_workaround_261
68 #define _ex_dmiss _ex_workaround_261
69 #define _ex_dmult _ex_workaround_261
71 ENTRY(_ex_workaround_261)
72 /*
73 * Work around an anomaly: if we see a new DCPLB fault, return
74 * without doing anything. Then, if we get the same fault again,
75 * handle it.
76 */
77 P4 = R7; /* Store EXCAUSE */
78 p5.l = _last_cplb_fault_retx;
79 p5.h = _last_cplb_fault_retx;
80 r7 = [p5];
81 r6 = retx;
82 [p5] = r6;
83 cc = r6 == r7;
84 if !cc jump _bfin_return_from_exception;
85 /* fall through */
86 R7 = P4;
87 R6 = 0x26; /* Data CPLB Miss */
88 cc = R6 == R7;
89 if cc jump _ex_dcplb_miss (BP);
90 R6 = 0x23; /* Data CPLB Miss */
91 cc = R6 == R7;
92 if cc jump _ex_dcplb_viol (BP);
93 /* Handle 0x23 Data CPLB Protection Violation
94 * and Data CPLB Multiple Hits - Linux Trap Zero
95 */
96 jump _ex_trap_c;
97 ENDPROC(_ex_workaround_261)
99 #else
100 #ifdef CONFIG_MPU
101 #define _ex_dviol _ex_dcplb_viol
102 #else
103 #define _ex_dviol _ex_trap_c
104 #endif
105 #define _ex_dmiss _ex_dcplb_miss
106 #define _ex_dmult _ex_trap_c
107 #endif
110 ENTRY(_ex_dcplb_viol)
111 ENTRY(_ex_dcplb_miss)
112 ENTRY(_ex_icplb_miss)
113 (R7:6,P5:4) = [sp++];
114 ASTAT = [sp++];
115 SAVE_ALL_SYS
116 #ifdef CONFIG_MPU
117 /* We must load R1 here, _before_ DEBUG_HWTRACE_SAVE, since that
118 * will change the stack pointer. */
119 R0 = SEQSTAT;
120 R1 = SP;
121 #endif
122 DEBUG_HWTRACE_SAVE(p5, r7)
123 #ifdef CONFIG_MPU
124 sp += -12;
125 call _cplb_hdr;
126 sp += 12;
127 CC = R0 == 0;
128 IF !CC JUMP _handle_bad_cplb;
129 #else
130 call __cplb_hdr;
131 #endif
132 DEBUG_HWTRACE_RESTORE(p5, r7)
133 RESTORE_ALL_SYS
134 SP = EX_SCRATCH_REG;
135 rtx;
136 ENDPROC(_ex_icplb_miss)
138 ENTRY(_ex_syscall)
139 (R7:6,P5:4) = [sp++];
140 ASTAT = [sp++];
141 raise 15; /* invoked by TRAP #0, for sys call */
142 sp = EX_SCRATCH_REG;
143 rtx
144 ENDPROC(_ex_syscall)
146 ENTRY(_ex_soft_bp)
147 r7 = retx;
148 r7 += -2;
149 retx = r7;
150 jump.s _ex_trap_c;
151 ENDPROC(_ex_soft_bp)
153 ENTRY(_ex_single_step)
154 r7 = retx;
155 r6 = reti;
156 cc = r7 == r6;
157 if cc jump _bfin_return_from_exception
158 r7 = syscfg;
159 bitclr (r7, 0);
160 syscfg = R7;
162 p5.l = lo(IPEND);
163 p5.h = hi(IPEND);
164 r6 = [p5];
165 cc = bittst(r6, 5);
166 if !cc jump _ex_trap_c;
167 p4.l = lo(EVT5);
168 p4.h = hi(EVT5);
169 r6.h = _exception_to_level5;
170 r6.l = _exception_to_level5;
171 r7 = [p4];
172 cc = r6 == r7;
173 if !cc jump _ex_trap_c;
174 ENDPROC(_ex_single_step)
176 ENTRY(_bfin_return_from_exception)
177 #if ANOMALY_05000257
178 R7=LC0;
179 LC0=R7;
180 R7=LC1;
181 LC1=R7;
182 #endif
183 (R7:6,P5:4) = [sp++];
184 ASTAT = [sp++];
185 sp = EX_SCRATCH_REG;
186 rtx;
187 ENDPROC(_bfin_return_from_exception)
189 ENTRY(_handle_bad_cplb)
190 DEBUG_HWTRACE_RESTORE(p5, r7)
191 /* To get here, we just tried and failed to change a CPLB
192 * so, handle things in trap_c (C code), by lowering to
193 * IRQ5, just like we normally do. Since this is not a
194 * "normal" return path, we have a do alot of stuff to
195 * the stack to get ready so, we can fall through - we
196 * need to make a CPLB exception look like a normal exception
197 */
199 RESTORE_ALL_SYS
200 [--sp] = ASTAT;
201 [--sp] = (R7:6,P5:4);
203 ENTRY(_ex_replaceable)
204 nop;
206 ENTRY(_ex_trap_c)
207 /* Make sure we are not in a double fault */
208 p4.l = lo(IPEND);
209 p4.h = hi(IPEND);
210 r7 = [p4];
211 CC = BITTST (r7, 5);
212 if CC jump _double_fault;
214 /* Call C code (trap_c) to handle the exception, which most
215 * likely involves sending a signal to the current process.
216 * To avoid double faults, lower our priority to IRQ5 first.
217 */
218 P5.h = _exception_to_level5;
219 P5.l = _exception_to_level5;
220 p4.l = lo(EVT5);
221 p4.h = hi(EVT5);
222 [p4] = p5;
223 csync;
225 p4.l = lo(DCPLB_FAULT_ADDR);
226 p4.h = hi(DCPLB_FAULT_ADDR);
227 r7 = [p4];
228 p5.h = _saved_dcplb_fault_addr;
229 p5.l = _saved_dcplb_fault_addr;
230 [p5] = r7;
232 r7 = [p4 + (ICPLB_FAULT_ADDR - DCPLB_FAULT_ADDR)];
233 p5.h = _saved_icplb_fault_addr;
234 p5.l = _saved_icplb_fault_addr;
235 [p5] = r7;
237 p4.l = __retx;
238 p4.h = __retx;
239 r6 = retx;
240 [p4] = r6;
241 p4.l = lo(SAFE_USER_INSTRUCTION);
242 p4.h = hi(SAFE_USER_INSTRUCTION);
243 retx = p4;
245 /* Disable all interrupts, but make sure level 5 is enabled so
246 * we can switch to that level. Save the old mask. */
247 cli r6;
248 p4.l = _excpt_saved_imask;
249 p4.h = _excpt_saved_imask;
250 [p4] = r6;
251 r6 = 0x3f;
252 sti r6;
254 (R7:6,P5:4) = [sp++];
255 ASTAT = [sp++];
256 SP = EX_SCRATCH_REG;
257 raise 5;
258 rtx;
259 ENDPROC(_ex_trap_c)
261 /* We just realized we got an exception, while we were processing a different
262 * exception. This is a unrecoverable event, so crash
263 */
264 ENTRY(_double_fault)
265 /* Turn caches & protection off, to ensure we don't get any more
266 * double exceptions
267 */
269 P4.L = LO(IMEM_CONTROL);
270 P4.H = HI(IMEM_CONTROL);
272 R5 = [P4]; /* Control Register*/
273 BITCLR(R5,ENICPLB_P);
274 SSYNC; /* SSYNC required before writing to IMEM_CONTROL. */
275 .align 8;
276 [P4] = R5;
277 SSYNC;
279 P4.L = LO(DMEM_CONTROL);
280 P4.H = HI(DMEM_CONTROL);
281 R5 = [P4];
282 BITCLR(R5,ENDCPLB_P);
283 SSYNC; /* SSYNC required before writing to DMEM_CONTROL. */
284 .align 8;
285 [P4] = R5;
286 SSYNC;
288 /* Fix up the stack */
289 (R7:6,P5:4) = [sp++];
290 ASTAT = [sp++];
291 SP = EX_SCRATCH_REG;
293 /* We should be out of the exception stack, and back down into
294 * kernel or user space stack
295 */
296 SAVE_ALL_SYS
298 /* The dumping functions expect the return address in the RETI
299 * slot. */
300 r6 = retx;
301 [sp + PT_PC] = r6;
303 r0 = sp; /* stack frame pt_regs pointer argument ==> r0 */
304 SP += -12;
305 call _double_fault_c;
306 SP += 12;
307 .L_double_fault_panic:
308 JUMP .L_double_fault_panic
310 ENDPROC(_double_fault)
312 ENTRY(_exception_to_level5)
313 SAVE_ALL_SYS
315 p4.l = __retx;
316 p4.h = __retx;
317 r6 = [p4];
318 [sp + PT_PC] = r6;
320 /* Restore interrupt mask. We haven't pushed RETI, so this
321 * doesn't enable interrupts until we return from this handler. */
322 p4.l = _excpt_saved_imask;
323 p4.h = _excpt_saved_imask;
324 r6 = [p4];
325 sti r6;
327 /* Restore the hardware error vector. */
328 P5.h = _evt_ivhw;
329 P5.l = _evt_ivhw;
330 p4.l = lo(EVT5);
331 p4.h = hi(EVT5);
332 [p4] = p5;
333 csync;
335 p2.l = lo(IPEND);
336 p2.h = hi(IPEND);
337 csync;
338 r0 = [p2]; /* Read current IPEND */
339 [sp + PT_IPEND] = r0; /* Store IPEND */
341 r0 = sp; /* stack frame pt_regs pointer argument ==> r0 */
342 SP += -12;
343 call _trap_c;
344 SP += 12;
346 call _ret_from_exception;
347 RESTORE_ALL_SYS
348 rti;
349 ENDPROC(_exception_to_level5)
351 ENTRY(_trap) /* Exception: 4th entry into system event table(supervisor mode)*/
352 /* Since the kernel stack can be anywhere, it's not guaranteed to be
353 * covered by a CPLB. Switch to an exception stack; use RETN as a
354 * scratch register (for want of a better option).
355 */
356 EX_SCRATCH_REG = sp;
357 sp.l = _exception_stack_top;
358 sp.h = _exception_stack_top;
359 /* Try to deal with syscalls quickly. */
360 [--sp] = ASTAT;
361 [--sp] = (R7:6,P5:4);
362 r7 = SEQSTAT; /* reason code is in bit 5:0 */
363 r6.l = lo(SEQSTAT_EXCAUSE);
364 r6.h = hi(SEQSTAT_EXCAUSE);
365 r7 = r7 & r6;
366 p5.h = _ex_table;
367 p5.l = _ex_table;
368 p4 = r7;
369 p5 = p5 + (p4 << 2);
370 p4 = [p5];
371 jump (p4);
373 .Lbadsys:
374 r7 = -ENOSYS; /* signextending enough */
375 [sp + PT_R0] = r7; /* return value from system call */
376 jump .Lsyscall_really_exit;
377 ENDPROC(_trap)
379 ENTRY(_kernel_execve)
380 link SIZEOF_PTREGS;
381 p0 = sp;
382 r3 = SIZEOF_PTREGS / 4;
383 r4 = 0(x);
384 0:
385 [p0++] = r4;
386 r3 += -1;
387 cc = r3 == 0;
388 if !cc jump 0b (bp);
390 p0 = sp;
391 sp += -16;
392 [sp + 12] = p0;
393 call _do_execve;
394 SP += 16;
395 cc = r0 == 0;
396 if ! cc jump 1f;
397 /* Success. Copy our temporary pt_regs to the top of the kernel
398 * stack and do a normal exception return.
399 */
400 r1 = sp;
401 r0 = (-KERNEL_STACK_SIZE) (x);
402 r1 = r1 & r0;
403 p2 = r1;
404 p3 = [p2];
405 r0 = KERNEL_STACK_SIZE - 4 (z);
406 p1 = r0;
407 p1 = p1 + p2;
409 p0 = fp;
410 r4 = [p0--];
411 r3 = SIZEOF_PTREGS / 4;
412 0:
413 r4 = [p0--];
414 [p1--] = r4;
415 r3 += -1;
416 cc = r3 == 0;
417 if ! cc jump 0b (bp);
419 r0 = (KERNEL_STACK_SIZE - SIZEOF_PTREGS) (z);
420 p1 = r0;
421 p1 = p1 + p2;
422 sp = p1;
423 r0 = syscfg;
424 [SP + PT_SYSCFG] = r0;
425 [p3 + (TASK_THREAD + THREAD_KSP)] = sp;
427 RESTORE_CONTEXT;
428 rti;
429 1:
430 unlink;
431 rts;
432 ENDPROC(_kernel_execve)
434 ENTRY(_system_call)
435 /* Store IPEND */
436 p2.l = lo(IPEND);
437 p2.h = hi(IPEND);
438 csync;
439 r0 = [p2];
440 [sp + PT_IPEND] = r0;
442 /* Store RETS for now */
443 r0 = rets;
444 [sp + PT_RESERVED] = r0;
445 /* Set the stack for the current process */
446 r7 = sp;
447 r6.l = lo(ALIGN_PAGE_MASK);
448 r6.h = hi(ALIGN_PAGE_MASK);
449 r7 = r7 & r6; /* thread_info */
450 p2 = r7;
451 p2 = [p2];
453 [p2+(TASK_THREAD+THREAD_KSP)] = sp;
455 /* Check the System Call */
456 r7 = __NR_syscall;
457 /* System call number is passed in P0 */
458 r6 = p0;
459 cc = r6 < r7;
460 if ! cc jump .Lbadsys;
462 /* are we tracing syscalls?*/
463 r7 = sp;
464 r6.l = lo(ALIGN_PAGE_MASK);
465 r6.h = hi(ALIGN_PAGE_MASK);
466 r7 = r7 & r6;
467 p2 = r7;
468 r7 = [p2+TI_FLAGS];
469 CC = BITTST(r7,TIF_SYSCALL_TRACE);
470 if CC JUMP _sys_trace;
472 /* Execute the appropriate system call */
474 p4 = p0;
475 p5.l = _sys_call_table;
476 p5.h = _sys_call_table;
477 p5 = p5 + (p4 << 2);
478 r0 = [sp + PT_R0];
479 r1 = [sp + PT_R1];
480 r2 = [sp + PT_R2];
481 p5 = [p5];
483 [--sp] = r5;
484 [--sp] = r4;
485 [--sp] = r3;
486 SP += -12;
487 call (p5);
488 SP += 24;
489 [sp + PT_R0] = r0;
491 .Lresume_userspace:
492 r7 = sp;
493 r4.l = lo(ALIGN_PAGE_MASK);
494 r4.h = hi(ALIGN_PAGE_MASK);
495 r7 = r7 & r4; /* thread_info->flags */
496 p5 = r7;
497 .Lresume_userspace_1:
498 /* Disable interrupts. */
499 [--sp] = reti;
500 reti = [sp++];
502 r7 = [p5 + TI_FLAGS];
503 r4.l = lo(_TIF_WORK_MASK);
504 r4.h = hi(_TIF_WORK_MASK);
505 r7 = r7 & r4;
507 .Lsyscall_resched:
508 cc = BITTST(r7, TIF_NEED_RESCHED);
509 if !cc jump .Lsyscall_sigpending;
511 /* Reenable interrupts. */
512 [--sp] = reti;
513 r0 = [sp++];
515 SP += -12;
516 call _schedule;
517 SP += 12;
519 jump .Lresume_userspace_1;
521 .Lsyscall_sigpending:
522 cc = BITTST(r7, TIF_RESTORE_SIGMASK);
523 if cc jump .Lsyscall_do_signals;
524 cc = BITTST(r7, TIF_SIGPENDING);
525 if !cc jump .Lsyscall_really_exit;
526 .Lsyscall_do_signals:
527 /* Reenable interrupts. */
528 [--sp] = reti;
529 r0 = [sp++];
531 r0 = sp;
532 SP += -12;
533 call _do_signal;
534 SP += 12;
536 .Lsyscall_really_exit:
537 r5 = [sp + PT_RESERVED];
538 rets = r5;
539 rts;
540 ENDPROC(_system_call)
542 _sys_trace:
543 call _syscall_trace;
545 /* Execute the appropriate system call */
547 p4 = [SP + PT_P0];
548 p5.l = _sys_call_table;
549 p5.h = _sys_call_table;
550 p5 = p5 + (p4 << 2);
551 r0 = [sp + PT_R0];
552 r1 = [sp + PT_R1];
553 r2 = [sp + PT_R2];
554 r3 = [sp + PT_R3];
555 r4 = [sp + PT_R4];
556 r5 = [sp + PT_R5];
557 p5 = [p5];
559 [--sp] = r5;
560 [--sp] = r4;
561 [--sp] = r3;
562 SP += -12;
563 call (p5);
564 SP += 24;
565 [sp + PT_R0] = r0;
567 call _syscall_trace;
568 jump .Lresume_userspace;
569 ENDPROC(_sys_trace)
571 ENTRY(_resume)
572 /*
573 * Beware - when entering resume, prev (the current task) is
574 * in r0, next (the new task) is in r1.
575 */
576 p0 = r0;
577 p1 = r1;
578 [--sp] = rets;
579 [--sp] = fp;
580 [--sp] = (r7:4, p5:3);
582 /* save usp */
583 p2 = usp;
584 [p0+(TASK_THREAD+THREAD_USP)] = p2;
586 /* save current kernel stack pointer */
587 [p0+(TASK_THREAD+THREAD_KSP)] = sp;
589 /* save program counter */
590 r1.l = _new_old_task;
591 r1.h = _new_old_task;
592 [p0+(TASK_THREAD+THREAD_PC)] = r1;
594 /* restore the kernel stack pointer */
595 sp = [p1+(TASK_THREAD+THREAD_KSP)];
597 /* restore user stack pointer */
598 p0 = [p1+(TASK_THREAD+THREAD_USP)];
599 usp = p0;
601 /* restore pc */
602 p0 = [p1+(TASK_THREAD+THREAD_PC)];
603 jump (p0);
605 /*
606 * Following code actually lands up in a new (old) task.
607 */
609 _new_old_task:
610 (r7:4, p5:3) = [sp++];
611 fp = [sp++];
612 rets = [sp++];
614 /*
615 * When we come out of resume, r0 carries "old" task, becuase we are
616 * in "new" task.
617 */
618 rts;
619 ENDPROC(_resume)
621 ENTRY(_ret_from_exception)
622 p2.l = lo(IPEND);
623 p2.h = hi(IPEND);
625 csync;
626 r0 = [p2];
627 [sp + PT_IPEND] = r0;
629 1:
630 r2 = LO(~0x37) (Z);
631 r0 = r2 & r0;
632 cc = r0 == 0;
633 if !cc jump 4f; /* if not return to user mode, get out */
635 /* Make sure any pending system call or deferred exception
636 * return in ILAT for this process to get executed, otherwise
637 * in case context switch happens, system call of
638 * first process (i.e in ILAT) will be carried
639 * forward to the switched process
640 */
642 p2.l = lo(ILAT);
643 p2.h = hi(ILAT);
644 r0 = [p2];
645 r1 = (EVT_IVG14 | EVT_IVG15) (z);
646 r0 = r0 & r1;
647 cc = r0 == 0;
648 if !cc jump 5f;
650 /* Set the stack for the current process */
651 r7 = sp;
652 r4.l = lo(ALIGN_PAGE_MASK);
653 r4.h = hi(ALIGN_PAGE_MASK);
654 r7 = r7 & r4; /* thread_info->flags */
655 p5 = r7;
656 r7 = [p5 + TI_FLAGS];
657 r4.l = lo(_TIF_WORK_MASK);
658 r4.h = hi(_TIF_WORK_MASK);
659 r7 = r7 & r4;
660 cc = r7 == 0;
661 if cc jump 4f;
663 p0.l = lo(EVT15);
664 p0.h = hi(EVT15);
665 p1.l = _schedule_and_signal;
666 p1.h = _schedule_and_signal;
667 [p0] = p1;
668 csync;
669 raise 15; /* raise evt14 to do signal or reschedule */
670 4:
671 r0 = syscfg;
672 bitclr(r0, 0);
673 syscfg = r0;
674 5:
675 rts;
676 ENDPROC(_ret_from_exception)
678 ENTRY(_return_from_int)
679 /* If someone else already raised IRQ 15, do nothing. */
680 csync;
681 p2.l = lo(ILAT);
682 p2.h = hi(ILAT);
683 r0 = [p2];
684 cc = bittst (r0, EVT_IVG15_P);
685 if cc jump 2f;
687 /* if not return to user mode, get out */
688 p2.l = lo(IPEND);
689 p2.h = hi(IPEND);
690 r0 = [p2];
691 r1 = 0x17(Z);
692 r2 = ~r1;
693 r2.h = 0;
694 r0 = r2 & r0;
695 r1 = 1;
696 r1 = r0 - r1;
697 r2 = r0 & r1;
698 cc = r2 == 0;
699 if !cc jump 2f;
701 /* Lower the interrupt level to 15. */
702 p0.l = lo(EVT15);
703 p0.h = hi(EVT15);
704 p1.l = _schedule_and_signal_from_int;
705 p1.h = _schedule_and_signal_from_int;
706 [p0] = p1;
707 csync;
708 #if ANOMALY_05000281
709 r0.l = lo(SAFE_USER_INSTRUCTION);
710 r0.h = hi(SAFE_USER_INSTRUCTION);
711 reti = r0;
712 #endif
713 r0 = 0x801f (z);
714 STI r0;
715 raise 15; /* raise evt15 to do signal or reschedule */
716 rti;
717 2:
718 rts;
719 ENDPROC(_return_from_int)
721 ENTRY(_lower_to_irq14)
722 #if ANOMALY_05000281
723 r0.l = lo(SAFE_USER_INSTRUCTION);
724 r0.h = hi(SAFE_USER_INSTRUCTION);
725 reti = r0;
726 #endif
727 r0 = 0x401f;
728 sti r0;
729 raise 14;
730 rti;
731 ENTRY(_evt14_softirq)
732 #ifdef CONFIG_DEBUG_HWERR
733 r0 = 0x3f;
734 sti r0;
735 #else
736 cli r0;
737 #endif
738 [--sp] = RETI;
739 SP += 4;
740 rts;
742 _schedule_and_signal_from_int:
743 /* To end up here, vector 15 was changed - so we have to change it
744 * back.
745 */
746 p0.l = lo(EVT15);
747 p0.h = hi(EVT15);
748 p1.l = _evt_system_call;
749 p1.h = _evt_system_call;
750 [p0] = p1;
751 csync;
753 /* Set orig_p0 to -1 to indicate this isn't the end of a syscall. */
754 r0 = -1 (x);
755 [sp + PT_ORIG_P0] = r0;
757 p1 = rets;
758 [sp + PT_RESERVED] = p1;
760 p0.l = _irq_flags;
761 p0.h = _irq_flags;
762 r0 = [p0];
763 sti r0;
765 r0 = sp;
766 sp += -12;
767 call _finish_atomic_sections;
768 sp += 12;
769 jump.s .Lresume_userspace;
771 _schedule_and_signal:
772 SAVE_CONTEXT_SYSCALL
773 /* To end up here, vector 15 was changed - so we have to change it
774 * back.
775 */
776 p0.l = lo(EVT15);
777 p0.h = hi(EVT15);
778 p1.l = _evt_system_call;
779 p1.h = _evt_system_call;
780 [p0] = p1;
781 csync;
782 p0.l = 1f;
783 p0.h = 1f;
784 [sp + PT_RESERVED] = P0;
785 call .Lresume_userspace;
786 1:
787 RESTORE_CONTEXT
788 rti;
789 ENDPROC(_lower_to_irq14)
791 /* We handle this 100% in exception space - to reduce overhead
792 * Only potiential problem is if the software buffer gets swapped out of the
793 * CPLB table - then double fault. - so we don't let this happen in other places
794 */
795 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
796 ENTRY(_ex_trace_buff_full)
797 [--sp] = P3;
798 [--sp] = P2;
799 [--sp] = LC0;
800 [--sp] = LT0;
801 [--sp] = LB0;
802 P5.L = _trace_buff_offset;
803 P5.H = _trace_buff_offset;
804 P3 = [P5]; /* trace_buff_offset */
805 P5.L = lo(TBUFSTAT);
806 P5.H = hi(TBUFSTAT);
807 R7 = [P5];
808 R7 <<= 1; /* double, since we need to read twice */
809 LC0 = R7;
810 R7 <<= 2; /* need to shift over again,
811 * to get the number of bytes */
812 P5.L = lo(TBUF);
813 P5.H = hi(TBUF);
814 R6 = ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*1024) - 1;
816 P2 = R7;
817 P3 = P3 + P2;
818 R7 = P3;
819 R7 = R7 & R6;
820 P3 = R7;
821 P2.L = _trace_buff_offset;
822 P2.H = _trace_buff_offset;
823 [P2] = P3;
825 P2.L = _software_trace_buff;
826 P2.H = _software_trace_buff;
828 LSETUP (.Lstart, .Lend) LC0;
829 .Lstart:
830 R7 = [P5]; /* read TBUF */
831 P4 = P3 + P2;
832 [P4] = R7;
833 P3 += -4;
834 R7 = P3;
835 R7 = R7 & R6;
836 .Lend:
837 P3 = R7;
839 LB0 = [sp++];
840 LT0 = [sp++];
841 LC0 = [sp++];
842 P2 = [sp++];
843 P3 = [sp++];
844 jump _bfin_return_from_exception;
845 ENDPROC(_ex_trace_buff_full)
847 #if CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN == 4
848 .data
849 #else
850 .section .l1.data.B
851 #endif /* CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN */
852 ENTRY(_trace_buff_offset)
853 .long 0;
854 ALIGN
855 ENTRY(_software_trace_buff)
856 .rept ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*256);
857 .long 0
858 .endr
859 #endif /* CONFIG_DEBUG_BFIN_HWTRACE_EXPAND */
861 #if CONFIG_EARLY_PRINTK
862 __INIT
863 ENTRY(_early_trap)
864 SAVE_ALL_SYS
865 trace_buffer_stop(p0,r0);
867 /* Turn caches off, to ensure we don't get double exceptions */
869 P4.L = LO(IMEM_CONTROL);
870 P4.H = HI(IMEM_CONTROL);
872 R5 = [P4]; /* Control Register*/
873 BITCLR(R5,ENICPLB_P);
874 CLI R1;
875 SSYNC; /* SSYNC required before writing to IMEM_CONTROL. */
876 .align 8;
877 [P4] = R5;
878 SSYNC;
880 P4.L = LO(DMEM_CONTROL);
881 P4.H = HI(DMEM_CONTROL);
882 R5 = [P4];
883 BITCLR(R5,ENDCPLB_P);
884 SSYNC; /* SSYNC required before writing to DMEM_CONTROL. */
885 .align 8;
886 [P4] = R5;
887 SSYNC;
888 STI R1;
890 r0 = sp; /* stack frame pt_regs pointer argument ==> r0 */
891 r1 = RETX;
893 SP += -12;
894 call _early_trap_c;
895 SP += 12;
896 ENDPROC(_early_trap)
897 __FINIT
898 #endif /* CONFIG_EARLY_PRINTK */
900 /*
901 * Put these in the kernel data section - that should always be covered by
902 * a CPLB. This is needed to ensure we don't get double fault conditions
903 */
905 #ifdef CONFIG_SYSCALL_TAB_L1
906 .section .l1.data
907 #else
908 .data
909 #endif
911 ENTRY(_ex_table)
912 /* entry for each EXCAUSE[5:0]
913 * This table must be in sync with the table in ./kernel/traps.c
914 * EXCPT instruction can provide 4 bits of EXCAUSE, allowing 16 to be user defined
915 */
916 .long _ex_syscall /* 0x00 - User Defined - Linux Syscall */
917 .long _ex_soft_bp /* 0x01 - User Defined - Software breakpoint */
918 .long _ex_replaceable /* 0x02 - User Defined */
919 .long _ex_trap_c /* 0x03 - User Defined - userspace stack overflow */
920 .long _ex_trap_c /* 0x04 - User Defined - dump trace buffer */
921 .long _ex_replaceable /* 0x05 - User Defined */
922 .long _ex_replaceable /* 0x06 - User Defined */
923 .long _ex_replaceable /* 0x07 - User Defined */
924 .long _ex_replaceable /* 0x08 - User Defined */
925 .long _ex_replaceable /* 0x09 - User Defined */
926 .long _ex_replaceable /* 0x0A - User Defined */
927 .long _ex_replaceable /* 0x0B - User Defined */
928 .long _ex_replaceable /* 0x0C - User Defined */
929 .long _ex_replaceable /* 0x0D - User Defined */
930 .long _ex_replaceable /* 0x0E - User Defined */
931 .long _ex_replaceable /* 0x0F - User Defined */
932 .long _ex_single_step /* 0x10 - HW Single step */
933 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
934 .long _ex_trace_buff_full /* 0x11 - Trace Buffer Full */
935 #else
936 .long _ex_trap_c /* 0x11 - Trace Buffer Full */
937 #endif
938 .long _ex_trap_c /* 0x12 - Reserved */
939 .long _ex_trap_c /* 0x13 - Reserved */
940 .long _ex_trap_c /* 0x14 - Reserved */
941 .long _ex_trap_c /* 0x15 - Reserved */
942 .long _ex_trap_c /* 0x16 - Reserved */
943 .long _ex_trap_c /* 0x17 - Reserved */
944 .long _ex_trap_c /* 0x18 - Reserved */
945 .long _ex_trap_c /* 0x19 - Reserved */
946 .long _ex_trap_c /* 0x1A - Reserved */
947 .long _ex_trap_c /* 0x1B - Reserved */
948 .long _ex_trap_c /* 0x1C - Reserved */
949 .long _ex_trap_c /* 0x1D - Reserved */
950 .long _ex_trap_c /* 0x1E - Reserved */
951 .long _ex_trap_c /* 0x1F - Reserved */
952 .long _ex_trap_c /* 0x20 - Reserved */
953 .long _ex_trap_c /* 0x21 - Undefined Instruction */
954 .long _ex_trap_c /* 0x22 - Illegal Instruction Combination */
955 .long _ex_dviol /* 0x23 - Data CPLB Protection Violation */
956 .long _ex_trap_c /* 0x24 - Data access misaligned */
957 .long _ex_trap_c /* 0x25 - Unrecoverable Event */
958 .long _ex_dmiss /* 0x26 - Data CPLB Miss */
959 .long _ex_dmult /* 0x27 - Data CPLB Multiple Hits - Linux Trap Zero */
960 .long _ex_trap_c /* 0x28 - Emulation Watchpoint */
961 .long _ex_trap_c /* 0x29 - Instruction fetch access error (535 only) */
962 .long _ex_trap_c /* 0x2A - Instruction fetch misaligned */
963 .long _ex_trap_c /* 0x2B - Instruction CPLB protection Violation */
964 .long _ex_icplb_miss /* 0x2C - Instruction CPLB miss */
965 .long _ex_trap_c /* 0x2D - Instruction CPLB Multiple Hits */
966 .long _ex_trap_c /* 0x2E - Illegal use of Supervisor Resource */
967 .long _ex_trap_c /* 0x2E - Illegal use of Supervisor Resource */
968 .long _ex_trap_c /* 0x2F - Reserved */
969 .long _ex_trap_c /* 0x30 - Reserved */
970 .long _ex_trap_c /* 0x31 - Reserved */
971 .long _ex_trap_c /* 0x32 - Reserved */
972 .long _ex_trap_c /* 0x33 - Reserved */
973 .long _ex_trap_c /* 0x34 - Reserved */
974 .long _ex_trap_c /* 0x35 - Reserved */
975 .long _ex_trap_c /* 0x36 - Reserved */
976 .long _ex_trap_c /* 0x37 - Reserved */
977 .long _ex_trap_c /* 0x38 - Reserved */
978 .long _ex_trap_c /* 0x39 - Reserved */
979 .long _ex_trap_c /* 0x3A - Reserved */
980 .long _ex_trap_c /* 0x3B - Reserved */
981 .long _ex_trap_c /* 0x3C - Reserved */
982 .long _ex_trap_c /* 0x3D - Reserved */
983 .long _ex_trap_c /* 0x3E - Reserved */
984 .long _ex_trap_c /* 0x3F - Reserved */
985 END(_ex_table)
987 ENTRY(_sys_call_table)
988 .long _sys_restart_syscall /* 0 */
989 .long _sys_exit
990 .long _sys_fork
991 .long _sys_read
992 .long _sys_write
993 .long _sys_open /* 5 */
994 .long _sys_close
995 .long _sys_ni_syscall /* old waitpid */
996 .long _sys_creat
997 .long _sys_link
998 .long _sys_unlink /* 10 */
999 .long _sys_execve
1000 .long _sys_chdir
1001 .long _sys_time
1002 .long _sys_mknod
1003 .long _sys_chmod /* 15 */
1004 .long _sys_chown /* chown16 */
1005 .long _sys_ni_syscall /* old break syscall holder */
1006 .long _sys_ni_syscall /* old stat */
1007 .long _sys_lseek
1008 .long _sys_getpid /* 20 */
1009 .long _sys_mount
1010 .long _sys_ni_syscall /* old umount */
1011 .long _sys_setuid
1012 .long _sys_getuid
1013 .long _sys_stime /* 25 */
1014 .long _sys_ptrace
1015 .long _sys_alarm
1016 .long _sys_ni_syscall /* old fstat */
1017 .long _sys_pause
1018 .long _sys_ni_syscall /* old utime */ /* 30 */
1019 .long _sys_ni_syscall /* old stty syscall holder */
1020 .long _sys_ni_syscall /* old gtty syscall holder */
1021 .long _sys_access
1022 .long _sys_nice
1023 .long _sys_ni_syscall /* 35 */ /* old ftime syscall holder */
1024 .long _sys_sync
1025 .long _sys_kill
1026 .long _sys_rename
1027 .long _sys_mkdir
1028 .long _sys_rmdir /* 40 */
1029 .long _sys_dup
1030 .long _sys_pipe
1031 .long _sys_times
1032 .long _sys_ni_syscall /* old prof syscall holder */
1033 .long _sys_brk /* 45 */
1034 .long _sys_setgid
1035 .long _sys_getgid
1036 .long _sys_ni_syscall /* old sys_signal */
1037 .long _sys_geteuid /* geteuid16 */
1038 .long _sys_getegid /* getegid16 */ /* 50 */
1039 .long _sys_acct
1040 .long _sys_umount /* recycled never used phys() */
1041 .long _sys_ni_syscall /* old lock syscall holder */
1042 .long _sys_ioctl
1043 .long _sys_fcntl /* 55 */
1044 .long _sys_ni_syscall /* old mpx syscall holder */
1045 .long _sys_setpgid
1046 .long _sys_ni_syscall /* old ulimit syscall holder */
1047 .long _sys_ni_syscall /* old old uname */
1048 .long _sys_umask /* 60 */
1049 .long _sys_chroot
1050 .long _sys_ustat
1051 .long _sys_dup2
1052 .long _sys_getppid
1053 .long _sys_getpgrp /* 65 */
1054 .long _sys_setsid
1055 .long _sys_ni_syscall /* old sys_sigaction */
1056 .long _sys_sgetmask
1057 .long _sys_ssetmask
1058 .long _sys_setreuid /* setreuid16 */ /* 70 */
1059 .long _sys_setregid /* setregid16 */
1060 .long _sys_ni_syscall /* old sys_sigsuspend */
1061 .long _sys_ni_syscall /* old sys_sigpending */
1062 .long _sys_sethostname
1063 .long _sys_setrlimit /* 75 */
1064 .long _sys_ni_syscall /* old getrlimit */
1065 .long _sys_getrusage
1066 .long _sys_gettimeofday
1067 .long _sys_settimeofday
1068 .long _sys_getgroups /* getgroups16 */ /* 80 */
1069 .long _sys_setgroups /* setgroups16 */
1070 .long _sys_ni_syscall /* old_select */
1071 .long _sys_symlink
1072 .long _sys_ni_syscall /* old lstat */
1073 .long _sys_readlink /* 85 */
1074 .long _sys_uselib
1075 .long _sys_ni_syscall /* sys_swapon */
1076 .long _sys_reboot
1077 .long _sys_ni_syscall /* old_readdir */
1078 .long _sys_ni_syscall /* sys_mmap */ /* 90 */
1079 .long _sys_munmap
1080 .long _sys_truncate
1081 .long _sys_ftruncate
1082 .long _sys_fchmod
1083 .long _sys_fchown /* fchown16 */ /* 95 */
1084 .long _sys_getpriority
1085 .long _sys_setpriority
1086 .long _sys_ni_syscall /* old profil syscall holder */
1087 .long _sys_statfs
1088 .long _sys_fstatfs /* 100 */
1089 .long _sys_ni_syscall
1090 .long _sys_ni_syscall /* old sys_socketcall */
1091 .long _sys_syslog
1092 .long _sys_setitimer
1093 .long _sys_getitimer /* 105 */
1094 .long _sys_newstat
1095 .long _sys_newlstat
1096 .long _sys_newfstat
1097 .long _sys_ni_syscall /* old uname */
1098 .long _sys_ni_syscall /* iopl for i386 */ /* 110 */
1099 .long _sys_vhangup
1100 .long _sys_ni_syscall /* obsolete idle() syscall */
1101 .long _sys_ni_syscall /* vm86old for i386 */
1102 .long _sys_wait4
1103 .long _sys_ni_syscall /* 115 */ /* sys_swapoff */
1104 .long _sys_sysinfo
1105 .long _sys_ni_syscall /* old sys_ipc */
1106 .long _sys_fsync
1107 .long _sys_ni_syscall /* old sys_sigreturn */
1108 .long _sys_clone /* 120 */
1109 .long _sys_setdomainname
1110 .long _sys_newuname
1111 .long _sys_ni_syscall /* old sys_modify_ldt */
1112 .long _sys_adjtimex
1113 .long _sys_ni_syscall /* 125 */ /* sys_mprotect */
1114 .long _sys_ni_syscall /* old sys_sigprocmask */
1115 .long _sys_ni_syscall /* old "creat_module" */
1116 .long _sys_init_module
1117 .long _sys_delete_module
1118 .long _sys_ni_syscall /* 130: old "get_kernel_syms" */
1119 .long _sys_quotactl
1120 .long _sys_getpgid
1121 .long _sys_fchdir
1122 .long _sys_bdflush
1123 .long _sys_ni_syscall /* 135 */ /* sys_sysfs */
1124 .long _sys_personality
1125 .long _sys_ni_syscall /* for afs_syscall */
1126 .long _sys_setfsuid /* setfsuid16 */
1127 .long _sys_setfsgid /* setfsgid16 */
1128 .long _sys_llseek /* 140 */
1129 .long _sys_getdents
1130 .long _sys_ni_syscall /* sys_select */
1131 .long _sys_flock
1132 .long _sys_ni_syscall /* sys_msync */
1133 .long _sys_readv /* 145 */
1134 .long _sys_writev
1135 .long _sys_getsid
1136 .long _sys_fdatasync
1137 .long _sys_sysctl
1138 .long _sys_ni_syscall /* 150 */ /* sys_mlock */
1139 .long _sys_ni_syscall /* sys_munlock */
1140 .long _sys_ni_syscall /* sys_mlockall */
1141 .long _sys_ni_syscall /* sys_munlockall */
1142 .long _sys_sched_setparam
1143 .long _sys_sched_getparam /* 155 */
1144 .long _sys_sched_setscheduler
1145 .long _sys_sched_getscheduler
1146 .long _sys_sched_yield
1147 .long _sys_sched_get_priority_max
1148 .long _sys_sched_get_priority_min /* 160 */
1149 .long _sys_sched_rr_get_interval
1150 .long _sys_nanosleep
1151 .long _sys_mremap
1152 .long _sys_setresuid /* setresuid16 */
1153 .long _sys_getresuid /* getresuid16 */ /* 165 */
1154 .long _sys_ni_syscall /* for vm86 */
1155 .long _sys_ni_syscall /* old "query_module" */
1156 .long _sys_ni_syscall /* sys_poll */
1157 .long _sys_nfsservctl
1158 .long _sys_setresgid /* setresgid16 */ /* 170 */
1159 .long _sys_getresgid /* getresgid16 */
1160 .long _sys_prctl
1161 .long _sys_rt_sigreturn
1162 .long _sys_rt_sigaction
1163 .long _sys_rt_sigprocmask /* 175 */
1164 .long _sys_rt_sigpending
1165 .long _sys_rt_sigtimedwait
1166 .long _sys_rt_sigqueueinfo
1167 .long _sys_rt_sigsuspend
1168 .long _sys_pread64 /* 180 */
1169 .long _sys_pwrite64
1170 .long _sys_lchown /* lchown16 */
1171 .long _sys_getcwd
1172 .long _sys_capget
1173 .long _sys_capset /* 185 */
1174 .long _sys_sigaltstack
1175 .long _sys_sendfile
1176 .long _sys_ni_syscall /* streams1 */
1177 .long _sys_ni_syscall /* streams2 */
1178 .long _sys_vfork /* 190 */
1179 .long _sys_getrlimit
1180 .long _sys_mmap2
1181 .long _sys_truncate64
1182 .long _sys_ftruncate64
1183 .long _sys_stat64 /* 195 */
1184 .long _sys_lstat64
1185 .long _sys_fstat64
1186 .long _sys_chown
1187 .long _sys_getuid
1188 .long _sys_getgid /* 200 */
1189 .long _sys_geteuid
1190 .long _sys_getegid
1191 .long _sys_setreuid
1192 .long _sys_setregid
1193 .long _sys_getgroups /* 205 */
1194 .long _sys_setgroups
1195 .long _sys_fchown
1196 .long _sys_setresuid
1197 .long _sys_getresuid
1198 .long _sys_setresgid /* 210 */
1199 .long _sys_getresgid
1200 .long _sys_lchown
1201 .long _sys_setuid
1202 .long _sys_setgid
1203 .long _sys_setfsuid /* 215 */
1204 .long _sys_setfsgid
1205 .long _sys_pivot_root
1206 .long _sys_ni_syscall /* sys_mincore */
1207 .long _sys_ni_syscall /* sys_madvise */
1208 .long _sys_getdents64 /* 220 */
1209 .long _sys_fcntl64
1210 .long _sys_ni_syscall /* reserved for TUX */
1211 .long _sys_ni_syscall
1212 .long _sys_gettid
1213 .long _sys_readahead /* 225 */
1214 .long _sys_setxattr
1215 .long _sys_lsetxattr
1216 .long _sys_fsetxattr
1217 .long _sys_getxattr
1218 .long _sys_lgetxattr /* 230 */
1219 .long _sys_fgetxattr
1220 .long _sys_listxattr
1221 .long _sys_llistxattr
1222 .long _sys_flistxattr
1223 .long _sys_removexattr /* 235 */
1224 .long _sys_lremovexattr
1225 .long _sys_fremovexattr
1226 .long _sys_tkill
1227 .long _sys_sendfile64
1228 .long _sys_futex /* 240 */
1229 .long _sys_sched_setaffinity
1230 .long _sys_sched_getaffinity
1231 .long _sys_ni_syscall /* sys_set_thread_area */
1232 .long _sys_ni_syscall /* sys_get_thread_area */
1233 .long _sys_io_setup /* 245 */
1234 .long _sys_io_destroy
1235 .long _sys_io_getevents
1236 .long _sys_io_submit
1237 .long _sys_io_cancel
1238 .long _sys_ni_syscall /* 250 */ /* sys_alloc_hugepages */
1239 .long _sys_ni_syscall /* sys_freec_hugepages */
1240 .long _sys_exit_group
1241 .long _sys_lookup_dcookie
1242 .long _sys_bfin_spinlock
1243 .long _sys_epoll_create /* 255 */
1244 .long _sys_epoll_ctl
1245 .long _sys_epoll_wait
1246 .long _sys_ni_syscall /* remap_file_pages */
1247 .long _sys_set_tid_address
1248 .long _sys_timer_create /* 260 */
1249 .long _sys_timer_settime
1250 .long _sys_timer_gettime
1251 .long _sys_timer_getoverrun
1252 .long _sys_timer_delete
1253 .long _sys_clock_settime /* 265 */
1254 .long _sys_clock_gettime
1255 .long _sys_clock_getres
1256 .long _sys_clock_nanosleep
1257 .long _sys_statfs64
1258 .long _sys_fstatfs64 /* 270 */
1259 .long _sys_tgkill
1260 .long _sys_utimes
1261 .long _sys_fadvise64_64
1262 .long _sys_ni_syscall /* vserver */
1263 .long _sys_ni_syscall /* 275, mbind */
1264 .long _sys_ni_syscall /* get_mempolicy */
1265 .long _sys_ni_syscall /* set_mempolicy */
1266 .long _sys_mq_open
1267 .long _sys_mq_unlink
1268 .long _sys_mq_timedsend /* 280 */
1269 .long _sys_mq_timedreceive
1270 .long _sys_mq_notify
1271 .long _sys_mq_getsetattr
1272 .long _sys_ni_syscall /* kexec_load */
1273 .long _sys_waitid /* 285 */
1274 .long _sys_add_key
1275 .long _sys_request_key
1276 .long _sys_keyctl
1277 .long _sys_ioprio_set
1278 .long _sys_ioprio_get /* 290 */
1279 .long _sys_inotify_init
1280 .long _sys_inotify_add_watch
1281 .long _sys_inotify_rm_watch
1282 .long _sys_ni_syscall /* migrate_pages */
1283 .long _sys_openat /* 295 */
1284 .long _sys_mkdirat
1285 .long _sys_mknodat
1286 .long _sys_fchownat
1287 .long _sys_futimesat
1288 .long _sys_fstatat64 /* 300 */
1289 .long _sys_unlinkat
1290 .long _sys_renameat
1291 .long _sys_linkat
1292 .long _sys_symlinkat
1293 .long _sys_readlinkat /* 305 */
1294 .long _sys_fchmodat
1295 .long _sys_faccessat
1296 .long _sys_pselect6
1297 .long _sys_ppoll
1298 .long _sys_unshare /* 310 */
1299 .long _sys_sram_alloc
1300 .long _sys_sram_free
1301 .long _sys_dma_memcpy
1302 .long _sys_accept
1303 .long _sys_bind /* 315 */
1304 .long _sys_connect
1305 .long _sys_getpeername
1306 .long _sys_getsockname
1307 .long _sys_getsockopt
1308 .long _sys_listen /* 320 */
1309 .long _sys_recv
1310 .long _sys_recvfrom
1311 .long _sys_recvmsg
1312 .long _sys_send
1313 .long _sys_sendmsg /* 325 */
1314 .long _sys_sendto
1315 .long _sys_setsockopt
1316 .long _sys_shutdown
1317 .long _sys_socket
1318 .long _sys_socketpair /* 330 */
1319 .long _sys_semctl
1320 .long _sys_semget
1321 .long _sys_semop
1322 .long _sys_msgctl
1323 .long _sys_msgget /* 335 */
1324 .long _sys_msgrcv
1325 .long _sys_msgsnd
1326 .long _sys_shmat
1327 .long _sys_shmctl
1328 .long _sys_shmdt /* 340 */
1329 .long _sys_shmget
1330 .long _sys_splice
1331 .long _sys_sync_file_range
1332 .long _sys_tee
1333 .long _sys_vmsplice /* 345 */
1334 .long _sys_epoll_pwait
1335 .long _sys_utimensat
1336 .long _sys_signalfd
1337 .long _sys_timerfd_create
1338 .long _sys_eventfd /* 350 */
1339 .long _sys_pread64
1340 .long _sys_pwrite64
1341 .long _sys_fadvise64
1342 .long _sys_set_robust_list
1343 .long _sys_get_robust_list /* 355 */
1344 .long _sys_fallocate
1345 .long _sys_semtimedop
1346 .long _sys_timerfd_settime
1347 .long _sys_timerfd_gettime
1349 .rept NR_syscalls-(.-_sys_call_table)/4
1350 .long _sys_ni_syscall
1351 .endr
1352 _excpt_saved_imask:
1353 .long 0;
1355 _exception_stack:
1356 .rept 1024
1357 .long 0;
1358 .endr
1359 _exception_stack_top:
1361 #if ANOMALY_05000261
1362 /* Used by the assembly entry point to work around an anomaly. */
1363 _last_cplb_fault_retx:
1364 .long 0;
1365 #endif
1366 /* Used to save the real RETX when temporarily storing a safe
1367 * return address. */
1368 __retx:
1369 .long 0;