src/CMakeLists.txt

   1 include(CheckCSourceCompiles)
   2 include(CheckIncludeFiles)
   3 include(CheckFunctionExists)
   4 include(CheckSymbolExists)
   5 include(CheckVariableExists)
   6 include(CheckTypeSize)
   7 include(CheckLibraryExists)
   8 include(CMakeDetermineCCompiler)
   9 include(FindThreads)
  10 include(FindPkgConfig)
  11
  12 include(LighttpdMacros)
  13
  14 add_definitions(-D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE -D_LARGE_FILES)
  15
  16 option(WITH_XATTR "with xattr-support for the stat-cache [default: off]")
  17 option(WITH_MYSQL "with mysql-support for the mod_sql_vhost [default: off]")
  18 # option(WITH_POSTGRESQL "with postgress-support for the mod_sql_vhost [default: off]")
  19 option(WITH_OPENSSL "with openssl-support [default: off]")
  20 option(WITH_PCRE "with regex support [default: on]" ON)
  21 option(WITH_WEBDAV_PROPS "with property-support for mod_webdav [default: off]")
  22 option(WITH_WEBDAV_LOCKS "locks in webdav [default: off]")
  23 option(WITH_BZIP "with bzip2-support for mod_compress [default: off]")
  24 option(WITH_ZLIB "with deflate-support for mod_compress [default: on]" ON)
  25 option(WITH_KRB5 "with Kerberos5-support for the mod_auth [default: off]")
  26 option(WITH_LDAP "with LDAP-support for the mod_auth [default: off]")
  27 option(WITH_LUA "with lua 5.1 for mod_magnet [default: off]")
  28 # option(WITH_VALGRIND "with internal support for valgrind [default: off]")
  29 # option(WITH_KERBEROS5 "use Kerberos5 support with OpenSSL [default: off]")
  30 option(WITH_FAM "fam/gamin for reducing number of stat() calls [default: off]")
  31 option(WITH_GDBM "gdbm storage for mod_trigger_b4_dl [default: off]")
  32 option(WITH_MEMCACHED "memcached storage for mod_trigger_b4_dl [default: off]")
  33 option(WITH_LIBEV "libev support for fdevent handlers [default: off]")
  34 option(WITH_LIBUNWIND "with libunwind to print backtraces in asserts [default: off]")
  35 option(WITH_GEOIP "with GeoIP-support mod_geoip [default: off]")
  36
  37 if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  38         option(BUILD_EXTRA_WARNINGS "extra warnings")
  39
  40         if(BUILD_EXTRA_WARNINGS)
  41                 set(WARN_CFLAGS "-g -g2 -Wall -Wmissing-declarations -Wdeclaration-after-statement -Wcast-align -Wsign-compare -Wnested-externs -Wpointer-arith -D_FORTIFY_SOURCE=2 -fstack-protector --param=ssp-buffer-size=4 -Wformat -Werror=format-security")
  42                 set(WARN_LDFLAGS "-Wl,--as-needed")
  43                 # -Werror -Wbad-function-cast -Wmissing-prototypes
  44         endif()
  45 endif()
  46
  47 option(BUILD_STATIC "build a static lighttpd with all modules added")
  48
  49 if(BUILD_STATIC)
  50         set(LIGHTTPD_STATIC 1)
  51 elseif(APPLE)
  52         set(CMAKE_SHARED_MODULE_PREFIX "")
  53 else()
  54         set(CMAKE_SHARED_LIBRARY_PREFIX "")
  55 endif()
  56
  57 if(WITH_LIBEV)
  58         find_package(LibEV REQUIRED)
  59         set(HAVE_LIBEV 1)
  60 endif()
  61
  62 if(WITH_LIBUNWIND)
  63         pkg_check_modules(LIBUNWIND REQUIRED libunwind)
  64         set(HAVE_LIBUNWIND 1)
  65 endif()
  66
  67 if(WITH_WEBDAV_PROPS)
  68         set(WITH_XML 1)
  69         set(WITH_SQLITE3 1)
  70         set(WITH_UUID 1)
  71 endif()
  72
  73 check_include_files(sys/devpoll.h HAVE_SYS_DEVPOLL_H)
  74 check_include_files(sys/epoll.h HAVE_SYS_EPOLL_H)
  75 check_include_files(sys/event.h HAVE_SYS_EVENT_H)
  76 check_include_files(sys/mman.h HAVE_SYS_MMAN_H)
  77 check_include_files(sys/poll.h HAVE_SYS_POLL_H)
  78 check_include_files(sys/port.h HAVE_SYS_PORT_H)
  79 check_include_files(sys/prctl.h HAVE_SYS_PRCTL_H)
  80 check_include_files(sys/resource.h HAVE_SYS_RESOURCE_H)
  81 check_include_files(sys/sendfile.h HAVE_SYS_SENDFILE_H)
  82 check_include_files(sys/select.h HAVE_SYS_SELECT_H)
  83 check_include_files(sys/types.h HAVE_SYS_TYPES_H)
  84 check_include_files(sys/uio.h HAVE_SYS_UIO_H)
  85 check_include_files(sys/un.h HAVE_SYS_UN_H)
  86 check_include_files(sys/wait.h HAVE_SYS_WAIT_H)
  87 check_include_files(sys/time.h HAVE_SYS_TIME_H)
  88 check_include_files(unistd.h HAVE_UNISTD_H)
  89 check_include_files(pthread.h HAVE_PTHREAD_H)
  90 check_include_files(getopt.h HAVE_GETOPT_H)
  91 check_include_files(inttypes.h HAVE_INTTYPES_H)
  92 check_include_files(poll.h HAVE_POLL_H)
  93 check_include_files(pwd.h HAVE_PWD_H)
  94 check_include_files(stddef.h HAVE_STDDEF_H)
  95 check_include_files(stdint.h HAVE_STDINT_H)
  96 check_include_files(syslog.h HAVE_SYSLOG_H)
  97
  98 # check for fastcgi lib, for the tests only
  99 check_include_files(fastcgi.h HAVE_FASTCGI_H)
 100 check_include_files(fastcgi/fastcgi.h HAVE_FASTCGI_FASTCGI_H)
 101
 102 # will be needed for auth
 103 check_include_files(crypt.h HAVE_CRYPT_H)
 104 # check if we need libcrypt for crypt_r()
 105 check_library_exists(crypt crypt_r "" HAVE_LIBCRYPT_CRYPT_R)
 106 if(HAVE_LIBCRYPT_CRYPT_R)
 107         set(HAVE_CRYPT_R 1)
 108         set(HAVE_LIBCRYPT 1)
 109 else()
 110         check_library_exists(crypt crypt "" HAVE_LIBCRYPT)
 111 endif()
 112 check_function_exists(crypt_r HAVE_CRYPT_R)
 113 check_function_exists(crypt HAVE_CRYPT)
 114
 115 check_include_files(sys/inotify.h HAVE_SYS_INOTIFY_H)
 116 if(HAVE_SYS_INOTIFY_H)
 117         check_function_exists(inotify_init HAVE_INOTIFY_INIT)
 118 endif()
 119
 120 set(CMAKE_EXTRA_INCLUDE_FILES sys/socket.h)
 121 check_type_size(socklen_t HAVE_SOCKLEN_T)
 122 set(CMAKE_EXTRA_INCLUDE_FILES)
 123
 124 check_include_files(linux/random.h HAVE_LINUX_RANDOM_H)
 125 set(CMAKE_EXTRA_INCLUDE_FILES linux/random.h)
 126 check_function_exists(getrandom HAVE_GETRANDOM)
 127 set(CMAKE_EXTRA_INCLUDE_FILES)
 128
 129 check_type_size(long SIZEOF_LONG)
 130 check_type_size(off_t SIZEOF_OFF_T)
 131
 132 check_function_exists(arc4random_buf HAVE_ARC4RANDOM_BUF)
 133 check_function_exists(chroot HAVE_CHROOT)
 134 check_function_exists(epoll_ctl HAVE_EPOLL_CTL)
 135 check_function_exists(fork HAVE_FORK)
 136 check_function_exists(getentropy HAVE_GETENTROPY)
 137 check_function_exists(getloadavg HAVE_GETLOADAVG)
 138 check_function_exists(getrlimit HAVE_GETRLIMIT)
 139 check_function_exists(getuid HAVE_GETUID)
 140 check_function_exists(gmtime_r HAVE_GMTIME_R)
 141 check_function_exists(inet_ntop HAVE_INET_NTOP)
 142 check_function_exists(jrand48 HAVE_JRAND48)
 143 check_function_exists(kqueue HAVE_KQUEUE)
 144 check_function_exists(localtime_r HAVE_LOCALTIME_R)
 145 check_function_exists(lstat HAVE_LSTAT)
 146 check_function_exists(madvise HAVE_MADVISE)
 147 check_function_exists(memcpy HAVE_MEMCPY)
 148 check_function_exists(memset HAVE_MEMSET)
 149 check_function_exists(mmap HAVE_MMAP)
 150 check_function_exists(pathconf HAVE_PATHCONF)
 151 check_function_exists(poll HAVE_POLL)
 152 check_function_exists(port_create HAVE_PORT_CREATE)
 153 check_function_exists(prctl HAVE_PRCTL)
 154 check_function_exists(pread HAVE_PREAD)
 155 check_function_exists(posix_fadvise HAVE_POSIX_FADVISE)
 156 check_function_exists(select HAVE_SELECT)
 157 check_function_exists(sendfile HAVE_SENDFILE)
 158 check_function_exists(send_file HAVE_SEND_FILE)
 159 check_function_exists(sendfile64 HAVE_SENDFILE64)
 160 check_function_exists(sendfilev HAVE_SENDFILEV)
 161 check_function_exists(sigaction HAVE_SIGACTION)
 162 check_function_exists(signal HAVE_SIGNAL)
 163 check_function_exists(sigtimedwait HAVE_SIGTIMEDWAIT)
 164 check_function_exists(srandom HAVE_SRANDOM)
 165 check_function_exists(strptime HAVE_STRPTIME)
 166 check_function_exists(syslog HAVE_SYSLOG)
 167 check_function_exists(writev HAVE_WRITEV)
 168 check_function_exists(inet_aton HAVE_INET_ATON)
 169 check_function_exists(issetugid HAVE_ISSETUGID)
 170 check_function_exists(inet_pton HAVE_INET_PTON)
 171 check_function_exists(memset_s HAVE_MEMSET_S)
 172 check_function_exists(explicit_bzero HAVE_EXPLICIT_BZERO)
 173 check_symbol_exists(clock_gettime "time.h" HAVE_CLOCK_GETTIME)
 174 if (NOT HAVE_CLOCK_GETTIME)
 175         check_library_exists(rt clock_gettime "time.h" HAVE_CLOCK_GETTIME)
 176 endif()
 177 check_c_source_compiles("
 178         #include <sys/types.h>
 179         #include <sys/socket.h>
 180         #include <netinet/in.h>
 181
 182         int main() {
 183                 struct sockaddr_in6 s; struct in6_addr t=in6addr_any; int i=AF_INET6; s; t.s6_addr[0] = 0;
 184                 return 0;
 185         }" HAVE_IPV6)
 186 check_c_source_compiles("
 187         __attribute__((weak)) void __dummy(void *x) { }
 188         int main() {
 189                 void *x;
 190                 __dummy(x);
 191         }
 192         " HAVE_WEAK_SYMBOLS)
 193 check_c_source_compiles("
 194         #include <time.h>
 195         int main(void) {
 196                 struct tm t;
 197                 t.tm_gmtoff = 0;
 198                 return 0;
 199         }
 200         " HAVE_STRUCT_TM_GMTOFF)
 201
 202 ## refactor me
 203 macro(XCONFIG _package _include_DIR _link_DIR _link_FLAGS _cflags)
 204 # reset the variables at the beginning
 205         set(${_include_DIR})
 206         set(${_link_DIR})
 207         set(${_link_FLAGS})
 208         set(${_cflags})
 209
 210         find_program(${_package}CONFIG_EXECUTABLE NAMES ${_package} PATHS /usr/local/bin )
 211
 212         # if pkg-config has been found
 213         if(${_package}CONFIG_EXECUTABLE)
 214                 set(XCONFIG_EXECUTABLE "${${_package}CONFIG_EXECUTABLE}")
 215                 message(STATUS "found ${_package}: ${XCONFIG_EXECUTABLE}")
 216
 217                 exec_program(${XCONFIG_EXECUTABLE} ARGS --libs OUTPUT_VARIABLE __link_FLAGS)
 218                 string(REPLACE "\n" "" ${_link_FLAGS} ${__link_FLAGS})
 219                 exec_program(${XCONFIG_EXECUTABLE} ARGS --cflags OUTPUT_VARIABLE __cflags)
 220                 string(REPLACE "\n" "" ${_cflags} ${__cflags})
 221         else()
 222                 message(STATUS "found ${_package}: no")
 223         endif()
 224 endmacro(XCONFIG _package _include_DIR _link_DIR _link_FLAGS _cflags)
 225
 226 if(WITH_XATTR)
 227         check_include_files(attr/attributes.h HAVE_ATTR_ATTRIBUTES_H)
 228         if(HAVE_ATTR_ATTRIBUTES_H)
 229                 check_library_exists(attr attr_get "" HAVE_XATTR)
 230         endif()
 231 else()
 232         unset(HAVE_ATTR_ATTRIBUTES_H)
 233         unset(HAVE_XATTR)
 234 endif()
 235
 236 if(WITH_MYSQL)
 237         xconfig(mysql_config MYSQL_INCDIR MYSQL_LIBDIR MYSQL_LDFLAGS MYSQL_CFLAGS)
 238
 239         set(CMAKE_REQUIRED_INCLUDES /usr/include/mysql)
 240         check_include_files(mysql.h HAVE_MYSQL_H)
 241         set(CMAKE_REQUIRED_INCLUDES)
 242         if(HAVE_MYSQL_H)
 243                 check_library_exists(mysqlclient mysql_real_connect "" HAVE_MYSQL)
 244         endif()
 245 else()
 246         unset(HAVE_MYSQL_H)
 247         unset(HAVE_MYSQL)
 248 endif()
 249
 250 if(WITH_OPENSSL)
 251         if(APPLE)
 252                 set(CMAKE_REQUIRED_INCLUDES /opt/local/include)
 253         endif()
 254         check_include_files(openssl/ssl.h HAVE_OPENSSL_SSL_H)
 255         if(APPLE)
 256                 set(CMAKE_REQUIRED_INCLUDES)
 257         endif()
 258         if(HAVE_OPENSSL_SSL_H)
 259                 check_library_exists(crypto BIO_f_base64 "" HAVE_LIBCRYPTO)
 260                 if(HAVE_LIBCRYPTO)
 261                         check_library_exists(ssl SSL_new "" HAVE_LIBSSL)
 262                 endif()
 263         endif()
 264 else()
 265         unset(HAVE_OPENSSL_SSL_H)
 266         unset(HAVE_LIBCRYPTO)
 267         unset(HAVE_LIBSSL)
 268 endif()
 269
 270 if(WITH_PCRE)
 271         ## if we have pcre-config, use it
 272         xconfig(pcre-config PCRE_INCDIR PCRE_LIBDIR PCRE_LDFLAGS PCRE_CFLAGS)
 273         if(PCRE_LDFLAGS OR PCRE_CFLAGS)
 274                 message(STATUS "found pcre at: LDFLAGS: ${PCRE_LDFLAGS} CFLAGS: ${PCRE_CFLAGS}")
 275
 276                 if(NOT PCRE_CFLAGS STREQUAL "\n")
 277                         ## if it is empty we'll get newline returned
 278                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${PCRE_CFLAGS}")
 279                 endif()
 280
 281                 set(HAVE_PCRE_H 1)
 282                 set(HAVE_LIBPCRE 1)
 283         else()
 284                 if(NOT WIN32)
 285                         check_include_files(pcre.h HAVE_PCRE_H)
 286                         check_library_exists(pcre pcre_exec "" HAVE_LIBPCRE)
 287                         set(PCRE_LDFLAGS -lpcre)
 288                 else()
 289                         find_path(PCRE_INCLUDE_DIR pcre.h
 290                         /usr/local/include
 291                         /usr/include
 292                         )
 293
 294                         set(PCRE_NAMES pcre)
 295                         find_library(PCRE_LIBRARY
 296                         NAMES ${PCRE_NAMES}
 297                         PATHS /usr/lib /usr/local/lib
 298                         )
 299
 300                         if(PCRE_INCLUDE_DIR AND PCRE_LIBRARY)
 301                                 set(CMAKE_REQUIRED_INCLUDES ${PCRE_INCLUDE_DIR})
 302                                 set(CMAKE_REQUIRED_LIBRARIES ${PCRE_LIBRARY})
 303                                 check_include_files(pcre.h HAVE_PCRE_H)
 304                                 check_library_exists(pcre pcre_exec "" HAVE_LIBPCRE)
 305                                 set(CMAKE_REQUIRED_INCLUDES)
 306                                 set(CMAKE_REQUIRED_LIBRARIES)
 307                                 include_directories(${PCRE_INCLUDE_DIR})
 308                         endif()
 309                 endif()
 310         endif()
 311
 312         if(NOT HAVE_PCRE_H)
 313                 message(FATAL_ERROR "pcre.h couldn't be found")
 314         endif()
 315         if(NOT HAVE_LIBPCRE)
 316                 message(FATAL_ERROR "libpcre couldn't be found")
 317         endif()
 318 else()
 319         unset(HAVE_PCRE_H)
 320         unset(HAVE_LIBPCRE)
 321 endif()
 322
 323
 324 if(WITH_XML)
 325         xconfig(xml2-config XML2_INCDIR XML2_LIBDIR XML2_LDFLAGS XML2_CFLAGS)
 326         if(XML2_LDFLAGS OR XML2_CFLAGS)
 327                 message(STATUS "found xml2 at: LDFLAGS: ${XML2_LDFLAGS} CFLAGS: ${XML2_CFLAGS}")
 328
 329                 ## if it is empty we'll get newline returned
 330                 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${XML2_CFLAGS}")
 331
 332                 check_include_files(libxml/tree.h HAVE_LIBXML_H)
 333
 334                 set(CMAKE_REQUIRED_FLAGS ${XML2_LDFLAGS})
 335                 check_library_exists(xml2 xmlParseChunk "" HAVE_LIBXML)
 336                 set(CMAKE_REQUIRED_FLAGS)
 337         else()
 338                 check_include_files(libxml.h HAVE_LIBXML_H)
 339                 check_library_exists(xml2 xmlParseChunk "" HAVE_LIBXML)
 340         endif()
 341
 342         if(NOT HAVE_LIBXML_H)
 343                 message(FATAL_ERROR "libxml/tree.h couldn't be found")
 344         endif()
 345         if(NOT HAVE_LIBXML)
 346                 message(FATAL_ERROR "libxml2 couldn't be found")
 347         endif()
 348 else()
 349         unset(HAVE_LIBXML_H)
 350         unset(HAVE_LIBXML)
 351 endif()
 352
 353 if(WITH_SQLITE3)
 354         check_include_files(sqlite3.h HAVE_SQLITE3_H)
 355         check_library_exists(sqlite3 sqlite3_reset "" HAVE_SQLITE3)
 356 else()
 357         unset(HAVE_SQLITE3_H)
 358         unset(HAVE_SQLITE3)
 359 endif()
 360
 361 if(WITH_UUID)
 362         check_include_files(uuid/uuid.h HAVE_UUID_UUID_H)
 363         check_library_exists(uuid uuid_generate "" NEED_LIBUUID)
 364         if(NOT NEED_LIBUUID)
 365                 check_function_exists(uuid_generate HAVE_LIBUUID)
 366         else()
 367                 set(HAVE_LIBUUID 1)
 368         endif()
 369 else()
 370         unset(HAVE_UUID_UUID_H)
 371         unset(NEED_LIBUUID)
 372         unset(HAVE_LIBUUID)
 373 endif()
 374
 375 if(WITH_ZLIB)
 376         if(NOT WIN32)
 377                 check_include_files(zlib.h HAVE_ZLIB_H)
 378                 check_library_exists(z deflate "" HAVE_LIBZ)
 379                 set(ZLIB_LIBRARY z)
 380         else()
 381                 find_path(ZLIB_INCLUDE_DIR zlib.h
 382                         /usr/local/include
 383                         /usr/include
 384                 )
 385
 386                 set(ZLIB_NAMES z zlib zdll)
 387                         find_library(ZLIB_LIBRARY
 388                         NAMES ${ZLIB_NAMES}
 389                         PATHS /usr/lib /usr/local/lib
 390                 )
 391
 392                 if(ZLIB_INCLUDE_DIR AND ZLIB_LIBRARY)
 393                         set(CMAKE_REQUIRED_INCLUDES ${ZLIB_INCLUDE_DIR})
 394                         set(CMAKE_REQUIRED_LIBRARIES ${ZLIB_LIBRARY})
 395                         get_filename_component(ZLIB_NAME ${ZLIB_LIBRARY} NAME)
 396                         check_include_files(zlib.h HAVE_ZLIB_H)
 397                         check_library_exists(${ZLIB_NAME} deflate "" HAVE_LIBZ)
 398                         set(CMAKE_REQUIRED_INCLUDES)
 399                         set(CMAKE_REQUIRED_LIBRARIES)
 400                         include_directories(${ZLIB_INCLUDE_DIR})
 401                 endif()
 402         endif()
 403 else()
 404         unset(HAVE_ZLIB_H)
 405         unset(HAVE_LIBZ)
 406         unset(ZLIB_INCLUDE_DIR)
 407         unset(ZLIB_LIBRARY)
 408 endif()
 409
 410 if(WITH_BZIP)
 411         check_include_files(bzlib.h HAVE_BZLIB_H)
 412         check_library_exists(bz2 BZ2_bzCompress "" HAVE_LIBBZ2)
 413 else()
 414         unset(HAVE_BZLIB_H)
 415         unset(HAVE_LIBBZ2)
 416 endif()
 417
 418 if(WITH_LDAP)
 419         check_include_files(ldap.h HAVE_LDAP_H)
 420         check_library_exists(ldap ldap_bind "" HAVE_LIBLDAP)
 421         check_include_files(lber.h HAVE_LBER_H)
 422         check_library_exists(lber ber_printf "" HAVE_LIBLBER)
 423         set(LDAP_DEPRECATED 1) # Using deprecated ldap api
 424 else()
 425         unset(HAVE_LDAP_H)
 426         unset(HAVE_LIBLDAP)
 427         unset(HAVE_LBER_H)
 428         unset(HAVE_LIBLBER)
 429 endif()
 430
 431 if(WITH_LUA)
 432         pkg_search_module(LUA REQUIRED lua5.3 lua-5.3 lua5.2 lua-5.2 lua5.1 lua-5.1 lua)
 433         message(STATUS "found lua at: INCDIR: ${LUA_INCLUDE_DIRS} LIBDIR: ${LUA_LIBRARY_DIRS} LDFLAGS: ${LUA_LDFLAGS} CFLAGS: ${LUA_CFLAGS}")
 434         set(HAVE_LIBLUA 1 "Have liblua")
 435         set(HAVE_LUA_H  1 "Have liblua header")
 436 else()
 437         unset(HAVE_LIBLUA)
 438         unset(HAVE_LUA_H)
 439 endif()
 440
 441 if(WITH_FAM)
 442         check_include_files(fam.h HAVE_FAM_H)
 443         check_library_exists(fam FAMOpen2 "" HAVE_LIBFAM)
 444         if(HAVE_LIBFAM)
 445                 set(CMAKE_REQUIRED_LIBRARIES fam)
 446                 check_function_exists(FAMNoExists HAVE_FAMNOEXISTS)
 447         endif()
 448 else()
 449         unset(HAVE_FAM_H)
 450         unset(HAVE_LIBFAM)
 451         unset(HAVE_FAMNOEXISTS)
 452 endif()
 453
 454 if(WITH_GDBM)
 455         check_include_files(gdbm.h HAVE_GDBM_H)
 456         check_library_exists(gdbm gdbm_open "" HAVE_GDBM)
 457 else()
 458         unset(HAVE_GDBM_H)
 459         unset(HAVE_GDBM)
 460 endif()
 461
 462 if(WITH_MEMCACHED)
 463         check_include_files(libmemcached/memcached.h HAVE_LIBMEMCACHED_MEMCACHED_H)
 464         check_library_exists(memcached memcached "" HAVE_LIBMEMCACHED)
 465         if(HAVE_LIBMEMCACHED_MEMCACHED_H AND HAVE_LIBMEMCACHED)
 466                 set(USE_MEMCACHED 1)
 467         else()
 468                 message(FATAL_ERROR "didn't find libmemcached")
 469         endif()
 470 endif()
 471
 472 if(WITH_GEOIP)
 473         check_library_exists(geoip GeoIP_country_name_by_addr "" HAVE_GEOIP)
 474 endif()
 475
 476 if(NOT BUILD_STATIC)
 477         check_include_files(dlfcn.h HAVE_DLFCN_H)
 478 else()
 479         unset(HAVE_DLFCN_H)
 480 endif()
 481
 482 if(HAVE_DLFCN_H)
 483         check_library_exists(dl dlopen "" HAVE_LIBDL)
 484 else()
 485         unset(HAVE_LIBDL)
 486 endif()
 487
 488 set(LIGHTTPD_VERSION_ID 10400)
 489 set(PACKAGE_NAME "${CMAKE_PROJECT_NAME}")
 490 set(PACKAGE_VERSION "${CPACK_PACKAGE_VERSION}")
 491
 492 if(NOT SBINDIR)
 493         set(SBINDIR "sbin")
 494 endif()
 495
 496 if(NOT LIGHTTPD_MODULES_DIR)
 497         set(LIGHTTPD_MODULES_DIR "lib${LIB_SUFFIX}/lighttpd")
 498 endif()
 499
 500 if(NOT WIN32)
 501         set(LIGHTTPD_LIBRARY_DIR "${CMAKE_INSTALL_PREFIX}/${LIGHTTPD_MODULES_DIR}")
 502 else()
 503         ## We use relative path in windows
 504         set(LIGHTTPD_LIBRARY_DIR "lib")
 505 endif()
 506
 507 ## Write out config.h
 508 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
 509
 510 add_definitions(-DHAVE_CONFIG_H)
 511
 512 include_directories(${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
 513
 514 set(COMMON_SRC
 515         base64.c buffer.c log.c
 516         keyvalue.c chunk.c
 517         http_chunk.c stream.c fdevent.c
 518         stat_cache.c plugin.c joblist.c etag.c array.c
 519         data_string.c data_array.c
 520         data_integer.c md5.c data_fastcgi.c
 521         vector.c
 522         fdevent_select.c fdevent_libev.c
 523         fdevent_poll.c fdevent_linux_sysepoll.c
 524         fdevent_solaris_devpoll.c fdevent_solaris_port.c
 525         fdevent_freebsd_kqueue.c
 526         data_config.c
 527         inet_ntop_cache.c crc32.c
 528         connections-glue.c
 529         configfile-glue.c
 530         http-header-glue.c
 531         http_auth.c
 532         splaytree.c
 533         rand.c
 534         status_counter.c safe_memclear.c
 535 )
 536
 537 if(WIN32)
 538         message(STATUS "Adding local getopt implementation.")
 539         set(COMMON_SRC ${COMMON_SRC} xgetopt.c)
 540 endif()
 541
 542 add_executable(lemon lemon.c)
 543
 544 ## Build parsers by using lemon...
 545 lemon_parser(configparser.y)
 546 lemon_parser(mod_ssi_exprparser.y)
 547
 548 set(L_INSTALL_TARGETS)
 549
 550 add_executable(lighttpd-angel lighttpd-angel.c)
 551 set(L_INSTALL_TARGETS ${L_INSTALL_TARGETS} lighttpd-angel)
 552 add_target_properties(lighttpd-angel COMPILE_FLAGS "-DSBIN_DIR=\\\\\"${CMAKE_INSTALL_PREFIX}/${SBINDIR}\\\\\"")
 553
 554 add_executable(lighttpd
 555         server.c
 556         response.c
 557         connections.c
 558         network.c
 559         network_darwin_sendfile.c
 560         network_freebsd_sendfile.c
 561         network_linux_sendfile.c
 562         network_openssl.c
 563         network_solaris_sendfilev.c
 564         network_write.c
 565         network_write_mmap.c
 566         network_write_no_mmap.c
 567         network_writev.c
 568         configfile.c
 569         configparser.c
 570         request.c
 571         proc_open.c
 572         ${COMMON_SRC}
 573 )
 574 set(L_INSTALL_TARGETS ${L_INSTALL_TARGETS} lighttpd)
 575
 576 add_and_install_library(mod_access mod_access.c)
 577 add_and_install_library(mod_accesslog mod_accesslog.c)
 578 add_and_install_library(mod_alias mod_alias.c)
 579 add_and_install_library(mod_auth "mod_auth.c")
 580 add_and_install_library(mod_authn_file "mod_authn_file.c")
 581 if(NOT WIN32)
 582         add_and_install_library(mod_cgi mod_cgi.c)
 583 endif()
 584 add_and_install_library(mod_compress mod_compress.c)
 585 add_and_install_library(mod_deflate mod_deflate.c)
 586 add_and_install_library(mod_dirlisting mod_dirlisting.c)
 587 add_and_install_library(mod_evasive mod_evasive.c)
 588 add_and_install_library(mod_evhost mod_evhost.c)
 589 add_and_install_library(mod_expire mod_expire.c)
 590 add_and_install_library(mod_extforward mod_extforward.c)
 591 add_and_install_library(mod_fastcgi mod_fastcgi.c)
 592 add_and_install_library(mod_flv_streaming mod_flv_streaming.c)
 593 add_and_install_library(mod_indexfile mod_indexfile.c)
 594 add_and_install_library(mod_proxy mod_proxy.c)
 595 add_and_install_library(mod_redirect mod_redirect.c)
 596 add_and_install_library(mod_rewrite mod_rewrite.c)
 597 add_and_install_library(mod_rrdtool mod_rrdtool.c)
 598 add_and_install_library(mod_scgi mod_scgi.c)
 599 add_and_install_library(mod_secdownload mod_secdownload.c)
 600 add_and_install_library(mod_setenv mod_setenv.c)
 601 add_and_install_library(mod_simple_vhost mod_simple_vhost.c)
 602 add_and_install_library(mod_ssi "mod_ssi_exprparser.c;mod_ssi_expr.c;mod_ssi.c")
 603 add_and_install_library(mod_staticfile mod_staticfile.c)
 604 add_and_install_library(mod_status mod_status.c)
 605 add_and_install_library(mod_uploadprogress mod_uploadprogress.c)
 606 add_and_install_library(mod_userdir mod_userdir.c)
 607 add_and_install_library(mod_usertrack mod_usertrack.c)
 608 add_and_install_library(mod_webdav mod_webdav.c)
 609
 610 add_executable(test_buffer
 611         test_buffer.c
 612         buffer.c
 613 )
 614 add_test(NAME test_buffer COMMAND test_buffer)
 615
 616 add_executable(test_base64
 617         test_base64.c
 618         buffer.c
 619         base64.c
 620 )
 621 add_test(NAME test_base64 COMMAND test_base64)
 622
 623 add_executable(test_configfile
 624         test_configfile.c
 625         buffer.c
 626         array.c
 627         data_string.c
 628         keyvalue.c
 629         vector.c
 630         log.c
 631 )
 632 add_test(NAME test_configfile COMMAND test_configfile)
 633
 634 if(HAVE_PCRE_H)
 635         target_link_libraries(lighttpd ${PCRE_LDFLAGS})
 636         add_target_properties(lighttpd COMPILE_FLAGS ${PCRE_CFLAGS})
 637         target_link_libraries(mod_rewrite ${PCRE_LDFLAGS})
 638         add_target_properties(mod_rewrite COMPILE_FLAGS ${PCRE_CFLAGS})
 639         target_link_libraries(mod_dirlisting ${PCRE_LDFLAGS})
 640         add_target_properties(mod_dirlisting COMPILE_FLAGS ${PCRE_CFLAGS})
 641         target_link_libraries(mod_redirect ${PCRE_LDFLAGS})
 642         add_target_properties(mod_redirect COMPILE_FLAGS ${PCRE_CFLAGS})
 643         target_link_libraries(test_configfile ${PCRE_LDFLAGS})
 644         add_target_properties(test_configfile COMPILE_FLAGS ${PCRE_CFLAGS})
 645 endif()
 646
 647 if(WITH_PCRE AND (WITH_MEMCACHED OR WITH_GDBM))
 648         add_and_install_library(mod_trigger_b4_dl mod_trigger_b4_dl.c)
 649         target_link_libraries(mod_trigger_b4_dl ${PCRE_LDFLAGS})
 650         add_target_properties(mod_trigger_b4_dl COMPILE_FLAGS ${PCRE_CFLAGS})
 651 endif()
 652
 653 if(WITH_LUA)
 654         add_and_install_library(mod_magnet "mod_magnet.c;mod_magnet_cache.c")
 655         target_link_libraries(mod_magnet ${LUA_LDFLAGS})
 656         add_target_properties(mod_magnet COMPILE_FLAGS ${LUA_CFLAGS})
 657
 658         add_and_install_library(mod_cml "mod_cml.c;mod_cml_lua.c;mod_cml_funcs.c")
 659         target_link_libraries(mod_cml ${LUA_LDFLAGS})
 660         add_target_properties(mod_cml COMPILE_FLAGS ${LUA_CFLAGS})
 661 endif()
 662
 663 if(WITH_GEOIP)
 664         add_and_install_library(mod_geoip mod_geoip.c)
 665         target_link_libraries(mod_geoip GeoIP)
 666 endif()
 667
 668 if(HAVE_MYSQL_H AND HAVE_MYSQL)
 669         add_and_install_library(mod_mysql_vhost "mod_mysql_vhost.c")
 670         target_link_libraries(mod_mysql_vhost mysqlclient)
 671         include_directories(/usr/include/mysql)
 672
 673         add_and_install_library(mod_authn_mysql "mod_authn_mysql.c")
 674         set(L_MOD_AUTHN_MYSQL)
 675         if(HAVE_LIBCRYPT)
 676                 set(L_MOD_AUTHN_MYSQL ${L_MOD_AUTHN_MYSQL} crypt)
 677         endif()
 678         target_link_libraries(mod_authn_mysql ${L_MOD_AUTHN_MYSQL} mysqlclient)
 679 endif()
 680
 681 set(L_MOD_WEBDAV)
 682 if(HAVE_SQLITE3_H)
 683         set(L_MOD_WEBDAV ${L_MOD_WEBDAV} sqlite3)
 684 endif()
 685 if(HAVE_LIBXML_H)
 686         target_link_libraries(mod_webdav ${XML2_LDFLAGS})
 687 endif()
 688 if(HAVE_UUID_H)
 689         if(NEED_LIBUUID)
 690                 set(L_MOD_WEBDAV ${L_MOD_WEBDAV} uuid)
 691         endif()
 692 endif()
 693
 694 target_link_libraries(mod_webdav ${L_MOD_WEBDAV})
 695
 696 set(L_MOD_AUTHN_FILE)
 697 if(HAVE_LIBCRYPT)
 698         set(L_MOD_AUTHN_FILE ${L_MOD_AUTHN_FILE} crypt)
 699 endif()
 700 target_link_libraries(mod_authn_file ${L_MOD_AUTHN_FILE})
 701
 702 if(WITH_KRB5)
 703         check_library_exists(krb5 krb5_init_context "" HAVE_KRB5)
 704         add_and_install_library(mod_authn_gssapi "mod_authn_gssapi.c")
 705         set(L_MOD_AUTHN_GSSAPI ${L_MOD_AUTHN_GSSAPI} krb5 gssapi_krb5)
 706         target_link_libraries(mod_authn_gssapi ${L_MOD_AUTHN_GSSAPI})
 707 endif()
 708
 709 if(WITH_LDAP)
 710         add_and_install_library(mod_authn_ldap "mod_authn_ldap.c")
 711         set(L_MOD_AUTHN_LDAP ${L_MOD_AUTHN_LDAP} ldap lber)
 712         target_link_libraries(mod_authn_ldap ${L_MOD_AUTHN_LDAP})
 713 endif()
 714
 715 if(HAVE_ZLIB_H)
 716         if(HAVE_BZLIB_H)
 717                 target_link_libraries(mod_compress ${ZLIB_LIBRARY} bz2)
 718                 target_link_libraries(mod_deflate ${ZLIB_LIBRARY} bz2)
 719         else()
 720                 target_link_libraries(mod_compress ${ZLIB_LIBRARY})
 721                 target_link_libraries(mod_deflate ${ZLIB_LIBRARY})
 722         endif()
 723 endif()
 724
 725 if(HAVE_LIBFAM)
 726         target_link_libraries(lighttpd fam)
 727 endif()
 728
 729 if(HAVE_GDBM_H)
 730         target_link_libraries(mod_trigger_b4_dl gdbm)
 731 endif()
 732
 733 if(WITH_MEMCACHED)
 734         target_link_libraries(mod_trigger_b4_dl memcached)
 735 endif()
 736
 737 if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 738         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu99 -Wall -g -Wshadow -W -pedantic ${WARN_CFLAGS}")
 739         set(CMAKE_C_FLAGS_RELEASE        "${CMAKE_C_FLAGS_RELEASE}     -O2")
 740         set(CMAKE_C_FLAGS_DEBUG          "${CMAKE_C_FLAGS_DEBUG}       -O0")
 741         set(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_WITHDEBINFO} -O2")
 742         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${WARN_LDFLAGS}")
 743         set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${WARN_LDFLAGS}")
 744 endif()
 745
 746 if((NOT APPLE) OR CMAKE_C_COMPILER_ID MATCHES "GNU")
 747         add_target_properties(lighttpd LINK_FLAGS "-Wl,-export-dynamic")
 748 endif()
 749
 750 set_target_properties(lighttpd PROPERTIES CMAKE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 751
 752 if(WIN32)
 753         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DNVALGRIND")
 754         add_target_properties(lighttpd COMPILE_FLAGS "-DLI_DECLARE_EXPORTS")
 755         target_link_libraries(lighttpd ws2_32)
 756         target_link_libraries(mod_proxy ws2_32)
 757         target_link_libraries(mod_fcgi ws2_32)
 758         target_link_libraries(mod_scgi ws2_32)
 759         target_link_libraries(mod_ssi ws2_32)
 760
 761         if(MINGW)
 762                 target_link_libraries(lighttpd msvcr70)
 763                 add_target_properties(lighttpd LINK_FLAGS "-Wl,-subsystem,console")
 764         endif()
 765 endif()
 766
 767 if(NOT BUILD_STATIC)
 768         if(HAVE_LIBDL)
 769                 target_link_libraries(lighttpd dl)
 770         endif()
 771 endif()
 772
 773 if(HAVE_LIBSSL AND HAVE_LIBCRYPTO)
 774         target_link_libraries(lighttpd ssl)
 775         target_link_libraries(lighttpd crypto)
 776 endif()
 777
 778 if(WITH_LIBEV)
 779         target_link_libraries(lighttpd ${LIBEV_LDFLAGS})
 780         add_target_properties(lighttpd COMPILE_FLAGS ${LIBEV_CFLAGS})
 781 endif()
 782
 783 if(WITH_LIBUNWIND)
 784         target_link_libraries(lighttpd ${LIBUNWIND_LDFLAGS})
 785         add_target_properties(lighttpd COMPILE_FLAGS ${LIBUNWIND_CFLAGS})
 786
 787         target_link_libraries(test_buffer ${LIBUNWIND_LDFLAGS})
 788         add_target_properties(test_buffer COMPILE_FLAGS ${LIBUNWIND_CFLAGS})
 789         target_link_libraries(test_base64 ${LIBUNWIND_LDFLAGS})
 790         add_target_properties(test_base64 COMPILE_FLAGS ${LIBUNWIND_CFLAGS})
 791         target_link_libraries(test_configfile ${PCRE_LDFLAGS} ${LIBUNWIND_LDFLAGS})
 792         add_target_properties(test_configfile COMPILE_FLAGS ${PCRE_CFLAGS} ${LIBUNWIND_CFLAGS})
 793 endif()
 794
 795 if(NOT WIN32)
 796 install(TARGETS ${L_INSTALL_TARGETS}
 797         RUNTIME DESTINATION ${SBINDIR}
 798         LIBRARY DESTINATION ${LIGHTTPD_MODULES_DIR}
 799         ARCHIVE DESTINATION ${LIGHTTPD_MODULES_DIR}/static)
 800 else()
 801 ## HACK to make win32 to install our libraries in desired directory..
 802 install(TARGETS lighttpd
 803         RUNTIME DESTINATION ${SBINDIR}
 804         ARCHIVE DESTINATION lib/static)
 805 list(REMOVE_ITEM L_INSTALL_TARGETS lighttpd)
 806 install(TARGETS ${L_INSTALL_TARGETS}
 807         RUNTIME DESTINATION ${SBINDIR}/lib
 808         LIBRARY DESTINATION lib
 809         ARCHIVE DESTINATION lib/static)
 810 endif()