configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5
   6 m4_include([m4/version.m4])
   7
   8 AC_INIT([libquvi], m4_esyscmd([./gen-ver.sh -c | tr -d '\n']),
   9         [http://quvi.sf.net/bugs/],[],[http://quvi.sf.net/])
  10
  11 # Interface
  12 LT_CUR=libquvi_lt_cur
  13 LT_REV=libquvi_lt_rev
  14 LT_AGE=libquvi_lt_age
  15 AC_SUBST([LT_CUR])
  16 AC_SUBST([LT_REV])
  17 AC_SUBST([LT_AGE])
  18
  19 AC_CONFIG_SRCDIR([src/api/new.c])
  20 AC_CONFIG_HEADERS([config.h])
  21 AC_CONFIG_AUX_DIR([config.aux])
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AC_CANONICAL_TARGET
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target", [...])
  28 AC_DEFINE_UNQUOTED([CANONICAL_BUILD], "$build", [...])
  29 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [...])
  30
  31 AM_INIT_AUTOMAKE([1.11.1 -Wall -Werror dist-xz no-dist-gzip tar-ustar])
  32 AM_SILENT_RULES([yes])
  33 #AM_PROG_AR
  34
  35 AM_GNU_GETTEXT_VERSION([0.18.1])
  36 AM_GNU_GETTEXT([external])
  37 # GETTEXT_PACKAGE is used by glib.
  38 AC_DEFINE([GETTEXT_PACKAGE], [PACKAGE], [Define to the gettext package name])
  39 AC_SUBST([GETTEXT_PACKAGE], [PACKAGE])
  40
  41 LT_INIT([disable-static])
  42 LT_PREREQ([2.2.6])
  43
  44 # Checks for programs.
  45 AC_PROG_CC
  46 AM_PROG_CC_C_O
  47
  48 AC_PATH_PROG([DOXYGEN], [doxygen], [no])
  49 AM_CONDITIONAL([HAVE_DOXYGEN], [test x"$DOXYGEN" != "xno"])
  50 AC_SUBST([DOXYGEN])
  51
  52 AC_PATH_PROG([DATE], [date], [no])
  53 AS_IF([test "$DATE" != x"$xno"], [build_time=`$DATE +"%F %T %z"`])
  54 AC_DEFINE_UNQUOTED([BUILD_TIME], ["$build_time"], [We have build time])
  55
  56 BUILD_TIME="$build_time"
  57 AC_SUBST([BUILD_TIME])
  58
  59 AC_PATH_PROG([VALGRIND], [valgrind], [no])
  60 AM_CONDITIONAL([HAVE_VALGRIND], [test x"$VALGRIND" != "xno"])
  61 AC_SUBST([VALGRIND])
  62
  63 # Checks for libraries.
  64 PKG_CHECK_MODULES([liblua], [lua >= 5.1], [], [
  65   PKG_CHECK_MODULES([liblua], [lua51 >= 5.1], [], [
  66     PKG_CHECK_MODULES([liblua], [lua5.1 >= 5.1], [], [
  67       PKG_CHECK_MODULES(liblua, [lua-5.1 >= 5.1])])
  68   ])
  69 ])
  70 PKG_CHECK_MODULES([libproxy], [libproxy-1.0 >= 0.3.1])
  71 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.21])
  72 PKG_CHECK_MODULES([glib], [glib-2.0 >= 2.24])
  73
  74 # Checks for scripts.
  75 pkg_scripts=libquvi-scripts-0.9
  76
  77 AC_ARG_WITH([scriptsdir],
  78   [AS_HELP_STRING([--with-scriptsdir=DIR],
  79     [Set libquvi-scripts directory to DIR. This negates the
  80     libquvi-scripts check.  DIR is assumed to contain the files
  81     installed with libquvi-scripts to the
  82       $prefix/share/libquvi-scripts/ directory.])],
  83   [scriptsdir=$withval
  84    versionfile=$scriptsdir/version],
  85   [PKG_CHECK_MODULES([libquvi_scripts], ["$pkg_scripts" >= 0.9])
  86     scriptsdir=`$PKG_CONFIG --variable scriptsdir $pkg_scripts 2>/dev/null`
  87     versionfile=`$PKG_CONFIG --variable versionfile $pkg_scripts 2>/dev/null`
  88     scriptsmodver=`$PKG_CONFIG --modversion $pkg_scripts 2>/dev/null`])
  89
  90 AS_IF([test -z "$scriptsdir"], [
  91   AC_MSG_ERROR([scriptsdir: variable not found])])
  92
  93 AS_IF([ ! test -d "$scriptsdir"], [
  94   AC_MSG_ERROR([$scriptsdir: does not exist or is not a directory])])
  95
  96 AS_IF([test -z "$versionfile"], [
  97   AC_MSG_ERROR([versionfile: variable not found])])
  98
  99 AS_IF([ ! test -f "$versionfile"], [
 100   AC_MSG_WARN([$versionfile: does not exist or is not not a regular file])])
 101
 102 AC_DEFINE_UNQUOTED([SCRIPTSDIR], ["$scriptsdir"], [We have scriptsdir])
 103 AC_DEFINE_UNQUOTED([VERSIONFILE], ["$versionfile"], [We have versionfile])
 104
 105 scriptsver=`head -n1 "$versionfile" 2>/dev/null`
 106
 107 # Checks for header files.
 108 AC_CHECK_HEADERS([stdint.h string.h])
 109
 110 # Checks for typedefs, structures, and compiler characteristics.
 111 AC_TYPE_UINT32_T
 112 AC_TYPE_UINT64_T
 113 AC_TYPE_UINT8_T
 114
 115 # Checks for library functions.
 116 AC_CHECK_FUNCS([strrchr])
 117
 118 # Version.
 119 VN=`$srcdir/gen-ver.sh`
 120 AC_DEFINE_UNQUOTED([VN], ["$VN"], [We have version number from gen-ver.sh])
 121
 122 VN_C=`$srcdir/gen-ver.sh -c`
 123 AC_SUBST([VN_C])
 124
 125 # Version: Major/Minor -pair, used to find the libquvi scripts.
 126 # e.g. $prefix/share/libquvi-scripts/$maj.$min/
 127 VERSION_MM=`$srcdir/gen-ver.sh -c -m`
 128 AC_DEFINE_UNQUOTED([VERSION_MM], "$VERSION_MM", [Version major/minor])
 129
 130 # --with-manual
 131 AC_ARG_WITH([manual],
 132   [AS_HELP_STRING([--with-manual],
 133     [install manual pages @<:@default=yes@:>@])],
 134   [],
 135   [with_manual=yes])
 136 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
 137
 138 AC_CONFIG_FILES([
 139   Makefile
 140   doc/man3/Makefile
 141   doc/dox/Makefile
 142   doc/dox/Doxyfile
 143   doc/Makefile
 144   examples/Makefile
 145   examples/lib/Makefile
 146   src/misc/Makefile
 147   src/curl/Makefile
 148   src/net/Makefile
 149   src/api/Makefile
 150   src/api/doxy/main.dp
 151   src/lua/Makefile
 152   src/quvi-0.9/quvi/Makefile
 153   src/quvi-0.9/Makefile
 154   src/Makefile
 155   tests/Makefile
 156   tests/lib/Makefile
 157   libquvi-0.9.pc
 158   po/Makefile.in])
 159 AC_OUTPUT
 160
 161 AC_MSG_NOTICE([
 162   version         ${VERSION}
 163   prefix          ${prefix}
 164   compiler        ${CC}
 165   cflags          ${CFLAGS}
 166 System types
 167   target          ${target}
 168   build           ${build}
 169   host            ${host}
 170 Install options
 171   with
 172   - manual        ${with_manual}
 173 libquvi-scripts
 174   .pc modversion  ${scriptsmodver}
 175   versionfile     ${versionfile}
 176     version       ${scriptsver}
 177   scriptsdir      ${scriptsdir}])