m4/m4.m4

   1 # m4.m4 serial 12
   2
   3 # Copyright (C) 2000, 2006-2019, 2021-2024 Free Software Foundation,
   4 # Inc.
   5
   6 # Copying and distribution of this file, with or without modification,
   7 # are permitted in any medium without royalty provided the copyright
   8 # notice and this notice are preserved.  This file is offered as-is,
   9 # without warranty of any kind.
  10
  11 # AC_PROG_GNU_M4
  12 # --------------
  13 # Check for GNU M4, at least 1.4.6 (all earlier versions had bugs in
  14 # trace support and regexp support):
  15 # http://lists.gnu.org/archive/html/bug-gnu-utils/2006-11/msg00096.html
  16 # http://lists.gnu.org/archive/html/bug-autoconf/2009-07/msg00023.html
  17 # Also, check whether --error-output (through 1.4.x) or --debugfile (2.0)
  18 # is supported, and AC_SUBST M4_DEBUGFILE accordingly.
  19 # Also avoid versions of m4 that trigger strstr bugs.
  20 AC_DEFUN([AC_PROG_GNU_M4],
  21   [AC_ARG_VAR([M4], [Location of GNU M4 1.4.6 or later.  Defaults to the first
  22     program of 'm4', 'gm4', or 'gnum4' on PATH that meets Autoconf needs.])
  23   AC_CACHE_CHECK([for GNU M4 that supports accurate traces], [ac_cv_path_M4],
  24     [rm -f conftest.m4f
  25 ac_had_posixly_correct=${POSIXLY_CORRECT:+yes}
  26 AS_UNSET([POSIXLY_CORRECT])
  27 AC_PATH_PROGS_FEATURE_CHECK([M4], [m4 gm4 gnum4],
  28       [dnl Creative quoting here to avoid raw dnl and ifdef in configure.
  29       # Root out GNU M4 1.4.5, as well as non-GNU m4 that ignore -t, -F.
  30       # Root out GNU M4 1.4.15 with buggy false negative replacement strstr.
  31       # Root out Glibc 2.9 - 2.12 and GNU M4 1.4.11 - 1.4.15 with buggy
  32       # false positive strstr.
  33       ac_snippet=change'quote(<,>)in''dir(<if''def>,mac,bug)'
  34       ac_snippet=${ac_snippet}pat'subst(a,\(b\)\|\(a\),\1)d'nl
  35       ac_snippet=$ac_snippet${as_nl}if'else(in''dex(..wi.d.,.d.),-1,bug)'
  36       ac_snippet=$ac_snippet${as_nl}if'else(in''dex(dnl
  37 ;:11-:12-:12-:12-:12-:12-:12-:12-:12.:12.:12.:12.:12.:12.:12.:12.:12-,dnl
  38 :12-:12-:12-:12-:12-:12-:12-:12-),-1,,strstr-bug2)'
  39       test -z "`$ac_path_M4 -F conftest.m4f </dev/null 2>&1`" \
  40       && test -z "`AS_ECHO([$ac_snippet]) | $ac_path_M4 --trace=mac 2>&1`" \
  41       && test -f conftest.m4f \
  42       && ac_cv_path_M4=$ac_path_M4 ac_path_M4_found=:
  43       rm -f conftest.m4f],
  44       [AC_MSG_ERROR([no acceptable m4 could be found in \$PATH.
  45 GNU M4 1.4.6 or later is required; 1.4.16 or newer is recommended.
  46 GNU M4 1.4.15 uses a buggy replacement strstr on some systems.
  47 Glibc 2.9 - 2.12 and GNU M4 1.4.11 - 1.4.15 have another strstr bug.])])])
  48   M4=$ac_cv_path_M4
  49   AC_CACHE_CHECK([whether $ac_cv_path_M4 accepts --gnu],
  50     [ac_cv_prog_gnu_m4_gnu],
  51     [case `$M4 --help < /dev/null 2>&1` in
  52       *--gnu*) ac_cv_prog_gnu_m4_gnu=yes ;;
  53       *) ac_cv_prog_gnu_m4_gnu=no ;;
  54     esac])
  55   if test yes = "$ac_cv_prog_gnu_m4_gnu"; then
  56     M4_GNU=--gnu
  57   else
  58     M4_GNU=
  59   fi
  60   AC_SUBST([M4_GNU])
  61   if test yes = "$ac_had_posixly_correct"; then
  62     POSIXLY_CORRECT=:
  63     if test no = $ac_cv_prog_gnu_m4_gnu; then
  64       AC_MSG_WARN([the version of M4 that was found does not support -g])
  65       AC_MSG_WARN([using it with POSIXLY_CORRECT set may cause problems])
  66     fi
  67   fi
  68   AC_CACHE_CHECK([how m4 supports trace files], [ac_cv_prog_gnu_m4_debugfile],
  69     [case `$M4 --help < /dev/null 2>&1` in
  70       *debugfile*) ac_cv_prog_gnu_m4_debugfile=--debugfile ;;
  71       *) ac_cv_prog_gnu_m4_debugfile=--error-output ;;
  72     esac])
  73   AC_SUBST([M4_DEBUGFILE], [$ac_cv_prog_gnu_m4_debugfile])
  74 ])
  75
  76 # Compatibility for bootstrapping with Autoconf 2.61.
  77 dnl FIXME - replace this with AC_PREREQ([2.62]) after the release.
  78 # AC_PATH_PROGS_FEATURE_CHECK was added the same time the slightly broken,
  79 # undocumented _AC_PATH_PROG_FEATURE_CHECK was deleted.
  80 m4_ifndef([AC_PATH_PROGS_FEATURE_CHECK],
  81   [m4_define([AC_PATH_PROGS_FEATURE_CHECK],
  82     [_AC_PATH_PROG_FEATURE_CHECK([$1], [$2], [$3], [$5])
  83 ])])