m4/virt-firewalld-zone.m4

   1 dnl firewalld_zone check - whether or not to install the firewall "libvirt" zone
   2 dnl
   3 dnl Copyright (C) 2019 Red Hat, Inc.
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library.  If not, see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_DEFUN([LIBVIRT_ARG_FIREWALLD_ZONE], [
  21   LIBVIRT_ARG_WITH([FIREWALLD_ZONE], [Whether to install firewalld libvirt zone], [check])
  22 ])
  23
  24 AC_DEFUN([LIBVIRT_CHECK_FIREWALLD_ZONE], [
  25   AC_REQUIRE([LIBVIRT_CHECK_FIREWALLD])
  26   AC_MSG_CHECKING([for whether to install firewalld libvirt zone])
  27
  28   if test "x$with_firewalld_zone" = "xcheck" ; then
  29     with_firewalld_zone=$with_firewalld
  30   fi
  31
  32   if test "x$with_firewalld_zone" = "xyes" ; then
  33     if test "x$with_firewalld" != "xyes" ; then
  34       AC_MSG_ERROR([You must have firewalld support enabled to enable firewalld-zone])
  35     fi
  36     AC_DEFINE_UNQUOTED([WITH_FIREWALLD_ZONE], [1], [whether firewalld libvirt zone is installed])
  37   fi
  38
  39   AM_CONDITIONAL([WITH_FIREWALLD_ZONE], [test "x$with_firewalld_zone" != "xno"])
  40   AC_MSG_RESULT($with_firewalld_zone)
  41 ])
  42
  43 AC_DEFUN([LIBVIRT_RESULT_FIREWALLD_ZONE], [
  44   LIBVIRT_RESULT([firewalld-zone], [$with_firewalld_zone])
  45 ])