configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5
   6 m4_include([m4/version.m4])
   7
   8 AC_INIT([libquvi],[libquvi_lt_rel],
   9         [http://quvi.sf.net/bugs/],[],[http://quvi.sf.net/])
  10
  11 # Interface:
  12 LT_REL=libquvi_lt_rel
  13 LT_CUR=libquvi_lt_cur
  14 LT_REV=libquvi_lt_rev
  15 LT_AGE=libquvi_lt_age
  16 AC_SUBST([LT_REL])
  17 AC_SUBST([LT_CUR])
  18 AC_SUBST([LT_REV])
  19 AC_SUBST([LT_AGE])
  20
  21 AC_CONFIG_SRCDIR([src/api/new.c])
  22 AC_CONFIG_HEADERS([config.h])
  23 AC_CONFIG_AUX_DIR([config.aux])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CANONICAL_TARGET
  27 AC_USE_SYSTEM_EXTENSIONS
  28
  29 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target", [...])
  30 AC_DEFINE_UNQUOTED([CANONICAL_BUILD], "$build", [...])
  31 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [...])
  32
  33 AM_INIT_AUTOMAKE([1.11.1 -Wall -Werror dist-xz no-dist-gzip tar-ustar])
  34 AM_SILENT_RULES([yes])
  35 #AM_PROG_AR
  36
  37 LT_INIT([disable-static])
  38 LT_PREREQ([2.2.6])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AM_PROG_CC_C_O
  43
  44 AC_PATH_PROG([DOXYGEN], [doxygen], [no])
  45 AM_CONDITIONAL([HAVE_DOXYGEN], [test x"$DOXYGEN" != "xno"])
  46 AC_SUBST([DOXYGEN])
  47
  48 AC_PATH_PROG([DATE], [date], [no])
  49 AS_IF([test "$DATE" != x"$xno"], [build_time=`$DATE +"%F %T %z"`])
  50 AC_DEFINE_UNQUOTED([BUILD_TIME], ["$build_time"], [We have build time])
  51
  52 AC_PATH_PROG([VALGRIND], [valgrind], [no])
  53 AM_CONDITIONAL([HAVE_VALGRIND], [test x"$VALGRIND" != "xno"])
  54 AC_SUBST([VALGRIND])
  55
  56 # Checks for libraries.
  57 PKG_CHECK_MODULES([liblua], [lua >= 5.1], [], [
  58   PKG_CHECK_MODULES([liblua], [lua51 >= 5.1], [], [
  59     PKG_CHECK_MODULES([liblua], [lua5.1 >= 5.1], [], [
  60       PKG_CHECK_MODULES(liblua, [lua-5.1 >= 5.1])])
  61   ])
  62 ])
  63 PKG_CHECK_MODULES([libproxy], [libproxy-1.0 >= 0.3.1])
  64 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.21])
  65 PKG_CHECK_MODULES([glib], [glib-2.0 >= 2.24])
  66
  67 # Checks for scripts.
  68 pkg_scripts=libquvi-scripts-1.0
  69
  70 AC_ARG_WITH([scriptsdir],
  71   [AS_HELP_STRING([--with-scriptsdir=DIR],
  72     [Set libquvi-scripts directory to DIR. This negates the
  73     libquvi-scripts check.  DIR is assumed to contain the files
  74     installed with libquvi-scripts to the
  75       $prefix/share/libquvi-scripts/ directory.])],
  76   [scriptsdir=$withval
  77    versionfile=$scriptsdir/version],
  78   [PKG_CHECK_MODULES([libquvi_scripts], [libquvi-scripts-1.0 >= 1.0])
  79     scriptsdir=`$PKG_CONFIG --variable scriptsdir $pkg_scripts 2>/dev/null`
  80     versionfile=`$PKG_CONFIG --variable versionfile $pkg_scripts 2>/dev/null`
  81     scriptsmodver=`$PKG_CONFIG --modversion $pkg_scripts 2>/dev/null`])
  82
  83 AS_IF([test -z "$scriptsdir"], [
  84   AC_MSG_ERROR([scriptsdir: variable not found])])
  85
  86 AS_IF([ ! test -d "$scriptsdir"], [
  87   AC_MSG_ERROR([$scriptsdir: does not exist or is not a directory])])
  88
  89 AS_IF([test -z "$versionfile"], [
  90   AC_MSG_ERROR([versionfile: variable not found])])
  91
  92 AS_IF([ ! test -f "$versionfile"], [
  93   AC_MSG_ERROR([$versionfile: does not exist or is not not a regular file])])
  94
  95 AC_DEFINE_UNQUOTED([SCRIPTSDIR], ["$scriptsdir"], [We have scriptsdir])
  96 AC_DEFINE_UNQUOTED([VERSIONFILE], ["$versionfile"], [We have versionfile])
  97
  98 scriptsver=`head -n1 "$versionfile" 2>/dev/null`
  99
 100 # Checks for header files.
 101 AC_CHECK_HEADERS([stdint.h string.h])
 102
 103 # Checks for typedefs, structures, and compiler characteristics.
 104 AC_TYPE_UINT32_T
 105 AC_TYPE_UINT64_T
 106 AC_TYPE_UINT8_T
 107
 108 # Checks for library functions.
 109 AC_CHECK_FUNCS([strrchr])
 110
 111 # Version.
 112 VN=`$srcdir/gen-ver.sh $srcdir`
 113 AC_DEFINE_UNQUOTED([VN], ["$VN"], [We have version number from gen-ver.sh])
 114
 115 # --with-manual
 116 AC_ARG_WITH([manual],
 117   [AS_HELP_STRING([--with-manual],
 118     [install manual pages @<:@default=yes@:>@])],
 119   [],
 120   [with_manual=yes])
 121 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
 122
 123 AC_CONFIG_FILES([
 124   Makefile
 125   doc/man3/Makefile
 126   doc/dox/Makefile
 127   doc/dox/Doxyfile
 128   doc/Makefile
 129   examples/Makefile
 130   examples/lib/Makefile
 131   src/misc/Makefile
 132   src/curl/Makefile
 133   src/net/Makefile
 134   src/api/Makefile
 135   src/lua/Makefile
 136   src/quvi-1.0/quvi/Makefile
 137   src/quvi-1.0/Makefile
 138   src/Makefile
 139   tests/Makefile
 140   tests/lib/Makefile
 141   libquvi-1.0.pc])
 142 AC_OUTPUT
 143
 144 AC_MSG_NOTICE([
 145   version         ${VERSION} (${VN})
 146   prefix          ${prefix}
 147   compiler        ${CC}
 148   cflags          ${CFLAGS}
 149 System types
 150   target          ${target}
 151   build           ${build}
 152   host            ${host}
 153 Options
 154   install manual  ${with_manual}
 155 libquvi-scripts
 156   .pc modversion  ${scriptsmodver}
 157   versionfile     ${versionfile}
 158     version       ${scriptsver}
 159   scriptsdir      ${scriptsdir}])