m4/virt-secdriver-selinux.m4

   1 dnl The SElinux security driver
   2 dnl
   3 dnl Copyright (C) 2016 Red Hat, Inc.
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library.  If not, see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_DEFUN([LIBVIRT_SECDRIVER_ARG_SELINUX], [
  21   LIBVIRT_ARG_WITH([SECDRIVER_SELINUX], [use SELinux security driver], [check])
  22 ])
  23
  24 AC_DEFUN([LIBVIRT_SECDRIVER_CHECK_SELINUX], [
  25   AC_REQUIRE([LIBVIRT_CHECK_SELINUX])
  26
  27   if test "$with_selinux" != "yes" ; then
  28     if test "$with_secdriver_selinux" = "check" ; then
  29       with_secdriver_selinux=no
  30     fi
  31     if test "$with_secdriver_selinux" != "no"; then
  32       AC_MSG_ERROR([You must install the libselinux development package and enable SELinux with the --with-selinux=yes in order to compile libvirt --with-secdriver-selinux=yes])
  33     fi
  34   elif test "$with_secdriver_selinux" != "no"; then
  35     old_CFLAGS="$CFLAGS"
  36     old_LIBS="$LIBS"
  37     CFLAGS="$CFLAGS $SELINUX_CFLAGS"
  38     LIBS="$CFLAGS $SELINUX_LIBS"
  39
  40     fail=0
  41     AC_CHECK_FUNC([selinux_virtual_domain_context_path], [], [fail=1])
  42     AC_CHECK_FUNC([selinux_virtual_image_context_path], [], [fail=1])
  43     AC_CHECK_FUNCS([selinux_lxc_contexts_path])
  44     CFLAGS="$old_CFLAGS"
  45     LIBS="$old_LIBS"
  46
  47     if test "$fail" = "1" ; then
  48       if test "$with_secdriver_selinux" = "check" ; then
  49         with_secdriver_selinux=no
  50       else
  51         AC_MSG_ERROR([You must install libselinux development package >= 2.0.82 in order to compile libvirt --with-secdriver-selinux=yes])
  52       fi
  53     else
  54       with_secdriver_selinux=yes
  55       AC_DEFINE_UNQUOTED([WITH_SECDRIVER_SELINUX], 1, [whether SELinux security driver is available])
  56     fi
  57   fi
  58   AM_CONDITIONAL([WITH_SECDRIVER_SELINUX], [test "$with_secdriver_selinux" != "no"])
  59 ])
  60
  61 AC_DEFUN([LIBVIRT_SECDRIVER_RESULT_SELINUX], [
  62   LIBVIRT_RESULT([SELinux], [$with_secdriver_selinux])
  63 ])