scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2009 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;
 190 ;;; Scheme music expression --> Lily-syntax-using string translator
 191 ;;;
 192 (use-modules (srfi srfi-39)
 193              (scm display-lily))
 194
 195 (define*-public (display-lily-music expr parser #:key force-duration)
 196   "Display the music expression using LilyPond syntax"
 197   (memoize-clef-names supported-clefs)
 198   (parameterize ((*indent* 0)
 199                  (*previous-duration* (ly:make-duration 2))
 200                  (*force-duration* force-duration))
 201     (display (music->lily-string expr parser))
 202     (newline)))
 203
 204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 205
 206 (define-public (shift-one-duration-log music shift dot)
 207   "  add SHIFT to duration-log of 'duration in music and optionally
 208   a dot to any note encountered. This scales the music up by a factor
 209   2^shift * (2 - (1/2)^dot)"
 210   (let ((d (ly:music-property music 'duration)))
 211     (if (ly:duration? d)
 212         (let* ((cp (ly:duration-factor d))
 213                (nd (ly:make-duration (+ shift (ly:duration-log d))
 214                                      (+ dot (ly:duration-dot-count d))
 215                                      (car cp)
 216                                      (cdr cp))))
 217           (set! (ly:music-property music 'duration) nd)))
 218     music))
 219
 220 (define-public (shift-duration-log music shift dot)
 221   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 222              music))
 223
 224 (define-public (make-repeat name times main alts)
 225   "create a repeat music expression, with all properties initialized properly"
 226   (define (first-note-duration music)
 227     "Finds the duration of the first NoteEvent by searching depth-first
 228 through MUSIC."
 229     (if (memq 'note-event (ly:music-property music 'types))
 230         (ly:music-property music 'duration)
 231         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 232                              (list (ly:music-property music 'element))
 233                              (ly:music-property music 'elements))))
 234           (and (pair? elts)
 235                (let ((dur (first-note-duration (car elts))))
 236                  (if (ly:duration? dur)
 237                      dur
 238                      (loop (cdr elts))))))))
 239
 240   (let ((talts (if (< times (length alts))
 241                    (begin
 242                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 243                      (take alts times))
 244                    alts))
 245         (r (make-repeated-music name)))
 246     (set! (ly:music-property r 'element) main)
 247     (set! (ly:music-property r 'repeat-count) (max times 1))
 248     (set! (ly:music-property r 'elements) talts)
 249     (if (equal? name "tremolo")
 250         (let* ((dots (1- (logcount times)))
 251                (mult (/ (* times (ash 1 dots)) (1- (ash 2 dots))))
 252                (shift (- (ly:intlog2 (floor mult))))
 253                (note-duration (first-note-duration r))
 254                (duration-log (if (ly:duration? note-duration)
 255                                  (ly:duration-log note-duration)
 256                                  1))
 257                (tremolo-type (ash 1 duration-log)))
 258           (set! (ly:music-property r 'tremolo-type) tremolo-type)
 259           (if (not (integer?  mult))
 260               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 261           (if (memq 'sequential-music (ly:music-property main 'types))
 262               ;; \repeat "tremolo" { c4 d4 }
 263               (let ((children (length (ly:music-property main 'elements))))
 264
 265                 ;; fixme: should be more generic.
 266                 (if (and (not (= children 2))
 267                          (not (= children 1)))
 268                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 269                 (ly:music-compress r (ly:make-moment 1 children))
 270                 (shift-duration-log r
 271                                     (if (= children 2)  (1- shift) shift)
 272                                     dots))
 273               ;; \repeat "tremolo" c4
 274               (shift-duration-log r shift dots)))
 275         r)))
 276
 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 278 ;; clusters.
 279
 280 (define-public (note-to-cluster music)
 281   "Replace NoteEvents by ClusterNoteEvents."
 282   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 283       (make-music 'ClusterNoteEvent
 284                   'pitch (ly:music-property music 'pitch)
 285                   'duration (ly:music-property music 'duration))
 286       music))
 287
 288 (define-public (notes-to-clusters music)
 289   (music-map note-to-cluster music))
 290
 291 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 292 ;; repeats.
 293
 294 (define-public (unfold-repeats music)
 295   "
 296 This function replaces all repeats  with unfold repeats. "
 297
 298   (let ((es (ly:music-property music 'elements))
 299         (e  (ly:music-property music 'element))
 300         )
 301     (if (memq 'repeated-music (ly:music-property music 'types))
 302         (let*
 303             ((props (ly:music-mutable-properties music))
 304              (old-name (ly:music-property music 'name))
 305              (flattened  (flatten-alist props)))
 306
 307           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 308                                               flattened)))
 309
 310           (if (equal? old-name 'TremoloRepeatedMusic)
 311               (let* ((seq-arg? (memq 'sequential-music
 312                                      (ly:music-property e 'types)))
 313                      (count  (ly:music-property music 'repeat-count))
 314                      (dot-shift (if (= 0 (remainder count 3))
 315                                     -1 0)))
 316
 317                 (if (= 0 -1)
 318                     (set! count (* 2 (quotient count 3))))
 319
 320                 (shift-duration-log music (+ (if seq-arg? 1 0)
 321                                              (ly:intlog2 count)) dot-shift)
 322
 323                 (if seq-arg?
 324                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 325                                                                   e 'elements)) 1)))))))
 326
 327
 328     (if (pair? es)
 329         (set! (ly:music-property music 'elements)
 330               (map unfold-repeats es)))
 331     (if (ly:music? e)
 332         (set! (ly:music-property music 'element)
 333               (unfold-repeats e)))
 334     music))
 335
 336 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 337 ;; property setting music objs.
 338
 339 (define-public (make-grob-property-set grob gprop val)
 340   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 341 i.e.  this is not an override"
 342   (make-music 'OverrideProperty
 343               'symbol grob
 344               'grob-property gprop
 345               'grob-value val
 346               'pop-first #t))
 347
 348 (define-public (make-grob-property-override grob gprop val)
 349   "Make a Music expression that overrides GPROP to VAL in GROB."
 350   (make-music 'OverrideProperty
 351               'symbol grob
 352               'grob-property gprop
 353               'grob-value val))
 354
 355 (define-public (make-grob-property-revert grob gprop)
 356   "Revert the grob property GPROP for GROB."
 357   (make-music 'RevertProperty
 358               'symbol grob
 359               'grob-property gprop))
 360
 361 (define direction-polyphonic-grobs
 362   '(DotColumn
 363     Dots
 364     Fingering
 365     LaissezVibrerTie
 366     PhrasingSlur
 367     RepeatTie
 368     Rest
 369     Script
 370     Slur
 371     Stem
 372     TextScript
 373     Tie))
 374
 375 (define-safe-public (make-voice-props-set n)
 376   (make-sequential-music
 377    (append
 378     (map (lambda (x) (make-grob-property-set x 'direction
 379                                              (if (odd? n) -1 1)))
 380          direction-polyphonic-grobs)
 381     (list
 382      (make-property-set 'graceSettings
 383                         ;; TODO: take this from voicedGraceSettings or similar.
 384                         '((Voice Stem font-size -3)
 385                           (Voice NoteHead font-size -3)
 386                           (Voice TabNoteHead font-size -4)
 387                           (Voice Dots font-size -3)
 388                           (Voice Stem length-fraction 0.8)
 389                           (Voice Stem no-stem-extend #t)
 390                           (Voice Beam beam-thickness 0.384)
 391                           (Voice Beam length-fraction 0.8)
 392                           (Voice Accidental font-size -4)
 393                           (Voice AccidentalCautionary font-size -4)
 394                           (Voice Script font-size -3)
 395                           (Voice Fingering font-size -8)
 396                           (Voice StringNumber font-size -8)))
 397
 398      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 399      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 400
 401 (define-safe-public (make-voice-props-revert)
 402   (make-sequential-music
 403    (append
 404     (map (lambda (x) (make-grob-property-revert x 'direction))
 405          direction-polyphonic-grobs)
 406     (list (make-property-unset 'graceSettings)
 407           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 408           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 409
 410
 411 (define-safe-public (context-spec-music m context #:optional id)
 412   "Add \\context CONTEXT = ID to M. "
 413   (let ((cm (make-music 'ContextSpeccedMusic
 414                         'element m
 415                         'context-type context)))
 416     (if (string? id)
 417         (set! (ly:music-property cm 'context-id) id))
 418     cm))
 419
 420 (define-public (descend-to-context m context)
 421   "Like context-spec-music, but only descending. "
 422   (let ((cm (context-spec-music m context)))
 423     (ly:music-set-property! cm 'descend-only #t)
 424     cm))
 425
 426 (define-public (make-non-relative-music mus)
 427   (make-music 'UnrelativableMusic
 428               'element mus))
 429
 430 (define-public (make-apply-context func)
 431   (make-music 'ApplyContext
 432               'procedure func))
 433
 434 (define-public (make-sequential-music elts)
 435   (make-music 'SequentialMusic
 436               'elements elts))
 437
 438 (define-public (make-simultaneous-music elts)
 439   (make-music 'SimultaneousMusic
 440               'elements elts))
 441
 442 (define-safe-public (make-event-chord elts)
 443   (make-music 'EventChord
 444               'elements elts))
 445
 446 (define-public (make-skip-music dur)
 447   (make-music 'SkipMusic
 448               'duration dur))
 449
 450 (define-public (make-grace-music music)
 451   (make-music 'GraceMusic
 452               'element music))
 453
 454 ;;;;;;;;;;;;;;;;
 455
 456 ;; mmrest
 457 (define-public (make-multi-measure-rest duration location)
 458   (make-music 'MultiMeasureRestMusic
 459               'origin location
 460               'duration duration))
 461
 462 (define-public (make-property-set sym val)
 463   (make-music 'PropertySet
 464               'symbol sym
 465               'value val))
 466
 467 (define-public (make-property-unset sym)
 468   (make-music 'PropertyUnset
 469               'symbol sym))
 470
 471 (define-public (make-ottava-set octavation)
 472   (let ((m (make-music 'ApplyContext)))
 473     (define (ottava-modify context)
 474       "Either reset middleCPosition to the stored original, or remember
 475 old middleCPosition, add OCTAVATION to middleCPosition, and set
 476 OTTAVATION to `8va', or whatever appropriate."
 477       (if (number? (ly:context-property  context 'middleCOffset))
 478           (let ((where (ly:context-property-where-defined context 'middleCOffset)))
 479             (ly:context-unset-property where 'middleCOffset)
 480             (ly:context-unset-property where 'ottavation)))
 481
 482       (let* ((offset (* -7 octavation))
 483              (string (assoc-get octavation '((2 . "15ma")
 484                                              (1 . "8va")
 485                                              (0 . #f)
 486                                              (-1 . "8vb")
 487                                              (-2 . "15mb")))))
 488         (ly:context-set-property! context 'middleCOffset offset)
 489         (ly:context-set-property! context 'ottavation string)
 490         (ly:set-middle-C! context)))
 491     (set! (ly:music-property m 'procedure) ottava-modify)
 492     (context-spec-music m 'Staff)))
 493
 494 (define-public (set-octavation ottavation)
 495   (ly:export (make-ottava-set ottavation)))
 496
 497 ;;; Need to keep this definition for \time calls from parser
 498 (define-public (make-time-signature-set num den)
 499   "Set properties for time signature NUM/DEN."
 500   (make-beam-rule-time-signature-set num den '()))
 501
 502 ;;; Used for calls that include beat-grouping setting
 503 (define-public (set-time-signature num den . rest)
 504   "Set properties for time signature @var{num/den}.
 505 If @var{rest} is present, it is used to make a default
 506 @code{beamSetting} rule."
 507  (ly:export (apply make-beam-rule-time-signature-set
 508                     (list num den rest))))
 509
 510 (define-public (make-beam-rule-time-signature-set num den rest)
 511   "Implement settings for new time signature.  Can be
 512 called from either make-time-signature-set (used by \time
 513 in parser) or set-time-signature (called from scheme code
 514 included in .ly file."
 515
 516   (define (make-default-beaming-rule context)
 517    (override-property-setting
 518     context
 519     'beamSettings
 520     (list (cons num den) 'end)
 521     (list (cons '* (car rest)))))
 522
 523   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 524          (beat (ly:make-moment 1 den))
 525          (len  (ly:make-moment num den))
 526          (set2 (make-property-set 'beatLength beat))
 527          (set3 (make-property-set 'measureLength len))
 528          (beaming-rule
 529           (if (null? rest)
 530               '()
 531               (list (make-apply-context make-default-beaming-rule))))
 532          (output (cons* set1 set2 set3 beaming-rule)))
 533     (descend-to-context
 534      (context-spec-music
 535       (make-sequential-music output)
 536        'Timing)
 537      'Score)))
 538
 539 (define-public (make-mark-set label)
 540   "Make the music for the \\mark command."
 541   (let* ((set (if (integer? label)
 542                   (context-spec-music (make-property-set 'rehearsalMark label)
 543                                       'Score)
 544                   #f))
 545          (ev (make-music 'MarkEvent))
 546          (ch (make-event-chord (list ev))))
 547     (if set
 548         (make-sequential-music (list set ch))
 549         (begin
 550           (set! (ly:music-property ev 'label) label)
 551           ch))))
 552
 553 (define-safe-public (make-articulation name)
 554   (make-music 'ArticulationEvent
 555               'articulation-type name))
 556
 557 (define-public (make-lyric-event string duration)
 558   (make-music 'LyricEvent
 559               'duration duration
 560               'text string))
 561
 562 (define-safe-public (make-span-event type span-dir)
 563   (make-music type
 564               'span-direction span-dir))
 565
 566 (define-public (override-head-style heads style)
 567   "Override style for @var{heads} to @var{style}."
 568   (make-sequential-music
 569     (if (pair? heads)
 570         (map (lambda (h)
 571               (make-grob-property-override h 'style style))
 572          heads)
 573         (list (make-grob-property-override heads 'style style)))))
 574
 575 (define-public (revert-head-style heads)
 576   "Revert style for @var{heads}."
 577   (make-sequential-music
 578     (if (pair? heads)
 579         (map (lambda (h)
 580               (make-grob-property-revert h 'style))
 581          heads)
 582         (list (make-grob-property-revert heads 'style)))))
 583
 584 (define-public (style-note-heads heads style music)
 585  "Set @var{style} for all @var{heads} in @var{music}.  Works both
 586 inside of and outside of chord construct."
 587   ;; are we inside a <...>?
 588   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 589       ;; yes -> use a tweak
 590       (begin
 591         (set! (ly:music-property music 'tweaks)
 592               (acons 'style style (ly:music-property music 'tweaks)))
 593         music)
 594       ;; not in <...>, so use overrides
 595       (make-sequential-music
 596         (list
 597           (override-head-style heads style)
 598           music
 599           (revert-head-style heads)))))
 600
 601  (define-public (set-mus-properties! m alist)
 602   "Set all of ALIST as properties of M."
 603   (if (pair? alist)
 604       (begin
 605         (set! (ly:music-property m (caar alist)) (cdar alist))
 606         (set-mus-properties! m (cdr alist)))))
 607
 608 (define-public (music-separator? m)
 609   "Is M a separator?"
 610   (let ((ts (ly:music-property m 'types)))
 611     (memq 'separator ts)))
 612
 613 ;;; splitting chords into voices.
 614 (define (voicify-list lst number)
 615   "Make a list of Musics.
 616
 617    voicify-list :: [ [Music ] ] -> number -> [Music]
 618    LST is a list music-lists.
 619
 620    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 621 "
 622   (if (null? lst)
 623       '()
 624       (cons (context-spec-music
 625              (make-sequential-music
 626               (list (make-voice-props-set number)
 627                     (make-simultaneous-music (car lst))))
 628              'Bottom  (number->string (1+ number)))
 629             (voicify-list (cdr lst) (1+ number)))))
 630
 631 (define (voicify-chord ch)
 632   "Split the parts of a chord into different Voices using separator"
 633   (let ((es (ly:music-property ch 'elements)))
 634     (set! (ly:music-property  ch 'elements)
 635           (voicify-list (split-list-by-separator es music-separator?) 0))
 636     ch))
 637
 638 (define-public (voicify-music m)
 639   "Recursively split chords that are separated with \\ "
 640   (if (not (ly:music? m))
 641       (ly:error (_ "music expected: ~S") m))
 642   (let ((es (ly:music-property m 'elements))
 643         (e (ly:music-property m 'element)))
 644
 645     (if (pair? es)
 646         (set! (ly:music-property m 'elements) (map voicify-music es)))
 647     (if (ly:music? e)
 648         (set! (ly:music-property m 'element)  (voicify-music e)))
 649     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 650              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 651         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 652     m))
 653
 654 (define-public (empty-music)
 655   (ly:export (make-music 'Music)))
 656
 657 ;; Make a function that checks score element for being of a specific type.
 658 (define-public (make-type-checker symbol)
 659   (lambda (elt)
 660     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 661
 662 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 663   (if (func grob)
 664       (set! (ly:grob-property grob sym) val)))
 665
 666
 667 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 668   "Usage:
 669
 670 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 671
 672 "
 673   (let ((meta (ly:grob-property grob 'meta)))
 674     (if (equal? (assoc-get 'name meta) grob-name)
 675         (set! (ly:grob-property grob symbol) val))))
 676
 677
 678 ;;
 679 (define-public (smart-bar-check n)
 680   "Make  a bar check that checks for a specific bar number.
 681 "
 682   (let ((m (make-music 'ApplyContext)))
 683     (define (checker tr)
 684       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 685         (if (= bn n)
 686             #t
 687             (ly:error
 688              ;; FIXME: uncomprehensable message
 689              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 690              n bn))))
 691     (set! (ly:music-property m 'procedure) checker)
 692     m))
 693
 694
 695 (define-public (skip->rest mus)
 696
 697   "Replace MUS by RestEvent of the same duration if it is a
 698 SkipEvent. Useful for extracting parts from crowded scores"
 699
 700   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 701    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 702    mus))
 703
 704
 705 (define-public (music-has-type music type)
 706   (memq type (ly:music-property music 'types)))
 707
 708 (define-public (music-clone music)
 709   (define (alist->args alist acc)
 710     (if (null? alist)
 711         acc
 712         (alist->args (cdr alist)
 713                      (cons (caar alist) (cons (cdar alist) acc)))))
 714
 715   (apply
 716    make-music
 717    (ly:music-property music 'name)
 718    (alist->args (ly:music-mutable-properties music) '())))
 719
 720 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 721 ;; warn for bare chords at start.
 722
 723
 724 (define-public (ly:music-message music msg)
 725   (let ((ip (ly:music-property music 'origin)))
 726     (if (ly:input-location? ip)
 727         (ly:input-message ip msg)
 728         (ly:warning msg))))
 729
 730 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 731 ;;
 732 ;; setting stuff for grace context.
 733 ;;
 734
 735 (define (vector-extend v x)
 736   "Make a new vector consisting of V, with X added to the end."
 737   (let* ((n (vector-length v))
 738          (nv (make-vector (+ n 1) '())))
 739     (vector-move-left! v 0 n nv 0)
 740     (vector-set! nv n x)
 741     nv))
 742
 743 (define (vector-map f v)
 744   "Map  F over V. This function returns nothing."
 745   (do ((n (vector-length v))
 746        (i 0 (+ i 1)))
 747       ((>= i n))
 748     (f (vector-ref v i))))
 749
 750 (define (vector-reverse-map f v)
 751   "Map  F over V, N to 0 order. This function returns nothing."
 752   (do ((i (- (vector-length v) 1) (- i 1)))
 753       ((< i 0))
 754     (f (vector-ref v i))))
 755
 756 (define-public (add-grace-property context-name grob sym val)
 757   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 758   (define (set-prop context)
 759     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 760            (current (ly:context-property where 'graceSettings))
 761            (new-settings (append current
 762                                  (list (list context-name grob sym val)))))
 763       (ly:context-set-property! where 'graceSettings new-settings)))
 764   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 765
 766 (define-public (remove-grace-property context-name grob sym)
 767   "Remove all SYM for GROB in CONTEXT-NAME. "
 768   (define (sym-grob-context? property sym grob context-name)
 769     (and (eq? (car property) context-name)
 770          (eq? (cadr property) grob)
 771          (eq? (caddr property) sym)))
 772   (define (delete-prop context)
 773     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 774            (current (ly:context-property where 'graceSettings))
 775            (prop-settings (filter
 776                             (lambda(x) (sym-grob-context? x sym grob context-name))
 777                             current))
 778            (new-settings current))
 779       (for-each (lambda(x)
 780                  (set! new-settings (delete x new-settings)))
 781                prop-settings)
 782       (ly:context-set-property! where 'graceSettings new-settings)))
 783   (ly:export (context-spec-music (make-apply-context delete-prop) 'Voice)))
 784
 785
 786
 787 (defmacro-public def-grace-function (start stop . docstring)
 788   "Helper macro for defining grace music"
 789   `(define-music-function (parser location music) (ly:music?)
 790      ,@docstring
 791      (make-music 'GraceMusic
 792                  'origin location
 793                  'element (make-music 'SequentialMusic
 794                                       'elements (list (ly:music-deep-copy ,start)
 795                                                       music
 796                                                       (ly:music-deep-copy ,stop))))))
 797
 798 (defmacro-public define-music-function (args signature . body)
 799   "Helper macro for `ly:make-music-function'.
 800 Syntax:
 801   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 802     ...function body...)
 803 "
 804 (if (and (pair? body) (pair? (car body)) (eqv? '_i (caar body)))
 805       ;; When the music function definition contains a i10n doc string,
 806       ;; (_i "doc string"), keep the literal string only
 807       (let ((docstring (cadar body))
 808             (body (cdr body)))
 809         `(ly:make-music-function (list ,@signature)
 810                                  (lambda (,@args)
 811                                    ,docstring
 812                                    ,@body)))
 813       `(ly:make-music-function (list ,@signature)
 814                                (lambda (,@args)
 815                                  ,@body))))
 816
 817
 818 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 819
 820 (define-public (cue-substitute quote-music)
 821   "Must happen after quote-substitute."
 822
 823   (if (vector? (ly:music-property quote-music 'quoted-events))
 824       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 825              (main-voice (if (eq? 1 dir) 1 0))
 826              (cue-voice (if (eq? 1 dir) 0 1))
 827              (main-music (ly:music-property quote-music 'element))
 828              (return-value quote-music))
 829
 830         (if (or (eq? 1 dir) (eq? -1 dir))
 831
 832             ;; if we have stem dirs, change both quoted and main music
 833             ;; to have opposite stems.
 834             (begin
 835               (set! return-value
 836
 837                     ;; cannot context-spec Quote-music, since context
 838                     ;; for the quotes is determined in the iterator.
 839                     (make-sequential-music
 840                      (list
 841                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 842                       quote-music
 843                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 844               (set! main-music
 845                     (make-sequential-music
 846                      (list
 847                       (make-voice-props-set main-voice)
 848                       main-music
 849                       (make-voice-props-revert))))
 850               (set! (ly:music-property quote-music 'element) main-music)))
 851
 852         return-value)
 853       quote-music))
 854
 855 (define-public ((quote-substitute quote-tab) music)
 856   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 857          (quoted-vector (if (string? quoted-name)
 858                             (hash-ref quote-tab quoted-name #f)
 859                             #f)))
 860
 861
 862     (if (string? quoted-name)
 863         (if (vector? quoted-vector)
 864             (begin
 865               (set! (ly:music-property music 'quoted-events) quoted-vector)
 866               (set! (ly:music-property music 'iterator-ctor)
 867                     ly:quote-iterator::constructor))
 868             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 869     music))
 870
 871
 872 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 873 ;; switch it on here, so parsing and init isn't checked (too slow!)
 874 ;;
 875 ;; automatic music transformations.
 876
 877 (define (switch-on-debugging m)
 878   (if (defined? 'set-debug-cell-accesses!)
 879       (set-debug-cell-accesses! 15000))
 880   m)
 881
 882 (define (music-check-error music)
 883   (define found #f)
 884   (define (signal m)
 885     (if (and (ly:music? m)
 886              (eq? (ly:music-property m 'error-found) #t))
 887         (set! found #t)))
 888
 889   (for-each signal (ly:music-property music 'elements))
 890   (signal (ly:music-property music 'element))
 891
 892   (if found
 893       (set! (ly:music-property music 'error-found) #t))
 894   music)
 895
 896 (define (precompute-music-length music)
 897   (set! (ly:music-property music 'length)
 898         (ly:music-length music))
 899   music)
 900
 901 (define-public (make-duration-of-length moment)
 902  "Make duration of the given MOMENT length."
 903  (ly:make-duration 0 0
 904   (ly:moment-main-numerator moment)
 905   (ly:moment-main-denominator moment)))
 906
 907 (define (skip-this moment)
 908  "set skipTypesetting, make SkipMusic of the given MOMENT length,
 909  and then unset skipTypesetting."
 910  (make-sequential-music
 911   (list
 912    (context-spec-music (make-property-set 'skipTypesetting #t)
 913     'Score)
 914    (make-music 'SkipMusic 'duration
 915     (make-duration-of-length moment))
 916    (context-spec-music (make-property-set 'skipTypesetting #f)
 917     'Score))))
 918
 919 (define (unskip-this moment)
 920  "unset skipTypesetting, make SkipMusic of the given MOMENT length,
 921  and then set skipTypesetting."
 922  (make-sequential-music
 923   (list
 924    (context-spec-music (make-property-set 'skipTypesetting #f)
 925     'Score)
 926    (make-music 'SkipMusic 'duration
 927     (make-duration-of-length moment))
 928    (context-spec-music (make-property-set 'skipTypesetting #t)
 929     'Score))))
 930
 931 (define (skip-as-needed music parser)
 932  "Replace MUSIC by
 933  << {  \\set skipTypesetting = ##f
 934  LENGTHOF(\\showFirstLength)
 935  \\set skipTypesetting = ##t
 936  LENGTHOF(\\showLastLength) }
 937  MUSIC >>
 938  if appropriate.
 939
 940  When only showFirstLength is set,
 941  the 'length property of the music is
 942  overridden to speed up compiling."
 943  (let*
 944   ((show-last (ly:parser-lookup parser 'showLastLength))
 945    (show-first (ly:parser-lookup parser 'showFirstLength)))
 946   (cond
 947
 948    ;; both properties may be set.
 949    ((and (ly:music? show-first) (ly:music? show-last))
 950     (let*
 951      ((orig-length (ly:music-length music))
 952       (skip-length (ly:moment-sub orig-length (ly:music-length show-last)))
 953       (begin-length (ly:music-length show-first)))
 954      (make-simultaneous-music
 955       (list
 956        (make-sequential-music
 957         (list
 958          (skip-this skip-length)
 959          ;; let's draw a separator between the beginning and the end
 960          (context-spec-music (make-property-set 'whichBar "||")
 961           'Timing)))
 962        (unskip-this begin-length)
 963        music))))
 964
 965    ;; we may only want to print the last length
 966    ((ly:music? show-last)
 967     (let*
 968      ((orig-length (ly:music-length music))
 969       (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 970      (make-simultaneous-music
 971       (list
 972        (skip-this skip-length)
 973        music))))
 974
 975    ;; we may only want to print the beginning; in this case
 976    ;; only the first length will be processed (much faster).
 977    ((ly:music? show-first)
 978     (let*
 979      ((orig-length (ly:music-length music))
 980       (begin-length (ly:music-length show-first)))
 981      ;; the first length must not exceed the original length.
 982      (if (ly:moment<? begin-length orig-length)
 983       (set! (ly:music-property music 'length)
 984        (ly:music-length show-first)))
 985      music))
 986
 987    (else music))))
 988
 989
 990 (define-public toplevel-music-functions
 991   (list
 992    (lambda (music parser) (voicify-music music))
 993    (lambda (x parser) (music-map music-check-error x))
 994    (lambda (x parser) (music-map precompute-music-length x))
 995    (lambda (music parser)
 996
 997      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 998
 999    ;; switch-on-debugging
1000    (lambda (x parser) (music-map cue-substitute x))
1001
1002    (lambda (x parser)
1003      (skip-as-needed x parser)
1004    )))
1005
1006 ;;;;;;;;;;
1007 ;;; general purpose music functions
1008
1009 (define (shift-octave pitch octave-shift)
1010   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1011   (ly:make-pitch
1012      (+ (ly:pitch-octave pitch) octave-shift)
1013      (ly:pitch-notename pitch)
1014      (ly:pitch-alteration pitch)))
1015
1016
1017 ;;;;;;;;;;;;;;;;;
1018 ;; lyrics
1019
1020 (define (apply-durations lyric-music durations)
1021   (define (apply-duration music)
1022     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1023              (ly:duration?  (ly:music-property music 'duration)))
1024         (begin
1025           (set! (ly:music-property music 'duration) (car durations))
1026           (set! durations (cdr durations)))))
1027
1028   (music-map apply-duration lyric-music))
1029
1030
1031 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1032 ;; accidentals
1033
1034 (define (recent-enough? bar-number alteration-def laziness)
1035   (if (or (number? alteration-def)
1036           (equal? laziness #t))
1037       #t
1038       (<= bar-number (+ (cadr alteration-def) laziness))))
1039
1040 (define (is-tied? alteration-def)
1041   (let* ((def (if (pair? alteration-def)
1042                  (car alteration-def)
1043                  alteration-def)))
1044
1045     (if (equal? def 'tied) #t #f)))
1046
1047 (define (extract-alteration alteration-def)
1048   (cond ((number? alteration-def)
1049          alteration-def)
1050         ((pair? alteration-def)
1051          (car alteration-def))
1052         (else 0)))
1053
1054 (define (check-pitch-against-signature context pitch barnum laziness octaveness)
1055   "Checks the need for an accidental and a @q{restore} accidental against
1056 @code{localKeySignature}. The @var{laziness} is the number of measures
1057 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1058 only cancel accidentals in the same measure; if @var{laziness} is three,
1059 we cancel accidentals up to three measures after they first appear.
1060 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1061 specifies whether accidentals should be canceled in different octaves."
1062   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1063                               ((equal? octaveness 'same-octave) #f)
1064                               (else
1065                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1066                                (ly:warning (_ "Defaulting to 'any-octave."))
1067                                #t)))
1068          (key-sig (ly:context-property context 'keySignature))
1069          (local-key-sig (ly:context-property context 'localKeySignature))
1070          (notename (ly:pitch-notename pitch))
1071          (octave (ly:pitch-octave pitch))
1072          (pitch-handle (cons octave notename))
1073          (need-restore #f)
1074          (need-accidental #f)
1075          (previous-alteration #f)
1076          (from-other-octaves #f)
1077          (from-same-octave (ly:assoc-get pitch-handle local-key-sig))
1078          (from-key-sig (ly:assoc-get notename local-key-sig)))
1079
1080     ;; If no key signature match is found from localKeySignature, we may have a custom
1081     ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1082     ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1083     ;; localKeySignature, try extracting from keySignature instead.
1084     (if (equal? from-key-sig #f)
1085         (set! from-key-sig (ly:assoc-get pitch-handle key-sig)))
1086
1087     ;; loop through localKeySignature to search for a notename match from other octaves
1088     (let loop ((l local-key-sig))
1089       (if (pair? l)
1090           (let ((entry (car l)))
1091             (if (and (pair? (car entry))
1092                      (= (cdar entry) notename))
1093                 (set! from-other-octaves (cdr entry))
1094                 (loop (cdr l))))))
1095
1096     ;; find previous alteration-def for comparison with pitch
1097     (cond
1098      ;; from same octave?
1099      ((and (eq? ignore-octave #f)
1100            (not (equal? from-same-octave #f))
1101            (recent-enough? barnum from-same-octave laziness))
1102       (set! previous-alteration from-same-octave))
1103
1104      ;; from any octave?
1105      ((and (eq? ignore-octave #t)
1106            (not (equal? from-other-octaves #f))
1107            (recent-enough? barnum from-other-octaves laziness))
1108       (set! previous-alteration from-other-octaves))
1109
1110      ;; not recent enough, extract from key signature/local key signature
1111      ((not (equal? from-key-sig #f))
1112       (set! previous-alteration from-key-sig)))
1113
1114     (if (is-tied? previous-alteration)
1115         (set! need-accidental #t)
1116
1117         (let* ((prev-alt (extract-alteration previous-alteration))
1118                (this-alt (ly:pitch-alteration pitch)))
1119
1120           (if (not (= this-alt prev-alt))
1121               (begin
1122                 (set! need-accidental #t)
1123                 (if (and (not (= this-alt 0))
1124                          (or (< (abs this-alt) (abs prev-alt))
1125                              (< (* prev-alt this-alt) 0)))
1126                     (set! need-restore #t))))))
1127
1128     (cons need-restore need-accidental)))
1129
1130 (define-public ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1131   "Creates an accidental rule that makes its decision based on the octave of the note
1132   and a laziness value.
1133   octaveness is either 'same-octave or 'any-octave and defines whether the rule should
1134   respond to accidental changes in other octaves than the current. 'same-octave is the
1135   normal way to typeset accidentals - an accidental is made if the alteration is different
1136   from the last active pitch in the same octave. 'any-octave looks at the last active pitch
1137   in any octave.
1138   laziness states over how many bars an accidental should be remembered.
1139   0 is default - accidental lasts over 0 bar lines, that is, to the end of current measure.
1140   A positive integer means that the accidental lasts over that many bar lines.
1141   -1 is 'forget immediately', that is, only look at key signature.
1142   #t is forever."
1143   (check-pitch-against-signature context pitch barnum laziness octaveness))
1144
1145 (define (key-entry-notename entry)
1146   "Return the pitch of an entry in localKeySignature. The entry is either of the form
1147   '(notename . alter) or '((octave . notename) . (alter barnum . measurepos))."
1148   (if (number? (car entry))
1149       (car entry)
1150       (cdar entry)))
1151
1152 (define (key-entry-octave entry)
1153   "Return the octave of an entry in localKeySignature (or #f if the entry does not have
1154   an octave)."
1155   (and (pair? (car entry)) (caar entry)))
1156
1157 (define (key-entry-bar-number entry)
1158   "Return the bar number of an entry in localKeySignature (or #f if the entry does not
1159   have a bar number)."
1160   (and (pair? (car entry)) (caddr entry)))
1161
1162 (define (key-entry-measure-position entry)
1163   "Return the measure position of an entry in localKeySignature (or #f if the entry does
1164   not have a measure position)."
1165   (and (pair? (car entry)) (cdddr entry)))
1166
1167 (define (key-entry-alteration entry)
1168   "Return the alteration of an entry in localKeySignature."
1169   (if (number? (car entry))
1170       (cdr entry)
1171       (cadr entry)))
1172
1173 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1174   "Return the first entry in keysig that matches the pitch.
1175   accept-global states whether key signature entries should be included.
1176   accept-local states whether local accidentals should be included.
1177   if no matching entry is found, #f is returned."
1178   (if (pair? keysig)
1179       (let* ((entry (car keysig))
1180              (entryoct (key-entry-octave entry))
1181              (entrynn (key-entry-notename entry))
1182              (oct (ly:pitch-octave pitch))
1183              (nn (ly:pitch-notename pitch)))
1184         (if (and (equal? nn entrynn)
1185                  (or (and accept-global (equal? #f entryoct))
1186                      (and accept-local (equal? oct entryoct))))
1187             entry
1188             (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))
1189       #f))
1190
1191 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1192   "an accidental rule that typesets an accidental if it differs from the key signature
1193    AND does not directly follow a note on the same staff-line.
1194    This rule should not be used alone because it does neither look at bar lines
1195    nor different accidentals at the same notename"
1196   (let* ((keysig (ly:context-property context 'localKeySignature))
1197          (entry (find-pitch-entry keysig pitch #t #t)))
1198     (if (equal? #f entry)
1199         (cons #f #f)
1200         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1201                (key-acc (if (equal? global-entry #f)
1202                             0
1203                             (key-entry-alteration global-entry)))
1204                (acc (ly:pitch-alteration pitch))
1205                (entrymp (key-entry-measure-position entry))
1206                (entrybn (key-entry-bar-number entry)))
1207           (cons #f (not (or (equal? acc key-acc)
1208                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1209
1210 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1211   "an accidental rule that typesets a cautionary accidental
1212   if it is included in the key signature AND does not directly follow
1213   a note on the same staff-line."
1214   (let* ((keysig (ly:context-property context 'localKeySignature))
1215          (entry (find-pitch-entry keysig pitch #t #t)))
1216     (if (equal? #f entry)
1217         (cons #f #f)
1218         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1219                (key-acc (if (equal? global-entry #f)
1220                             0
1221                             (key-entry-alteration global-entry)))
1222                (acc (ly:pitch-alteration pitch))
1223                (entrymp (key-entry-measure-position entry))
1224                (entrybn (key-entry-bar-number entry)))
1225           (cons #f (not (or (equal? acc key-acc)
1226                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1227
1228 (define-public (set-accidentals-properties extra-natural
1229                                            auto-accs auto-cauts
1230                                            context)
1231   (context-spec-music
1232    (make-sequential-music
1233     (append (if (boolean? extra-natural)
1234                 (list (make-property-set 'extraNatural extra-natural))
1235                 '())
1236             (list (make-property-set 'autoAccidentals auto-accs)
1237                   (make-property-set 'autoCautionaries auto-cauts))))
1238    context))
1239
1240 (define-public (set-accidental-style style . rest)
1241   "Set accidental style to STYLE. Optionally takes a context argument,
1242 e.g. 'Staff or 'Voice. The context defaults to Staff, except for piano styles, which
1243 use GrandStaff as a context. "
1244   (let ((context (if (pair? rest)
1245                      (car rest) 'Staff))
1246         (pcontext (if (pair? rest)
1247                       (car rest) 'GrandStaff)))
1248     (ly:export
1249      (cond
1250       ;; accidentals as they were common in the 18th century.
1251       ((equal? style 'default)
1252        (set-accidentals-properties #t
1253                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1254                                    '()
1255                                    context))
1256       ;; accidentals from one voice do NOT get cancelled in other voices
1257       ((equal? style 'voice)
1258        (set-accidentals-properties #t
1259                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1260                                    '()
1261                                    context))
1262       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1263       ;; This includes all the default accidentals, but accidentals also needs cancelling
1264       ;; in other octaves and in the next measure.
1265       ((equal? style 'modern)
1266        (set-accidentals-properties #f
1267                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1268                                            ,(make-accidental-rule 'any-octave 0)
1269                                            ,(make-accidental-rule 'same-octave 1))
1270                                    '()
1271                                    context))
1272       ;; the accidentals that Stone adds to the old standard as cautionaries
1273       ((equal? style 'modern-cautionary)
1274        (set-accidentals-properties #f
1275                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1276                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1277                                            ,(make-accidental-rule 'same-octave 1))
1278                                    context))
1279       ;; same as modern, but accidentals different from the key signature are always
1280       ;; typeset - unless they directly follow a note of the same pitch.
1281       ((equal? style 'neo-modern)
1282        (set-accidentals-properties #f
1283                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1284                                            ,(make-accidental-rule 'any-octave 0)
1285                                            ,(make-accidental-rule 'same-octave 1)
1286                                            ,neo-modern-accidental-rule)
1287                                    '()
1288                                    context))
1289       ((equal? style 'neo-modern-cautionary)
1290        (set-accidentals-properties #f
1291                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1292                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1293                                            ,(make-accidental-rule 'same-octave 1)
1294                                            ,neo-modern-accidental-rule)
1295                                    context))
1296       ;; Accidentals as they were common in dodecaphonic music with no tonality.
1297       ;; Each note gets one accidental.
1298       ((equal? style 'dodecaphonic)
1299        (set-accidentals-properties #f
1300                                    `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1301                                    '()
1302                                    context))
1303       ;; Multivoice accidentals to be read both by musicians playing one voice
1304       ;; and musicians playing all voices.
1305       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
1306       ((equal? style 'modern-voice)
1307        (set-accidentals-properties  #f
1308                                     `(Voice ,(make-accidental-rule 'same-octave 0)
1309                                             ,(make-accidental-rule 'any-octave 0)
1310                                             ,(make-accidental-rule 'same-octave 1)
1311                                       Staff ,(make-accidental-rule 'same-octave 0)
1312                                             ,(make-accidental-rule 'any-octave 0)
1313                                             ,(make-accidental-rule 'same-octave 1))
1314                                     '()
1315                                     context))
1316       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1317       ;; as cautionaries
1318       ((equal? style 'modern-voice-cautionary)
1319        (set-accidentals-properties #f
1320                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1321                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1322                                            ,(make-accidental-rule 'same-octave 1)
1323                                      Staff ,(make-accidental-rule 'same-octave 0)
1324                                            ,(make-accidental-rule 'any-octave 0)
1325                                            ,(make-accidental-rule 'same-octave 1))
1326                                    context))
1327       ;; stone's suggestions for accidentals on grand staff.
1328       ;; Accidentals are cancelled across the staves in the same grand staff as well
1329       ((equal? style 'piano)
1330        (set-accidentals-properties #f
1331                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1332                                            ,(make-accidental-rule 'any-octave 0)
1333                                            ,(make-accidental-rule 'same-octave 1)
1334                                      GrandStaff
1335                                            ,(make-accidental-rule 'any-octave 0)
1336                                            ,(make-accidental-rule 'same-octave 1))
1337                                    '()
1338                                    pcontext))
1339       ((equal? style 'piano-cautionary)
1340        (set-accidentals-properties #f
1341                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1342                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1343                                            ,(make-accidental-rule 'same-octave 1)
1344                                      GrandStaff
1345                                            ,(make-accidental-rule 'any-octave 0)
1346                                            ,(make-accidental-rule 'same-octave 1))
1347                                    pcontext))
1348
1349       ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1350       ;; tones specified by the key signature.
1351        ((equal? style 'teaching)
1352        (set-accidentals-properties #f
1353                                     `(Staff ,(make-accidental-rule 'same-octave 0))
1354                                     `(Staff ,(make-accidental-rule 'same-octave 1)
1355                                            ,teaching-accidental-rule)
1356                                    context))
1357
1358       ;; do not set localKeySignature when a note alterated differently from
1359       ;; localKeySignature is found.
1360       ;; Causes accidentals to be printed at every note instead of
1361       ;; remembered for the duration of a measure.
1362       ;; accidentals not being remembered, causing accidentals always to
1363       ;; be typeset relative to the time signature
1364       ((equal? style 'forget)
1365        (set-accidentals-properties '()
1366                                    `(Staff ,(make-accidental-rule 'same-octave -1))
1367                                    '()
1368                                    context))
1369       ;; Do not reset the key at the start of a measure.  Accidentals will be
1370       ;; printed only once and are in effect until overridden, possibly many
1371       ;; measures later.
1372       ((equal? style 'no-reset)
1373        (set-accidentals-properties '()
1374                                    `(Staff ,(make-accidental-rule 'same-octave #t))
1375                                    '()
1376                                    context))
1377       (else
1378        (ly:warning (_ "unknown accidental style: ~S") style)
1379        (make-sequential-music '()))))))
1380
1381 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1382
1383 (define-public (skip-of-length mus)
1384   "Create a skip of exactly the same length as MUS."
1385   (let* ((skip
1386           (make-music
1387            'SkipEvent
1388            'duration (ly:make-duration 0 0))))
1389
1390     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1391
1392 (define-public (mmrest-of-length mus)
1393   "Create a mmrest of exactly the same length as MUS."
1394
1395   (let* ((skip
1396           (make-multi-measure-rest
1397            (ly:make-duration 0 0) '())))
1398     (ly:music-compress skip (ly:music-length mus))
1399     skip))
1400
1401 (define-public (pitch-of-note event-chord)
1402
1403   (let*
1404       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
1405                     (ly:music-property event-chord 'elements))))
1406
1407     (if (pair? evs)
1408         (ly:music-property (car evs) 'pitch)
1409         #f)))
1410
1411 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1412
1413 (define-public (extract-named-music music music-name)
1414 "Return a flat list of all music named @code{music-name}
1415 from @code{music}."
1416    (let ((extracted-list
1417           (if (ly:music? music)
1418               (if (eq? (ly:music-property music 'name) music-name)
1419                   (list music)
1420                   (let ((elt (ly:music-property music 'element))
1421                         (elts (ly:music-property music 'elements)))
1422                     (if (ly:music? elt)
1423                         (extract-named-music elt music-name)
1424                         (if (null? elts)
1425                             '()
1426                             (map (lambda(x)
1427                                     (extract-named-music x music-name ))
1428                              elts)))))
1429               '())))
1430      (flatten-list extracted-list)))
1431
1432 (define-public (event-chord-notes event-chord)
1433 "Return a list of all notes from @{event-chord}."
1434   (filter
1435     (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
1436     (ly:music-property event-chord 'elements)))
1437
1438 (define-public (event-chord-pitches event-chord)
1439 "Return a list of all pitches from @{event-chord}."
1440   (map (lambda (x) (ly:music-property x 'pitch))
1441        (event-chord-notes event-chord)))