| blob | 459d4a0dca8dfae3c247858b2cf22be91be392a8 |
1 /*
2 * linux/arch/x86_64/entry.S
3 *
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 * Copyright (C) 2000, 2001, 2002 Andi Kleen SuSE Labs
6 * Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
7 */
9 /*
10 * entry.S contains the system-call and fault low-level handling routines.
11 *
12 * Some of this is documented in Documentation/x86/entry_64.txt
13 *
14 * NOTE: This code handles signal-recognition, which happens every time
15 * after an interrupt and after each system call.
16 *
17 * Normal syscalls and interrupts don't save a full stack frame, this is
18 * only done for syscall tracing, signals or fork/exec et.al.
19 *
20 * A note on terminology:
21 * - top of stack: Architecture defined interrupt frame from SS to RIP
22 * at the top of the kernel process stack.
23 * - partial stack frame: partially saved registers up to R11.
24 * - full stack frame: Like partial stack frame, but all register saved.
25 *
26 * Some macro usage:
27 * - CFI macros are used to generate dwarf2 unwind information for better
28 * backtraces. They don't change any code.
29 * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
30 * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
31 * There are unfortunately lots of special cases where some registers
32 * not touched. The macro is a big mess that should be cleaned up.
33 * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
34 * Gives a full stack frame.
35 * - ENTRY/END Define functions in the symbol table.
36 * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
37 * frame that is otherwise undefined after a SYSCALL
38 * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
39 * - errorentry/paranoidentry/zeroentry - Define exception entry points.
40 */
42 #include <linux/linkage.h>
43 #include <asm/segment.h>
44 #include <asm/cache.h>
45 #include <asm/errno.h>
46 #include <asm/dwarf2.h>
47 #include <asm/calling.h>
48 #include <asm/asm-offsets.h>
49 #include <asm/msr.h>
50 #include <asm/unistd.h>
51 #include <asm/thread_info.h>
52 #include <asm/hw_irq.h>
53 #include <asm/page_types.h>
54 #include <asm/irqflags.h>
55 #include <asm/paravirt.h>
56 #include <asm/ftrace.h>
57 #include <asm/percpu.h>
58 #include <asm/asm.h>
59 #include <linux/err.h>
61 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
62 #include <linux/elf-em.h>
63 #define AUDIT_ARCH_X86_64 (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
64 #define __AUDIT_ARCH_64BIT 0x80000000
65 #define __AUDIT_ARCH_LE 0x40000000
67 .code64
68 .section .entry.text, "ax"
70 #ifdef CONFIG_FUNCTION_TRACER
71 #ifdef CONFIG_DYNAMIC_FTRACE
72 ENTRY(mcount)
73 retq
74 END(mcount)
76 /* skip is set if stack has been adjusted */
77 .macro ftrace_caller_setup skip=0
78 MCOUNT_SAVE_FRAME \skip
80 /* Load the ftrace_ops into the 3rd parameter */
81 leaq function_trace_op, %rdx
83 /* Load ip into the first parameter */
84 movq RIP(%rsp), %rdi
85 subq $MCOUNT_INSN_SIZE, %rdi
86 /* Load the parent_ip into the second parameter */
87 movq 8(%rbp), %rsi
88 .endm
90 ENTRY(ftrace_caller)
91 /* Check if tracing was disabled (quick check) */
92 cmpl $0, function_trace_stop
93 jne ftrace_stub
95 ftrace_caller_setup
96 /* regs go into 4th parameter (but make it NULL) */
97 movq $0, %rcx
99 GLOBAL(ftrace_call)
100 call ftrace_stub
102 MCOUNT_RESTORE_FRAME
103 ftrace_return:
105 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
106 GLOBAL(ftrace_graph_call)
107 jmp ftrace_stub
108 #endif
110 GLOBAL(ftrace_stub)
111 retq
112 END(ftrace_caller)
114 ENTRY(ftrace_regs_caller)
115 /* Save the current flags before compare (in SS location)*/
116 pushfq
118 /* Check if tracing was disabled (quick check) */
119 cmpl $0, function_trace_stop
120 jne ftrace_restore_flags
122 /* skip=8 to skip flags saved in SS */
123 ftrace_caller_setup 8
125 /* Save the rest of pt_regs */
126 movq %r15, R15(%rsp)
127 movq %r14, R14(%rsp)
128 movq %r13, R13(%rsp)
129 movq %r12, R12(%rsp)
130 movq %r11, R11(%rsp)
131 movq %r10, R10(%rsp)
132 movq %rbp, RBP(%rsp)
133 movq %rbx, RBX(%rsp)
134 /* Copy saved flags */
135 movq SS(%rsp), %rcx
136 movq %rcx, EFLAGS(%rsp)
137 /* Kernel segments */
138 movq $__KERNEL_DS, %rcx
139 movq %rcx, SS(%rsp)
140 movq $__KERNEL_CS, %rcx
141 movq %rcx, CS(%rsp)
142 /* Stack - skipping return address */
143 leaq SS+16(%rsp), %rcx
144 movq %rcx, RSP(%rsp)
146 /* regs go into 4th parameter */
147 leaq (%rsp), %rcx
149 GLOBAL(ftrace_regs_call)
150 call ftrace_stub
152 /* Copy flags back to SS, to restore them */
153 movq EFLAGS(%rsp), %rax
154 movq %rax, SS(%rsp)
156 /* restore the rest of pt_regs */
157 movq R15(%rsp), %r15
158 movq R14(%rsp), %r14
159 movq R13(%rsp), %r13
160 movq R12(%rsp), %r12
161 movq R10(%rsp), %r10
162 movq RBP(%rsp), %rbp
163 movq RBX(%rsp), %rbx
165 /* skip=8 to skip flags saved in SS */
166 MCOUNT_RESTORE_FRAME 8
168 /* Restore flags */
169 popfq
171 jmp ftrace_return
172 ftrace_restore_flags:
173 popfq
174 jmp ftrace_stub
176 END(ftrace_regs_caller)
179 #else /* ! CONFIG_DYNAMIC_FTRACE */
180 ENTRY(mcount)
181 cmpl $0, function_trace_stop
182 jne ftrace_stub
184 cmpq $ftrace_stub, ftrace_trace_function
185 jnz trace
187 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
188 cmpq $ftrace_stub, ftrace_graph_return
189 jnz ftrace_graph_caller
191 cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
192 jnz ftrace_graph_caller
193 #endif
195 GLOBAL(ftrace_stub)
196 retq
198 trace:
199 MCOUNT_SAVE_FRAME
201 movq RIP(%rsp), %rdi
202 movq 8(%rbp), %rsi
203 subq $MCOUNT_INSN_SIZE, %rdi
205 call *ftrace_trace_function
207 MCOUNT_RESTORE_FRAME
209 jmp ftrace_stub
210 END(mcount)
211 #endif /* CONFIG_DYNAMIC_FTRACE */
212 #endif /* CONFIG_FUNCTION_TRACER */
214 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
215 ENTRY(ftrace_graph_caller)
216 MCOUNT_SAVE_FRAME
218 leaq 8(%rbp), %rdi
219 movq RIP(%rsp), %rsi
220 movq (%rbp), %rdx
221 subq $MCOUNT_INSN_SIZE, %rsi
223 call prepare_ftrace_return
225 MCOUNT_RESTORE_FRAME
227 retq
228 END(ftrace_graph_caller)
230 GLOBAL(return_to_handler)
231 subq $24, %rsp
233 /* Save the return values */
234 movq %rax, (%rsp)
235 movq %rdx, 8(%rsp)
236 movq %rbp, %rdi
238 call ftrace_return_to_handler
240 movq %rax, %rdi
241 movq 8(%rsp), %rdx
242 movq (%rsp), %rax
243 addq $24, %rsp
244 jmp *%rdi
245 #endif
248 #ifndef CONFIG_PREEMPT
249 #define retint_kernel retint_restore_args
250 #endif
252 #ifdef CONFIG_PARAVIRT
253 ENTRY(native_usergs_sysret64)
254 swapgs
255 sysretq
256 ENDPROC(native_usergs_sysret64)
257 #endif /* CONFIG_PARAVIRT */
260 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
261 #ifdef CONFIG_TRACE_IRQFLAGS
262 bt $9,EFLAGS-\offset(%rsp) /* interrupts off? */
263 jnc 1f
264 TRACE_IRQS_ON
265 1:
266 #endif
267 .endm
269 /*
270 * When dynamic function tracer is enabled it will add a breakpoint
271 * to all locations that it is about to modify, sync CPUs, update
272 * all the code, sync CPUs, then remove the breakpoints. In this time
273 * if lockdep is enabled, it might jump back into the debug handler
274 * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
275 *
276 * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
277 * make sure the stack pointer does not get reset back to the top
278 * of the debug stack, and instead just reuses the current stack.
279 */
280 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
282 .macro TRACE_IRQS_OFF_DEBUG
283 call debug_stack_set_zero
284 TRACE_IRQS_OFF
285 call debug_stack_reset
286 .endm
288 .macro TRACE_IRQS_ON_DEBUG
289 call debug_stack_set_zero
290 TRACE_IRQS_ON
291 call debug_stack_reset
292 .endm
294 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
295 bt $9,EFLAGS-\offset(%rsp) /* interrupts off? */
296 jnc 1f
297 TRACE_IRQS_ON_DEBUG
298 1:
299 .endm
301 #else
302 # define TRACE_IRQS_OFF_DEBUG TRACE_IRQS_OFF
303 # define TRACE_IRQS_ON_DEBUG TRACE_IRQS_ON
304 # define TRACE_IRQS_IRETQ_DEBUG TRACE_IRQS_IRETQ
305 #endif
307 /*
308 * C code is not supposed to know about undefined top of stack. Every time
309 * a C function with an pt_regs argument is called from the SYSCALL based
310 * fast path FIXUP_TOP_OF_STACK is needed.
311 * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
312 * manipulation.
313 */
315 /* %rsp:at FRAMEEND */
316 .macro FIXUP_TOP_OF_STACK tmp offset=0
317 movq PER_CPU_VAR(old_rsp),\tmp
318 movq \tmp,RSP+\offset(%rsp)
319 movq $__USER_DS,SS+\offset(%rsp)
320 movq $__USER_CS,CS+\offset(%rsp)
321 movq $-1,RCX+\offset(%rsp)
322 movq R11+\offset(%rsp),\tmp /* get eflags */
323 movq \tmp,EFLAGS+\offset(%rsp)
324 .endm
326 .macro RESTORE_TOP_OF_STACK tmp offset=0
327 movq RSP+\offset(%rsp),\tmp
328 movq \tmp,PER_CPU_VAR(old_rsp)
329 movq EFLAGS+\offset(%rsp),\tmp
330 movq \tmp,R11+\offset(%rsp)
331 .endm
333 .macro FAKE_STACK_FRAME child_rip
334 /* push in order ss, rsp, eflags, cs, rip */
335 xorl %eax, %eax
336 pushq_cfi $__KERNEL_DS /* ss */
337 /*CFI_REL_OFFSET ss,0*/
338 pushq_cfi %rax /* rsp */
339 CFI_REL_OFFSET rsp,0
340 pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
341 /*CFI_REL_OFFSET rflags,0*/
342 pushq_cfi $__KERNEL_CS /* cs */
343 /*CFI_REL_OFFSET cs,0*/
344 pushq_cfi \child_rip /* rip */
345 CFI_REL_OFFSET rip,0
346 pushq_cfi %rax /* orig rax */
347 .endm
349 .macro UNFAKE_STACK_FRAME
350 addq $8*6, %rsp
351 CFI_ADJUST_CFA_OFFSET -(6*8)
352 .endm
354 /*
355 * initial frame state for interrupts (and exceptions without error code)
356 */
357 .macro EMPTY_FRAME start=1 offset=0
358 .if \start
359 CFI_STARTPROC simple
360 CFI_SIGNAL_FRAME
361 CFI_DEF_CFA rsp,8+\offset
362 .else
363 CFI_DEF_CFA_OFFSET 8+\offset
364 .endif
365 .endm
367 /*
368 * initial frame state for interrupts (and exceptions without error code)
369 */
370 .macro INTR_FRAME start=1 offset=0
371 EMPTY_FRAME \start, SS+8+\offset-RIP
372 /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
373 CFI_REL_OFFSET rsp, RSP+\offset-RIP
374 /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
375 /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
376 CFI_REL_OFFSET rip, RIP+\offset-RIP
377 .endm
379 /*
380 * initial frame state for exceptions with error code (and interrupts
381 * with vector already pushed)
382 */
383 .macro XCPT_FRAME start=1 offset=0
384 INTR_FRAME \start, RIP+\offset-ORIG_RAX
385 /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
386 .endm
388 /*
389 * frame that enables calling into C.
390 */
391 .macro PARTIAL_FRAME start=1 offset=0
392 XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
393 CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
394 CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
395 CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
396 CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
397 CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
398 CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
399 CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
400 CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
401 CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
402 .endm
404 /*
405 * frame that enables passing a complete pt_regs to a C function.
406 */
407 .macro DEFAULT_FRAME start=1 offset=0
408 PARTIAL_FRAME \start, R11+\offset-R15
409 CFI_REL_OFFSET rbx, RBX+\offset
410 CFI_REL_OFFSET rbp, RBP+\offset
411 CFI_REL_OFFSET r12, R12+\offset
412 CFI_REL_OFFSET r13, R13+\offset
413 CFI_REL_OFFSET r14, R14+\offset
414 CFI_REL_OFFSET r15, R15+\offset
415 .endm
417 /* save partial stack frame */
418 .macro SAVE_ARGS_IRQ
419 cld
420 /* start from rbp in pt_regs and jump over */
421 movq_cfi rdi, RDI-RBP
422 movq_cfi rsi, RSI-RBP
423 movq_cfi rdx, RDX-RBP
424 movq_cfi rcx, RCX-RBP
425 movq_cfi rax, RAX-RBP
426 movq_cfi r8, R8-RBP
427 movq_cfi r9, R9-RBP
428 movq_cfi r10, R10-RBP
429 movq_cfi r11, R11-RBP
431 /* Save rbp so that we can unwind from get_irq_regs() */
432 movq_cfi rbp, 0
434 /* Save previous stack value */
435 movq %rsp, %rsi
437 leaq -RBP(%rsp),%rdi /* arg1 for handler */
438 testl $3, CS-RBP(%rsi)
439 je 1f
440 SWAPGS
441 /*
442 * irq_count is used to check if a CPU is already on an interrupt stack
443 * or not. While this is essentially redundant with preempt_count it is
444 * a little cheaper to use a separate counter in the PDA (short of
445 * moving irq_enter into assembly, which would be too much work)
446 */
447 1: incl PER_CPU_VAR(irq_count)
448 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
449 CFI_DEF_CFA_REGISTER rsi
451 /* Store previous stack value */
452 pushq %rsi
453 CFI_ESCAPE 0x0f /* DW_CFA_def_cfa_expression */, 6, \
454 0x77 /* DW_OP_breg7 */, 0, \
455 0x06 /* DW_OP_deref */, \
456 0x08 /* DW_OP_const1u */, SS+8-RBP, \
457 0x22 /* DW_OP_plus */
458 /* We entered an interrupt context - irqs are off: */
459 TRACE_IRQS_OFF
460 .endm
462 ENTRY(save_rest)
463 PARTIAL_FRAME 1 REST_SKIP+8
464 movq 5*8+16(%rsp), %r11 /* save return address */
465 movq_cfi rbx, RBX+16
466 movq_cfi rbp, RBP+16
467 movq_cfi r12, R12+16
468 movq_cfi r13, R13+16
469 movq_cfi r14, R14+16
470 movq_cfi r15, R15+16
471 movq %r11, 8(%rsp) /* return address */
472 FIXUP_TOP_OF_STACK %r11, 16
473 ret
474 CFI_ENDPROC
475 END(save_rest)
477 /* save complete stack frame */
478 .pushsection .kprobes.text, "ax"
479 ENTRY(save_paranoid)
480 XCPT_FRAME 1 RDI+8
481 cld
482 movq_cfi rdi, RDI+8
483 movq_cfi rsi, RSI+8
484 movq_cfi rdx, RDX+8
485 movq_cfi rcx, RCX+8
486 movq_cfi rax, RAX+8
487 movq_cfi r8, R8+8
488 movq_cfi r9, R9+8
489 movq_cfi r10, R10+8
490 movq_cfi r11, R11+8
491 movq_cfi rbx, RBX+8
492 movq_cfi rbp, RBP+8
493 movq_cfi r12, R12+8
494 movq_cfi r13, R13+8
495 movq_cfi r14, R14+8
496 movq_cfi r15, R15+8
497 movl $1,%ebx
498 movl $MSR_GS_BASE,%ecx
499 rdmsr
500 testl %edx,%edx
501 js 1f /* negative -> in kernel */
502 SWAPGS
503 xorl %ebx,%ebx
504 1: ret
505 CFI_ENDPROC
506 END(save_paranoid)
507 .popsection
509 /*
510 * A newly forked process directly context switches into this address.
511 *
512 * rdi: prev task we switched from
513 */
514 ENTRY(ret_from_fork)
515 DEFAULT_FRAME
517 LOCK ; btr $TIF_FORK,TI_flags(%r8)
519 pushq_cfi kernel_eflags(%rip)
520 popfq_cfi # reset kernel eflags
522 call schedule_tail # rdi: 'prev' task parameter
524 GET_THREAD_INFO(%rcx)
526 RESTORE_REST
528 testl $3, CS-ARGOFFSET(%rsp) # from kernel_thread?
529 jz retint_restore_args
531 testl $_TIF_IA32, TI_flags(%rcx) # 32-bit compat task needs IRET
532 jnz int_ret_from_sys_call
534 RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
535 jmp ret_from_sys_call # go to the SYSRET fastpath
537 CFI_ENDPROC
538 END(ret_from_fork)
540 /*
541 * System call entry. Up to 6 arguments in registers are supported.
542 *
543 * SYSCALL does not save anything on the stack and does not change the
544 * stack pointer.
545 */
547 /*
548 * Register setup:
549 * rax system call number
550 * rdi arg0
551 * rcx return address for syscall/sysret, C arg3
552 * rsi arg1
553 * rdx arg2
554 * r10 arg3 (--> moved to rcx for C)
555 * r8 arg4
556 * r9 arg5
557 * r11 eflags for syscall/sysret, temporary for C
558 * r12-r15,rbp,rbx saved by C code, not touched.
559 *
560 * Interrupts are off on entry.
561 * Only called from user space.
562 *
563 * XXX if we had a free scratch register we could save the RSP into the stack frame
564 * and report it properly in ps. Unfortunately we haven't.
565 *
566 * When user can change the frames always force IRET. That is because
567 * it deals with uncanonical addresses better. SYSRET has trouble
568 * with them due to bugs in both AMD and Intel CPUs.
569 */
571 ENTRY(system_call)
572 CFI_STARTPROC simple
573 CFI_SIGNAL_FRAME
574 CFI_DEF_CFA rsp,KERNEL_STACK_OFFSET
575 CFI_REGISTER rip,rcx
576 /*CFI_REGISTER rflags,r11*/
577 SWAPGS_UNSAFE_STACK
578 /*
579 * A hypervisor implementation might want to use a label
580 * after the swapgs, so that it can do the swapgs
581 * for the guest and jump here on syscall.
582 */
583 GLOBAL(system_call_after_swapgs)
585 movq %rsp,PER_CPU_VAR(old_rsp)
586 movq PER_CPU_VAR(kernel_stack),%rsp
587 /*
588 * No need to follow this irqs off/on section - it's straight
589 * and short:
590 */
591 ENABLE_INTERRUPTS(CLBR_NONE)
592 SAVE_ARGS 8,0
593 movq %rax,ORIG_RAX-ARGOFFSET(%rsp)
594 movq %rcx,RIP-ARGOFFSET(%rsp)
595 CFI_REL_OFFSET rip,RIP-ARGOFFSET
596 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
597 jnz tracesys
598 system_call_fastpath:
599 #if __SYSCALL_MASK == ~0
600 cmpq $__NR_syscall_max,%rax
601 #else
602 andl $__SYSCALL_MASK,%eax
603 cmpl $__NR_syscall_max,%eax
604 #endif
605 ja badsys
606 movq %r10,%rcx
607 call *sys_call_table(,%rax,8) # XXX: rip relative
608 movq %rax,RAX-ARGOFFSET(%rsp)
609 /*
610 * Syscall return path ending with SYSRET (fast path)
611 * Has incomplete stack frame and undefined top of stack.
612 */
613 ret_from_sys_call:
614 movl $_TIF_ALLWORK_MASK,%edi
615 /* edi: flagmask */
616 sysret_check:
617 LOCKDEP_SYS_EXIT
618 DISABLE_INTERRUPTS(CLBR_NONE)
619 TRACE_IRQS_OFF
620 movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
621 andl %edi,%edx
622 jnz sysret_careful
623 CFI_REMEMBER_STATE
624 /*
625 * sysretq will re-enable interrupts:
626 */
627 TRACE_IRQS_ON
628 movq RIP-ARGOFFSET(%rsp),%rcx
629 CFI_REGISTER rip,rcx
630 RESTORE_ARGS 1,-ARG_SKIP,0
631 /*CFI_REGISTER rflags,r11*/
632 movq PER_CPU_VAR(old_rsp), %rsp
633 USERGS_SYSRET64
635 CFI_RESTORE_STATE
636 /* Handle reschedules */
637 /* edx: work, edi: workmask */
638 sysret_careful:
639 bt $TIF_NEED_RESCHED,%edx
640 jnc sysret_signal
641 TRACE_IRQS_ON
642 ENABLE_INTERRUPTS(CLBR_NONE)
643 pushq_cfi %rdi
644 call schedule
645 popq_cfi %rdi
646 jmp sysret_check
648 /* Handle a signal */
649 sysret_signal:
650 TRACE_IRQS_ON
651 ENABLE_INTERRUPTS(CLBR_NONE)
652 #ifdef CONFIG_AUDITSYSCALL
653 bt $TIF_SYSCALL_AUDIT,%edx
654 jc sysret_audit
655 #endif
656 /*
657 * We have a signal, or exit tracing or single-step.
658 * These all wind up with the iret return path anyway,
659 * so just join that path right now.
660 */
661 FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
662 jmp int_check_syscall_exit_work
664 badsys:
665 movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
666 jmp ret_from_sys_call
668 #ifdef CONFIG_AUDITSYSCALL
669 /*
670 * Fast path for syscall audit without full syscall trace.
671 * We just call __audit_syscall_entry() directly, and then
672 * jump back to the normal fast path.
673 */
674 auditsys:
675 movq %r10,%r9 /* 6th arg: 4th syscall arg */
676 movq %rdx,%r8 /* 5th arg: 3rd syscall arg */
677 movq %rsi,%rcx /* 4th arg: 2nd syscall arg */
678 movq %rdi,%rdx /* 3rd arg: 1st syscall arg */
679 movq %rax,%rsi /* 2nd arg: syscall number */
680 movl $AUDIT_ARCH_X86_64,%edi /* 1st arg: audit arch */
681 call __audit_syscall_entry
682 LOAD_ARGS 0 /* reload call-clobbered registers */
683 jmp system_call_fastpath
685 /*
686 * Return fast path for syscall audit. Call __audit_syscall_exit()
687 * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
688 * masked off.
689 */
690 sysret_audit:
691 movq RAX-ARGOFFSET(%rsp),%rsi /* second arg, syscall return value */
692 cmpq $-MAX_ERRNO,%rsi /* is it < -MAX_ERRNO? */
693 setbe %al /* 1 if so, 0 if not */
694 movzbl %al,%edi /* zero-extend that into %edi */
695 call __audit_syscall_exit
696 movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
697 jmp sysret_check
698 #endif /* CONFIG_AUDITSYSCALL */
700 /* Do syscall tracing */
701 tracesys:
702 #ifdef CONFIG_AUDITSYSCALL
703 testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
704 jz auditsys
705 #endif
706 SAVE_REST
707 movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
708 FIXUP_TOP_OF_STACK %rdi
709 movq %rsp,%rdi
710 call syscall_trace_enter
711 /*
712 * Reload arg registers from stack in case ptrace changed them.
713 * We don't reload %rax because syscall_trace_enter() returned
714 * the value it wants us to use in the table lookup.
715 */
716 LOAD_ARGS ARGOFFSET, 1
717 RESTORE_REST
718 #if __SYSCALL_MASK == ~0
719 cmpq $__NR_syscall_max,%rax
720 #else
721 andl $__SYSCALL_MASK,%eax
722 cmpl $__NR_syscall_max,%eax
723 #endif
724 ja int_ret_from_sys_call /* RAX(%rsp) set to -ENOSYS above */
725 movq %r10,%rcx /* fixup for C */
726 call *sys_call_table(,%rax,8)
727 movq %rax,RAX-ARGOFFSET(%rsp)
728 /* Use IRET because user could have changed frame */
730 /*
731 * Syscall return path ending with IRET.
732 * Has correct top of stack, but partial stack frame.
733 */
734 GLOBAL(int_ret_from_sys_call)
735 DISABLE_INTERRUPTS(CLBR_NONE)
736 TRACE_IRQS_OFF
737 movl $_TIF_ALLWORK_MASK,%edi
738 /* edi: mask to check */
739 GLOBAL(int_with_check)
740 LOCKDEP_SYS_EXIT_IRQ
741 GET_THREAD_INFO(%rcx)
742 movl TI_flags(%rcx),%edx
743 andl %edi,%edx
744 jnz int_careful
745 andl $~TS_COMPAT,TI_status(%rcx)
746 jmp retint_swapgs
748 /* Either reschedule or signal or syscall exit tracking needed. */
749 /* First do a reschedule test. */
750 /* edx: work, edi: workmask */
751 int_careful:
752 bt $TIF_NEED_RESCHED,%edx
753 jnc int_very_careful
754 TRACE_IRQS_ON
755 ENABLE_INTERRUPTS(CLBR_NONE)
756 pushq_cfi %rdi
757 call schedule
758 popq_cfi %rdi
759 DISABLE_INTERRUPTS(CLBR_NONE)
760 TRACE_IRQS_OFF
761 jmp int_with_check
763 /* handle signals and tracing -- both require a full stack frame */
764 int_very_careful:
765 TRACE_IRQS_ON
766 ENABLE_INTERRUPTS(CLBR_NONE)
767 int_check_syscall_exit_work:
768 SAVE_REST
769 /* Check for syscall exit trace */
770 testl $_TIF_WORK_SYSCALL_EXIT,%edx
771 jz int_signal
772 pushq_cfi %rdi
773 leaq 8(%rsp),%rdi # &ptregs -> arg1
774 call syscall_trace_leave
775 popq_cfi %rdi
776 andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
777 jmp int_restore_rest
779 int_signal:
780 testl $_TIF_DO_NOTIFY_MASK,%edx
781 jz 1f
782 movq %rsp,%rdi # &ptregs -> arg1
783 xorl %esi,%esi # oldset -> arg2
784 call do_notify_resume
785 1: movl $_TIF_WORK_MASK,%edi
786 int_restore_rest:
787 RESTORE_REST
788 DISABLE_INTERRUPTS(CLBR_NONE)
789 TRACE_IRQS_OFF
790 jmp int_with_check
791 CFI_ENDPROC
792 END(system_call)
794 /*
795 * Certain special system calls that need to save a complete full stack frame.
796 */
797 .macro PTREGSCALL label,func,arg
798 ENTRY(\label)
799 PARTIAL_FRAME 1 8 /* offset 8: return address */
800 subq $REST_SKIP, %rsp
801 CFI_ADJUST_CFA_OFFSET REST_SKIP
802 call save_rest
803 DEFAULT_FRAME 0 8 /* offset 8: return address */
804 leaq 8(%rsp), \arg /* pt_regs pointer */
805 call \func
806 jmp ptregscall_common
807 CFI_ENDPROC
808 END(\label)
809 .endm
811 PTREGSCALL stub_clone, sys_clone, %r8
812 PTREGSCALL stub_fork, sys_fork, %rdi
813 PTREGSCALL stub_vfork, sys_vfork, %rdi
814 PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
815 PTREGSCALL stub_iopl, sys_iopl, %rsi
817 ENTRY(ptregscall_common)
818 DEFAULT_FRAME 1 8 /* offset 8: return address */
819 RESTORE_TOP_OF_STACK %r11, 8
820 movq_cfi_restore R15+8, r15
821 movq_cfi_restore R14+8, r14
822 movq_cfi_restore R13+8, r13
823 movq_cfi_restore R12+8, r12
824 movq_cfi_restore RBP+8, rbp
825 movq_cfi_restore RBX+8, rbx
826 ret $REST_SKIP /* pop extended registers */
827 CFI_ENDPROC
828 END(ptregscall_common)
830 ENTRY(stub_execve)
831 CFI_STARTPROC
832 addq $8, %rsp
833 PARTIAL_FRAME 0
834 SAVE_REST
835 FIXUP_TOP_OF_STACK %r11
836 movq %rsp, %rcx
837 call sys_execve
838 RESTORE_TOP_OF_STACK %r11
839 movq %rax,RAX(%rsp)
840 RESTORE_REST
841 jmp int_ret_from_sys_call
842 CFI_ENDPROC
843 END(stub_execve)
845 /*
846 * sigreturn is special because it needs to restore all registers on return.
847 * This cannot be done with SYSRET, so use the IRET return path instead.
848 */
849 ENTRY(stub_rt_sigreturn)
850 CFI_STARTPROC
851 addq $8, %rsp
852 PARTIAL_FRAME 0
853 SAVE_REST
854 movq %rsp,%rdi
855 FIXUP_TOP_OF_STACK %r11
856 call sys_rt_sigreturn
857 movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
858 RESTORE_REST
859 jmp int_ret_from_sys_call
860 CFI_ENDPROC
861 END(stub_rt_sigreturn)
863 #ifdef CONFIG_X86_X32_ABI
864 PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
866 ENTRY(stub_x32_rt_sigreturn)
867 CFI_STARTPROC
868 addq $8, %rsp
869 PARTIAL_FRAME 0
870 SAVE_REST
871 movq %rsp,%rdi
872 FIXUP_TOP_OF_STACK %r11
873 call sys32_x32_rt_sigreturn
874 movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
875 RESTORE_REST
876 jmp int_ret_from_sys_call
877 CFI_ENDPROC
878 END(stub_x32_rt_sigreturn)
880 ENTRY(stub_x32_execve)
881 CFI_STARTPROC
882 addq $8, %rsp
883 PARTIAL_FRAME 0
884 SAVE_REST
885 FIXUP_TOP_OF_STACK %r11
886 movq %rsp, %rcx
887 call sys32_execve
888 RESTORE_TOP_OF_STACK %r11
889 movq %rax,RAX(%rsp)
890 RESTORE_REST
891 jmp int_ret_from_sys_call
892 CFI_ENDPROC
893 END(stub_x32_execve)
895 #endif
897 /*
898 * Build the entry stubs and pointer table with some assembler magic.
899 * We pack 7 stubs into a single 32-byte chunk, which will fit in a
900 * single cache line on all modern x86 implementations.
901 */
902 .section .init.rodata,"a"
903 ENTRY(interrupt)
904 .section .entry.text
905 .p2align 5
906 .p2align CONFIG_X86_L1_CACHE_SHIFT
907 ENTRY(irq_entries_start)
908 INTR_FRAME
909 vector=FIRST_EXTERNAL_VECTOR
910 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
911 .balign 32
912 .rept 7
913 .if vector < NR_VECTORS
914 .if vector <> FIRST_EXTERNAL_VECTOR
915 CFI_ADJUST_CFA_OFFSET -8
916 .endif
917 1: pushq_cfi $(~vector+0x80) /* Note: always in signed byte range */
918 .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
919 jmp 2f
920 .endif
921 .previous
922 .quad 1b
923 .section .entry.text
924 vector=vector+1
925 .endif
926 .endr
927 2: jmp common_interrupt
928 .endr
929 CFI_ENDPROC
930 END(irq_entries_start)
932 .previous
933 END(interrupt)
934 .previous
936 /*
937 * Interrupt entry/exit.
938 *
939 * Interrupt entry points save only callee clobbered registers in fast path.
940 *
941 * Entry runs with interrupts off.
942 */
944 /* 0(%rsp): ~(interrupt number) */
945 .macro interrupt func
946 /* reserve pt_regs for scratch regs and rbp */
947 subq $ORIG_RAX-RBP, %rsp
948 CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
949 SAVE_ARGS_IRQ
950 call \func
951 .endm
953 /*
954 * Interrupt entry/exit should be protected against kprobes
955 */
956 .pushsection .kprobes.text, "ax"
957 /*
958 * The interrupt stubs push (~vector+0x80) onto the stack and
959 * then jump to common_interrupt.
960 */
961 .p2align CONFIG_X86_L1_CACHE_SHIFT
962 common_interrupt:
963 XCPT_FRAME
964 addq $-0x80,(%rsp) /* Adjust vector to [-256,-1] range */
965 interrupt do_IRQ
966 /* 0(%rsp): old_rsp-ARGOFFSET */
967 ret_from_intr:
968 DISABLE_INTERRUPTS(CLBR_NONE)
969 TRACE_IRQS_OFF
970 decl PER_CPU_VAR(irq_count)
972 /* Restore saved previous stack */
973 popq %rsi
974 CFI_DEF_CFA rsi,SS+8-RBP /* reg/off reset after def_cfa_expr */
975 leaq ARGOFFSET-RBP(%rsi), %rsp
976 CFI_DEF_CFA_REGISTER rsp
977 CFI_ADJUST_CFA_OFFSET RBP-ARGOFFSET
979 exit_intr:
980 GET_THREAD_INFO(%rcx)
981 testl $3,CS-ARGOFFSET(%rsp)
982 je retint_kernel
984 /* Interrupt came from user space */
985 /*
986 * Has a correct top of stack, but a partial stack frame
987 * %rcx: thread info. Interrupts off.
988 */
989 retint_with_reschedule:
990 movl $_TIF_WORK_MASK,%edi
991 retint_check:
992 LOCKDEP_SYS_EXIT_IRQ
993 movl TI_flags(%rcx),%edx
994 andl %edi,%edx
995 CFI_REMEMBER_STATE
996 jnz retint_careful
998 retint_swapgs: /* return to user-space */
999 /*
1000 * The iretq could re-enable interrupts:
1001 */
1002 DISABLE_INTERRUPTS(CLBR_ANY)
1003 TRACE_IRQS_IRETQ
1004 SWAPGS
1005 jmp restore_args
1007 retint_restore_args: /* return to kernel space */
1008 DISABLE_INTERRUPTS(CLBR_ANY)
1009 /*
1010 * The iretq could re-enable interrupts:
1011 */
1012 TRACE_IRQS_IRETQ
1013 restore_args:
1014 RESTORE_ARGS 1,8,1
1016 irq_return:
1017 INTERRUPT_RETURN
1018 _ASM_EXTABLE(irq_return, bad_iret)
1020 #ifdef CONFIG_PARAVIRT
1021 ENTRY(native_iret)
1022 iretq
1023 _ASM_EXTABLE(native_iret, bad_iret)
1024 #endif
1026 .section .fixup,"ax"
1027 bad_iret:
1028 /*
1029 * The iret traps when the %cs or %ss being restored is bogus.
1030 * We've lost the original trap vector and error code.
1031 * #GPF is the most likely one to get for an invalid selector.
1032 * So pretend we completed the iret and took the #GPF in user mode.
1033 *
1034 * We are now running with the kernel GS after exception recovery.
1035 * But error_entry expects us to have user GS to match the user %cs,
1036 * so swap back.
1037 */
1038 pushq $0
1040 SWAPGS
1041 jmp general_protection
1043 .previous
1045 /* edi: workmask, edx: work */
1046 retint_careful:
1047 CFI_RESTORE_STATE
1048 bt $TIF_NEED_RESCHED,%edx
1049 jnc retint_signal
1050 TRACE_IRQS_ON
1051 ENABLE_INTERRUPTS(CLBR_NONE)
1052 pushq_cfi %rdi
1053 call schedule
1054 popq_cfi %rdi
1055 GET_THREAD_INFO(%rcx)
1056 DISABLE_INTERRUPTS(CLBR_NONE)
1057 TRACE_IRQS_OFF
1058 jmp retint_check
1060 retint_signal:
1061 testl $_TIF_DO_NOTIFY_MASK,%edx
1062 jz retint_swapgs
1063 TRACE_IRQS_ON
1064 ENABLE_INTERRUPTS(CLBR_NONE)
1065 SAVE_REST
1066 movq $-1,ORIG_RAX(%rsp)
1067 xorl %esi,%esi # oldset
1068 movq %rsp,%rdi # &pt_regs
1069 call do_notify_resume
1070 RESTORE_REST
1071 DISABLE_INTERRUPTS(CLBR_NONE)
1072 TRACE_IRQS_OFF
1073 GET_THREAD_INFO(%rcx)
1074 jmp retint_with_reschedule
1076 #ifdef CONFIG_PREEMPT
1077 /* Returning to kernel space. Check if we need preemption */
1078 /* rcx: threadinfo. interrupts off. */
1079 ENTRY(retint_kernel)
1080 cmpl $0,TI_preempt_count(%rcx)
1081 jnz retint_restore_args
1082 bt $TIF_NEED_RESCHED,TI_flags(%rcx)
1083 jnc retint_restore_args
1084 bt $9,EFLAGS-ARGOFFSET(%rsp) /* interrupts off? */
1085 jnc retint_restore_args
1086 call preempt_schedule_irq
1087 jmp exit_intr
1088 #endif
1090 CFI_ENDPROC
1091 END(common_interrupt)
1092 /*
1093 * End of kprobes section
1094 */
1095 .popsection
1097 /*
1098 * APIC interrupts.
1099 */
1100 .macro apicinterrupt num sym do_sym
1101 ENTRY(\sym)
1102 INTR_FRAME
1103 pushq_cfi $~(\num)
1104 .Lcommon_\sym:
1105 interrupt \do_sym
1106 jmp ret_from_intr
1107 CFI_ENDPROC
1108 END(\sym)
1109 .endm
1111 #ifdef CONFIG_SMP
1112 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1113 irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1114 apicinterrupt REBOOT_VECTOR \
1115 reboot_interrupt smp_reboot_interrupt
1116 #endif
1118 #ifdef CONFIG_X86_UV
1119 apicinterrupt UV_BAU_MESSAGE \
1120 uv_bau_message_intr1 uv_bau_message_interrupt
1121 #endif
1122 apicinterrupt LOCAL_TIMER_VECTOR \
1123 apic_timer_interrupt smp_apic_timer_interrupt
1124 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1125 x86_platform_ipi smp_x86_platform_ipi
1127 #ifdef CONFIG_SMP
1128 ALIGN
1129 INTR_FRAME
1130 .irp idx,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1131 16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1132 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1133 ENTRY(invalidate_interrupt\idx)
1134 pushq_cfi $~(INVALIDATE_TLB_VECTOR_START+\idx)
1135 jmp .Lcommon_invalidate_interrupt0
1136 CFI_ADJUST_CFA_OFFSET -8
1137 END(invalidate_interrupt\idx)
1138 .endif
1139 .endr
1140 CFI_ENDPROC
1141 apicinterrupt INVALIDATE_TLB_VECTOR_START, \
1142 invalidate_interrupt0, smp_invalidate_interrupt
1143 #endif
1145 apicinterrupt THRESHOLD_APIC_VECTOR \
1146 threshold_interrupt smp_threshold_interrupt
1147 apicinterrupt THERMAL_APIC_VECTOR \
1148 thermal_interrupt smp_thermal_interrupt
1150 #ifdef CONFIG_SMP
1151 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1152 call_function_single_interrupt smp_call_function_single_interrupt
1153 apicinterrupt CALL_FUNCTION_VECTOR \
1154 call_function_interrupt smp_call_function_interrupt
1155 apicinterrupt RESCHEDULE_VECTOR \
1156 reschedule_interrupt smp_reschedule_interrupt
1157 #endif
1159 apicinterrupt ERROR_APIC_VECTOR \
1160 error_interrupt smp_error_interrupt
1161 apicinterrupt SPURIOUS_APIC_VECTOR \
1162 spurious_interrupt smp_spurious_interrupt
1164 #ifdef CONFIG_IRQ_WORK
1165 apicinterrupt IRQ_WORK_VECTOR \
1166 irq_work_interrupt smp_irq_work_interrupt
1167 #endif
1169 /*
1170 * Exception entry points.
1171 */
1172 .macro zeroentry sym do_sym
1173 ENTRY(\sym)
1174 INTR_FRAME
1175 PARAVIRT_ADJUST_EXCEPTION_FRAME
1176 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1177 subq $ORIG_RAX-R15, %rsp
1178 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1179 call error_entry
1180 DEFAULT_FRAME 0
1181 movq %rsp,%rdi /* pt_regs pointer */
1182 xorl %esi,%esi /* no error code */
1183 call \do_sym
1184 jmp error_exit /* %ebx: no swapgs flag */
1185 CFI_ENDPROC
1186 END(\sym)
1187 .endm
1189 .macro paranoidzeroentry sym do_sym
1190 ENTRY(\sym)
1191 INTR_FRAME
1192 PARAVIRT_ADJUST_EXCEPTION_FRAME
1193 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1194 subq $ORIG_RAX-R15, %rsp
1195 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1196 call save_paranoid
1197 TRACE_IRQS_OFF
1198 movq %rsp,%rdi /* pt_regs pointer */
1199 xorl %esi,%esi /* no error code */
1200 call \do_sym
1201 jmp paranoid_exit /* %ebx: no swapgs flag */
1202 CFI_ENDPROC
1203 END(\sym)
1204 .endm
1206 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1207 .macro paranoidzeroentry_ist sym do_sym ist
1208 ENTRY(\sym)
1209 INTR_FRAME
1210 PARAVIRT_ADJUST_EXCEPTION_FRAME
1211 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1212 subq $ORIG_RAX-R15, %rsp
1213 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1214 call save_paranoid
1215 TRACE_IRQS_OFF_DEBUG
1216 movq %rsp,%rdi /* pt_regs pointer */
1217 xorl %esi,%esi /* no error code */
1218 subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1219 call \do_sym
1220 addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1221 jmp paranoid_exit /* %ebx: no swapgs flag */
1222 CFI_ENDPROC
1223 END(\sym)
1224 .endm
1226 .macro errorentry sym do_sym
1227 ENTRY(\sym)
1228 XCPT_FRAME
1229 PARAVIRT_ADJUST_EXCEPTION_FRAME
1230 subq $ORIG_RAX-R15, %rsp
1231 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1232 call error_entry
1233 DEFAULT_FRAME 0
1234 movq %rsp,%rdi /* pt_regs pointer */
1235 movq ORIG_RAX(%rsp),%rsi /* get error code */
1236 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1237 call \do_sym
1238 jmp error_exit /* %ebx: no swapgs flag */
1239 CFI_ENDPROC
1240 END(\sym)
1241 .endm
1243 /* error code is on the stack already */
1244 .macro paranoiderrorentry sym do_sym
1245 ENTRY(\sym)
1246 XCPT_FRAME
1247 PARAVIRT_ADJUST_EXCEPTION_FRAME
1248 subq $ORIG_RAX-R15, %rsp
1249 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1250 call save_paranoid
1251 DEFAULT_FRAME 0
1252 TRACE_IRQS_OFF
1253 movq %rsp,%rdi /* pt_regs pointer */
1254 movq ORIG_RAX(%rsp),%rsi /* get error code */
1255 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1256 call \do_sym
1257 jmp paranoid_exit /* %ebx: no swapgs flag */
1258 CFI_ENDPROC
1259 END(\sym)
1260 .endm
1262 zeroentry divide_error do_divide_error
1263 zeroentry overflow do_overflow
1264 zeroentry bounds do_bounds
1265 zeroentry invalid_op do_invalid_op
1266 zeroentry device_not_available do_device_not_available
1267 paranoiderrorentry double_fault do_double_fault
1268 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1269 errorentry invalid_TSS do_invalid_TSS
1270 errorentry segment_not_present do_segment_not_present
1271 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1272 zeroentry coprocessor_error do_coprocessor_error
1273 errorentry alignment_check do_alignment_check
1274 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1277 /* Reload gs selector with exception handling */
1278 /* edi: new selector */
1279 ENTRY(native_load_gs_index)
1280 CFI_STARTPROC
1281 pushfq_cfi
1282 DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1283 SWAPGS
1284 gs_change:
1285 movl %edi,%gs
1286 2: mfence /* workaround */
1287 SWAPGS
1288 popfq_cfi
1289 ret
1290 CFI_ENDPROC
1291 END(native_load_gs_index)
1293 _ASM_EXTABLE(gs_change,bad_gs)
1294 .section .fixup,"ax"
1295 /* running with kernelgs */
1296 bad_gs:
1297 SWAPGS /* switch back to user gs */
1298 xorl %eax,%eax
1299 movl %eax,%gs
1300 jmp 2b
1301 .previous
1303 ENTRY(kernel_thread_helper)
1304 pushq $0 # fake return address
1305 CFI_STARTPROC
1306 /*
1307 * Here we are in the child and the registers are set as they were
1308 * at kernel_thread() invocation in the parent.
1309 */
1310 call *%rsi
1311 # exit
1312 mov %eax, %edi
1313 call do_exit
1314 ud2 # padding for call trace
1315 CFI_ENDPROC
1316 END(kernel_thread_helper)
1318 /*
1319 * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1320 *
1321 * C extern interface:
1322 * extern long execve(const char *name, char **argv, char **envp)
1323 *
1324 * asm input arguments:
1325 * rdi: name, rsi: argv, rdx: envp
1326 *
1327 * We want to fallback into:
1328 * extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1329 *
1330 * do_sys_execve asm fallback arguments:
1331 * rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1332 */
1333 ENTRY(kernel_execve)
1334 CFI_STARTPROC
1335 FAKE_STACK_FRAME $0
1336 SAVE_ALL
1337 movq %rsp,%rcx
1338 call sys_execve
1339 movq %rax, RAX(%rsp)
1340 RESTORE_REST
1341 testq %rax,%rax
1342 je int_ret_from_sys_call
1343 RESTORE_ARGS
1344 UNFAKE_STACK_FRAME
1345 ret
1346 CFI_ENDPROC
1347 END(kernel_execve)
1349 /* Call softirq on interrupt stack. Interrupts are off. */
1350 ENTRY(call_softirq)
1351 CFI_STARTPROC
1352 pushq_cfi %rbp
1353 CFI_REL_OFFSET rbp,0
1354 mov %rsp,%rbp
1355 CFI_DEF_CFA_REGISTER rbp
1356 incl PER_CPU_VAR(irq_count)
1357 cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1358 push %rbp # backlink for old unwinder
1359 call __do_softirq
1360 leaveq
1361 CFI_RESTORE rbp
1362 CFI_DEF_CFA_REGISTER rsp
1363 CFI_ADJUST_CFA_OFFSET -8
1364 decl PER_CPU_VAR(irq_count)
1365 ret
1366 CFI_ENDPROC
1367 END(call_softirq)
1369 #ifdef CONFIG_XEN
1370 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1372 /*
1373 * A note on the "critical region" in our callback handler.
1374 * We want to avoid stacking callback handlers due to events occurring
1375 * during handling of the last event. To do this, we keep events disabled
1376 * until we've done all processing. HOWEVER, we must enable events before
1377 * popping the stack frame (can't be done atomically) and so it would still
1378 * be possible to get enough handler activations to overflow the stack.
1379 * Although unlikely, bugs of that kind are hard to track down, so we'd
1380 * like to avoid the possibility.
1381 * So, on entry to the handler we detect whether we interrupted an
1382 * existing activation in its critical region -- if so, we pop the current
1383 * activation and restart the handler using the previous one.
1384 */
1385 ENTRY(xen_do_hypervisor_callback) # do_hypervisor_callback(struct *pt_regs)
1386 CFI_STARTPROC
1387 /*
1388 * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1389 * see the correct pointer to the pt_regs
1390 */
1391 movq %rdi, %rsp # we don't return, adjust the stack frame
1392 CFI_ENDPROC
1393 DEFAULT_FRAME
1394 11: incl PER_CPU_VAR(irq_count)
1395 movq %rsp,%rbp
1396 CFI_DEF_CFA_REGISTER rbp
1397 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1398 pushq %rbp # backlink for old unwinder
1399 call xen_evtchn_do_upcall
1400 popq %rsp
1401 CFI_DEF_CFA_REGISTER rsp
1402 decl PER_CPU_VAR(irq_count)
1403 jmp error_exit
1404 CFI_ENDPROC
1405 END(xen_do_hypervisor_callback)
1407 /*
1408 * Hypervisor uses this for application faults while it executes.
1409 * We get here for two reasons:
1410 * 1. Fault while reloading DS, ES, FS or GS
1411 * 2. Fault while executing IRET
1412 * Category 1 we do not need to fix up as Xen has already reloaded all segment
1413 * registers that could be reloaded and zeroed the others.
1414 * Category 2 we fix up by killing the current process. We cannot use the
1415 * normal Linux return path in this case because if we use the IRET hypercall
1416 * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1417 * We distinguish between categories by comparing each saved segment register
1418 * with its current contents: any discrepancy means we in category 1.
1419 */
1420 ENTRY(xen_failsafe_callback)
1421 INTR_FRAME 1 (6*8)
1422 /*CFI_REL_OFFSET gs,GS*/
1423 /*CFI_REL_OFFSET fs,FS*/
1424 /*CFI_REL_OFFSET es,ES*/
1425 /*CFI_REL_OFFSET ds,DS*/
1426 CFI_REL_OFFSET r11,8
1427 CFI_REL_OFFSET rcx,0
1428 movw %ds,%cx
1429 cmpw %cx,0x10(%rsp)
1430 CFI_REMEMBER_STATE
1431 jne 1f
1432 movw %es,%cx
1433 cmpw %cx,0x18(%rsp)
1434 jne 1f
1435 movw %fs,%cx
1436 cmpw %cx,0x20(%rsp)
1437 jne 1f
1438 movw %gs,%cx
1439 cmpw %cx,0x28(%rsp)
1440 jne 1f
1441 /* All segments match their saved values => Category 2 (Bad IRET). */
1442 movq (%rsp),%rcx
1443 CFI_RESTORE rcx
1444 movq 8(%rsp),%r11
1445 CFI_RESTORE r11
1446 addq $0x30,%rsp
1447 CFI_ADJUST_CFA_OFFSET -0x30
1448 pushq_cfi $0 /* RIP */
1449 pushq_cfi %r11
1450 pushq_cfi %rcx
1451 jmp general_protection
1452 CFI_RESTORE_STATE
1453 1: /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1454 movq (%rsp),%rcx
1455 CFI_RESTORE rcx
1456 movq 8(%rsp),%r11
1457 CFI_RESTORE r11
1458 addq $0x30,%rsp
1459 CFI_ADJUST_CFA_OFFSET -0x30
1460 pushq_cfi $0
1461 SAVE_ALL
1462 jmp error_exit
1463 CFI_ENDPROC
1464 END(xen_failsafe_callback)
1466 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1467 xen_hvm_callback_vector xen_evtchn_do_upcall
1469 #endif /* CONFIG_XEN */
1471 /*
1472 * Some functions should be protected against kprobes
1473 */
1474 .pushsection .kprobes.text, "ax"
1476 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1477 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1478 paranoiderrorentry stack_segment do_stack_segment
1479 #ifdef CONFIG_XEN
1480 zeroentry xen_debug do_debug
1481 zeroentry xen_int3 do_int3
1482 errorentry xen_stack_segment do_stack_segment
1483 #endif
1484 errorentry general_protection do_general_protection
1485 errorentry page_fault do_page_fault
1486 #ifdef CONFIG_KVM_GUEST
1487 errorentry async_page_fault do_async_page_fault
1488 #endif
1489 #ifdef CONFIG_X86_MCE
1490 paranoidzeroentry machine_check *machine_check_vector(%rip)
1491 #endif
1493 /*
1494 * "Paranoid" exit path from exception stack.
1495 * Paranoid because this is used by NMIs and cannot take
1496 * any kernel state for granted.
1497 * We don't do kernel preemption checks here, because only
1498 * NMI should be common and it does not enable IRQs and
1499 * cannot get reschedule ticks.
1500 *
1501 * "trace" is 0 for the NMI handler only, because irq-tracing
1502 * is fundamentally NMI-unsafe. (we cannot change the soft and
1503 * hard flags at once, atomically)
1504 */
1506 /* ebx: no swapgs flag */
1507 ENTRY(paranoid_exit)
1508 DEFAULT_FRAME
1509 DISABLE_INTERRUPTS(CLBR_NONE)
1510 TRACE_IRQS_OFF_DEBUG
1511 testl %ebx,%ebx /* swapgs needed? */
1512 jnz paranoid_restore
1513 testl $3,CS(%rsp)
1514 jnz paranoid_userspace
1515 paranoid_swapgs:
1516 TRACE_IRQS_IRETQ 0
1517 SWAPGS_UNSAFE_STACK
1518 RESTORE_ALL 8
1519 jmp irq_return
1520 paranoid_restore:
1521 TRACE_IRQS_IRETQ_DEBUG 0
1522 RESTORE_ALL 8
1523 jmp irq_return
1524 paranoid_userspace:
1525 GET_THREAD_INFO(%rcx)
1526 movl TI_flags(%rcx),%ebx
1527 andl $_TIF_WORK_MASK,%ebx
1528 jz paranoid_swapgs
1529 movq %rsp,%rdi /* &pt_regs */
1530 call sync_regs
1531 movq %rax,%rsp /* switch stack for scheduling */
1532 testl $_TIF_NEED_RESCHED,%ebx
1533 jnz paranoid_schedule
1534 movl %ebx,%edx /* arg3: thread flags */
1535 TRACE_IRQS_ON
1536 ENABLE_INTERRUPTS(CLBR_NONE)
1537 xorl %esi,%esi /* arg2: oldset */
1538 movq %rsp,%rdi /* arg1: &pt_regs */
1539 call do_notify_resume
1540 DISABLE_INTERRUPTS(CLBR_NONE)
1541 TRACE_IRQS_OFF
1542 jmp paranoid_userspace
1543 paranoid_schedule:
1544 TRACE_IRQS_ON
1545 ENABLE_INTERRUPTS(CLBR_ANY)
1546 call schedule
1547 DISABLE_INTERRUPTS(CLBR_ANY)
1548 TRACE_IRQS_OFF
1549 jmp paranoid_userspace
1550 CFI_ENDPROC
1551 END(paranoid_exit)
1553 /*
1554 * Exception entry point. This expects an error code/orig_rax on the stack.
1555 * returns in "no swapgs flag" in %ebx.
1556 */
1557 ENTRY(error_entry)
1558 XCPT_FRAME
1559 CFI_ADJUST_CFA_OFFSET 15*8
1560 /* oldrax contains error code */
1561 cld
1562 movq_cfi rdi, RDI+8
1563 movq_cfi rsi, RSI+8
1564 movq_cfi rdx, RDX+8
1565 movq_cfi rcx, RCX+8
1566 movq_cfi rax, RAX+8
1567 movq_cfi r8, R8+8
1568 movq_cfi r9, R9+8
1569 movq_cfi r10, R10+8
1570 movq_cfi r11, R11+8
1571 movq_cfi rbx, RBX+8
1572 movq_cfi rbp, RBP+8
1573 movq_cfi r12, R12+8
1574 movq_cfi r13, R13+8
1575 movq_cfi r14, R14+8
1576 movq_cfi r15, R15+8
1577 xorl %ebx,%ebx
1578 testl $3,CS+8(%rsp)
1579 je error_kernelspace
1580 error_swapgs:
1581 SWAPGS
1582 error_sti:
1583 TRACE_IRQS_OFF
1584 ret
1586 /*
1587 * There are two places in the kernel that can potentially fault with
1588 * usergs. Handle them here. The exception handlers after iret run with
1589 * kernel gs again, so don't set the user space flag. B stepping K8s
1590 * sometimes report an truncated RIP for IRET exceptions returning to
1591 * compat mode. Check for these here too.
1592 */
1593 error_kernelspace:
1594 incl %ebx
1595 leaq irq_return(%rip),%rcx
1596 cmpq %rcx,RIP+8(%rsp)
1597 je error_swapgs
1598 movl %ecx,%eax /* zero extend */
1599 cmpq %rax,RIP+8(%rsp)
1600 je bstep_iret
1601 cmpq $gs_change,RIP+8(%rsp)
1602 je error_swapgs
1603 jmp error_sti
1605 bstep_iret:
1606 /* Fix truncated RIP */
1607 movq %rcx,RIP+8(%rsp)
1608 jmp error_swapgs
1609 CFI_ENDPROC
1610 END(error_entry)
1613 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1614 ENTRY(error_exit)
1615 DEFAULT_FRAME
1616 movl %ebx,%eax
1617 RESTORE_REST
1618 DISABLE_INTERRUPTS(CLBR_NONE)
1619 TRACE_IRQS_OFF
1620 GET_THREAD_INFO(%rcx)
1621 testl %eax,%eax
1622 jne retint_kernel
1623 LOCKDEP_SYS_EXIT_IRQ
1624 movl TI_flags(%rcx),%edx
1625 movl $_TIF_WORK_MASK,%edi
1626 andl %edi,%edx
1627 jnz retint_careful
1628 jmp retint_swapgs
1629 CFI_ENDPROC
1630 END(error_exit)
1632 /*
1633 * Test if a given stack is an NMI stack or not.
1634 */
1635 .macro test_in_nmi reg stack nmi_ret normal_ret
1636 cmpq %\reg, \stack
1637 ja \normal_ret
1638 subq $EXCEPTION_STKSZ, %\reg
1639 cmpq %\reg, \stack
1640 jb \normal_ret
1641 jmp \nmi_ret
1642 .endm
1644 /* runs on exception stack */
1645 ENTRY(nmi)
1646 INTR_FRAME
1647 PARAVIRT_ADJUST_EXCEPTION_FRAME
1648 /*
1649 * We allow breakpoints in NMIs. If a breakpoint occurs, then
1650 * the iretq it performs will take us out of NMI context.
1651 * This means that we can have nested NMIs where the next
1652 * NMI is using the top of the stack of the previous NMI. We
1653 * can't let it execute because the nested NMI will corrupt the
1654 * stack of the previous NMI. NMI handlers are not re-entrant
1655 * anyway.
1656 *
1657 * To handle this case we do the following:
1658 * Check the a special location on the stack that contains
1659 * a variable that is set when NMIs are executing.
1660 * The interrupted task's stack is also checked to see if it
1661 * is an NMI stack.
1662 * If the variable is not set and the stack is not the NMI
1663 * stack then:
1664 * o Set the special variable on the stack
1665 * o Copy the interrupt frame into a "saved" location on the stack
1666 * o Copy the interrupt frame into a "copy" location on the stack
1667 * o Continue processing the NMI
1668 * If the variable is set or the previous stack is the NMI stack:
1669 * o Modify the "copy" location to jump to the repeate_nmi
1670 * o return back to the first NMI
1671 *
1672 * Now on exit of the first NMI, we first clear the stack variable
1673 * The NMI stack will tell any nested NMIs at that point that it is
1674 * nested. Then we pop the stack normally with iret, and if there was
1675 * a nested NMI that updated the copy interrupt stack frame, a
1676 * jump will be made to the repeat_nmi code that will handle the second
1677 * NMI.
1678 */
1680 /* Use %rdx as out temp variable throughout */
1681 pushq_cfi %rdx
1682 CFI_REL_OFFSET rdx, 0
1684 /*
1685 * If %cs was not the kernel segment, then the NMI triggered in user
1686 * space, which means it is definitely not nested.
1687 */
1688 cmpl $__KERNEL_CS, 16(%rsp)
1689 jne first_nmi
1691 /*
1692 * Check the special variable on the stack to see if NMIs are
1693 * executing.
1694 */
1695 cmpl $1, -8(%rsp)
1696 je nested_nmi
1698 /*
1699 * Now test if the previous stack was an NMI stack.
1700 * We need the double check. We check the NMI stack to satisfy the
1701 * race when the first NMI clears the variable before returning.
1702 * We check the variable because the first NMI could be in a
1703 * breakpoint routine using a breakpoint stack.
1704 */
1705 lea 6*8(%rsp), %rdx
1706 test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1707 CFI_REMEMBER_STATE
1709 nested_nmi:
1710 /*
1711 * Do nothing if we interrupted the fixup in repeat_nmi.
1712 * It's about to repeat the NMI handler, so we are fine
1713 * with ignoring this one.
1714 */
1715 movq $repeat_nmi, %rdx
1716 cmpq 8(%rsp), %rdx
1717 ja 1f
1718 movq $end_repeat_nmi, %rdx
1719 cmpq 8(%rsp), %rdx
1720 ja nested_nmi_out
1722 1:
1723 /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1724 leaq -6*8(%rsp), %rdx
1725 movq %rdx, %rsp
1726 CFI_ADJUST_CFA_OFFSET 6*8
1727 pushq_cfi $__KERNEL_DS
1728 pushq_cfi %rdx
1729 pushfq_cfi
1730 pushq_cfi $__KERNEL_CS
1731 pushq_cfi $repeat_nmi
1733 /* Put stack back */
1734 addq $(11*8), %rsp
1735 CFI_ADJUST_CFA_OFFSET -11*8
1737 nested_nmi_out:
1738 popq_cfi %rdx
1739 CFI_RESTORE rdx
1741 /* No need to check faults here */
1742 INTERRUPT_RETURN
1744 CFI_RESTORE_STATE
1745 first_nmi:
1746 /*
1747 * Because nested NMIs will use the pushed location that we
1748 * stored in rdx, we must keep that space available.
1749 * Here's what our stack frame will look like:
1750 * +-------------------------+
1751 * | original SS |
1752 * | original Return RSP |
1753 * | original RFLAGS |
1754 * | original CS |
1755 * | original RIP |
1756 * +-------------------------+
1757 * | temp storage for rdx |
1758 * +-------------------------+
1759 * | NMI executing variable |
1760 * +-------------------------+
1761 * | Saved SS |
1762 * | Saved Return RSP |
1763 * | Saved RFLAGS |
1764 * | Saved CS |
1765 * | Saved RIP |
1766 * +-------------------------+
1767 * | copied SS |
1768 * | copied Return RSP |
1769 * | copied RFLAGS |
1770 * | copied CS |
1771 * | copied RIP |
1772 * +-------------------------+
1773 * | pt_regs |
1774 * +-------------------------+
1775 *
1776 * The saved stack frame is used to fix up the copied stack frame
1777 * that a nested NMI may change to make the interrupted NMI iret jump
1778 * to the repeat_nmi. The original stack frame and the temp storage
1779 * is also used by nested NMIs and can not be trusted on exit.
1780 */
1781 /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1782 movq (%rsp), %rdx
1783 CFI_RESTORE rdx
1785 /* Set the NMI executing variable on the stack. */
1786 pushq_cfi $1
1788 /* Copy the stack frame to the Saved frame */
1789 .rept 5
1790 pushq_cfi 6*8(%rsp)
1791 .endr
1792 CFI_DEF_CFA_OFFSET SS+8-RIP
1794 /* Everything up to here is safe from nested NMIs */
1796 /*
1797 * If there was a nested NMI, the first NMI's iret will return
1798 * here. But NMIs are still enabled and we can take another
1799 * nested NMI. The nested NMI checks the interrupted RIP to see
1800 * if it is between repeat_nmi and end_repeat_nmi, and if so
1801 * it will just return, as we are about to repeat an NMI anyway.
1802 * This makes it safe to copy to the stack frame that a nested
1803 * NMI will update.
1804 */
1805 repeat_nmi:
1806 /*
1807 * Update the stack variable to say we are still in NMI (the update
1808 * is benign for the non-repeat case, where 1 was pushed just above
1809 * to this very stack slot).
1810 */
1811 movq $1, 5*8(%rsp)
1813 /* Make another copy, this one may be modified by nested NMIs */
1814 .rept 5
1815 pushq_cfi 4*8(%rsp)
1816 .endr
1817 CFI_DEF_CFA_OFFSET SS+8-RIP
1818 end_repeat_nmi:
1820 /*
1821 * Everything below this point can be preempted by a nested
1822 * NMI if the first NMI took an exception and reset our iret stack
1823 * so that we repeat another NMI.
1824 */
1825 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1826 subq $ORIG_RAX-R15, %rsp
1827 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1828 /*
1829 * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1830 * as we should not be calling schedule in NMI context.
1831 * Even with normal interrupts enabled. An NMI should not be
1832 * setting NEED_RESCHED or anything that normal interrupts and
1833 * exceptions might do.
1834 */
1835 call save_paranoid
1836 DEFAULT_FRAME 0
1838 /*
1839 * Save off the CR2 register. If we take a page fault in the NMI then
1840 * it could corrupt the CR2 value. If the NMI preempts a page fault
1841 * handler before it was able to read the CR2 register, and then the
1842 * NMI itself takes a page fault, the page fault that was preempted
1843 * will read the information from the NMI page fault and not the
1844 * origin fault. Save it off and restore it if it changes.
1845 * Use the r12 callee-saved register.
1846 */
1847 movq %cr2, %r12
1849 /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1850 movq %rsp,%rdi
1851 movq $-1,%rsi
1852 call do_nmi
1854 /* Did the NMI take a page fault? Restore cr2 if it did */
1855 movq %cr2, %rcx
1856 cmpq %rcx, %r12
1857 je 1f
1858 movq %r12, %cr2
1859 1:
1861 testl %ebx,%ebx /* swapgs needed? */
1862 jnz nmi_restore
1863 nmi_swapgs:
1864 SWAPGS_UNSAFE_STACK
1865 nmi_restore:
1866 RESTORE_ALL 8
1867 /* Clear the NMI executing stack variable */
1868 movq $0, 10*8(%rsp)
1869 jmp irq_return
1870 CFI_ENDPROC
1871 END(nmi)
1873 ENTRY(ignore_sysret)
1874 CFI_STARTPROC
1875 mov $-ENOSYS,%eax
1876 sysret
1877 CFI_ENDPROC
1878 END(ignore_sysret)
1880 /*
1881 * End of kprobes section
1882 */
1883 .popsection