configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.60)
   3 AC_INIT(pwmd, 3.0.9, [Ben Kibbey bjk@luxsci.net])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_AUX_DIR(build)
   6 AC_CANONICAL_TARGET
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AC_PROG_MAKE_SET
   9 AC_USE_SYSTEM_EXTENSIONS()
  10 AC_PROG_LIBTOOL
  11 AC_CONFIG_SRCDIR([src/pwmd.c])
  12 AM_CONFIG_HEADER([config.h])
  13 AM_GNU_GETTEXT([external])
  14 AM_GNU_GETTEXT_VERSION([0.16.1])
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC_C99
  18
  19 if test "$ac_cv_prog_cc_c99" = "no"; then
  20     AC_MSG_WARN("Unable to find a C99 compatible compiler.")
  21 fi
  22
  23 AX_C_BIGENDIAN_CROSS
  24 AC_PROG_AWK
  25 AC_PROG_LN_S
  26 AC_PROG_INSTALL
  27 AC_PROG_LN_S
  28 AC_PROG_CPP
  29 AC_PROG_MKDIR_P
  30
  31 dnl Checks for library functions.
  32 AX_PTHREAD(, [POSIX threads are required])
  33 CC="$PTHREAD_CC"
  34 save_CFLAGS="$CFLAGS"
  35 save_LIBS="$LIBS"
  36 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  37 LIBS="$PTHREAD_LIBS $LIBS"
  38
  39 acx_pthread_mutex_timedlock_ok=no
  40 AC_MSG_CHECKING([for pthread_mutex_timedlock()])
  41 AC_TRY_LINK_FUNC(pthread_mutex_timedlock, acx_pthread_mutex_timedlock_ok=yes)
  42 AC_MSG_RESULT($acx_pthread_mutex_timedlock_ok)
  43 if test x"$acx_pthread_mutex_timedlock_ok" = "xyes"; then
  44     AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK, 1, [Define if your OS has pthread_mutex_timedlock().])
  45 fi
  46
  47 acx_pthread_testcancel_ok=no
  48 AC_MSG_CHECKING([for pthread_testcancel()])
  49 AC_TRY_LINK_FUNC(pthread_testcancel, acx_pthread_testcancel_ok=yes)
  50 AC_MSG_RESULT($acx_pthread_testcancel_ok)
  51 if test x"$acx_pthread_testcancel_ok" = "xyes"; then
  52     AC_DEFINE(HAVE_PTHREAD_TESTCANCEL, 1, [Define if your OS has pthread_testcancel().])
  53 fi
  54
  55 acx_pthread_cancel_ok=no
  56 AC_MSG_CHECKING([for pthread_cancel()])
  57 AC_TRY_LINK_FUNC(pthread_cancel, acx_pthread_cancel_ok=yes)
  58 AC_MSG_RESULT($acx_pthread_cancel_ok)
  59 if test x"$acx_pthread_cancel_ok" = "xyes"; then
  60     AC_DEFINE(HAVE_PTHREAD_CANCEL, 1, [Define if your OS has pthread_cancel().])
  61 fi
  62
  63 acx_pthread_atfork_ok=no
  64 AC_MSG_CHECKING([for pthread_atfork()])
  65 AC_TRY_LINK_FUNC(pthread_atfork, acx_pthread_atfork_ok=yes)
  66 AC_MSG_RESULT($acx_pthread_atfork_ok)
  67 if test x"$acx_pthread_atfork_ok" = "xyes"; then
  68     AC_DEFINE(HAVE_PTHREAD_ATFORK, 1, [Define if your OS has pthread_atfork().])
  69 fi
  70
  71 CFLAGS="$save_CFLAGS"
  72 LIBS="$save_LIBS"
  73
  74 dnl Checks for header files.
  75 AC_HEADER_STDC
  76 AC_HEADER_SYS_WAIT
  77
  78 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h strings.h sys/time.h unistd.h \
  79                   libintl.h locale.h syslog.h termios.h getopt.h limits.h \
  80                   time.h])
  81
  82 AC_CHECK_DECLS([SO_BINDTODEVICE],,, [[#include <sys/types.h>
  83                                       #include <sys/socket.h>]])
  84
  85 case "$target_os" in
  86      linux*)
  87         AC_CHECK_HEADERS([linux/sockios.h sys/prctl.h])
  88         if test "x$ac_cv_header_linux_sockios_h" = xyes; then
  89                 AC_CHECK_DECL([SIOCOUTQ],,, [[#include <linux/sockios.h>]])
  90                 if test "x$ac_cv_have_decl_SIOCOUTQ" = xyes; then
  91                         AC_DEFINE(HAVE_DECL_SIOCOUTQ, 1,
  92                                 [Defined if SIOCOUTQ is available (Linux specific)])
  93                 fi
  94         fi
  95
  96         if test "x$ac_cv_header_sys_prctl_h" = xyes; then
  97            AC_CHECK_DECL([PR_SET_NAME],,, [[#include <sys/prctl.h>]])
  98               if test "x$ac_cv_have_decl_PR_SET_NAME" = xyes; then
  99                     AC_DEFINE(HAVE_PR_SET_NAME, 1,
 100                              [Defined if PR_SET_NAME is available (Linux specific)])
 101               fi
 102
 103            AC_CHECK_DECL([PR_SET_DUMPABLE],,, [[#include <sys/prctl.h>]])
 104               if test "x$ac_cv_have_decl_PR_SET_DUMPABLE" = xyes; then
 105                     AC_DEFINE(HAVE_PR_SET_DUMPABLE, 1,
 106                              [Defined if PR_SET_DUMPABLE is available (Linux specific)])
 107               fi
 108         fi
 109         ;;
 110      openbsd*)
 111         ;;
 112      *bsd*)
 113         AC_CHECK_HEADERS([sys/filio.h])
 114         if test "x$ac_cv_header_sys_filio_h" = xyes; then
 115                 AC_CHECK_DECL([FIONWRITE],,, [[#include <sys/filio.h>]])
 116                 if test "x$ac_cv_have_decl_FIONWRITE" = xyes; then
 117                         AC_DEFINE(HAVE_DECL_FIONWRITE, 1,
 118                                 [Defined if FIONWRITE is available (*BSD specific, not OpenBSD)])
 119                 fi
 120         fi
 121         ;;
 122      *)
 123 dnl     All others use SO_SNDLOWAT.
 124         ;;
 125 esac
 126
 127 dnl Checks for typedefs, structures, and compiler characteristics.
 128 AC_SYS_LARGEFILE
 129 AC_C_CONST
 130 AC_C_INLINE
 131 AC_TYPE_MODE_T
 132 AC_TYPE_SIZE_T
 133 AC_STRUCT_TM
 134 AC_TYPE_PID_T
 135 AC_TYPE_SIGNAL
 136 AC_TYPE_UINT8_T
 137 AC_TYPE_UINT32_T
 138 AC_TYPE_UINT64_T
 139
 140 dnl Checks for library functions.
 141 AC_FUNC_STAT
 142 AC_FUNC_FORK
 143 AC_FUNC_MEMCMP
 144 AC_FUNC_STRFTIME
 145 AC_CHECK_FUNCS([memset mkdir munmap setlocale socket strchr strerror strrchr \
 146                 strstr strtol setrlimit mlockall getopt_long backtrace \
 147                 getpwnam_r getgrnam_r])
 148 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
 149
 150 AM_PATH_LIBASSUAN([2.0.2],, AC_MSG_ERROR([libassuan not found]))
 151 PKG_PROG_PKG_CONFIG()
 152 AM_PATH_LIBGCRYPT([1:1.5.0],, AC_MSG_ERROR([libgcrypt not found]))
 153 AM_PATH_XML2(,, AC_MSG_ERROR([libxml2 not found]))
 154 AM_PATH_GPG_ERROR(,, AC_MSG_ERROR([libgpg-error not found]))
 155 AC_SEARCH_LIBS([clock_gettime], [rt])
 156
 157 dnl For data file conversion.
 158 AX_CHECK_ZLIB
 159
 160 dnl Remote TCP/TLS connections.
 161 AC_ARG_ENABLE(gnutls, AC_HELP_STRING([--enable-gnutls],
 162               [Enable TCP (GnuTLS) server support.]), USE_GNUTLS=$enableval,
 163               USE_GNUTLS=no)
 164 if test "x$USE_GNUTLS" = "xyes"; then
 165     PKG_CHECK_MODULES([GNUTLS], [gnutls])
 166     AC_DEFINE(WITH_GNUTLS, 1, [Define if you want TCP (GnuTLS) support.])
 167 fi
 168 AM_CONDITIONAL(WITH_GNUTLS, [test "x$USE_GNUTLS" = "xyes"])
 169
 170 dnl Enable gpg-agent support.
 171 AC_ARG_ENABLE(agent, AC_HELP_STRING([--enable-agent],
 172               [Enable public key/gpg-agent support.]), WITH_AGENT=$enableval,
 173               WITH_AGENT=no)
 174 if test "x$WITH_AGENT" = "xyes"; then
 175     AC_DEFINE(WITH_AGENT, 1, [Define if you want gpg-agent support.])
 176 fi
 177 AM_CONDITIONAL(WITH_AGENT, [test "x$WITH_AGENT" = "xyes"])
 178
 179 pinentry="/usr/bin/pinentry"
 180 dnl Default pinentry location.
 181 AC_ARG_WITH(pinentry, AC_HELP_STRING([--with-pinentry=PATH],
 182               [Default location of the pinentry binary (/usr/bin/pinentry)]),
 183               pinentry="$withval")
 184 AC_SUBST(pinentry)
 185 AC_DEFINE_UNQUOTED(PINENTRY_PATH, ["$pinentry"],
 186                    [Default location of the pinentry binary.])
 187
 188 # Cracklib support (requires pinentry support).
 189 AC_ARG_ENABLE(quality, AC_HELP_STRING([--enable-quality],
 190               [Enable password quality checking with cracklib.]),
 191               WITH_QUALITY=$enableval, WITH_QUALITY=no)
 192 if test "x$WITH_QUALITY" = "xyes"; then
 193     AC_CHECK_HEADER([crack.h],, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 194     AC_CHECK_LIB([crack], FascistCheck,, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 195     AC_DEFINE(WITH_QUALITY, 1, [Define if you want password quality checking.])
 196 fi
 197 AM_CONDITIONAL(WITH_QUALITY, [test "x$WITH_QUALITY" = "xyes"])
 198
 199 crackdict="/var/cache/cracklib/cracklib_dict"
 200 AC_ARG_WITH(crackdict, AC_HELP_STRING([--with-crack-dict=PATH],
 201               [Location of the cracklib dictionary (/var/cache/cracklib/cracklib_dict).]),
 202               crackdict="$withval")
 203 AC_SUBST(crackdict)
 204 AC_DEFINE_UNQUOTED(CRACKLIB_DICT, ["$crackdict"], [The location of the cracklib dictionary.])
 205
 206 AC_DEFUN([AC_DEBUG],
 207 [
 208     if test "$1"; then
 209         ac_cv_sys_debug=$1
 210     fi
 211
 212     AC_CACHE_CHECK([if debugging is wanted], [ac_cv_sys_debug],
 213         [ac_cv_sys_debug=no])
 214     AM_CONDITIONAL([WITH_DEBUG], [test "$ac_cv_sys_debug" = "yes"])
 215 ])
 216
 217 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging (memory de/allocations output).]),
 218     AC_DEBUG([$enableval]), AC_DEBUG)
 219
 220 AC_DEFUN([AC_MEM_DEBUG],
 221 [
 222     if test "$1"; then
 223         ac_cv_sys_mem_debug=$1
 224     fi
 225
 226     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 227         [ac_cv_sys_mem_debug=no])
 228     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 229 ])
 230
 231 AC_DEFUN([AC_MUTEX_DEBUG],
 232 [
 233     if test "$1"; then
 234         ac_cv_sys_mutex_debug=$1
 235     fi
 236
 237     AC_CACHE_CHECK([if mutex debugging is wanted], [ac_cv_sys_mutex_debug],
 238         [ac_cv_sys_mutex_debug=no])
 239     AM_CONDITIONAL([WITH_MUTEX_DEBUG], [test "$ac_cv_sys_mutex_debug" = "yes"])
 240 ])
 241
 242 AC_ARG_ENABLE(mutex_debug, AC_HELP_STRING([--enable-mutex-debug], [Enable mutex debugging output.]),
 243     AC_MUTEX_DEBUG([$enableval]), AC_MUTEX_DEBUG)
 244
 245 dnl Memory debugging.
 246 AC_ARG_ENABLE(mem_debug, AC_HELP_STRING([--enable-mem-debug], [Disable internal memory manager.]),
 247     AC_MEM_DEBUG([$enableval]), AC_MEM_DEBUG)
 248 AM_CONDITIONAL(MEM_DEBUG, test x"${ac_cv_sys_mem_debug}" != xno)
 249
 250 # Default pwmd home directory.
 251 AC_ARG_WITH(pwmd_homedir, AC_HELP_STRING([--with-pwmd-homedir=PATH],
 252               [Default pwmd home directory (~/.pwmd)]),
 253               pwmd_homedir="$withval", pwmd_homedir=)
 254 if test x"$pwmd_homedir" != "x"; then
 255    AC_DEFINE_UNQUOTED(PWMD_HOMEDIR, ["$pwmd_homedir"],
 256                                     [Default pwmd home directory (~/.pwmd).])
 257 fi
 258
 259 VERSION_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
 260 VERSION_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
 261 VERSION_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
 262 VERSION_NUM="`printf 0x%02x%02x%02X ${VERSION_MAJOR} ${VERSION_MINOR} ${VERSION_PATCH}`"
 263 AC_DEFINE_UNQUOTED(VERSION_HEX, ${VERSION_NUM}, [For the file header.])
 264
 265 dnl Disable optimizing of memset(). GCC and CLang (and others?) accept
 266 dnl multiple optimization flags and use the last one specified. The
 267 dnl non-optimized memset() may still use any CPU features found in the
 268 dnl user specified CFLAGS (-mtune) and libc.
 269 CFLAGS_ORIG="$CFLAGS"
 270 CFLAGS_MEMZERO="$CFLAGS -O0"
 271 CFLAGS=
 272 AC_SUBST(CFLAGS_ORIG)
 273 AC_SUBST(CFLAGS_MEMZERO)
 274
 275 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile po/Makefile.in
 276                  tests/Makefile])
 277 AC_OUTPUT
 278 echo
 279 echo "Features:"
 280 echo "    With gpg-agent..: $WITH_AGENT"
 281 echo "    Pinentry binary.: $pinentry"
 282 echo "    Cracklib........: $WITH_QUALITY"
 283 echo "    Cracklib dict...: $crackdict"
 284 echo "    TCP (GnuTLS)....: $USE_GNUTLS"
 285
 286 if test x"$pwmd_homedir" != "x"; then
 287 echo "    Home directory..: $pwmd_homedir"
 288 else
 289 echo "    Home directory..: ~/.pwmd"
 290 fi
 291
 292 echo "    Debug...........: ${ac_cv_sys_debug}"
 293 echo "    Memory debug....: ${ac_cv_sys_mem_debug}"
 294 echo "    Mutex debug.....: ${ac_cv_sys_mutex_debug}"