configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5
   6 m4_include([m4/version.m4])
   7
   8 AC_INIT([libquvi],[libquvi_lt_rel],
   9         [http://quvi.sf.net/bugs/],[],[http://quvi.sf.net/])
  10
  11 # Interface:
  12 LT_REL=libquvi_lt_rel
  13 LT_CUR=libquvi_lt_cur
  14 LT_REV=libquvi_lt_rev
  15 LT_AGE=libquvi_lt_age
  16 AC_SUBST([LT_REL])
  17 AC_SUBST([LT_CUR])
  18 AC_SUBST([LT_REV])
  19 AC_SUBST([LT_AGE])
  20
  21 AC_CONFIG_SRCDIR([src/api/new.c])
  22 AC_CONFIG_HEADERS([config.h])
  23 AC_CONFIG_AUX_DIR([config.aux])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CANONICAL_TARGET
  27 AC_USE_SYSTEM_EXTENSIONS
  28
  29 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target", [...])
  30 AC_DEFINE_UNQUOTED([CANONICAL_BUILD], "$build", [...])
  31 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [...])
  32
  33 AM_INIT_AUTOMAKE([1.11.1 -Wall -Werror dist-xz no-dist-gzip tar-ustar])
  34 AM_SILENT_RULES([yes])
  35 #AM_PROG_AR
  36
  37 LT_INIT([disable-static])
  38 LT_PREREQ([2.2.6])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AM_PROG_CC_C_O
  43
  44 AC_PATH_PROG([DOXYGEN], [doxygen], [no])
  45 AM_CONDITIONAL([HAVE_DOXYGEN], [test x"$DOXYGEN" != "xno"])
  46 AC_SUBST([DOXYGEN])
  47
  48 AC_PATH_PROG([DATE], [date], [no])
  49 AS_IF([test "$DATE" != x"$xno"], [build_time=`$DATE +"%F %T %z"`])
  50 AC_DEFINE_UNQUOTED([BUILD_TIME], ["$build_time"], [We have build time])
  51
  52 AC_PATH_PROG([VALGRIND], [valgrind], [no])
  53 AM_CONDITIONAL([HAVE_VALGRIND], [test x"$VALGRIND" != "xno"])
  54 AC_SUBST([VALGRIND])
  55
  56 # Checks for libraries.
  57 PKG_CHECK_MODULES([liblua], [lua >= 5.1], [], [
  58   PKG_CHECK_MODULES([liblua], [lua51 >= 5.1], [], [
  59     PKG_CHECK_MODULES([liblua], [lua5.1 >= 5.1], [], [
  60       PKG_CHECK_MODULES(liblua, [lua-5.1 >= 5.1])])
  61   ])
  62 ])
  63 PKG_CHECK_MODULES([libproxy], [libproxy-1.0 >= 0.3.1])
  64 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.21])
  65 PKG_CHECK_MODULES([glib], [glib-2.0 >= 2.24])
  66
  67 # Checks for scripts.
  68 pkg_scripts=libquvi-scripts-1.0
  69 AC_ARG_WITH([scriptsdir],
  70   [AS_HELP_STRING([--with-scriptsdir=DIR],
  71     [Set libquvi-scripts directory to DIR. Overrides the libquvi-scripts
  72     package check.  DIR is expected to contain all of the libquvi-scripts
  73     as well as the "version" file containing the libquvi-scripts version
  74     string.])],
  75   [scriptsdir=$withval
  76    versionfile=$scriptsdir/version],
  77   [PKG_CHECK_MODULES([libquvi_scripts], [libquvi-scripts-1.0 >= 1.0])
  78     scriptsdir=`$PKG_CONFIG --variable scriptsdir $pkg_scripts 2>/dev/null`
  79     versionfile=`$PKG_CONFIG --variable versionfile $pkg_scripts 2>/dev/null`
  80     scriptsmodver=`$PKG_CONFIG --modversion $pkg_scripts 2>/dev/null`])
  81
  82 AS_IF([test -z "$scriptsdir"], [
  83   AC_MSG_ERROR([scriptsdir: variable not found])])
  84
  85 AS_IF([ ! test -d "$scriptsdir"], [
  86   AC_MSG_ERROR([$scriptsdir: does not exist or is not a directory])])
  87
  88 AS_IF([test -z "$versionfile"], [
  89   AC_MSG_ERROR([versionfile: variable not found])])
  90
  91 AS_IF([ ! test -f "$versionfile"], [
  92   AC_MSG_ERROR([$versionfile: does not exist or is not not a regular file])])
  93
  94 AC_DEFINE_UNQUOTED([SCRIPTSDIR], ["$scriptsdir"], [We have scriptsdir])
  95 AC_DEFINE_UNQUOTED([VERSIONFILE], ["$versionfile"], [We have versionfile])
  96
  97 scriptsver=`head -n1 "$versionfile" 2>/dev/null`
  98
  99 # Checks for header files.
 100 AC_CHECK_HEADERS([stdint.h string.h])
 101
 102 # Checks for typedefs, structures, and compiler characteristics.
 103 AC_TYPE_UINT32_T
 104 AC_TYPE_UINT64_T
 105 AC_TYPE_UINT8_T
 106
 107 # Checks for library functions.
 108 AC_CHECK_FUNCS([strrchr])
 109
 110 # Version.
 111 VN=`$srcdir/gen-ver.sh $srcdir`
 112 AC_DEFINE_UNQUOTED([VN], ["$VN"], [We have version number from gen-ver.sh])
 113
 114 # --with-manual
 115 AC_ARG_WITH([manual],
 116   [AS_HELP_STRING([--with-manual],
 117     [install manual pages @<:@default=yes@:>@])],
 118   [],
 119   [with_manual=yes])
 120 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
 121
 122 AC_CONFIG_FILES([
 123   Makefile
 124   doc/man3/Makefile
 125   doc/dox/Makefile
 126   doc/dox/Doxyfile
 127   doc/Makefile
 128   examples/Makefile
 129   examples/lib/Makefile
 130   src/misc/Makefile
 131   src/curl/Makefile
 132   src/net/Makefile
 133   src/api/Makefile
 134   src/lua/Makefile
 135   src/quvi-1.0/quvi/Makefile
 136   src/quvi-1.0/Makefile
 137   src/Makefile
 138   tests/Makefile
 139   tests/lib/Makefile
 140   libquvi-1.0.pc])
 141 AC_OUTPUT
 142
 143 AC_MSG_NOTICE([
 144   version         ${VERSION} (${VN})
 145   prefix          ${prefix}
 146   compiler        ${CC}
 147   cflags          ${CFLAGS}
 148 System types
 149   target          ${target}
 150   build           ${build}
 151   host            ${host}
 152 Options
 153   install manual  ${with_manual}
 154 libquvi-scripts
 155   .pc modversion  ${scriptsmodver}
 156   versionfile     ${versionfile}
 157     version       ${scriptsver}
 158   scriptsdir      ${scriptsdir}])