mf/feta-klef.mf

   1 % Feta (not the Font-En-Tja) music font --  implement Clefs -*-Fundamental-*-
   2 % This file is part of LilyPond, the GNU music typesetter.
   3 %
   4 % Copyright (C) 1997--2009 Han-Wen Nienhuys <hanwen@xs4all.nl>,
   5 % Jan Nieuwenhuizen <janneke@gnu.org>,
   6 % Juergen Reuter <reuter@ipd.uka.de>
   7 %
   8 % LilyPond is free software: you can redistribute it and/or modify
   9 % it under the terms of the GNU General Public License as published by
  10 % the Free Software Foundation, either version 3 of the License, or
  11 % (at your option) any later version.
  12 %
  13 % LilyPond is distributed in the hope that it will be useful,
  14 % but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 % MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 % GNU General Public License for more details.
  17 %
  18 % You should have received a copy of the GNU General Public License
  19 % along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 fet_begingroup ("clefs");
  23
  24 %
  25 % [Wanske] says the bulbs should be positioned about 1/4 right of the
  26 % `arrow'.
  27 %
  28 % TODO: The hair-curve at z6r looks a little awkward.
  29 %
  30
  31 def draw_c_clef (expr reduction) =
  32         save hair, norm, reduced_ss, right_edge;
  33         save xoff;
  34
  35         reduced_ss# = staff_space# * reduction;
  36         norm# := 2/3 reduced_ss#;
  37         hair# := 0.06 reduced_ss# + 0.5 linethickness#;
  38         right_edge# = 15/4 norm# + 2 hair#;
  39         define_pixels (norm, reduced_ss, right_edge);
  40         define_whole_vertical_blacker_pixels (hair);
  41
  42         set_char_box (0, right_edge#, 2 reduced_ss#, 2 reduced_ss#);
  43
  44         % make unreduced glyph fit exactly into five staff lines
  45         if reduction = 1:
  46                 h := d := 2 staff_space_rounded;
  47         fi;
  48
  49         % assure that the gap between the left and right stem
  50         % has the same number of pixels as the thickness of the right
  51         % stem
  52         draw_block ((0, -d + feta_shift),
  53                     (3/4 norm + 1/2 hair, h));
  54         draw_block ((3/4 norm + 1/2 hair + hround (3/2 hair), -d + feta_shift),
  55                     (3/4 norm + 1/2 hair + 2 hround (3/2 hair), h));
  56
  57         % assure symmetry
  58         h := h - feta_shift;
  59
  60         pickup feta_fillpen;
  61
  62         xoff = 3/4 norm + 1/2 hair + 2 hround (3/2 hair);
  63         z5l = (xoff - 3/4 hair, 0);
  64         z5r = (x4, 0);
  65
  66         penpos1 (hair - pen_top - pen_bot, -90);
  67         top z1l = (xoff + norm + hair, h);
  68
  69         penpos2 (hround (norm - 3/2 hair) - pen_lft - pen_rt, 180);
  70         rt z2l = (w, h / 2);
  71
  72         penpos3 (hair - pen_top - pen_bot, 90);
  73         bot z3l = ((right_edge - xoff) / 2 + xoff,
  74                    vround (.5 norm - 1.5 hair));
  75
  76         penpos4 (hair - pen_lft - pen_rt, 0);
  77         top z4 = (xoff + 1/2 norm + 1/2 hair,
  78                   vfloor (reduced_ss - linethickness - .2 hair));
  79
  80         bot z6 = (xoff + 3/4 norm, vround (.5 norm - .5 hair));
  81
  82         save t;
  83         t = 0.833;
  84
  85         save pat;
  86         path pat;
  87
  88         pat = z5l{curl 1}
  89               .. z4l{up}
  90               .. z4r{down}
  91               .. z3r{right}
  92               ..tension t.. z2r{up}
  93               ..tension t.. flare_path (top z1l, 180, 90,
  94                                         hair, hfloor (norm - 1/2 hair), -1)
  95               ..tension t.. z2l{down}
  96               .. z3l{left}
  97               .. z6
  98               .. z5r{down};
  99
 100         filldraw pat shifted (0, feta_shift)
 101                  -- reverse pat yscaled -1 shifted (0, -feta_eps)
 102                  -- cycle;
 103
 104         penlabels (1, 2, 3, 4, 5, 6);
 105
 106         % ugh, should be bulb, not flare?
 107
 108         draw_staff (-2, 2, 0);
 109 enddef;
 110
 111
 112 fet_beginchar ("C clef", "C");
 113         draw_c_clef (1.0);
 114 fet_endchar;
 115
 116
 117 fet_beginchar ("C clef", "C_change");
 118         draw_c_clef (.8);
 119 fet_endchar;
 120
 121
 122 %
 123 % New bulb routine:
 124 %
 125 % Insert a brushed piece of the path, and draw the rest of the bulb
 126 % separately.
 127 %
 128 % The bulb has circular form.  Neat merging of the bulb and brushed path
 129 % is done by playing with tension.
 130 %
 131
 132 def new_bulb (expr start_point, start_angle,
 133               outer_tangent_point,
 134               end_point, end_angle,
 135               big_radius, bulb_radius, flare,
 136               direction, turning_dir) =
 137 begingroup;
 138         save pat, before, after;
 139         save center;
 140         save u, v;
 141         path pat, before, after;
 142         pair center;
 143
 144         clearxy;
 145
 146         center = outer_tangent_point
 147                  + big_radius * dir (0);
 148 %                + (big_radius - bulb_radius) * dir (-turning_dir * 90)
 149
 150         z1' = center + bulb_radius * dir (turning_dir * 180);
 151         z2' = outer_tangent_point + flare * dir (0);
 152         z3' = center + bulb_radius * dir (0);
 153         z4' = center + bulb_radius * dir (turning_dir * 90);
 154         z5' = center - 0.5 [big_radius, bulb_radius] * dir (turning_dir * 90);
 155
 156         labels (1', 2', 3', 4', 5');
 157
 158         before := z3'{dir (turning_dir * 90)}
 159                   .. z4'{-dir (0)}
 160                   ..tension 1.1.. z1'{-dir (turning_dir* 90)};
 161         after := z2'{dir (turning_dir * 90)}
 162                  .. end_point{dir (end_angle)};
 163         (u, v) = before intersectiontimes after;
 164
 165         pat := start_point{dir (start_angle)}
 166                .. outer_tangent_point{dir (-turning_dir * 90)}
 167                ..tension 1.02.. z5'{dir (0)}
 168                .. subpath (0, u) of before
 169                .. subpath (v, infinity) of after;
 170
 171         if direction = 0:
 172                 pat := reverse pat;
 173         fi
 174
 175 pat
 176 endgroup
 177 enddef;
 178
 179
 180 %
 181 % There is some variation in the shape of bass clefs.
 182 %
 183 % * In some clefs the size of the swoosh tip almost reaches the
 184 %   bottom staff line; in some it crosses the 2nd line from the bottom
 185 %   with a small overshoot.
 186 %
 187 %   The most popular design is where the X part of the tip is aligned
 188 %   with the left bulb boundary, and the Y part ends on the 2nd
 189 %   staffline exactly.  This is what we do.
 190 %
 191 % * The diameter of the bulb is the width of the open space.
 192 %
 193 % * The vertical center of the bulb can be on or slightly above the
 194 %   staff line.
 195 %
 196 % * The vertical position of the dots can be symmetrical around the
 197 %   staffline, centered in the staff space.  The Baerenreiter SCS has
 198 %   the bottom dot raised by approximately 0.1 staff space.
 199 %
 200 % * Uncarefully set music may have overshoots at the top.  We have none.
 201 %
 202 % * It is not exactly clear where the vertical tangent at the right
 203 %   of the swoosh should be.
 204 %
 205
 206 def draw_bass_clef (expr exact_center, reduction) =
 207         save reduced_ss, swoosh_width;
 208         save right_thickness, right_offset, tip_protrude;
 209         save dot_diam, bulb_y_offset, bulb_flare;
 210         pair tip_protrude;
 211
 212         reduced_ss# = staff_space# * reduction;
 213         2.2 dot_diam# = reduction * (staff_space# - stafflinethickness#);
 214         right_thickness# = 0.37 staff_space# + 1.2 linethickness#;
 215         swoosh_width# = 2.1 reduced_ss#;
 216         define_pixels (swoosh_width);
 217         define_whole_pixels (reduced_ss);
 218         define_whole_blacker_pixels (dot_diam, right_thickness);
 219
 220         right_offset = 0.05 staff_space;
 221         bulb_y_offset := 0.075 staff_space;
 222         bulb_flare := 2.5 linethickness;
 223 %       tip_protrude := (-linethickness, -.2 staff_space);
 224         tip_protrude := (0, 0);
 225
 226         set_char_box (-xpart exact_center,
 227                       xpart exact_center + swoosh_width# + 7/12 reduced_ss#,
 228                       -ypart exact_center + 2.5 reduced_ss#,
 229                       ypart exact_center + reduced_ss#);
 230
 231         y1 = bulb_y_offset;
 232         x1 = 0;
 233
 234         x2 = .5 [x1, x3];
 235         x2l = x2r = x2;
 236
 237         y2l := vround_pixels (reduced_ss# + 0.5 linethickness#);
 238         y2l - y2r = linethickness;
 239
 240         x3l - x1 = swoosh_width;
 241         x3l - x3r = right_thickness;
 242
 243         % optical correction: the top dot seems farther away if y3l = 0.
 244         y3l = right_offset;
 245
 246         z4 = -(0, 2.0 reduced_ss) + tip_protrude;
 247
 248         penpos3 (whatever, 185);
 249         penpos4 (linethickness, 135);
 250
 251         fill new_bulb (z2l, 180, z1, z2r, 0,
 252                        0.45 reduced_ss, 0.4 reduced_ss,
 253                        bulb_flare, 1, 1)
 254              .. z3r{down}
 255              .. {curl 0}simple_serif (z4r, z4l, 90){curl 0}
 256              .. z3l{up}
 257              ..tension 0.9.. cycle;
 258
 259         pickup pencircle scaled dot_diam;
 260
 261         lft x5 = hround (x3l + 1/3 reduced_ss - dot_diam / 2);
 262         bot y5 = vfloor (.5 reduced_ss - dot_diam / 2);
 263         z6 = z5 yscaled -1;
 264
 265         % for symmetry
 266         y5 := y5 + feta_shift;
 267
 268         drawdot z5;
 269         drawdot z6;
 270
 271         penlabels (1, 2, 3, 4, 5, 6);
 272
 273         draw_staff (-3, 1, 0);
 274 enddef;
 275
 276
 277 fet_beginchar ("F clef ", "F");
 278         draw_bass_clef ((0, 0), 1.0);
 279 fet_endchar;
 280
 281
 282 fet_beginchar ("F clef (reduced)", "F_change");
 283         draw_bass_clef ((0, 0), 0.8);
 284 fet_endchar;
 285
 286
 287
 288 %
 289 % Inspired by Baerenreiter
 290 %
 291 %
 292 % Beste lezers, kijk,
 293 %
 294 % Een bolletje hebben we bij toeval allemaal wel eens getekend, maar begint u
 295 % toch eenvoudig.  Eerst een eenvoudig kruis of herstellingsteken
 296 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 297 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 298 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 299 %
 300 %  -- vrij naar Van Kooten & De Bie
 301 %
 302
 303 def debugfill = fill enddef;
 304
 305 def draw_gclef (expr reduction) =
 306         save reduced_ss, downstroke_dir, downstroke_angle, center;
 307         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 308         save start_angle, inner_start_angle, thinness;
 309         save upward_swoosh_angle, bot_angle;
 310         save pat;
 311         path pat;
 312         pair downstroke_dir, center;
 313
 314         reduced_ss# = staff_space# * reduction;
 315         define_pixels (reduced_ss);
 316
 317         thinness = 0.095 staff_space + 0.75 linethickness;
 318         downstroke_dir = unitvector (14, -75);
 319         downstroke_angle = angle downstroke_dir;
 320         bot_angle = -180;               % downstroke_angle - 87
 321
 322         upward_swoosh_angle = 132;
 323         start_angle = -97;
 324
 325         breapth_factor = 21/14;
 326         inner_thick_end = 45;
 327         inner_start_angle = downstroke_angle - 43;
 328         thickness = .32 reduced_ss + 1.1 linethickness;
 329
 330         thinnib = thinness;
 331
 332         set_char_box (0, 1.71 * breapth_factor * reduced_ss#,
 333                       2.6 * reduced_ss#, 5 * reduced_ss#);
 334
 335         center := (breapth_factor * reduced_ss, 0);
 336
 337         z1 = center + whatever * dir (inner_start_angle);
 338         x1 = xpart center - .28 reduced_ss;
 339         penpos1 (thinnib, inner_start_angle);
 340
 341         x2r = xpart center;
 342         y2r = vround_pixels (reduced_ss# + .5 stafflinethickness#);
 343         penpos2 (thickness, 90);
 344
 345         z3 = (z4 - center) rotated inner_thick_end + center;
 346         penpos3 (thinnib, -90 + inner_thick_end);
 347
 348         x4 = xpart center - .1 reduced_ss;
 349         y4r = -y2r + feta_shift;
 350         penpos4 (thinnib, -90);
 351
 352         x5r = -breapth_factor * reduced_ss + xpart center;
 353         y5r = .37 reduced_ss + ypart center;
 354         penpos5 (thickness, upward_swoosh_angle);
 355
 356         z6 = center + whatever * downstroke_dir;
 357         y6 = ypart center + 2 reduced_ss;
 358         % penpos6 is computed later
 359
 360         z7l - z6 = whatever * (z5 - z6) ;
 361         y7l = 3.5 reduced_ss;
 362         penpos7 (thickness, upward_swoosh_angle);
 363
 364         x9 = .7 [x10, x7r];
 365         top y9l = 5 reduced_ss;
 366         penpos9 (1.45 thickness, -70);
 367
 368         x11 - x13r = 1.5 reduced_ss + 0.5 thinnib;
 369         y11 = ypart center - 47/28 reduced_ss;
 370         y12 = ypart center - 71/28 reduced_ss;
 371         y13 = .48 [y12, y4r];
 372         x12r = xpart (.45 [z13r, z11] + .75 reduced_ss * downstroke_dir);
 373
 374 %       z10 = center + whatever * dir (downstroke_angle - 1.5);
 375         x10 = x6 - 2 thinnib;
 376         y10 = ypart center + 3.5 reduced_ss;
 377         y10l - y10r = 1.0 thickness;
 378         z10r - z10l = .7 thinnib * dir (downstroke_angle + 90)
 379                       + whatever * downstroke_dir;
 380         z10 = .5 [z10l, z10r];
 381         z11 = center + whatever * downstroke_dir + (-0.05 reduced_ss, 0);
 382
 383         penpos11 (thinnib, start_angle + 90);
 384         penpos12 (thinnib, bot_angle + 90);
 385         penpos13 (thinnib + 0.14 staff_space, 180);
 386
 387         % this auxiliary point ensures good contour overlapping
 388         z8 = .5 [z9l, z9r] + .25 ((z9r - z9l) rotated -90);
 389
 390         z20 = z9l - (0, .25 blot_diameter);
 391         penpos20 (blot_diameter, 0);
 392
 393         pat := z10{down}
 394                .. z6
 395                ..tension 1.1.. z11{dir (start_angle)};
 396
 397         penpos6 (thinnib, angle (direction 1 of pat) + 90);
 398
 399         % two auxiliary points to simulate `draw' with `penstroke'
 400         z10' = point 0.3 of pat;
 401         penpos10' (1.3 thinnib, angle (direction 0.3 of pat) + 50);
 402
 403         z11' = point 1.5 of pat;
 404         penpos11' (thinnib, angle (direction 1.5 of pat) + 90);
 405
 406         z21l = z20l;
 407         z21r = z9r;
 408
 409         pat := z21l
 410                .. z10l{down}
 411                .. z10'l;
 412
 413         fill z2l{right}
 414              .. z3l
 415              .. z4l{left}
 416              ..tension 1.07.. z5l{up}  % inside curve
 417              .. z7l{up}
 418              ..tension 1.2.. z20r{curl 1}
 419              .. {direction 0 of pat}z20l
 420              -- z8
 421              -- z9r                     % {dir (downstroke_angle + 0)}
 422              ..tension 0.8.. z7r{down}
 423              .. z5r{down}
 424              .. z4r{right}
 425              .. z3r
 426              .. z2r{left}
 427              ..tension .95.. z1r
 428              -- simple_serif (z1r, z1l, 80)
 429              -- z1l
 430              ..tension 0.85.. cycle;
 431
 432         penstroke z21e
 433                   .. z10e{down}
 434                   .. z10'e
 435                   .. z6e
 436                   .. z11'e
 437                   .. z11e{dir (-95)}
 438                   .. z12e{dir (bot_angle)};
 439
 440         fill new_bulb (z12r, bot_angle, z13r, z12l, bot_angle + 180,
 441                        0.45 reduced_ss, 0.38 reduced_ss,
 442                        thinnib + .05 staff_space, 1, -1)
 443              -- cycle;
 444
 445         penlabels (range 1 thru 21);
 446         penlabels (10', 11');
 447
 448         draw_staff (-1, 3, 0);
 449 enddef;
 450
 451
 452 fet_beginchar ("G clef", "G");
 453         draw_gclef (1.0);
 454 fet_endchar;
 455
 456
 457 fet_beginchar ("G clef", "G_change");
 458         draw_gclef (0.8);
 459 fet_endchar;
 460
 461
 462 %%%%
 463 %
 464 % PERCUSSION
 465 %
 466
 467 %
 468 % The percussion clef extent is not coincident with its bbox, since
 469 % the percussion clef needs more space in front than a normal clef.
 470 %
 471
 472 def draw_percussion_clef (expr reduction) =
 473         save reduced_ss, razt;
 474
 475         reduced_ss# = staff_space# * reduction;
 476         define_pixels (reduced_ss);
 477
 478         set_char_box (-.67 reduced_ss#, 2.0 reduced_ss#,
 479                       reduced_ss#, reduced_ss#);
 480
 481         razt := hround (0.45 reduced_ss);
 482
 483         d := d - feta_shift;
 484
 485         draw_block ((-b, -d), (-b + razt, h));
 486         draw_block ((w - razt, -d), (w, h));
 487
 488         draw_staff (-3, 1, 1);
 489 enddef;
 490
 491
 492 fet_beginchar ("percussion clef", "percussion");
 493         draw_percussion_clef (1.0);
 494 fet_endchar;
 495
 496
 497 fet_beginchar ("percussion clef (reduced)", "percussion_change");
 498         draw_percussion_clef (.8);
 499 fet_endchar;
 500
 501
 502 def draw_tab_T (expr pos, siz, slant) =
 503 begingroup;
 504         save vx, vy;
 505         pair vx, vy;
 506
 507         clearxy;
 508
 509         vx = (xpart siz) * dir 0;
 510         vy = (ypart siz) * dir 90;
 511
 512         penpos1 (.75 penh, 100);
 513         z1 = z2 + (1/6 * vx - .15 * vy);
 514         penpos2 (hround (.9 penw), 0);
 515         x2l = hround xpart (pos + .75 vy);
 516         y2l = ypart (pos + .75 vy);
 517         penpos3 (penh, -100);
 518         z3l = pos + .4 vx + vy;
 519         penpos4 (penh, -90);
 520         z4 = -.1 vy + .5 [z3, z5];
 521         penpos5 (.8 penh, -30);
 522         x5r = xpart (pos + siz);
 523         y5l = ypart (pos + siz);
 524
 525         penpos10 (penw, 170);
 526         z10 = pos + .55 vx + .9 vy;
 527         penpos11 (.75 [penh, penw], 170);
 528         z11 = z10 - .5 vy + .025 vx;
 529         penpos12 (penh, 100);
 530         z12l = (xpart .5 [z13, z11], ypart (pos - .025 * siz));
 531         penpos13 (.75 penh, 60);
 532         z13 = pos + .2 vx + .15 vy;
 533
 534         % penlabels (range 1 thru 13);
 535
 536         soft_penstroke (z1e
 537                         ..tension 1.1.. z2e
 538                         .. z3e{right}
 539                         ..tension 1.5.. z4e
 540                         ..z5e)
 541           slanted slant shifted (slant * -ypart pos, 0);
 542
 543         soft_end_penstroke (z10e
 544                             ..tension 1.5.. z11e
 545                             .. z12e
 546                             ..tension 1.1.. z13e{(z13r - z13l) rotated 90})
 547           slanted slant shifted (slant * -ypart pos, 0);
 548 endgroup;
 549 enddef;
 550
 551
 552 def draw_tab_A (expr pos, siz, slant) =
 553 begingroup;
 554         save vx, vy, pat;
 555         pair vx, vy;
 556         path pat;
 557
 558         clearxy;
 559
 560         vx = (xpart siz) * dir 0;
 561         vy = (ypart siz) * dir 90;
 562
 563         penpos1 (.75 penh, -110);
 564         z1r = pos + .07 vy;
 565         penpos2 (penh, -75);
 566         z2r = (.5 [x1, x3], ypart pos);
 567         penpos3 (.25 [penh, penw], -30);
 568         z3 = (.45 [x2, x4], .15 [y2, y4]);
 569         penpos4 (1 [penh, penw], 0);
 570         z4 = pos + .5 vx + .975 vy;
 571
 572         penpos5 (1 [penh, penw], -180);
 573         z5 = z4;
 574         penpos6 (.2 [penh, penw], -150);
 575         z6l = (.8 [x5l, x7l], .9 [y5l, y7l]);
 576         penpos7 (penh,-90);
 577         z7r = (.5 [x6, x8], ypart pos);
 578         penpos8 (.75 penh, -70);
 579         z8r = (xpart (pos + siz), y7r + .075 ypart (siz));
 580
 581         pat := z2
 582                .. z3
 583                .. z4;
 584
 585         penpos10 (penh, angle (direction 1.2 of pat) - 180);
 586         z10 = point 1.2 of pat;
 587         penpos11 (.9 penh, -90);
 588         z11 = .4 [z10, z6] - 0.05 vy;
 589         penpos12 (.75 penh, -75);
 590         z12 = .3 [z11, z6] + 0.02 vy;
 591
 592         % penlabels (range 1 thru 12);
 593
 594         soft_penstroke (z1e{(z1r - z1l) rotated 90}
 595                         .. z2e
 596                         .. z3e
 597                         .. z4e)
 598           slanted slant shifted (slant * -ypart pos, 0);
 599
 600         soft_end_penstroke (z5e
 601                             .. z6e
 602                             .. z7e
 603                             .. z8e{(z8r - z8l) rotated 90})
 604           slanted slant shifted (slant * -ypart pos, 0);
 605
 606         soft_end_penstroke (z10e
 607                             .. z11e
 608                             .. z12e)
 609           slanted slant shifted (slant * -ypart pos, 0);
 610 endgroup;
 611 enddef;
 612
 613
 614 def draw_tab_B (expr pos, siz, slant) =
 615 begingroup;
 616         save vx, vy;
 617         pair vx, vy;
 618
 619         clearxy;
 620
 621         vx = (xpart siz) * dir 0;
 622         vy = (ypart siz) * dir 90;
 623
 624         penpos1 (.75 penh, 100);
 625         z1 = z2 + (.15 * vx - .1 * vy);
 626         penpos2 (hround (.9 penw), 0);
 627         x2l = hround xpart (pos + .75 vy);
 628         y2l = ypart (pos + .75 vy);
 629         penpos3 (penh, -100);
 630         z3l = pos + .4 vx + 1.05 vy;
 631         penpos4 (.8 [penh, penw], -180);
 632         z4 = (xpart (pos + .75 siz), .5 [y3, y5]);
 633         penpos5 (.8 penh, 90);
 634         z5 = (.5 [x10, x4], ypart (pos + .55 siz));
 635
 636         penpos6 (.8 penh, 270);
 637         z6 = z5;
 638         penpos7 (penw, 180);
 639         z7l = (xpart (pos + siz), .5 [y6, y8]);
 640         penpos8 (.8 penh, 45);
 641         z8 = .5 [z12l, z11l] + .15 vx - .05 vy;
 642
 643         penpos10 (.75 [penh, penw], 170);
 644         z10 = pos + .375 vx + vy;
 645         penpos11 (.8 [penh, penw], 150);
 646         z11 = z10 - .5 vy + .04 vx;
 647         penpos12 (penh, 100);
 648         z12l = (xpart .5 [z13, z11], ypart pos);
 649         penpos13 (.75 penh, 60);
 650         z13 = pos + .1 vx + .15 vy;
 651
 652         % penlabels (range 1 thru 13);
 653
 654         soft_penstroke (z1e
 655                         ..tension 1.1.. z2e
 656                         .. z3e
 657                         .. z4e
 658                         ..z5e {left})
 659           slanted slant shifted (slant * -ypart pos, 0);
 660
 661         soft_end_penstroke (z6e{right}
 662                             .. z7e
 663                             .. z8e{(z8r - z8l) rotated 90})
 664           slanted slant shifted (slant * -ypart pos, 0);
 665
 666         soft_end_penstroke (z10e
 667                             ..tension 1.5.. z11e
 668                             .. z12e
 669                             ..tension 1.1.. z13e{(z13r - z13l) rotated 90})
 670           slanted slant shifted (slant * -ypart pos, 0);
 671 endgroup;
 672 enddef;
 673
 674
 675 def draw_tab_clef (expr reduction) =
 676         save reduced_ss, letterheight, penw, penh;
 677
 678         reduced_ss# = staff_space# * reduction;
 679         letterheight# = 1.8 reduced_ss#;
 680         define_pixels (reduced_ss, letterheight);
 681
 682         set_char_box (-.2 reduced_ss#, 2.8 reduced_ss#,
 683                       1.6 letterheight#, 1.6 letterheight#);
 684
 685         penw = .45 reduced_ss;
 686         penh = .2 reduced_ss;
 687
 688         draw_tab_T ((-b + .15 reduced_ss, h - letterheight),
 689                     (2.1 reduced_ss, letterheight), 0.2);
 690         draw_tab_A ((-b - .05 reduced_ss, -.5 letterheight +.15 reduced_ss),
 691                     (2.2 reduced_ss, letterheight), 0.4);
 692         draw_tab_B ((-b + .025 reduced_ss, -d),
 693                     (2.1 reduced_ss, letterheight), 0.25);
 694
 695         draw_staff (-3, 2, 0.5);
 696 enddef;
 697
 698
 699 fet_beginchar ("tab clef", "tab");
 700         draw_tab_clef (1.0);
 701 fet_endchar;
 702
 703
 704 fet_beginchar ("tab clef (reduced)", "tab_change");
 705         draw_tab_clef (.8);
 706 fet_endchar;
 707
 708 fet_endgroup ("clefs");