arch/x86/kernel/vmlinux_64.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 1;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(0);  /* ___ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.text.head)
  32         _stext = .;
  33         /* Then the rest */
  34         TEXT_TEXT
  35         SCHED_TEXT
  36         LOCK_TEXT
  37         KPROBES_TEXT
  38         *(.fixup)
  39         *(.gnu.warning)
  40         _etext = .;             /* End of text section */
  41   } :text = 0x9090
  42
  43   NOTES :text :note
  44
  45   . = ALIGN(16);                /* Exception table */
  46   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  47         __start___ex_table = .;
  48          *(__ex_table)
  49         __stop___ex_table = .;
  50   } :text = 0x9090
  51
  52   RODATA
  53
  54   . = ALIGN(4);
  55   .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {
  56         __tracedata_start = .;
  57         *(.tracedata)
  58         __tracedata_end = .;
  59   }
  60
  61   . = ALIGN(PAGE_SIZE);         /* Align data segment to page size boundary */
  62                                 /* Data */
  63   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  64         DATA_DATA
  65         CONSTRUCTORS
  66         } :data
  67
  68   _edata = .;                   /* End of data section */
  69
  70   . = ALIGN(PAGE_SIZE);
  71   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  72   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  73         *(.data.cacheline_aligned)
  74   }
  75   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  76   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  77         *(.data.read_mostly)
  78   }
  79
  80 #define VSYSCALL_ADDR (-10*1024*1024)
  81 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  82 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  83
  84 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  85 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  86
  87 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  88 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  89
  90   . = VSYSCALL_ADDR;
  91   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  92   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  93
  94   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  95   .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) }
  96   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  97   .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data))
  98                 { *(.vsyscall_gtod_data) }
  99   vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
 100   .vsyscall_clock : AT(VLOAD(.vsyscall_clock))
 101                 { *(.vsyscall_clock) }
 102   vsyscall_clock = VVIRT(.vsyscall_clock);
 103
 104
 105   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1))
 106                 { *(.vsyscall_1) }
 107   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2))
 108                 { *(.vsyscall_2) }
 109
 110   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 111   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 112
 113   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 114   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 115   jiffies = VVIRT(.jiffies);
 116
 117   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3))
 118                 { *(.vsyscall_3) }
 119
 120   . = VSYSCALL_VIRT_ADDR + PAGE_SIZE;
 121
 122 #undef VSYSCALL_ADDR
 123 #undef VSYSCALL_PHYS_ADDR
 124 #undef VSYSCALL_VIRT_ADDR
 125 #undef VLOAD_OFFSET
 126 #undef VLOAD
 127 #undef VVIRT_OFFSET
 128 #undef VVIRT
 129
 130   . = ALIGN(THREAD_SIZE);       /* init_task */
 131   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 132         *(.data.init_task)
 133   }:data.init
 134
 135   . = ALIGN(PAGE_SIZE);
 136   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 137         *(.data.page_aligned)
 138   }
 139
 140   /* might get freed after init */
 141   . = ALIGN(PAGE_SIZE);
 142   __smp_alt_begin = .;
 143   __smp_locks = .;
 144   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 145         *(.smp_locks)
 146   }
 147   __smp_locks_end = .;
 148   . = ALIGN(PAGE_SIZE);
 149   __smp_alt_end = .;
 150
 151   . = ALIGN(PAGE_SIZE);         /* Init code and data */
 152   __init_begin = .;
 153   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 154         _sinittext = .;
 155         INIT_TEXT
 156         _einittext = .;
 157   }
 158   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 159         __initdata_begin = .;
 160         INIT_DATA
 161         __initdata_end = .;
 162    }
 163
 164   . = ALIGN(16);
 165   __setup_start = .;
 166   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 167   __setup_end = .;
 168   __initcall_start = .;
 169   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 170         INITCALLS
 171   }
 172   __initcall_end = .;
 173   __con_initcall_start = .;
 174   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 175         *(.con_initcall.init)
 176   }
 177   __con_initcall_end = .;
 178   __x86cpuvendor_start = .;
 179   .x86cpuvendor.init : AT(ADDR(.x86cpuvendor.init) - LOAD_OFFSET) {
 180         *(.x86cpuvendor.init)
 181   }
 182   __x86cpuvendor_end = .;
 183   SECURITY_INIT
 184
 185   . = ALIGN(8);
 186   .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 187   __parainstructions = .;
 188        *(.parainstructions)
 189   __parainstructions_end = .;
 190   }
 191
 192   . = ALIGN(8);
 193   __alt_instructions = .;
 194   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 195         *(.altinstructions)
 196   }
 197   __alt_instructions_end = .;
 198   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 199         *(.altinstr_replacement)
 200   }
 201   /* .exit.text is discard at runtime, not link time, to deal with references
 202      from .altinstructions and .eh_frame */
 203   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 204         EXIT_TEXT
 205   }
 206   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 207         EXIT_DATA
 208   }
 209
 210 #ifdef CONFIG_BLK_DEV_INITRD
 211   . = ALIGN(PAGE_SIZE);
 212   __initramfs_start = .;
 213   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 214   __initramfs_end = .;
 215 #endif
 216
 217   PERCPU(PAGE_SIZE)
 218
 219   . = ALIGN(PAGE_SIZE);
 220   __init_end = .;
 221
 222   . = ALIGN(PAGE_SIZE);
 223   __nosave_begin = .;
 224   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 225   . = ALIGN(PAGE_SIZE);
 226   __nosave_end = .;
 227
 228   __bss_start = .;              /* BSS */
 229   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 230         *(.bss.page_aligned)
 231         *(.bss)
 232         }
 233   __bss_stop = .;
 234
 235   _end = . ;
 236
 237   /* Sections to be discarded */
 238   /DISCARD/ : {
 239         *(.exitcall.exit)
 240         *(.eh_frame)
 241         }
 242
 243   STABS_DEBUG
 244
 245   DWARF_DEBUG
 246 }
 247
 248 /*
 249  * Build-time check on the image size:
 250  */
 251 ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 252         "kernel image bigger than KERNEL_IMAGE_SIZE")