| blob | 69732d279e8b2d4d99dc6e5d6e6d8de947a56e5c |
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * [_stext, _etext] is the text section
44 * [_sdata, _edata] is the data section
45 *
46 * Some of the included output section have their own set of constants.
47 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
48 * [__nosave_begin, __nosave_end] for the nosave data
49 */
51 #ifndef LOAD_OFFSET
52 #define LOAD_OFFSET 0
53 #endif
55 #include <linux/export.h>
57 /* Align . to a 8 byte boundary equals to maximum function alignment. */
58 #define ALIGN_FUNCTION() . = ALIGN(8)
60 /*
61 * Align to a 32 byte boundary equal to the
62 * alignment gcc 4.5 uses for a struct
63 */
64 #define STRUCT_ALIGNMENT 32
65 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
67 /* The actual configuration determine if the init/exit sections
68 * are handled as text/data or they can be discarded (which
69 * often happens at runtime)
70 */
71 #ifdef CONFIG_HOTPLUG_CPU
72 #define CPU_KEEP(sec) *(.cpu##sec)
73 #define CPU_DISCARD(sec)
74 #else
75 #define CPU_KEEP(sec)
76 #define CPU_DISCARD(sec) *(.cpu##sec)
77 #endif
79 #if defined(CONFIG_MEMORY_HOTPLUG)
80 #define MEM_KEEP(sec) *(.mem##sec)
81 #define MEM_DISCARD(sec)
82 #else
83 #define MEM_KEEP(sec)
84 #define MEM_DISCARD(sec) *(.mem##sec)
85 #endif
87 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
88 #define MCOUNT_REC() . = ALIGN(8); \
89 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
90 *(__mcount_loc) \
91 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
92 #else
93 #define MCOUNT_REC()
94 #endif
96 #ifdef CONFIG_TRACE_BRANCH_PROFILING
97 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
98 *(_ftrace_annotated_branch) \
99 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
100 #else
101 #define LIKELY_PROFILE()
102 #endif
104 #ifdef CONFIG_PROFILE_ALL_BRANCHES
105 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
106 *(_ftrace_branch) \
107 VMLINUX_SYMBOL(__stop_branch_profile) = .;
108 #else
109 #define BRANCH_PROFILE()
110 #endif
112 #ifdef CONFIG_EVENT_TRACING
113 #define FTRACE_EVENTS() . = ALIGN(8); \
114 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
115 *(_ftrace_events) \
116 VMLINUX_SYMBOL(__stop_ftrace_events) = .;
117 #else
118 #define FTRACE_EVENTS()
119 #endif
121 #ifdef CONFIG_TRACING
122 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
124 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
125 #else
126 #define TRACE_PRINTKS()
127 #endif
129 #ifdef CONFIG_FTRACE_SYSCALLS
130 #define TRACE_SYSCALLS() . = ALIGN(8); \
131 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
132 *(__syscalls_metadata) \
133 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
134 #else
135 #define TRACE_SYSCALLS()
136 #endif
138 #ifdef CONFIG_CLKSRC_OF
139 #define CLKSRC_OF_TABLES() . = ALIGN(8); \
140 VMLINUX_SYMBOL(__clksrc_of_table) = .; \
141 *(__clksrc_of_table) \
142 *(__clksrc_of_table_end)
143 #else
144 #define CLKSRC_OF_TABLES()
145 #endif
147 #ifdef CONFIG_IRQCHIP
148 #define IRQCHIP_OF_MATCH_TABLE() \
149 . = ALIGN(8); \
150 VMLINUX_SYMBOL(__irqchip_begin) = .; \
151 *(__irqchip_of_table) \
152 *(__irqchip_of_end)
153 #else
154 #define IRQCHIP_OF_MATCH_TABLE()
155 #endif
157 #ifdef CONFIG_COMMON_CLK
158 #define CLK_OF_TABLES() . = ALIGN(8); \
159 VMLINUX_SYMBOL(__clk_of_table) = .; \
160 *(__clk_of_table) \
161 *(__clk_of_table_end)
162 #else
163 #define CLK_OF_TABLES()
164 #endif
166 #define KERNEL_DTB() \
167 STRUCT_ALIGN(); \
168 VMLINUX_SYMBOL(__dtb_start) = .; \
169 *(.dtb.init.rodata) \
170 VMLINUX_SYMBOL(__dtb_end) = .;
172 /* .data section */
173 #define DATA_DATA \
174 *(.data) \
175 *(.ref.data) \
177 MEM_KEEP(init.data) \
178 MEM_KEEP(exit.data) \
179 *(.data.unlikely) \
180 STRUCT_ALIGN(); \
181 *(__tracepoints) \
183 . = ALIGN(8); \
184 VMLINUX_SYMBOL(__start___jump_table) = .; \
185 *(__jump_table) \
186 VMLINUX_SYMBOL(__stop___jump_table) = .; \
187 . = ALIGN(8); \
188 VMLINUX_SYMBOL(__start___verbose) = .; \
189 *(__verbose) \
190 VMLINUX_SYMBOL(__stop___verbose) = .; \
191 LIKELY_PROFILE() \
192 BRANCH_PROFILE() \
193 TRACE_PRINTKS()
195 /*
196 * Data section helpers
197 */
198 #define NOSAVE_DATA \
199 . = ALIGN(PAGE_SIZE); \
200 VMLINUX_SYMBOL(__nosave_begin) = .; \
201 *(.data..nosave) \
202 . = ALIGN(PAGE_SIZE); \
203 VMLINUX_SYMBOL(__nosave_end) = .;
205 #define PAGE_ALIGNED_DATA(page_align) \
206 . = ALIGN(page_align); \
207 *(.data..page_aligned)
209 #define READ_MOSTLY_DATA(align) \
210 . = ALIGN(align); \
211 *(.data..read_mostly) \
212 . = ALIGN(align);
214 #define CACHELINE_ALIGNED_DATA(align) \
215 . = ALIGN(align); \
216 *(.data..cacheline_aligned)
218 #define INIT_TASK_DATA(align) \
219 . = ALIGN(align); \
220 *(.data..init_task)
222 /*
223 * Read only Data
224 */
225 #define RO_DATA_SECTION(align) \
226 . = ALIGN((align)); \
227 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
228 VMLINUX_SYMBOL(__start_rodata) = .; \
229 *(.rodata) *(.rodata.*) \
231 . = ALIGN(8); \
232 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
234 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
236 } \
237 \
238 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
239 *(.rodata1) \
240 } \
241 \
242 BUG_TABLE \
243 \
245 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
246 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
247 *(.pci_fixup_early) \
248 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
249 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
250 *(.pci_fixup_header) \
251 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
252 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
253 *(.pci_fixup_final) \
254 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
255 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
256 *(.pci_fixup_enable) \
257 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
258 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
259 *(.pci_fixup_resume) \
260 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
261 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
262 *(.pci_fixup_resume_early) \
263 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
264 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
265 *(.pci_fixup_suspend) \
266 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
267 } \
268 \
270 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
271 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
272 *(.builtin_fw) \
273 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
274 } \
275 \
276 TRACEDATA \
277 \
279 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
280 VMLINUX_SYMBOL(__start___ksymtab) = .; \
281 *(SORT(___ksymtab+*)) \
282 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
283 } \
284 \
286 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
287 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
288 *(SORT(___ksymtab_gpl+*)) \
289 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
290 } \
291 \
293 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
294 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
295 *(SORT(___ksymtab_unused+*)) \
296 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
297 } \
298 \
300 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
301 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
302 *(SORT(___ksymtab_unused_gpl+*)) \
303 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
304 } \
305 \
307 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
308 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
309 *(SORT(___ksymtab_gpl_future+*)) \
310 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
311 } \
312 \
314 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
315 VMLINUX_SYMBOL(__start___kcrctab) = .; \
316 *(SORT(___kcrctab+*)) \
317 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
318 } \
319 \
321 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
322 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
323 *(SORT(___kcrctab_gpl+*)) \
324 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
325 } \
326 \
328 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
329 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
330 *(SORT(___kcrctab_unused+*)) \
331 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
332 } \
333 \
335 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
336 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
337 *(SORT(___kcrctab_unused_gpl+*)) \
338 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
339 } \
340 \
342 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
343 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
344 *(SORT(___kcrctab_gpl_future+*)) \
345 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
346 } \
347 \
349 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
350 *(__ksymtab_strings) \
351 } \
352 \
354 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
355 *(.ref.rodata) \
356 MEM_KEEP(init.rodata) \
357 MEM_KEEP(exit.rodata) \
358 } \
359 \
361 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
362 VMLINUX_SYMBOL(__start___param) = .; \
363 *(__param) \
364 VMLINUX_SYMBOL(__stop___param) = .; \
365 } \
366 \
368 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
369 VMLINUX_SYMBOL(__start___modver) = .; \
370 *(__modver) \
371 VMLINUX_SYMBOL(__stop___modver) = .; \
372 . = ALIGN((align)); \
373 VMLINUX_SYMBOL(__end_rodata) = .; \
374 } \
375 . = ALIGN((align));
377 /* RODATA & RO_DATA provided for backward compatibility.
378 * All archs are supposed to use RO_DATA() */
379 #define RODATA RO_DATA_SECTION(4096)
380 #define RO_DATA(align) RO_DATA_SECTION(align)
382 #define SECURITY_INIT \
383 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
384 VMLINUX_SYMBOL(__security_initcall_start) = .; \
385 *(.security_initcall.init) \
386 VMLINUX_SYMBOL(__security_initcall_end) = .; \
387 }
389 /* .text section. Map to function alignment to avoid address changes
390 * during second ld run in second ld pass when generating System.map */
391 #define TEXT_TEXT \
392 ALIGN_FUNCTION(); \
393 *(.text.hot) \
394 *(.text) \
395 *(.ref.text) \
396 MEM_KEEP(init.text) \
397 MEM_KEEP(exit.text) \
398 *(.text.unlikely)
401 /* sched.text is aling to function alignment to secure we have same
402 * address even at second ld pass when generating System.map */
403 #define SCHED_TEXT \
404 ALIGN_FUNCTION(); \
405 VMLINUX_SYMBOL(__sched_text_start) = .; \
406 *(.sched.text) \
407 VMLINUX_SYMBOL(__sched_text_end) = .;
409 /* spinlock.text is aling to function alignment to secure we have same
410 * address even at second ld pass when generating System.map */
411 #define LOCK_TEXT \
412 ALIGN_FUNCTION(); \
413 VMLINUX_SYMBOL(__lock_text_start) = .; \
414 *(.spinlock.text) \
415 VMLINUX_SYMBOL(__lock_text_end) = .;
417 #define KPROBES_TEXT \
418 ALIGN_FUNCTION(); \
419 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
420 *(.kprobes.text) \
421 VMLINUX_SYMBOL(__kprobes_text_end) = .;
423 #define ENTRY_TEXT \
424 ALIGN_FUNCTION(); \
425 VMLINUX_SYMBOL(__entry_text_start) = .; \
426 *(.entry.text) \
427 VMLINUX_SYMBOL(__entry_text_end) = .;
429 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
430 #define IRQENTRY_TEXT \
431 ALIGN_FUNCTION(); \
432 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
433 *(.irqentry.text) \
434 VMLINUX_SYMBOL(__irqentry_text_end) = .;
435 #else
436 #define IRQENTRY_TEXT
437 #endif
439 /* Section used for early init (in .S files) */
440 #define HEAD_TEXT *(.head.text)
442 #define HEAD_TEXT_SECTION \
443 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
444 HEAD_TEXT \
445 }
447 /*
448 * Exception table
449 */
450 #define EXCEPTION_TABLE(align) \
451 . = ALIGN(align); \
452 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
453 VMLINUX_SYMBOL(__start___ex_table) = .; \
454 *(__ex_table) \
455 VMLINUX_SYMBOL(__stop___ex_table) = .; \
456 }
458 /*
459 * Init task
460 */
461 #define INIT_TASK_DATA_SECTION(align) \
462 . = ALIGN(align); \
463 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
464 INIT_TASK_DATA(align) \
465 }
467 #ifdef CONFIG_CONSTRUCTORS
468 #define KERNEL_CTORS() . = ALIGN(8); \
469 VMLINUX_SYMBOL(__ctors_start) = .; \
470 *(.ctors) \
471 VMLINUX_SYMBOL(__ctors_end) = .;
472 #else
473 #define KERNEL_CTORS()
474 #endif
476 /* init and exit section handling */
477 #define INIT_DATA \
478 *(.init.data) \
479 MEM_DISCARD(init.data) \
480 KERNEL_CTORS() \
481 MCOUNT_REC() \
482 *(.init.rodata) \
483 FTRACE_EVENTS() \
484 TRACE_SYSCALLS() \
485 MEM_DISCARD(init.rodata) \
486 CLK_OF_TABLES() \
487 CLKSRC_OF_TABLES() \
488 KERNEL_DTB() \
489 IRQCHIP_OF_MATCH_TABLE()
491 #define INIT_TEXT \
492 *(.init.text) \
493 MEM_DISCARD(init.text)
495 #define EXIT_DATA \
496 *(.exit.data) \
497 MEM_DISCARD(exit.data) \
498 MEM_DISCARD(exit.rodata)
500 #define EXIT_TEXT \
501 *(.exit.text) \
502 MEM_DISCARD(exit.text)
504 #define EXIT_CALL \
505 *(.exitcall.exit)
507 /*
508 * bss (Block Started by Symbol) - uninitialized data
509 * zeroed during startup
510 */
511 #define SBSS(sbss_align) \
512 . = ALIGN(sbss_align); \
513 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
514 *(.sbss) \
515 *(.scommon) \
516 }
518 /*
519 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
520 * sections to the front of bss.
521 */
522 #ifndef BSS_FIRST_SECTIONS
523 #define BSS_FIRST_SECTIONS
524 #endif
526 #define BSS(bss_align) \
527 . = ALIGN(bss_align); \
528 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
529 BSS_FIRST_SECTIONS \
530 *(.bss..page_aligned) \
531 *(.dynbss) \
532 *(.bss) \
533 *(COMMON) \
534 }
536 /*
537 * DWARF debug sections.
538 * Symbols in the DWARF debugging sections are relative to
539 * the beginning of the section so we begin them at 0.
540 */
541 #define DWARF_DEBUG \
543 .debug 0 : { *(.debug) } \
544 .line 0 : { *(.line) } \
546 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
547 .debug_sfnames 0 : { *(.debug_sfnames) } \
549 .debug_aranges 0 : { *(.debug_aranges) } \
550 .debug_pubnames 0 : { *(.debug_pubnames) } \
552 .debug_info 0 : { *(.debug_info \
553 .gnu.linkonce.wi.*) } \
554 .debug_abbrev 0 : { *(.debug_abbrev) } \
555 .debug_line 0 : { *(.debug_line) } \
556 .debug_frame 0 : { *(.debug_frame) } \
557 .debug_str 0 : { *(.debug_str) } \
558 .debug_loc 0 : { *(.debug_loc) } \
559 .debug_macinfo 0 : { *(.debug_macinfo) } \
561 .debug_weaknames 0 : { *(.debug_weaknames) } \
562 .debug_funcnames 0 : { *(.debug_funcnames) } \
563 .debug_typenames 0 : { *(.debug_typenames) } \
564 .debug_varnames 0 : { *(.debug_varnames) } \
566 /* Stabs debugging sections. */
567 #define STABS_DEBUG \
568 .stab 0 : { *(.stab) } \
569 .stabstr 0 : { *(.stabstr) } \
570 .stab.excl 0 : { *(.stab.excl) } \
571 .stab.exclstr 0 : { *(.stab.exclstr) } \
572 .stab.index 0 : { *(.stab.index) } \
573 .stab.indexstr 0 : { *(.stab.indexstr) } \
574 .comment 0 : { *(.comment) }
576 #ifdef CONFIG_GENERIC_BUG
577 #define BUG_TABLE \
578 . = ALIGN(8); \
579 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
580 VMLINUX_SYMBOL(__start___bug_table) = .; \
581 *(__bug_table) \
582 VMLINUX_SYMBOL(__stop___bug_table) = .; \
583 }
584 #else
585 #define BUG_TABLE
586 #endif
588 #ifdef CONFIG_PM_TRACE
589 #define TRACEDATA \
590 . = ALIGN(4); \
591 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
592 VMLINUX_SYMBOL(__tracedata_start) = .; \
593 *(.tracedata) \
594 VMLINUX_SYMBOL(__tracedata_end) = .; \
595 }
596 #else
597 #define TRACEDATA
598 #endif
600 #define NOTES \
601 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
602 VMLINUX_SYMBOL(__start_notes) = .; \
603 *(.note.*) \
604 VMLINUX_SYMBOL(__stop_notes) = .; \
605 }
607 #define INIT_SETUP(initsetup_align) \
608 . = ALIGN(initsetup_align); \
609 VMLINUX_SYMBOL(__setup_start) = .; \
610 *(.init.setup) \
611 VMLINUX_SYMBOL(__setup_end) = .;
613 #define INIT_CALLS_LEVEL(level) \
614 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
615 *(.initcall##level##.init) \
616 *(.initcall##level##s.init) \
618 #define INIT_CALLS \
619 VMLINUX_SYMBOL(__initcall_start) = .; \
620 *(.initcallearly.init) \
621 INIT_CALLS_LEVEL(0) \
622 INIT_CALLS_LEVEL(1) \
623 INIT_CALLS_LEVEL(2) \
624 INIT_CALLS_LEVEL(3) \
625 INIT_CALLS_LEVEL(4) \
626 INIT_CALLS_LEVEL(5) \
627 INIT_CALLS_LEVEL(rootfs) \
628 INIT_CALLS_LEVEL(6) \
629 INIT_CALLS_LEVEL(7) \
630 VMLINUX_SYMBOL(__initcall_end) = .;
632 #define CON_INITCALL \
633 VMLINUX_SYMBOL(__con_initcall_start) = .; \
634 *(.con_initcall.init) \
635 VMLINUX_SYMBOL(__con_initcall_end) = .;
637 #define SECURITY_INITCALL \
638 VMLINUX_SYMBOL(__security_initcall_start) = .; \
639 *(.security_initcall.init) \
640 VMLINUX_SYMBOL(__security_initcall_end) = .;
642 #ifdef CONFIG_BLK_DEV_INITRD
643 #define INIT_RAM_FS \
644 . = ALIGN(4); \
645 VMLINUX_SYMBOL(__initramfs_start) = .; \
646 *(.init.ramfs) \
647 . = ALIGN(8); \
648 *(.init.ramfs.info)
649 #else
650 #define INIT_RAM_FS
651 #endif
653 /*
654 * Default discarded sections.
655 *
656 * Some archs want to discard exit text/data at runtime rather than
657 * link time due to cross-section references such as alt instructions,
658 * bug table, eh_frame, etc. DISCARDS must be the last of output
659 * section definitions so that such archs put those in earlier section
660 * definitions.
661 */
662 #define DISCARDS \
663 /DISCARD/ : { \
664 EXIT_TEXT \
665 EXIT_DATA \
666 EXIT_CALL \
667 *(.discard) \
668 *(.discard.*) \
669 }
671 /**
672 * PERCPU_INPUT - the percpu input sections
673 * @cacheline: cacheline size
674 *
675 * The core percpu section names and core symbols which do not rely
676 * directly upon load addresses.
677 *
678 * @cacheline is used to align subsections to avoid false cacheline
679 * sharing between subsections for different purposes.
680 */
681 #define PERCPU_INPUT(cacheline) \
682 VMLINUX_SYMBOL(__per_cpu_start) = .; \
683 *(.data..percpu..first) \
684 . = ALIGN(PAGE_SIZE); \
685 *(.data..percpu..page_aligned) \
686 . = ALIGN(cacheline); \
687 *(.data..percpu..readmostly) \
688 . = ALIGN(cacheline); \
689 *(.data..percpu) \
690 *(.data..percpu..shared_aligned) \
691 VMLINUX_SYMBOL(__per_cpu_end) = .;
693 /**
694 * PERCPU_VADDR - define output section for percpu area
695 * @cacheline: cacheline size
696 * @vaddr: explicit base address (optional)
697 * @phdr: destination PHDR (optional)
698 *
699 * Macro which expands to output section for percpu area.
700 *
701 * @cacheline is used to align subsections to avoid false cacheline
702 * sharing between subsections for different purposes.
703 *
704 * If @vaddr is not blank, it specifies explicit base address and all
705 * percpu symbols will be offset from the given address. If blank,
706 * @vaddr always equals @laddr + LOAD_OFFSET.
707 *
708 * @phdr defines the output PHDR to use if not blank. Be warned that
709 * output PHDR is sticky. If @phdr is specified, the next output
710 * section in the linker script will go there too. @phdr should have
711 * a leading colon.
712 *
713 * Note that this macros defines __per_cpu_load as an absolute symbol.
714 * If there is no need to put the percpu section at a predetermined
715 * address, use PERCPU_SECTION.
716 */
717 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
718 VMLINUX_SYMBOL(__per_cpu_load) = .; \
719 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
720 - LOAD_OFFSET) { \
721 PERCPU_INPUT(cacheline) \
722 } phdr \
723 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
725 /**
726 * PERCPU_SECTION - define output section for percpu area, simple version
727 * @cacheline: cacheline size
728 *
729 * Align to PAGE_SIZE and outputs output section for percpu area. This
730 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
731 * __per_cpu_start will be identical.
732 *
733 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
734 * except that __per_cpu_load is defined as a relative symbol against
735 * .data..percpu which is required for relocatable x86_32 configuration.
736 */
737 #define PERCPU_SECTION(cacheline) \
738 . = ALIGN(PAGE_SIZE); \
739 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
740 VMLINUX_SYMBOL(__per_cpu_load) = .; \
741 PERCPU_INPUT(cacheline) \
742 }
745 /*
746 * Definition of the high level *_SECTION macros
747 * They will fit only a subset of the architectures
748 */
751 /*
752 * Writeable data.
753 * All sections are combined in a single .data section.
754 * The sections following CONSTRUCTORS are arranged so their
755 * typical alignment matches.
756 * A cacheline is typical/always less than a PAGE_SIZE so
757 * the sections that has this restriction (or similar)
758 * is located before the ones requiring PAGE_SIZE alignment.
759 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
760 * matches the requirement of PAGE_ALIGNED_DATA.
761 *
762 * use 0 as page_align if page_aligned data is not used */
763 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
764 . = ALIGN(PAGE_SIZE); \
765 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
766 INIT_TASK_DATA(inittask) \
767 NOSAVE_DATA \
768 PAGE_ALIGNED_DATA(pagealigned) \
769 CACHELINE_ALIGNED_DATA(cacheline) \
770 READ_MOSTLY_DATA(cacheline) \
771 DATA_DATA \
772 CONSTRUCTORS \
773 }
775 #define INIT_TEXT_SECTION(inittext_align) \
776 . = ALIGN(inittext_align); \
777 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
778 VMLINUX_SYMBOL(_sinittext) = .; \
779 INIT_TEXT \
780 VMLINUX_SYMBOL(_einittext) = .; \
781 }
783 #define INIT_DATA_SECTION(initsetup_align) \
784 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
785 INIT_DATA \
786 INIT_SETUP(initsetup_align) \
787 INIT_CALLS \
788 CON_INITCALL \
789 SECURITY_INITCALL \
790 INIT_RAM_FS \
791 }
793 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
794 . = ALIGN(sbss_align); \
795 VMLINUX_SYMBOL(__bss_start) = .; \
796 SBSS(sbss_align) \
797 BSS(bss_align) \
798 . = ALIGN(stop_align); \
799 VMLINUX_SYMBOL(__bss_stop) = .;