configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5
   6 m4_include([m4/version.m4])
   7
   8 AC_INIT([libquvi], m4_esyscmd([./gen-ver.sh -c | tr -d '\n']),
   9         [http://quvi.sf.net/bugs/],[],[http://quvi.sf.net/])
  10
  11 AC_DEFINE_UNQUOTED([BUILD_OPTS], "$@",
  12   [Define to configure invocation command line options])
  13
  14 # Interface
  15 LT_CUR=libquvi_lt_cur
  16 LT_REV=libquvi_lt_rev
  17 LT_AGE=libquvi_lt_age
  18 AC_SUBST([LT_CUR])
  19 AC_SUBST([LT_REV])
  20 AC_SUBST([LT_AGE])
  21
  22 AC_CONFIG_SRCDIR([src/api/new.c])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_AUX_DIR([config.aux])
  25 AC_CONFIG_MACRO_DIR([m4])
  26
  27 AC_CANONICAL_TARGET
  28 AC_USE_SYSTEM_EXTENSIONS
  29
  30 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target",
  31   [Define to canonical target])
  32 AC_DEFINE_UNQUOTED([CANONICAL_BUILD], "$build",
  33   [Define to canonical build])
  34 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host",
  35   [Define to canonical host])
  36
  37 # GNU Automake 1.13 spews a warning about AM_GNU_GETTEXT (0.18.1,
  38 # 0.18.2) using the deprecated AM_PROG_MKDIR_P macro. Do not specify
  39 # '-Werror` in the options to work around this.
  40 AM_INIT_AUTOMAKE([1.11.1 -Wall dist-xz no-dist-gzip tar-ustar])
  41 AM_SILENT_RULES([yes])
  42
  43 # GNU Automake 1.12 requires this macro. Earlier versions do not
  44 # recognize this macro. Work around this.
  45 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  46
  47 AM_GNU_GETTEXT_VERSION([0.18.1])
  48 AM_GNU_GETTEXT([external])
  49 # GETTEXT_PACKAGE is used by glib.
  50 AC_DEFINE([GETTEXT_PACKAGE], [PACKAGE], [Define to the gettext package name])
  51 AC_SUBST([GETTEXT_PACKAGE], [PACKAGE])
  52
  53 LT_INIT([disable-static])
  54 LT_PREREQ([2.2.6])
  55
  56 # Checks for programs.
  57 AC_PROG_CC
  58 AM_PROG_CC_C_O
  59
  60 AC_PATH_PROG([DOXYGEN], [doxygen], [no])
  61 AM_CONDITIONAL([HAVE_DOXYGEN], [test x"$DOXYGEN" != "xno"])
  62 AC_SUBST([DOXYGEN])
  63
  64 AC_PATH_PROG([A2X], [a2x], [no])
  65 AM_CONDITIONAL([HAVE_A2X], [test x"$A2X" != "xno"])
  66 AC_SUBST([A2X])
  67
  68 AC_PATH_PROG([DATE], [date], [no])
  69 AS_IF([test "$DATE" != x"$xno"], [build_time=`$DATE +"%F %T %z"`])
  70 AC_DEFINE_UNQUOTED([BUILD_TIME], ["$build_time"], [We have build time])
  71
  72 BUILD_TIME="$build_time"
  73 AC_SUBST([BUILD_TIME])
  74
  75 AC_PATH_PROG([VALGRIND], [valgrind], [no])
  76 AM_CONDITIONAL([HAVE_VALGRIND], [test x"$VALGRIND" != "xno"])
  77 AC_SUBST([VALGRIND])
  78
  79 # Checks for libraries.
  80 PKG_CHECK_MODULES([liblua], [lua >= 5.1], [], [
  81   PKG_CHECK_MODULES([liblua], [lua51 >= 5.1], [], [
  82     PKG_CHECK_MODULES([liblua], [lua5.1 >= 5.1], [], [
  83       PKG_CHECK_MODULES(liblua, [lua-5.1 >= 5.1])])
  84   ])
  85 ])
  86 PKG_CHECK_MODULES([libproxy], [libproxy-1.0 >= 0.3.1])
  87 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.21])
  88 PKG_CHECK_MODULES([glib], [glib-2.0 >= 2.24])
  89 AM_PATH_LIBGCRYPT
  90
  91 # Checks for scripts.
  92 pkg_scripts=libquvi-scripts-0.9
  93
  94 AC_ARG_WITH([scriptsdir],
  95   [AS_HELP_STRING([--with-scriptsdir=DIR],
  96     [Set libquvi-scripts directory to DIR. This negates the
  97     libquvi-scripts check.  DIR is assumed to contain the files
  98     installed with libquvi-scripts to the
  99       $prefix/share/libquvi-scripts/ directory.])],
 100   [scriptsdir=$withval
 101    versionfile=$scriptsdir/version],
 102   [PKG_CHECK_MODULES([libquvi_scripts], ["$pkg_scripts" >= 0.9])
 103     scriptsdir=`$PKG_CONFIG --variable scriptsdir $pkg_scripts 2>/dev/null`
 104     versionfile=`$PKG_CONFIG --variable versionfile $pkg_scripts 2>/dev/null`
 105     scriptsmodver=`$PKG_CONFIG --modversion $pkg_scripts 2>/dev/null`])
 106
 107 AS_IF([test -z "$scriptsdir"], [
 108   AC_MSG_ERROR([scriptsdir: variable not found])])
 109
 110 AS_IF([ ! test -d "$scriptsdir"], [
 111   AC_MSG_ERROR([$scriptsdir: does not exist or is not a directory])])
 112
 113 AS_IF([test -z "$versionfile"], [
 114   AC_MSG_ERROR([versionfile: variable not found])])
 115
 116 AS_IF([ ! test -f "$versionfile"], [
 117   AC_MSG_WARN([$versionfile: does not exist or is not not a regular file])])
 118
 119 AC_DEFINE_UNQUOTED([SCRIPTSDIR], ["$scriptsdir"], [We have scriptsdir])
 120 AC_DEFINE_UNQUOTED([VERSIONFILE], ["$versionfile"], [We have versionfile])
 121
 122 scriptsver=`head -n1 "$versionfile" 2>/dev/null`
 123
 124 # Checks for header files.
 125 AC_CHECK_HEADERS([stdint.h string.h locale.h])
 126
 127 # Checks for typedefs, structures, and compiler characteristics.
 128 AC_TYPE_UINT32_T
 129 AC_TYPE_UINT64_T
 130 AC_TYPE_UINT8_T
 131
 132 # Checks for library functions.
 133 AC_CHECK_FUNCS([strrchr memset setlocale])
 134
 135 # Version.
 136 VN=`$srcdir/gen-ver.sh`
 137 AC_DEFINE_UNQUOTED([VN], ["$VN"], [We have version number from gen-ver.sh])
 138
 139 VN_C=`$srcdir/gen-ver.sh -c`
 140 AC_SUBST([VN_C])
 141
 142 # Version: Major/Minor -pair, used to find the libquvi scripts.
 143 # e.g. $prefix/share/libquvi-scripts/$maj.$min/
 144 VERSION_MM=`$srcdir/gen-ver.sh -c -m`
 145 AC_DEFINE_UNQUOTED([VERSION_MM], "$VERSION_MM", [Version major/minor])
 146
 147 # --with-manual
 148 AC_ARG_WITH([manual],
 149   [AS_HELP_STRING([--with-manual],
 150     [install manual pages @<:@default=yes@:>@])],
 151   [],
 152   [with_manual=yes])
 153 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
 154
 155 AC_CONFIG_FILES([
 156   Makefile
 157   doc/man3/Makefile
 158   doc/man7/Makefile
 159   doc/dox/Makefile
 160   doc/dox/Doxyfile
 161   doc/Makefile
 162   examples/Makefile
 163   examples/lib/Makefile
 164   src/misc/Makefile
 165   src/gcrypt/Makefile
 166   src/curl/Makefile
 167   src/net/Makefile
 168   src/api/Makefile
 169   src/api/doxy/main.dp
 170   src/lua/Makefile
 171   src/quvi-0.9/quvi/Makefile
 172   src/quvi-0.9/Makefile
 173   src/Makefile
 174   tests/Makefile
 175   tests/lib/Makefile
 176   libquvi-0.9.pc
 177   po/Makefile.in])
 178 AC_OUTPUT
 179
 180 AC_MSG_NOTICE([
 181   version         ${VERSION}
 182   prefix          ${prefix}
 183   compiler        ${CC}
 184   cflags          ${CFLAGS}
 185 System types
 186   target          ${target}
 187   build           ${build}
 188   host            ${host}
 189 Install options
 190   with
 191   - manual        ${with_manual}
 192 libquvi-scripts
 193   .pc modversion  ${scriptsmodver}
 194   versionfile     ${versionfile}
 195     version       ${scriptsver}
 196   scriptsdir      ${scriptsdir}])