ltdl.m4

   1 ## ltdl.m4 - Configure ltdl for the target system. -*-Autoconf-*-
   2 ## Copyright (C) 1999-2000 Free Software Foundation, Inc.
   3 ##
   4 ## This program is free software; you can redistribute it and/or modify
   5 ## it under the terms of the GNU General Public License as published by
   6 ## the Free Software Foundation; either version 2 of the License, or
   7 ## (at your option) any later version.
   8 ##
   9 ## This program is distributed in the hope that it will be useful, but
  10 ## WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 ## General Public License for more details.
  13 ##
  14 ## You should have received a copy of the GNU General Public License
  15 ## along with this program; if not, write to the Free Software
  16 ## Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  17 ##
  18 ## As a special exception to the GNU General Public License, if you
  19 ## distribute this file as part of a program that contains a
  20 ## configuration script generated by Autoconf, you may include it under
  21 ## the same distribution terms that you use for the rest of that program.
  22
  23 # serial 6 AC_LIB_LTDL
  24
  25 # AC_WITH_LTDL
  26 # ------------
  27 # Clients of libltdl can use this macro to allow the installer to
  28 # choose between a shipped copy of the ltdl sources or a preinstalled
  29 # version of the library.
  30 AC_DEFUN([AC_WITH_LTDL],
  31 [AC_REQUIRE([AC_LIB_LTDL])
  32 AC_SUBST([LIBLTDL])
  33 AC_SUBST([INCLTDL])
  34
  35 # Unless the user asks us to check, assume no installed ltdl exists.
  36 use_installed_libltdl=no
  37
  38 AC_ARG_WITH([included_ltdl],
  39     [  --with-included-ltdl    use the GNU ltdl sources included here])
  40
  41 if test "x$with_included_ltdl" != xyes; then
  42   # We are not being forced to use the included libltdl sources, so
  43   # decide whether there is a useful installed version we can use.
  44   AC_CHECK_HEADER([ltdl.h],
  45       [AC_CHECK_LIB([ltdl], [lt_dlcaller_register],
  46           [with_included_ltdl=no],
  47           [with_included_ltdl=yes])
  48   ])
  49 fi
  50
  51 if test "x$enable_ltdl_install" != xyes; then
  52   # If the user did not specify an installable libltdl, then default
  53   # to a convenience lib.
  54   AC_LIBLTDL_CONVENIENCE
  55 fi
  56
  57 if test "x$with_included_ltdl" = xno; then
  58   # If the included ltdl is not to be used. then Use the
  59   # preinstalled libltdl we found.
  60   AC_DEFINE([HAVE_LTDL], 1,
  61     [Define this if a modern libltdl is already installed])
  62   LIBLTDL=-lltdl
  63 fi
  64
  65 # Report our decision...
  66 AC_MSG_CHECKING([whether to use included libltdl])
  67 AC_MSG_RESULT([$with_included_ltdl])
  68
  69 AC_CONFIG_SUBDIRS([libltdl])
  70 ])# AC_WITH_LTDL
  71
  72
  73 # AC_LIB_LTDL
  74 # -----------
  75 # Perform all the checks necessary for compilation of the ltdl objects
  76 #  -- including compiler checks and header checks.
  77 AC_DEFUN([AC_LIB_LTDL],
  78 [AC_PREREQ(2.50)
  79 AC_REQUIRE([AC_PROG_CC])
  80 AC_REQUIRE([AC_C_CONST])
  81 AC_REQUIRE([AC_HEADER_STDC])
  82 AC_REQUIRE([AC_HEADER_DIRENT])
  83 AC_REQUIRE([_LT_AC_CHECK_DLFCN])
  84 AC_REQUIRE([AC_LTDL_ENABLE_INSTALL])
  85 AC_REQUIRE([AC_LTDL_SHLIBEXT])
  86 AC_REQUIRE([AC_LTDL_SHLIBPATH])
  87 AC_REQUIRE([AC_LTDL_SYSSEARCHPATH])
  88 AC_REQUIRE([AC_LTDL_OBJDIR])
  89 AC_REQUIRE([AC_LTDL_DLPREOPEN])
  90 AC_REQUIRE([AC_LTDL_DLLIB])
  91 AC_REQUIRE([AC_LTDL_SYMBOL_USCORE])
  92 AC_REQUIRE([AC_LTDL_DLSYM_USCORE])
  93 AC_REQUIRE([AC_LTDL_SYS_DLOPEN_DEPLIBS])
  94 AC_REQUIRE([AC_LTDL_FUNC_ARGZ])
  95
  96 AC_CHECK_HEADERS([assert.h ctype.h errno.h malloc.h memory.h stdlib.h \
  97                   stdio.h unistd.h])
  98 AC_CHECK_HEADERS([dl.h sys/dl.h dld.h])
  99 AC_CHECK_HEADERS([string.h strings.h], [break])
 100
 101 AC_CHECK_FUNCS([strchr index], [break])
 102 AC_CHECK_FUNCS([strrchr rindex], [break])
 103 AC_CHECK_FUNCS([memcpy bcopy], [break])
 104 AC_CHECK_FUNCS([memmove strcmp])
 105 AC_CHECK_FUNCS([closedir opendir readdir])
 106 ])# AC_LIB_LTDL
 107
 108
 109 # AC_LTDL_ENABLE_INSTALL
 110 # ----------------------
 111 AC_DEFUN([AC_LTDL_ENABLE_INSTALL],
 112 [AC_ARG_ENABLE([ltdl-install],
 113     [AC_HELP_STRING([--enable-ltdl-install], [install libltdl])])
 114
 115 AM_CONDITIONAL(INSTALL_LTDL, test x"${enable_ltdl_install-no}" != xno)
 116 AM_CONDITIONAL(CONVENIENCE_LTDL, test x"${enable_ltdl_convenience-no}" != xno)
 117 ])])# AC_LTDL_ENABLE_INSTALL
 118
 119
 120 # AC_LTDL_SYS_DLOPEN_DEPLIBS
 121 # --------------------------
 122 AC_DEFUN([AC_LTDL_SYS_DLOPEN_DEPLIBS],
 123 [AC_REQUIRE([AC_CANONICAL_HOST])
 124 AC_CACHE_CHECK([whether deplibs are loaded by dlopen],
 125   [libltdl_cv_sys_dlopen_deplibs],
 126   [# PORTME does your system automatically load deplibs for dlopen?
 127   # or its logical equivalent (e.g. shl_load for HP-UX < 11)
 128   # For now, we just catch OSes we know something about -- in the
 129   # future, we'll try test this programmatically.
 130   libltdl_cv_sys_dlopen_deplibs=unknown
 131   case "$host_os" in
 132   aix3*|aix4.1.*|aix4.2.*)
 133     # Unknown whether this is true for these versions of AIX, but
 134     # we want this `case' here to explicitly catch those versions.
 135     libltdl_cv_sys_dlopen_deplibs=unknown
 136     ;;
 137   aix[[45]]*)
 138     libltdl_cv_sys_dlopen_deplibs=yes
 139     ;;
 140   darwin*)
 141     # Assuming the user has installed a libdl from somewhere, this is true
 142     # If you are looking for one http://www.opendarwin.org/projects/dlcompat
 143     libltdl_cv_sys_dlopen_deplibs=yes
 144     ;;
 145   gnu*)
 146     libltdl_cv_sys_dlopen_deplibs=yes
 147     ;;
 148   hpux10*|hpux11*)
 149     libltdl_cv_sys_dlopen_deplibs=yes
 150     ;;
 151   irix[[12345]]*|irix6.[[01]]*)
 152     # Catch all versions of IRIX before 6.2, and indicate that we don't
 153     # know how it worked for any of those versions.
 154     libltdl_cv_sys_dlopen_deplibs=unknown
 155     ;;
 156   irix*)
 157     # The case above catches anything before 6.2, and it's known that
 158     # at 6.2 and later dlopen does load deplibs.
 159     libltdl_cv_sys_dlopen_deplibs=yes
 160     ;;
 161   linux*)
 162     libltdl_cv_sys_dlopen_deplibs=yes
 163     ;;
 164   netbsd*)
 165     libltdl_cv_sys_dlopen_deplibs=yes
 166     ;;
 167   openbsd*)
 168     libltdl_cv_sys_dlopen_deplibs=yes
 169     ;;
 170   osf[[1234]]*)
 171     # dlopen did load deplibs (at least at 4.x), but until the 5.x series,
 172     # it did *not* use an RPATH in a shared library to find objects the
 173     # library depends on, so we explictly say `no'.
 174     libltdl_cv_sys_dlopen_deplibs=no
 175     ;;
 176   osf5.0|osf5.0a|osf5.1)
 177     # dlopen *does* load deplibs and with the right loader patch applied
 178     # it even uses RPATH in a shared library to search for shared objects
 179     # that the library depends on, but there's no easy way to know if that
 180     # patch is installed.  Since this is the case, all we can really
 181     # say is unknown -- it depends on the patch being installed.  If
 182     # it is, this changes to `yes'.  Without it, it would be `no'.
 183     libltdl_cv_sys_dlopen_deplibs=unknown
 184     ;;
 185   osf*)
 186     # the two cases above should catch all versions of osf <= 5.1.  Read
 187     # the comments above for what we know about them.
 188     # At > 5.1, deplibs are loaded *and* any RPATH in a shared library
 189     # is used to find them so we can finally say `yes'.
 190     libltdl_cv_sys_dlopen_deplibs=yes
 191     ;;
 192   solaris*)
 193     libltdl_cv_sys_dlopen_deplibs=yes
 194     ;;
 195   esac
 196   ])
 197 if test "$libltdl_cv_sys_dlopen_deplibs" != yes; then
 198  AC_DEFINE([LTDL_DLOPEN_DEPLIBS], [1],
 199     [Define if the OS needs help to load dependent libraries for dlopen().])
 200 fi
 201 ])# AC_LTDL_SYS_DLOPEN_DEPLIBS
 202
 203
 204 # AC_LTDL_SHLIBEXT
 205 # ----------------
 206 AC_DEFUN([AC_LTDL_SHLIBEXT],
 207 [AC_REQUIRE([AC_LIBTOOL_SYS_DYNAMIC_LINKER])
 208 AC_CACHE_CHECK([which extension is used for shared libraries],
 209   [libltdl_cv_shlibext],
 210   [ac_last=
 211   for ac_spec in $library_names_spec; do
 212     ac_last="$ac_spec"
 213   done
 214   echo "$ac_last" | [sed 's/\[.*\]//;s/^[^.]*//;s/\$.*$//;s/\.$//'] > conftest
 215   libltdl_cv_shlibext=`cat conftest`
 216   rm -f conftest
 217   ])
 218   # The above does not work on darwin, due to the test's in the library_names_spec
 219   # The test description should probably say "which extension is used for loadable
 220   # modules"
 221   case "$host_os" in
 222     darwin*) libltdl_cv_shlibext=".so" ;;
 223   esac
 224 if test -n "$libltdl_cv_shlibext"; then
 225   AC_DEFINE_UNQUOTED(LTDL_SHLIB_EXT, "$libltdl_cv_shlibext",
 226     [Define to the extension used for shared libraries, say, ".so".])
 227 fi
 228 ])# AC_LTDL_SHLIBEXT
 229
 230
 231 # AC_LTDL_SHLIBPATH
 232 # -----------------
 233 AC_DEFUN([AC_LTDL_SHLIBPATH],
 234 [AC_REQUIRE([AC_LIBTOOL_SYS_DYNAMIC_LINKER])
 235 AC_CACHE_CHECK([which variable specifies run-time library path],
 236   [libltdl_cv_shlibpath_var], [libltdl_cv_shlibpath_var="$shlibpath_var"])
 237 if test -n "$libltdl_cv_shlibpath_var"; then
 238   AC_DEFINE_UNQUOTED(LTDL_SHLIBPATH_VAR, "$libltdl_cv_shlibpath_var",
 239     [Define to the name of the environment variable that determines the dynamic library search path.])
 240 fi
 241 ])# AC_LTDL_SHLIBPATH
 242
 243
 244 # AC_LTDL_SYSSEARCHPATH
 245 # ---------------------
 246 AC_DEFUN([AC_LTDL_SYSSEARCHPATH],
 247 [AC_REQUIRE([AC_LIBTOOL_SYS_DYNAMIC_LINKER])
 248 AC_CACHE_CHECK([for the default library search path],
 249   [libltdl_cv_sys_search_path],
 250   [libltdl_cv_sys_search_path="$sys_lib_dlsearch_path_spec"])
 251 if test -n "$libltdl_cv_sys_search_path"; then
 252   sys_search_path=
 253   for dir in $libltdl_cv_sys_search_path; do
 254     if test -z "$sys_search_path"; then
 255       sys_search_path="$dir"
 256     else
 257       sys_search_path="$sys_search_path$PATH_SEPARATOR$dir"
 258     fi
 259   done
 260   AC_DEFINE_UNQUOTED(LTDL_SYSSEARCHPATH, "$sys_search_path",
 261     [Define to the system default library search path.])
 262 fi
 263 ])# AC_LTDL_SYSSEARCHPATH
 264
 265
 266 # AC_LTDL_OBJDIR
 267 # --------------
 268 AC_DEFUN([AC_LTDL_OBJDIR],
 269 [AC_CACHE_CHECK([for objdir],
 270   [libltdl_cv_objdir],
 271   [libltdl_cv_objdir="$objdir"
 272   if test -n "$objdir"; then
 273     :
 274   else
 275     rm -f .libs 2>/dev/null
 276     mkdir .libs 2>/dev/null
 277     if test -d .libs; then
 278       libltdl_cv_objdir=.libs
 279     else
 280       # MS-DOS does not allow filenames that begin with a dot.
 281       libltdl_cv_objdir=_libs
 282     fi
 283   rmdir .libs 2>/dev/null
 284   fi
 285   ])
 286 AC_DEFINE_UNQUOTED(LTDL_OBJDIR, "$libltdl_cv_objdir/",
 287   [Define to the sub-directory in which libtool stores uninstalled libraries.])
 288 ])# AC_LTDL_OBJDIR
 289
 290
 291 # AC_LTDL_DLPREOPEN
 292 # -----------------
 293 AC_DEFUN([AC_LTDL_DLPREOPEN],
 294 [AC_REQUIRE([AC_LIBTOOL_SYS_GLOBAL_SYMBOL_PIPE])
 295 AC_CACHE_CHECK([whether libtool supports -dlopen/-dlpreopen],
 296   [libltdl_cv_preloaded_symbols],
 297   [if test -n "$lt_cv_sys_global_symbol_pipe"; then
 298     libltdl_cv_preloaded_symbols=yes
 299   else
 300     libltdl_cv_preloaded_symbols=no
 301   fi
 302   ])
 303 if test x"$libltdl_cv_preloaded_symbols" = xyes; then
 304   AC_DEFINE(HAVE_PRELOADED_SYMBOLS, 1,
 305     [Define if libtool can extract symbol lists from object files.])
 306 fi
 307 ])# AC_LTDL_DLPREOPEN
 308
 309
 310 # AC_LTDL_DLLIB
 311 # -------------
 312 AC_DEFUN([AC_LTDL_DLLIB],
 313 [LIBADD_DL=
 314 AC_SUBST(LIBADD_DL)
 315 AC_LANG_PUSH([C])
 316
 317 AC_CHECK_FUNC([shl_load],
 318       [AC_DEFINE([HAVE_SHL_LOAD], [1],
 319                  [Define if you have the shl_load function.])],
 320   [AC_CHECK_LIB([dld], [shl_load],
 321         [AC_DEFINE([HAVE_SHL_LOAD], [1],
 322                    [Define if you have the shl_load function.])
 323         LIBADD_DL="$LIBADD_DL -ldld"],
 324     [AC_CHECK_LIB([dl], [dlopen],
 325           [AC_DEFINE([HAVE_LIBDL], [1],
 326                      [Define if you have the libdl library or equivalent.])
 327                 LIBADD_DL="-ldl" libltdl_cv_lib_dl_dlopen="yes"],
 328       [AC_TRY_LINK([#if HAVE_DLFCN_H
 329 #  include <dlfcn.h>
 330 #endif
 331       ],
 332         [dlopen(0, 0);],
 333             [AC_DEFINE([HAVE_LIBDL], [1],
 334                              [Define if you have the libdl library or equivalent.]) libltdl_cv_func_dlopen="yes"],
 335         [AC_CHECK_LIB([svld], [dlopen],
 336               [AC_DEFINE([HAVE_LIBDL], [1],
 337                          [Define if you have the libdl library or equivalent.])
 338                     LIBADD_DL="-lsvld" libltdl_cv_func_dlopen="yes"],
 339           [AC_CHECK_LIB([dld], [dld_link],
 340                 [AC_DEFINE([HAVE_DLD], [1],
 341                            [Define if you have the GNU dld library.])
 342                 LIBADD_DL="$LIBADD_DL -ldld"
 343           ])
 344         ])
 345       ])
 346     ])
 347   ])
 348 ])
 349
 350 if test x"$libltdl_cv_func_dlopen" = xyes || test x"$libltdl_cv_lib_dl_dlopen" = xyes
 351 then
 352   lt_save_LIBS="$LIBS"
 353   LIBS="$LIBS $LIBADD_DL"
 354   AC_CHECK_FUNCS([dlerror])
 355   LIBS="$lt_save_LIBS"
 356 fi
 357 AC_LANG_POP
 358 ])# AC_LTDL_DLLIB
 359
 360
 361 # AC_LTDL_SYMBOL_USCORE
 362 # ---------------------
 363 # does the compiler prefix global symbols with an underscore?
 364 AC_DEFUN([AC_LTDL_SYMBOL_USCORE],
 365 [AC_REQUIRE([AC_LIBTOOL_SYS_GLOBAL_SYMBOL_PIPE])
 366 AC_CACHE_CHECK([for _ prefix in compiled symbols],
 367   [ac_cv_sys_symbol_underscore],
 368   [ac_cv_sys_symbol_underscore=no
 369   cat > conftest.$ac_ext <<EOF
 370 void nm_test_func(){}
 371 int main(){nm_test_func;return 0;}
 372 EOF
 373   if AC_TRY_EVAL(ac_compile); then
 374     # Now try to grab the symbols.
 375     ac_nlist=conftest.nm
 376     if AC_TRY_EVAL(NM conftest.$ac_objext \| $lt_cv_sys_global_symbol_pipe \> $ac_nlist) && test -s "$ac_nlist"; then
 377       # See whether the symbols have a leading underscore.
 378       if grep '^. _nm_test_func' "$ac_nlist" >/dev/null; then
 379         ac_cv_sys_symbol_underscore=yes
 380       else
 381         if grep '^. nm_test_func ' "$ac_nlist" >/dev/null; then
 382           :
 383         else
 384           echo "configure: cannot find nm_test_func in $ac_nlist" >&AC_FD_CC
 385         fi
 386       fi
 387     else
 388       echo "configure: cannot run $lt_cv_sys_global_symbol_pipe" >&AC_FD_CC
 389     fi
 390   else
 391     echo "configure: failed program was:" >&AC_FD_CC
 392     cat conftest.c >&AC_FD_CC
 393   fi
 394   rm -rf conftest*
 395   ])
 396 ])# AC_LTDL_SYMBOL_USCORE
 397
 398
 399 # AC_LTDL_DLSYM_USCORE
 400 # --------------------
 401 AC_DEFUN([AC_LTDL_DLSYM_USCORE],
 402 [AC_REQUIRE([AC_LTDL_SYMBOL_USCORE])
 403 if test x"$ac_cv_sys_symbol_underscore" = xyes; then
 404   if test x"$libltdl_cv_func_dlopen" = xyes ||
 405      test x"$libltdl_cv_lib_dl_dlopen" = xyes ; then
 406         AC_CACHE_CHECK([whether we have to add an underscore for dlsym],
 407           [libltdl_cv_need_uscore],
 408           [libltdl_cv_need_uscore=unknown
 409           save_LIBS="$LIBS"
 410           LIBS="$LIBS $LIBADD_DL"
 411           _LT_AC_TRY_DLOPEN_SELF(
 412             [libltdl_cv_need_uscore=no], [libltdl_cv_need_uscore=yes],
 413             [],                          [libltdl_cv_need_uscore=cross])
 414           LIBS="$save_LIBS"
 415         ])
 416   fi
 417 fi
 418
 419 if test x"$libltdl_cv_need_uscore" = xyes; then
 420   AC_DEFINE(NEED_USCORE, 1,
 421     [Define if dlsym() requires a leading underscore in symbol names.])
 422 fi
 423 ])# AC_LTDL_DLSYM_USCORE
 424
 425 # AC_LTDL_FUNC_ARGZ
 426 # -----------------
 427 AC_DEFUN([AC_LTDL_FUNC_ARGZ],
 428 [AC_CHECK_HEADERS([argz.h])
 429
 430 AC_CHECK_TYPES([error_t],
 431   [],
 432   [AC_DEFINE([error_t], [int],
 433     [Define to a type to use for `error_t' if it is not otherwise available.])],
 434   [#if HAVE_ARGZ_H
 435 #  include <argz.h>
 436 #endif])
 437
 438 AC_CHECK_FUNCS([argz_append argz_create_sep argz_insert argz_next argz_stringify])
 439 ])# AC_LTDL_FUNC_ARGZ