docs/newapi.xsl

   1 <?xml version="1.0"?>
   2 <!--
   3   Stylesheet to generate the HTML documentation from an XML API descriptions:
   4   xsltproc newapi.xsl libvirt-api.xml
   5
   6   Daniel Veillard
   7 -->
   8 <xsl:stylesheet version="1.0"
   9   xmlns="http://www.w3.org/1999/xhtml"
  10   xmlns:html="http://www.w3.org/1999/xhtml"
  11   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  12   xmlns:exsl="http://exslt.org/common"
  13   xmlns:str="http://exslt.org/strings"
  14   extension-element-prefixes="exsl str"
  15   exclude-result-prefixes="exsl str">
  16
  17   <!-- Import the main part of the site stylesheets -->
  18   <xsl:import href="page.xsl"/>
  19
  20   <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
  21
  22   <!-- Build keys for all symbols -->
  23   <xsl:key name="symbols" match="/api/symbols/*" use="@name"/>
  24
  25   <xsl:param name="builddir" select="'..'"/>
  26
  27   <!-- the target directory for the HTML output -->
  28   <xsl:variable name="htmldir">html</xsl:variable>
  29   <xsl:variable name="href_base">../</xsl:variable>
  30
  31   <xsl:variable name="acls">
  32     <xsl:copy-of select="document('{$builddir}/src/libvirt_access.xml')/aclinfo/api"/>
  33   </xsl:variable>
  34   <xsl:variable name="qemuacls">
  35     <xsl:copy-of select="document('{$builddir}/src/libvirt_access_qemu.xml')/aclinfo/api"/>
  36   </xsl:variable>
  37   <xsl:variable name="lxcacls">
  38     <xsl:copy-of select="document('{$builddir}/src/libvirt_access_lxc.xml')/aclinfo/api"/>
  39   </xsl:variable>
  40
  41   <xsl:template name="aclinfo">
  42     <xsl:param name="api"/>
  43
  44     <xsl:if test="count(exsl:node-set($acls)/api[@name=$api]/check) > 0">
  45       <h5>Access control parameter checks</h5>
  46       <table class="acl">
  47         <thead>
  48           <tr>
  49             <th>Object</th>
  50             <th>Permission</th>
  51             <th>Condition</th>
  52           </tr>
  53         </thead>
  54         <xsl:apply-templates select="exsl:node-set($acls)/api[@name=$api]/check" mode="acl"/>
  55       </table>
  56     </xsl:if>
  57     <xsl:if test="count(exsl:node-set($acls)/api[@name=$api]/filter) > 0">
  58       <h5>Access control return value filters</h5>
  59       <table class="acl">
  60         <thead>
  61           <tr>
  62             <th>Object</th>
  63             <th>Permission</th>
  64           </tr>
  65         </thead>
  66         <xsl:apply-templates select="exsl:node-set($acls)/api[@name=$api]/filter" mode="acl"/>
  67       </table>
  68     </xsl:if>
  69   </xsl:template>
  70
  71   <xsl:template match="check" mode="acl">
  72     <tr>
  73       <td><a href="../acl.html#object_{@object}"><xsl:value-of select="@object"/></a></td>
  74       <td><a href="../acl.html#perm_{@object}_{@perm}"><xsl:value-of select="@perm"/></a></td>
  75       <xsl:choose>
  76         <xsl:when test="@flags">
  77           <td><xsl:value-of select="@flags"/></td>
  78         </xsl:when>
  79         <xsl:otherwise>
  80           <td>-</td>
  81         </xsl:otherwise>
  82       </xsl:choose>
  83     </tr>
  84   </xsl:template>
  85
  86   <xsl:template match="filter" mode="acl">
  87     <tr>
  88       <td><xsl:value-of select="@object"/></td>
  89       <td><xsl:value-of select="@perm"/></td>
  90     </tr>
  91   </xsl:template>
  92
  93
  94   <xsl:template name="navbar">
  95     <xsl:variable name="previous" select="preceding-sibling::file[1]"/>
  96     <xsl:variable name="next" select="following-sibling::file[1]"/>
  97     <table class="navigation" width="100%" summary="Navigation header"
  98            cellpadding="2" cellspacing="2">
  99       <tr valign="middle">
 100         <xsl:if test="$previous">
 101           <td><a accesskey="p" href="libvirt-{$previous/@name}.html"><img src="left.png" width="24" height="24" border="0" alt="Prev"></img></a></td>
 102           <th align="left"><a href="libvirt-{$previous/@name}.html"><xsl:value-of select="$previous/@name"/></a></th>
 103         </xsl:if>
 104         <td><a accesskey="u" href="index.html"><img src="up.png" width="24" height="24" border="0" alt="Up"></img></a></td>
 105         <th align="left"><a href="index.html">API documentation</a></th>
 106         <td><a accesskey="h" href="../index.html"><img src="home.png" width="24" height="24" border="0" alt="Home"></img></a></td>
 107         <th align="center"><a href="../index.html">The virtualization API</a></th>
 108         <xsl:if test="$next">
 109           <th align="right"><a href="libvirt-{$next/@name}.html"><xsl:value-of select="$next/@name"/></a></th>
 110           <td><a accesskey="n" href="libvirt-{$next/@name}.html"><img src="right.png" width="24" height="24" border="0" alt="Next"></img></a></td>
 111         </xsl:if>
 112       </tr>
 113     </table>
 114   </xsl:template>
 115
 116   <!-- This is convoluted but needed to force the current document to
 117        be the API one and not the result tree from the tokenize() result,
 118        because the keys are only defined on the main document -->
 119   <xsl:template mode="dumptoken" match='*'>
 120     <xsl:param name="token"/>
 121     <xsl:variable name="stem" select="translate($token, '(),.:;@', '')"/>
 122     <xsl:variable name="ref" select="key('symbols', $stem)"/>
 123     <xsl:choose>
 124       <xsl:when test="$ref">
 125         <xsl:value-of select="substring-before($token, $stem)"/>
 126         <a href="libvirt-{$ref/@file}.html#{$ref/@name}"><xsl:value-of select="$stem"/></a>
 127         <xsl:value-of select="substring-after($token, $stem)"/>
 128       </xsl:when>
 129       <xsl:when test="starts-with($token, 'http://')">
 130         <a href="{$token}">
 131           <xsl:value-of select="$token"/>
 132         </a>
 133       </xsl:when>
 134       <xsl:when test="starts-with($token, '&lt;http://') and contains($token, '&gt;')">
 135         <xsl:variable name="link"
 136                       select="substring(substring-before($token, '&gt;'), 2)"/>
 137         <a href="{$link}">
 138           <xsl:value-of select="$link"/>
 139         </a>
 140         <xsl:value-of select="substring-after($token, '&gt;')"/>
 141       </xsl:when>
 142       <xsl:otherwise>
 143         <xsl:value-of select="$token"/>
 144       </xsl:otherwise>
 145     </xsl:choose>
 146   </xsl:template>
 147
 148   <!-- dumps a string, making cross-reference links -->
 149   <xsl:template name="dumptext">
 150     <xsl:param name="text"/>
 151     <xsl:variable name="ctxt" select='.'/>
 152     <!-- <xsl:value-of select="$text"/> -->
 153     <xsl:for-each select="str:tokenize($text, ' &#9;&#10;&#13;')">
 154       <xsl:apply-templates select="$ctxt" mode='dumptoken'>
 155         <xsl:with-param name="token" select="string(.)"/>
 156       </xsl:apply-templates>
 157       <xsl:if test="position() != last()">
 158         <xsl:text> </xsl:text>
 159       </xsl:if>
 160     </xsl:for-each>
 161   </xsl:template>
 162
 163
 164   <!-- process blocks of text. blocks are separated by two consecutive line -->
 165   <!-- breaks.                                                              -->
 166   <!--                                                                      -->
 167   <!-- blocks indented with at least 2 spaces are considered code blocks.   -->
 168   <!--                                                                      -->
 169   <!-- consecutive code blocks are collapsed into a single code block.      -->
 170   <xsl:template name="formatblock">
 171     <xsl:param name="block"/>
 172     <xsl:param name="rest"/>
 173
 174     <xsl:variable name="multipleCodeBlocks"
 175                   select="starts-with($block, '  ') and starts-with($rest, '  ')"/>
 176
 177     <xsl:choose>
 178       <xsl:when test="$multipleCodeBlocks">
 179         <xsl:call-template name="formatblock">
 180           <xsl:with-param name="block">
 181             <xsl:choose>
 182               <xsl:when test="contains($rest, '&#xA;&#xA;')">
 183                 <xsl:value-of select="concat($block, '&#xA;  &#xA;',
 184                                         substring-before($rest, '&#xA;&#xA;'))" />
 185               </xsl:when>
 186               <xsl:otherwise>
 187                 <xsl:value-of select="concat($block, '&#xA;  &#xA;', $rest)" />
 188               </xsl:otherwise>
 189             </xsl:choose>
 190           </xsl:with-param>
 191           <xsl:with-param name="rest" select="substring-after($rest, '&#xA;&#xA;')"/>
 192         </xsl:call-template>
 193       </xsl:when>
 194       <xsl:when test="starts-with($block, '  ')">
 195         <pre class="code"><xsl:for-each select="str:tokenize($block, '&#xA;')">
 196           <xsl:choose>
 197             <xsl:when test="starts-with(., '  ')">
 198               <xsl:value-of select="substring(., 3)"/>
 199             </xsl:when>
 200             <xsl:otherwise>
 201               <xsl:value-of select="."/>
 202             </xsl:otherwise>
 203           </xsl:choose>
 204           <xsl:if test="position() != last()">
 205             <xsl:text>&#xA;</xsl:text>
 206           </xsl:if>
 207         </xsl:for-each></pre>
 208       </xsl:when>
 209       <xsl:otherwise>
 210         <p>
 211           <xsl:call-template name="dumptext">
 212             <xsl:with-param name="text" select="$block"/>
 213           </xsl:call-template>
 214         </p>
 215       </xsl:otherwise>
 216     </xsl:choose>
 217     <xsl:if test="not($multipleCodeBlocks)">
 218       <xsl:call-template name="formattext">
 219         <xsl:with-param name="text" select="$rest"/>
 220       </xsl:call-template>
 221     </xsl:if>
 222   </xsl:template>
 223
 224   <xsl:template name="formattext">
 225     <xsl:param name="text" />
 226
 227     <xsl:if test="$text">
 228       <xsl:variable name="head" select="substring-before($text, '&#xA;&#xA;')"/>
 229       <xsl:variable name="rest" select="substring-after($text, '&#xA;&#xA;')"/>
 230
 231       <xsl:call-template name="formatblock">
 232         <xsl:with-param name="block">
 233           <xsl:choose>
 234             <xsl:when test="contains($text, '&#xA;&#xA;')">
 235               <xsl:value-of select="$head"/>
 236             </xsl:when>
 237             <xsl:otherwise>
 238               <xsl:value-of select="$text"/>
 239             </xsl:otherwise>
 240           </xsl:choose>
 241         </xsl:with-param>
 242         <xsl:with-param name="rest" select="$rest"/>
 243       </xsl:call-template>
 244     </xsl:if>
 245   </xsl:template>
 246
 247   <xsl:template match="macro" mode="toc">
 248     <span class="directive">#define</span><xsl:text> </xsl:text>
 249     <a href="#{@name}"><xsl:value-of select="@name"/></a>
 250     <xsl:text>
 251 </xsl:text>
 252   </xsl:template>
 253
 254   <xsl:template match="variable" mode="toc">
 255     <span class="type">
 256       <xsl:call-template name="dumptext">
 257         <xsl:with-param name="text" select="string(@type)"/>
 258       </xsl:call-template>
 259     </span>
 260     <xsl:text> </xsl:text>
 261     <a name="{@name}"></a>
 262     <xsl:value-of select="@name"/>
 263     <xsl:text>
 264 </xsl:text>
 265   </xsl:template>
 266
 267   <xsl:template match="typedef" mode="toc">
 268     <span class="keyword">typedef</span>
 269     <xsl:text> </xsl:text><xsl:variable name="name" select="string(@name)"/>
 270     <xsl:choose>
 271       <xsl:when test="@type = 'enum'">
 272         <span class="keyword">enum</span><xsl:text> </xsl:text>
 273         <a href="#{$name}"><xsl:value-of select="$name"/></a>
 274         <xsl:text>
 275 </xsl:text>
 276       </xsl:when>
 277       <xsl:otherwise>
 278         <span class="type">
 279           <xsl:call-template name="dumptext">
 280             <xsl:with-param name="text" select="@type"/>
 281           </xsl:call-template>
 282         </span>
 283         <xsl:text> </xsl:text>
 284         <a name="{$name}"><xsl:value-of select="$name"/></a>
 285         <xsl:text>
 286 </xsl:text>
 287       </xsl:otherwise>
 288     </xsl:choose>
 289   </xsl:template>
 290
 291   <xsl:template name="enumvalue">
 292     <xsl:param name="value" select="@value"/>
 293     <xsl:param name="valuehex" select="@value_hex"/>
 294     <xsl:param name="valuebitshift" select="@value_bitshift"/>
 295     <xsl:value-of select="@value"/>
 296     <xsl:if test="$valuehex != '' or $valuebitshift != ''">
 297       <xsl:text> (</xsl:text>
 298       <xsl:if test="$valuehex != ''">
 299         <xsl:value-of select="@value_hex"/>
 300       </xsl:if>
 301       <xsl:if test="$valuebitshift != ''">
 302         <xsl:text>; 1 &lt;&lt; </xsl:text>
 303         <xsl:value-of select="@value_bitshift"/>
 304       </xsl:if>
 305       <xsl:text>)</xsl:text>
 306     </xsl:if>
 307   </xsl:template>
 308
 309   <xsl:template match="typedef[@type = 'enum']">
 310     <xsl:variable name="name" select="string(@name)"/>
 311     <h3><a id="{$name}"><code><xsl:value-of select="$name"/></code></a></h3>
 312     <div class="api">
 313       <pre>
 314         <span class="keyword">enum</span><xsl:text> </xsl:text>
 315         <xsl:value-of select="$name"/>
 316         <xsl:text> {
 317 </xsl:text>
 318       </pre>
 319       <table>
 320         <xsl:for-each select="/api/symbols/enum[@type = $name]">
 321           <xsl:sort select="@value" data-type="number" order="ascending"/>
 322           <tr>
 323             <td><a name="{@name}"><xsl:value-of select="@name"/></a></td>
 324             <td><xsl:text> = </xsl:text></td>
 325             <xsl:choose>
 326               <xsl:when test="@info != ''">
 327                 <td class="enumvalue"><xsl:call-template name="enumvalue"/></td>
 328                 <td>
 329                   <div class="comment">
 330                     <xsl:call-template name="dumptext">
 331                       <xsl:with-param name="text" select="@info"/>
 332                     </xsl:call-template>
 333                   </div>
 334                 </td>
 335               </xsl:when>
 336               <xsl:otherwise>
 337                 <td colspan="2" class="enumvalue"><xsl:call-template name="enumvalue"/></td>
 338               </xsl:otherwise>
 339             </xsl:choose>
 340           </tr>
 341         </xsl:for-each>
 342       </table>
 343       <pre>
 344         <xsl:text>}
 345 </xsl:text>
 346       </pre>
 347     </div>
 348   </xsl:template>
 349
 350   <xsl:template match="struct" mode="toc">
 351     <span class="keyword">typedef</span><xsl:text> </xsl:text>
 352     <span class="type"><xsl:value-of select="@type"/></span>
 353     <xsl:text> </xsl:text>
 354     <a href="#{@name}"><xsl:value-of select="@name"/></a>
 355     <xsl:text>
 356 </xsl:text>
 357   </xsl:template>
 358
 359   <xsl:template match="struct">
 360     <h3><a id="{@name}"><code><xsl:value-of select="@name"/></code></a></h3>
 361     <div class="api">
 362       <pre>
 363         <span class="keyword">struct </span>
 364         <xsl:value-of select="@name"/>
 365         <xsl:text> {
 366 </xsl:text>
 367       </pre>
 368       <xsl:if test="field">
 369         <table>
 370           <xsl:for-each select="field">
 371             <xsl:choose>
 372               <xsl:when test='@type = "union"'>
 373                 <tr><td><span class="keyword">union</span> {</td></tr>
 374                 <tr>
 375                   <td><table>
 376                     <xsl:for-each select="union/field">
 377                       <tr>
 378                         <td>
 379                           <span class="type">
 380                             <xsl:call-template name="dumptext">
 381                               <xsl:with-param name="text" select="@type"/>
 382                             </xsl:call-template>
 383                           </span>
 384                         </td>
 385                         <td><xsl:value-of select="@name"/></td>
 386                         <xsl:if test="@info != ''">
 387                           <td>
 388                             <div class="comment">
 389                               <xsl:call-template name="dumptext">
 390                                 <xsl:with-param name="text" select="@info"/>
 391                               </xsl:call-template>
 392                             </div>
 393                           </td>
 394                         </xsl:if>
 395                       </tr>
 396                     </xsl:for-each>
 397                   </table></td>
 398                 <td></td></tr>
 399                 <tr><td>}</td>
 400                 <td><xsl:value-of select="@name"/></td>
 401                 <xsl:if test="@info != ''">
 402                   <td>
 403                     <div class="comment">
 404                       <xsl:call-template name="dumptext">
 405                         <xsl:with-param name="text" select="@info"/>
 406                       </xsl:call-template>
 407                     </div>
 408                   </td>
 409                 </xsl:if>
 410                 <td></td></tr>
 411               </xsl:when>
 412               <xsl:otherwise>
 413                 <tr>
 414                   <td>
 415                     <span class="type">
 416                       <xsl:call-template name="dumptext">
 417                         <xsl:with-param name="text" select="@type"/>
 418                       </xsl:call-template>
 419                     </span>
 420                   </td>
 421                   <td><xsl:value-of select="@name"/></td>
 422                   <xsl:if test="@info != ''">
 423                     <td>
 424                       <div class="comment">
 425                         <xsl:call-template name="dumptext">
 426                         <xsl:with-param name="text" select="@info"/>
 427                         </xsl:call-template>
 428                       </div>
 429                     </td>
 430                   </xsl:if>
 431                 </tr>
 432               </xsl:otherwise>
 433             </xsl:choose>
 434           </xsl:for-each>
 435         </table>
 436       </xsl:if>
 437       <xsl:if test="not(field)">
 438         <div class="undisclosed">The content of this structure is not made public by the API</div>
 439       </xsl:if>
 440       <pre>
 441         <xsl:text>
 442 }
 443 </xsl:text>
 444       </pre>
 445     </div>
 446   </xsl:template>
 447
 448   <xsl:template match="macro">
 449     <xsl:variable name="name" select="string(@name)"/>
 450     <h3><a id="{$name}"><code><xsl:value-of select="$name"/></code></a></h3>
 451     <pre class="api"><span class="directive">#define</span><xsl:text> </xsl:text><xsl:value-of select="$name"/></pre>
 452     <div class="description">
 453     <xsl:call-template name="formattext">
 454       <xsl:with-param name="text" select="info"/>
 455     </xsl:call-template>
 456     </div><xsl:text>
 457 </xsl:text>
 458   </xsl:template>
 459
 460   <xsl:template match="function" mode="toc">
 461     <xsl:variable name="name" select="string(@name)"/>
 462     <xsl:variable name="nlen" select="string-length($name)"/>
 463     <xsl:variable name="tlen" select="string-length(return/@type)"/>
 464     <xsl:variable name="blen" select="(($nlen + 8) - (($nlen + 8) mod 8)) + (($tlen + 8) - (($tlen + 8) mod 8))"/>
 465     <span class="type">
 466       <xsl:call-template name="dumptext">
 467         <xsl:with-param name="text" select="return/@type"/>
 468       </xsl:call-template>
 469     </span>
 470     <xsl:text>&#9;</xsl:text>
 471     <a href="#{@name}"><xsl:value-of select="@name"/></a>
 472     <xsl:if test="$blen - 40 &lt; -8">
 473       <xsl:text>&#9;</xsl:text>
 474     </xsl:if>
 475     <xsl:if test="$blen - 40 &lt; 0">
 476       <xsl:text>&#9;</xsl:text>
 477     </xsl:if>
 478     <xsl:text>&#9;(</xsl:text>
 479     <xsl:if test="not(arg)">
 480       <span class="type">void</span>
 481     </xsl:if>
 482     <xsl:for-each select="arg">
 483       <span class="type">
 484         <xsl:call-template name="dumptext">
 485           <xsl:with-param name="text" select="@type"/>
 486         </xsl:call-template>
 487       </span>
 488       <xsl:text> </xsl:text>
 489       <xsl:value-of select="@name"/>
 490       <xsl:if test="position() != last()">
 491         <xsl:text>, </xsl:text><br/>
 492         <xsl:if test="$blen - 40 &gt; 8">
 493           <xsl:text>&#9;</xsl:text>
 494         </xsl:if>
 495         <xsl:if test="$blen - 40 &gt; 0">
 496           <xsl:text>&#9;</xsl:text>
 497         </xsl:if>
 498         <xsl:text>&#9;&#9;&#9;&#9;&#9; </xsl:text>
 499       </xsl:if>
 500     </xsl:for-each>
 501     <xsl:text>)
 502 </xsl:text>
 503   </xsl:template>
 504
 505   <xsl:template match="functype" mode="toc">
 506     <xsl:variable name="name" select="string(@name)"/>
 507     <xsl:variable name="nlen" select="string-length($name)"/>
 508     <xsl:variable name="tlen" select="string-length(return/@type)"/>
 509     <xsl:variable name="blen" select="(($nlen + 8) - (($nlen + 8) mod 8)) + (($tlen + 8) - (($tlen + 8) mod 8))"/>
 510     <span class="keyword">typedef</span><xsl:text> </xsl:text>
 511     <a href="#{$name}"><xsl:value-of select="$name"/></a>
 512     <xsl:text>
 513 </xsl:text>
 514     <span class="type">
 515       <xsl:call-template name="dumptext">
 516         <xsl:with-param name="text" select="return/@type"/>
 517       </xsl:call-template>
 518     </span>
 519     <xsl:text>&#9;</xsl:text>
 520     <a href="#{$name}"><xsl:value-of select="$name"/></a>
 521     <xsl:if test="$blen - 40 &lt; -8">
 522       <xsl:text>&#9;</xsl:text>
 523     </xsl:if>
 524     <xsl:if test="$blen - 40 &lt; 0">
 525       <xsl:text>&#9;</xsl:text>
 526     </xsl:if>
 527     <xsl:text>&#9;(</xsl:text>
 528     <xsl:if test="not(arg)">
 529       <span class="type">void</span>
 530     </xsl:if>
 531     <xsl:for-each select="arg">
 532       <span class="type">
 533         <xsl:call-template name="dumptext">
 534           <xsl:with-param name="text" select="@type"/>
 535         </xsl:call-template>
 536       </span>
 537       <xsl:text> </xsl:text>
 538       <xsl:value-of select="@name"/>
 539       <xsl:if test="position() != last()">
 540         <xsl:text>, </xsl:text><br/>
 541         <xsl:if test="$blen - 40 &gt; 8">
 542           <xsl:text>&#9;</xsl:text>
 543         </xsl:if>
 544         <xsl:if test="$blen - 40 &gt; 0">
 545           <xsl:text>&#9;</xsl:text>
 546         </xsl:if>
 547         <xsl:text>&#9;&#9;&#9;&#9;&#9; </xsl:text>
 548       </xsl:if>
 549     </xsl:for-each>
 550     <xsl:text>)
 551 </xsl:text>
 552     <xsl:text>
 553 </xsl:text>
 554   </xsl:template>
 555
 556   <xsl:template match="functype">
 557     <xsl:variable name="name" select="string(@name)"/>
 558     <xsl:variable name="nlen" select="string-length($name)"/>
 559     <xsl:variable name="tlen" select="string-length(return/@type)"/>
 560     <xsl:variable name="blen" select="(($nlen + 8) - (($nlen + 8) mod 8)) + (($tlen + 8) - (($tlen + 8) mod 8))"/>
 561     <h3><a id="{$name}"><code><xsl:value-of select="$name"/></code></a></h3>
 562     <pre class="api">
 563     <span class="keyword">typedef</span><xsl:text> </xsl:text>
 564     <span class="type">
 565       <xsl:call-template name="dumptext">
 566         <xsl:with-param name="text" select="return/@type"/>
 567       </xsl:call-template>
 568     </span>
 569     <xsl:text>&#9;(*</xsl:text>
 570     <xsl:value-of select="@name"/>
 571     <xsl:if test="$blen - 40 &lt; -8">
 572       <xsl:text>&#9;</xsl:text>
 573     </xsl:if>
 574     <xsl:if test="$blen - 40 &lt; 0">
 575       <xsl:text>&#9;</xsl:text>
 576     </xsl:if>
 577     <xsl:text>)&#9;(</xsl:text>
 578     <xsl:if test="not(arg)">
 579       <span class="type">void</span>
 580     </xsl:if>
 581     <xsl:for-each select="arg">
 582       <span class="type">
 583         <xsl:call-template name="dumptext">
 584           <xsl:with-param name="text" select="@type"/>
 585         </xsl:call-template>
 586       </span>
 587       <xsl:text> </xsl:text>
 588       <xsl:value-of select="@name"/>
 589       <xsl:if test="position() != last()">
 590         <xsl:text>,
 591 </xsl:text>
 592         <xsl:if test="$blen - 40 &gt; 8">
 593           <xsl:text>&#9;</xsl:text>
 594         </xsl:if>
 595         <xsl:if test="$blen - 40 &gt; 0">
 596           <xsl:text>&#9;</xsl:text>
 597         </xsl:if>
 598         <xsl:text>&#9;&#9;&#9;&#9;&#9; </xsl:text>
 599       </xsl:if>
 600     </xsl:for-each>
 601     <xsl:text>)
 602 </xsl:text>
 603     </pre>
 604     <div class="description">
 605     <xsl:call-template name="formattext">
 606       <xsl:with-param name="text" select="info"/>
 607     </xsl:call-template>
 608     </div>
 609     <xsl:if test="arg | return">
 610       <dl class="variablelist">
 611       <xsl:for-each select="arg">
 612         <dt><xsl:value-of select="@name"/></dt>
 613         <dd>
 614           <xsl:call-template name="dumptext">
 615               <xsl:with-param name="text" select="@info"/>
 616             </xsl:call-template>
 617         </dd>
 618       </xsl:for-each>
 619       <xsl:if test="return/@info">
 620         <dt>Returns</dt>
 621         <dd>
 622           <xsl:call-template name="dumptext">
 623             <xsl:with-param name="text" select="return/@info"/>
 624           </xsl:call-template>
 625         </dd>
 626       </xsl:if>
 627       </dl>
 628     </xsl:if>
 629     <br/>
 630     <xsl:text>
 631 </xsl:text>
 632   </xsl:template>
 633
 634   <xsl:template match="function">
 635     <xsl:variable name="name" select="string(@name)"/>
 636     <xsl:variable name="nlen" select="string-length($name)"/>
 637     <xsl:variable name="tlen" select="string-length(return/@type)"/>
 638     <xsl:variable name="blen" select="(($nlen + 8) - (($nlen + 8) mod 8)) + (($tlen + 8) - (($tlen + 8) mod 8))"/>
 639     <h3><a id="{$name}"><code><xsl:value-of select="$name"/></code></a></h3>
 640     <pre class="api">
 641     <span class="type">
 642       <xsl:call-template name="dumptext">
 643         <xsl:with-param name="text" select="return/@type"/>
 644       </xsl:call-template>
 645     </span>
 646     <xsl:text>&#9;</xsl:text>
 647     <xsl:value-of select="@name"/>
 648     <xsl:if test="$blen - 40 &lt; -8">
 649       <xsl:text>&#9;</xsl:text>
 650     </xsl:if>
 651     <xsl:if test="$blen - 40 &lt; 0">
 652       <xsl:text>&#9;</xsl:text>
 653     </xsl:if>
 654     <xsl:text>&#9;(</xsl:text>
 655     <xsl:if test="not(arg)">
 656       <span class="type">void</span>
 657     </xsl:if>
 658     <xsl:for-each select="arg">
 659       <span class="type">
 660         <xsl:call-template name="dumptext">
 661           <xsl:with-param name="text" select="@type"/>
 662         </xsl:call-template>
 663       </span>
 664       <xsl:text> </xsl:text>
 665       <xsl:value-of select="@name"/>
 666       <xsl:if test="position() != last()">
 667         <xsl:text>,
 668 </xsl:text>
 669         <xsl:if test="$blen - 40 &gt; 8">
 670           <xsl:text>&#9;</xsl:text>
 671         </xsl:if>
 672         <xsl:if test="$blen - 40 &gt; 0">
 673           <xsl:text>&#9;</xsl:text>
 674         </xsl:if>
 675         <xsl:text>&#9;&#9;&#9;&#9;&#9; </xsl:text>
 676       </xsl:if>
 677     </xsl:for-each>
 678     <xsl:text>)</xsl:text>
 679     </pre>
 680     <div class="description">
 681     <xsl:call-template name="formattext">
 682       <xsl:with-param name="text" select="info"/>
 683     </xsl:call-template>
 684     </div><xsl:text>
 685 </xsl:text>
 686     <xsl:if test="arg | return/@info">
 687       <dl class="variablelist">
 688         <xsl:for-each select="arg">
 689           <dt><xsl:value-of select="@name"/></dt>
 690           <dd>
 691             <xsl:call-template name="dumptext">
 692               <xsl:with-param name="text" select="@info"/>
 693             </xsl:call-template>
 694           </dd>
 695         </xsl:for-each>
 696         <xsl:if test="return/@info">
 697           <dt>Returns</dt>
 698           <dd>
 699             <xsl:call-template name="dumptext">
 700               <xsl:with-param name="text" select="return/@info"/>
 701             </xsl:call-template>
 702           </dd>
 703         </xsl:if>
 704       </dl>
 705     </xsl:if>
 706     <div class="acl">
 707       <xsl:call-template name="aclinfo">
 708         <xsl:with-param name="api" select="$name"/>
 709       </xsl:call-template>
 710     </div>
 711   </xsl:template>
 712
 713   <xsl:template match="exports" mode="toc">
 714     <xsl:apply-templates select="key('symbols', string(@symbol))[1]" mode="toc"/>
 715   </xsl:template>
 716
 717   <xsl:template match="exports">
 718     <xsl:apply-templates select="key('symbols', string(@symbol))[1]"/>
 719   </xsl:template>
 720
 721   <xsl:template name="description">
 722     <xsl:if test="deprecated">
 723       <h2 style="font-weight:bold;color:red;text-align:center">This module is deprecated</h2>
 724     </xsl:if>
 725     <xsl:if test="description">
 726       <p>
 727         <xsl:call-template name="dumptext">
 728           <xsl:with-param name="text" select="description"/>
 729         </xsl:call-template>
 730       </p>
 731     </xsl:if>
 732   </xsl:template>
 733
 734   <xsl:template name="docomponents">
 735     <xsl:apply-templates select="exports[@type='macro']">
 736       <xsl:sort select='@symbol'/>
 737     </xsl:apply-templates>
 738     <xsl:apply-templates select="exports[@type='enum']">
 739       <xsl:sort select='@symbol'/>
 740     </xsl:apply-templates>
 741     <xsl:apply-templates select="exports[@type='typedef']">
 742       <xsl:sort select='@symbol'/>
 743     </xsl:apply-templates>
 744     <xsl:apply-templates select="exports[@type='struct']">
 745       <xsl:sort select='@symbol'/>
 746     </xsl:apply-templates>
 747     <xsl:apply-templates select="exports[@type='function']">
 748       <xsl:sort select='@symbol'/>
 749     </xsl:apply-templates>
 750   </xsl:template>
 751
 752   <xsl:template match="file">
 753     <xsl:variable name="name" select="@name"/>
 754     <xsl:variable name="title">Module <xsl:value-of select="$name"/> from <xsl:value-of select="/api/@name"/></xsl:variable>
 755     <xsl:text disable-output-escaping="yes">&lt;!DOCTYPE html&gt;
 756 </xsl:text>
 757     <html>
 758       <body>
 759         <h1><xsl:value-of select="$title"/></h1>
 760         <xsl:call-template name="description"/>
 761         <h2>Table of Contents</h2>
 762         <xsl:if test="count(exports[@type='macro']) > 0">
 763           <h3><a href="#macros">Macros</a></h3>
 764           <pre class="api">
 765             <xsl:apply-templates select="exports[@type='macro']" mode="toc">
 766               <xsl:sort select='@symbol'/>
 767             </xsl:apply-templates>
 768           </pre>
 769         </xsl:if>
 770         <h3><a href="#types">Types</a></h3>
 771         <pre class="api">
 772           <xsl:apply-templates select="exports[@type='typedef']" mode="toc">
 773             <xsl:sort select='@symbol'/>
 774           </xsl:apply-templates>
 775         </pre>
 776         <h3><a href="#functions">Functions</a></h3>
 777         <pre class="api">
 778           <xsl:apply-templates select="exports[@type='function']" mode="toc">
 779             <xsl:sort select='@symbol'/>
 780           </xsl:apply-templates>
 781         </pre>
 782
 783         <h2>Description</h2>
 784
 785         <xsl:if test="count(exports[@type='macro']) > 0">
 786           <h3><a id="macros">Macros</a></h3>
 787           <xsl:apply-templates select="exports[@type='macro']">
 788             <xsl:sort select='@symbol'/>
 789           </xsl:apply-templates>
 790         </xsl:if>
 791         <h3><a id="types">Types</a></h3>
 792         <xsl:apply-templates select="exports[@type='typedef']">
 793           <xsl:sort select='@symbol'/>
 794         </xsl:apply-templates>
 795         <h3><a id="functions">Functions</a></h3>
 796         <xsl:apply-templates select="exports[@type='function']">
 797           <xsl:sort select='@symbol'/>
 798         </xsl:apply-templates>
 799       </body>
 800     </html>
 801   </xsl:template>
 802
 803   <xsl:template match="file" mode="toc">
 804     <xsl:variable name="name" select="@name"/>
 805     <li>
 806       <a href="libvirt-{$name}.html"><xsl:value-of select="$name"/></a>
 807       <xsl:text>: </xsl:text>
 808       <xsl:value-of select="summary"/>
 809     </li>
 810   </xsl:template>
 811
 812   <xsl:template name="mainpage">
 813     <xsl:variable name="title">Reference Manual for <xsl:value-of select="/api/@name"/></xsl:variable>
 814     <xsl:text disable-output-escaping="yes">&lt;!DOCTYPE html&gt;
 815 </xsl:text>
 816     <html>
 817       <body>
 818         <h1><xsl:value-of select="$title"/></h1>
 819         <h2>Table of Contents</h2>
 820         <ul>
 821           <xsl:apply-templates select="/api/files/file" mode="toc"/>
 822         </ul>
 823       </body>
 824     </html>
 825   </xsl:template>
 826
 827   <xsl:template match="/">
 828     <!-- Save the main index.html as well as a couple of copies -->
 829     <xsl:variable name="mainpage">
 830       <xsl:call-template name="mainpage"/>
 831     </xsl:variable>
 832     <xsl:document
 833       href="{concat($htmldir, '/index.html')}"
 834       method="xml"
 835       indent="yes"
 836       encoding="UTF-8">
 837       <xsl:apply-templates select="exsl:node-set($mainpage)" mode="page">
 838         <xsl:with-param name="pagename" select="concat($htmldir, '/index.html')"/>
 839         <xsl:with-param name="timestamp" select="$timestamp"/>
 840       </xsl:apply-templates>
 841     </xsl:document>
 842
 843     <xsl:for-each select="/api/files/file">
 844       <xsl:variable name="subpage">
 845         <xsl:apply-templates select="."/>
 846       </xsl:variable>
 847
 848       <xsl:document
 849         href="{concat($htmldir, '/libvirt-', @name, '.html')}"
 850         method="xml"
 851         indent="yes"
 852         encoding="UTF-8">
 853         <xsl:apply-templates select="exsl:node-set($subpage)" mode="page">
 854           <xsl:with-param name="pagename" select="concat($htmldir, '/libvirt-', @name, '.html')"/>
 855           <xsl:with-param name="timestamp" select="$timestamp"/>
 856         </xsl:apply-templates>
 857       </xsl:document>
 858     </xsl:for-each>
 859   </xsl:template>
 860
 861 </xsl:stylesheet>