configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation
   3 #
   4 # This file is part of LIBTASN1.
   5 #
   6 # This file is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This file is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 # General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this file; if not, write to the Free Software Foundation,
  18 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  19
  20 AC_PREREQ(2.59)
  21 AC_INIT([libtasn1], [0.3.6], [bug-gnutls@gnu.org])
  22 AM_INIT_AUTOMAKE([1.9 gnits])
  23 AM_CONFIG_HEADER(config.h)
  24 AB_INIT
  25
  26 # Library code modified:                              REVISION++
  27 # Interfaces changed/added/removed:   CURRENT++       REVISION=0
  28 # Interfaces added:                             AGE++
  29 # Interfaces removed:                           AGE=0
  30 AC_SUBST(LT_CURRENT, 3)
  31 AC_SUBST(LT_REVISION, 6)
  32 AC_SUBST(LT_AGE, 0)
  33
  34 AC_PROG_CC
  35 gl_EARLY
  36 AC_PROG_YACC
  37 AC_PROG_LN_S
  38
  39 dnl Checks for programs.
  40 AC_PROG_INSTALL
  41 AM_MISSING_PROG(PERL,perl,$missing_dir)
  42 AM_MISSING_PROG(HELP2MAN, help2man, $missing_dir)
  43
  44 AC_MSG_NOTICE([Detecting options for shared libraries])
  45 AC_LIBTOOL_WIN32_DLL
  46 AM_PROG_LIBTOOL
  47
  48 AC_MSG_NOTICE([Detecting compiler options])
  49 AC_C_CONST
  50
  51 dnl In order to use the reentrant libc functions.
  52 dnl I hope it is portable enough.
  53 CFLAGS="${CFLAGS} -D_REENTRANT -D_THREAD_SAFE"
  54
  55 if test "$GCC" = "yes"; then
  56         CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wstrict-prototypes"
  57
  58         AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
  59         _gcc_cflags_save=$CFLAGS
  60         CFLAGS="-Wno-pointer-sign"
  61         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
  62         AC_MSG_RESULT($_gcc_psign)
  63         if test x"$_gcc_psign" != xyes ; then
  64           CFLAGS=$_gcc_cflags_save;
  65         fi
  66
  67         AC_MSG_CHECKING([whether we have GNU assembler])
  68         GAS=`as --version < /dev/null 2>/dev/null|grep GNU`
  69         if test "$GAS"; then
  70           CFLAGS="${CFLAGS} -pipe"
  71           AC_MSG_RESULT(yes)
  72         else
  73           AC_MSG_RESULT(no)
  74         fi
  75 fi
  76
  77
  78 AC_MSG_NOTICE([Detecting C library capabilities])
  79
  80 AC_CHECK_HEADERS(getopt.h strings.h inttypes.h stdint.h)
  81 AC_CHECK_FUNCS(getopt_long)
  82 AC_FUNC_ALLOCA
  83
  84 AC_MSG_NOTICE([Detecting system's parameters])
  85
  86 # Run self-tests under valgrind?
  87 if test "$cross_compiling" = no; then
  88   AC_CHECK_PROGS(VALGRIND, valgrind)
  89 fi
  90 if test -n "$VALGRIND" && $VALGRIND true > /dev/null 2>&1; then
  91   opt_valgrind_tests=yes
  92 else
  93   opt_valgrind_tests=no
  94   VALGRIND=
  95 fi
  96 AC_MSG_CHECKING([whether self tests are run under valgrind])
  97 AC_ARG_ENABLE(valgrind-tests,
  98         AS_HELP_STRING([--enable-valgrind-tests],
  99                        [run self tests under valgrind]),
 100   opt_valgrind_tests=$enableval)
 101 AC_MSG_RESULT($opt_valgrind_tests)
 102
 103 AC_CHECK_SIZEOF(unsigned long int, 4)
 104 AC_CHECK_SIZEOF(unsigned int, 4)
 105
 106 # For some systems we know that we have ld_version scripts.
 107 # Use it then as default.
 108 have_ld_version_script=no
 109 case "${host}" in
 110     *-*-linux*)
 111         have_ld_version_script=yes
 112         ;;
 113     *-*-gnu*)
 114         have_ld_version_script=yes
 115         ;;
 116 esac
 117 AC_ARG_ENABLE([ld-version-script],
 118               AC_HELP_STRING([--enable-ld-version-script],
 119                              [enable/disable use of linker version script.
 120                               (default is system dependent)]),
 121               [have_ld_version_script=$enableval],
 122               [ : ] )
 123 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 124
 125 # For gnulib compatibility modules in gl/.
 126 gl_INIT
 127
 128 # For libtasn1-config.
 129 LIBTASN1_LIBS="-L${libdir} -ltasn1 $LIBS"
 130 LIBTASN1_CFLAGS="-I${includedir}"
 131 AC_SUBST(LIBTASN1_LIBS)
 132 AC_SUBST(LIBTASN1_CFLAGS)
 133 AC_CONFIG_COMMANDS([chmod],[[
 134  chmod +x lib/libtasn1-config
 135 ]],[[]])
 136
 137 # Check for gtk-doc.
 138 GTK_DOC_CHECK(1.2)
 139
 140 # Update version number in lib/libtasn1.h.
 141 if ! sed 's/_VERSION ".*"/_VERSION "'$PACKAGE_VERSION'"/' \
 142      $srcdir/lib/libtasn1.h > fixhdr.tmp; then
 143   AC_MSG_ERROR([[*** Failed to update version number in lib/libtasn1.h...]])
 144 fi
 145 if cmp -s $srcdir/lib/libtasn1.h fixhdr.tmp 2>/dev/null; then
 146   rm -f fixhdr.tmp
 147 elif ! mv fixhdr.tmp $srcdir/lib/libtasn1.h; then
 148   AC_MSG_ERROR([[*** Failed to move fixhdr.tmp to lib/libtasn1.h...]])
 149 fi
 150
 151 AC_CONFIG_FILES([Makefile src/Makefile tests/Makefile lib/Makefile \
 152         lib/libtasn1.pc lib/libtasn1-config doc/Makefile \
 153         doc/reference/Makefile])
 154 AC_OUTPUT