docs/page.xsl

   1 <?xml version="1.0"?>
   2 <xsl:stylesheet
   3   xmlns="http://www.w3.org/1999/xhtml"
   4   xmlns:html="http://www.w3.org/1999/xhtml"
   5   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   6   xmlns:exsl="http://exslt.org/common"
   7   exclude-result-prefixes="xsl exsl html"
   8   version="1.0">
   9
  10   <xsl:template match="node() | @*" mode="content">
  11     <xsl:copy>
  12       <xsl:apply-templates select="node() | @*" mode="content"/>
  13     </xsl:copy>
  14   </xsl:template>
  15
  16
  17   <xsl:template match="html:ul[@id='toc']" mode="content">
  18     <xsl:call-template name="toc"/>
  19   </xsl:template>
  20
  21   <xsl:template match="html:div[@id='include']" mode="content">
  22     <xsl:call-template name="include"/>
  23   </xsl:template>
  24
  25   <xsl:template name="toc">
  26     <ul>
  27       <xsl:for-each select="/html:html/html:body/html:h2[count(html:a) = 1]">
  28         <xsl:variable name="thish2" select="."/>
  29         <li>
  30           <a href="#{html:a/@id}"><xsl:value-of select="html:a/text()"/></a>
  31           <xsl:if test="count(./following-sibling::html:h3[preceding-sibling::html:h2[1] = $thish2 and count(html:a) = 1]) > 0">
  32             <ul>
  33               <xsl:for-each select="./following-sibling::html:h3[preceding-sibling::html:h2[1] = $thish2 and count(html:a) = 1]">
  34                 <xsl:variable name="thish3" select="."/>
  35                 <li>
  36                   <a href="#{html:a/@id}"><xsl:value-of select="html:a/text()"/></a>
  37                   <xsl:if test="count(./following-sibling::html:h4[preceding-sibling::html:h3[1] = $thish3 and count(html:a) = 1]) > 0">
  38                     <ul>
  39                       <xsl:for-each select="./following-sibling::html:h4[preceding-sibling::html:h3[1] = $thish3 and count(html:a) = 1]">
  40                         <xsl:variable name="thish4" select="."/>
  41                         <li>
  42                           <a href="#{html:a/@id}"><xsl:value-of select="html:a/text()"/></a>
  43                           <xsl:if test="count(./following-sibling::html:h5[preceding-sibling::html:h4[1] = $thish4 and count(html:a) = 1]) > 0">
  44                             <ul>
  45                               <xsl:for-each select="./following-sibling::html:h5[preceding-sibling::html:h4[1] = $thish4 and count(html:a) = 1]">
  46                                 <xsl:variable name="thish5" select="."/>
  47                                 <li>
  48                                   <a href="#{html:a/@id}"><xsl:value-of select="html:a/text()"/></a>
  49                                   <xsl:if test="count(./following-sibling::html:h6[preceding-sibling::html:h5[1] = $thish5 and count(html:a) = 1]) > 0">
  50                                     <ul>
  51                                       <xsl:for-each select="./following-sibling::html:h6[preceding-sibling::html:h5[1] = $thish5 and count(html:a) = 1]">
  52                                         <li>
  53                                           <a href="#{html:a/@id}"><xsl:value-of select="html:a/text()"/></a>
  54                                         </li>
  55                                       </xsl:for-each>
  56                                     </ul>
  57                                   </xsl:if>
  58                                 </li>
  59                               </xsl:for-each>
  60                             </ul>
  61                           </xsl:if>
  62                         </li>
  63                       </xsl:for-each>
  64                     </ul>
  65                   </xsl:if>
  66                 </li>
  67               </xsl:for-each>
  68             </ul>
  69           </xsl:if>
  70         </li>
  71       </xsl:for-each>
  72     </ul>
  73   </xsl:template>
  74
  75   <!-- This is the master page structure -->
  76   <xsl:template match="/" mode="page">
  77     <xsl:param name="pagename"/>
  78     <xsl:param name="timestamp"/>
  79     <xsl:text disable-output-escaping="yes">&lt;!DOCTYPE html&gt;
  80 </xsl:text>
  81     <html>
  82       <xsl:comment>
  83         This file is autogenerated from <xsl:value-of select="$pagename"/>.in
  84         Do not edit this file. Changes will be lost.
  85       </xsl:comment>
  86       <xsl:comment>
  87         This page was generated at <xsl:value-of select="$timestamp"/>.
  88       </xsl:comment>
  89       <head>
  90         <meta charset="UTF-8"/>
  91         <meta name="viewport" content="width=device-width, initial-scale=1"/>
  92         <link rel="stylesheet" type="text/css" href="{$href_base}main.css"/>
  93         <link rel="apple-touch-icon" sizes="180x180" href="/apple-touch-icon.png"/>
  94         <link rel="icon" type="image/png" sizes="32x32" href="/favicon-32x32.png"/>
  95         <link rel="icon" type="image/png" sizes="16x16" href="/favicon-16x16.png"/>
  96         <link rel="manifest" href="/manifest.json"/>
  97         <meta name="theme-color" content="#ffffff"/>
  98         <title>libvirt: <xsl:value-of select="html:html/html:body/html:h1"/></title>
  99         <meta name="description" content="libvirt, virtualization, virtualization API"/>
 100         <xsl:apply-templates select="/html:html/html:head/*" mode="content"/>
 101
 102         <script type="text/javascript" src="{$href_base}js/main.js">
 103           <xsl:comment>// forces non-empty element</xsl:comment>
 104         </script>
 105       </head>
 106       <body onload="pageload()">
 107         <xsl:if test="html:html/html:body/@class">
 108           <xsl:attribute name="class">
 109             <xsl:value-of select="html:html/html:body/@class"/>
 110           </xsl:attribute>
 111         </xsl:if>
 112         <div id="body">
 113           <div id="content">
 114             <xsl:apply-templates select="/html:html/html:body/*" mode="content"/>
 115           </div>
 116         </div>
 117         <div id="nav">
 118           <div id="home">
 119             <a href="{$href_base}index.html">Home</a>
 120           </div>
 121           <div id="jumplinks">
 122             <ul>
 123               <li><a href="{$href_base}downloads.html">Download</a></li>
 124               <li><a href="{$href_base}contribute.html">Contribute</a></li>
 125               <li><a href="{$href_base}docs.html">Docs</a></li>
 126             </ul>
 127           </div>
 128           <div id="search">
 129             <form id="simplesearch" action="https://www.google.com/search" enctype="application/x-www-form-urlencoded" method="get">
 130               <div>
 131                 <input id="searchsite" name="sitesearch" type="hidden" value="libvirt.org"/>
 132                 <input id="searchq" name="q" type="text" size="12" value=""/>
 133                 <input name="submit" type="submit" value="Go"/>
 134               </div>
 135             </form>
 136             <div id="advancedsearch">
 137               <span><input type="radio" name="what" id="whatwebsite" checked="checked" value="website"/><label for="whatwebsite">Website</label></span>
 138               <span><input type="radio" name="what" id="whatwiki" value="wiki"/><label for="whatwiki">Wiki</label></span>
 139               <span><input type="radio" name="what" id="whatdevs" value="devs"/><label for="whatdevs">Developers list</label></span>
 140               <span><input type="radio" name="what" id="whatusers" value="users"/><label for="whatusers">Users list</label></span>
 141             </div>
 142           </div>
 143         </div>
 144         <div id="footer">
 145           <div id="contact">
 146             <h3>Contact</h3>
 147             <ul>
 148               <li><a href="{$href_base}contact.html#email">email</a></li>
 149               <li><a href="{$href_base}contact.html#irc">irc</a></li>
 150             </ul>
 151           </div>
 152           <div id="community">
 153             <h3>Community</h3>
 154             <ul>
 155               <li><a href="https://twitter.com/hashtag/libvirt">twitter</a></li>
 156               <li><a href="http://stackoverflow.com/questions/tagged/libvirt">stackoverflow</a></li>
 157               <li><a href="http://serverfault.com/questions/tagged/libvirt">serverfault</a></li>
 158             </ul>
 159           </div>
 160           <div id="conduct">
 161             Participants in the libvirt project agree to abide by <a href="{$href_base}governance.html#codeofconduct">the project code of conduct</a>
 162           </div>
 163           <br class="clear"/>
 164         </div>
 165       </body>
 166     </html>
 167   </xsl:template>
 168
 169   <xsl:template name="include">
 170     <xsl:variable name="inchtml">
 171       <xsl:copy-of select="document(@filename)"/>
 172     </xsl:variable>
 173
 174     <xsl:apply-templates select="exsl:node-set($inchtml)/html:html/html:body/*" mode="content"/>
 175   </xsl:template>
 176
 177   <xsl:template match="html:h2 | html:h3 | html:h4 | html:h5 | html:h6" mode="content">
 178     <xsl:element name="{name()}">
 179       <xsl:apply-templates mode="copy" />
 180       <xsl:if test="./html:a/@id">
 181         <a class="headerlink" href="#{html:a/@id}" title="Permalink to this headline">&#xb6;</a>
 182       </xsl:if>
 183     </xsl:element>
 184   </xsl:template>
 185
 186   <xsl:template match="text()" mode="copy">
 187     <xsl:value-of select="."/>
 188   </xsl:template>
 189
 190   <xsl:template match="node()" mode="copy">
 191     <xsl:element name="{name()}">
 192       <xsl:copy-of select="./@*"/>
 193       <xsl:apply-templates mode="copy" />
 194     </xsl:element>
 195   </xsl:template>
 196 </xsl:stylesheet>