configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.60)
   3 AC_INIT(libpwmd, 7.0.0-dev, [Ben Kibbey bjk@luxsci.net])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_AUX_DIR(build)
   6 AC_CANONICAL_TARGET
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AC_PROG_MAKE_SET
   9 #AC_DISABLE_SHARED
  10 AC_USE_SYSTEM_EXTENSIONS
  11 AC_PROG_LIBTOOL
  12 AC_CONFIG_SRCDIR([src/libpwmd.c])
  13 AM_CONFIG_HEADER([config.h])
  14 AM_GNU_GETTEXT([external])
  15 AM_GNU_GETTEXT_VERSION([0.16.1])
  16
  17 VER_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
  18 VER_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
  19 VER_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
  20 AC_SUBST(VER_MAJOR)
  21 AC_SUBST(VER_MINOR)
  22 AC_SUBST(VER_PATCH)
  23 VER_MAJOR_HEX=`printf "%02X" $VER_MAJOR`
  24 VER_MINOR_HEX=`printf "%02X" $VER_MINOR`
  25 VER_PATCH_HEX=`printf "%02X" $VER_PATCH`
  26 AC_SUBST(VER_MAJOR_HEX)
  27 AC_SUBST(VER_MINOR_HEX)
  28 AC_SUBST(VER_PATCH_HEX)
  29 VER_STRING="\"$VERSION\""
  30 AC_SUBST(VER_STRING)
  31
  32 case "$target_os" in
  33     darwin*)
  34         LDFLAGS="$LDFLAGS -flat_namespace -L/sw/lib"
  35         CPPFLAGS="$CPPFLAGS -I/sw/include -L/sw/lib"
  36         ;;
  37     linux*)
  38         case "$target_cpu" in
  39             x86_64*)
  40                 LDFLAGS="$LDFLAGS -lrt"
  41                 ;;
  42             *)
  43                 ;;
  44         esac
  45         ;;
  46     *)
  47         ;;
  48 esac
  49
  50 dnl Checks for programs.
  51 AC_PROG_CC_C99
  52
  53 if test "$ac_cv_prog_cc_c99" = "no"; then
  54     AC_MSG_ERROR("Unable to find a C99 compatible compiler.")
  55 fi
  56
  57 dnl Borrowed from libssh2!
  58 dnl ************************************************************
  59 dnl Enable hiding of internal symbols in library to reduce its size and
  60 dnl speed dynamic linking of applications.  This currently is only supported
  61 dnl on gcc >= 4.0 and SunPro C.
  62 dnl
  63 AC_MSG_CHECKING([whether to enable hidden symbols in the library])
  64 AC_ARG_ENABLE(hidden-symbols,
  65 AC_HELP_STRING([--enable-hidden-symbols],[Hide internal symbols in library])
  66 AC_HELP_STRING([--disable-hidden-symbols],[Leave all symbols with default visibility in library]),
  67 [ case "$enableval" in
  68   no)
  69        AC_MSG_RESULT(no)
  70        ;;
  71   *)
  72        AC_MSG_CHECKING([whether $CC supports it])
  73        if test "$GCC" = yes ; then
  74          if $CC --help --verbose 2>&1 | grep fvisibility= > /dev/null ; then
  75            AC_MSG_RESULT(yes)
  76            AC_DEFINE(LIBPWMD_API, [__attribute__ ((visibility ("default")))], [to make a symbol visible])
  77            CFLAGS="$CFLAGS -fvisibility=hidden"
  78          else
  79             AC_MSG_RESULT(no)
  80           fi
  81
  82        else
  83          dnl Test for SunPro cc
  84          if $CC 2>&1 | grep flags >/dev/null && $CC -flags | grep xldscope= >/dev/null ; then
  85            AC_MSG_RESULT(yes)
  86            AC_DEFINE(LIBPWMD_API, [__global], [to make a symbol visible])
  87            CFLAGS="$CFLAGS -xldscope=hidden"
  88          else
  89            AC_MSG_RESULT(no)
  90          fi
  91        fi
  92        ;;
  93   esac ],
  94        AC_MSG_RESULT(no)
  95 )
  96
  97 dnl Checks for header files.
  98 AC_HEADER_STDC
  99 AC_HEADER_SYS_WAIT
 100 AC_CHECK_HEADERS([fcntl.h limits.h stdlib.h string.h unistd.h sys/socket.h \
 101                   getopt.h])
 102
 103 dnl Checks for typedefs, structures, and compiler characteristics.
 104 AC_C_CONST
 105 AC_TYPE_SIZE_T
 106 AC_STRUCT_TM
 107 AC_TYPE_SSIZE_T
 108 AC_TYPE_PID_T
 109
 110 ACX_PTHREAD(, AC_MSG_ERROR([Missing or incomplete pthread installation]))
 111 PKG_PROG_PKG_CONFIG
 112
 113 AC_ARG_ENABLE(interactive, AC_HELP_STRING([--disable-interactive], [Disable interactive mode in pwmc.]),
 114                 WITH_INTERACTIVE=no, WITH_INTERACTIVE=yes)
 115 AC_MSG_CHECKING([if interactive mode is wanted])
 116 AC_MSG_RESULT($WITH_INTERACTIVE)
 117 if test "x$WITH_INTERACTIVE" = "xyes"; then
 118     VL_LIB_READLINE
 119
 120     if test "x$vl_cv_lib_readline" != "xno"; then
 121         READLINE_LIBS="$vl_cv_lib_readline"
 122         AC_SUBST(READLINE_LIBS)
 123     else
 124         WITH_INTERACTIVE="no"
 125     fi
 126 fi
 127 AM_CONDITIONAL([WITH_READLINE], [test x"$vl_cv_lib_readline" != "x"])
 128
 129 AM_PATH_LIBASSUAN([2.0.1],, AC_MSG_ERROR([libassuan not found]))
 130 AM_PATH_GPG_ERROR(,, AC_MSG_ERROR([Missing or incomplete libgpg-error installation.]))
 131
 132 AC_ARG_ENABLE(ssh, AC_HELP_STRING([--enable-ssh], [Enable SSH support.]),
 133                 WITH_SSH=$enableval, WITH_SSH=no)
 134 AC_MSG_CHECKING([if ssh support is wanted])
 135 AC_MSG_RESULT($WITH_SSH)
 136 if test "x$WITH_SSH" = "xyes"; then
 137     AC_MSG_CHECKING([for libssh2 availability])
 138     PKG_CHECK_EXISTS([libssh2], have_libssh2=1)
 139     WITH_SSH=no
 140
 141     if test $have_libssh2; then
 142         PKG_CHECK_MODULES([libssh2], [libssh2 >= 1.2.8])
 143         AC_DEFINE(WITH_SSH, 1, [Define if you want SSH support.])
 144         WITH_SSH=yes
 145     fi
 146 fi
 147 AM_CONDITIONAL([WITH_SSH], [test "x$WITH_SSH" = "xyes"])
 148
 149 AC_ARG_ENABLE(gnutls, AC_HELP_STRING([--enable-gnutls],
 150               [Enable GnuTLS client support.]), WITH_GNUTLS=$enableval,
 151               WITH_GNUTLS=no)
 152 AC_MSG_CHECKING([if gnutls support is wanted])
 153 AC_MSG_RESULT($WITH_GNUTLS)
 154 if test "x$WITH_GNUTLS" = "xyes"; then
 155     AC_MSG_CHECKING([for libgnutls availability])
 156     PKG_CHECK_EXISTS(gnutls, have_libgnutls=1, AC_MSG_ERROR([gnutls pkg-config module not found]))
 157     WITH_GNUTLS=no
 158
 159     if test $have_libgnutls; then
 160         PKG_CHECK_MODULES([GNUTLS], [gnutls])
 161         AC_DEFINE(WITH_GNUTLS, 1, [Define if you want GnuTLS support.])
 162         WITH_GNUTLS=yes
 163     fi
 164 fi
 165 AM_CONDITIONAL(WITH_GNUTLS, [test "x$WITH_GNUTLS" = "xyes"])
 166
 167 dnl Checks for library functions.
 168 AC_FUNC_MALLOC
 169 AC_FUNC_REALLOC
 170 AC_FUNC_STRFTIME
 171 AC_FUNC_SELECT_ARGTYPES
 172 AC_CHECK_FUNCS([memmove select socket strdup strerror setlocale getcwd \
 173                 memset stpcpy strchr strrchr strtok_r getopt_long getpwuid_r])
 174 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
 175
 176 AC_DEFUN([AC_MEM_DEBUG],
 177 [
 178     if test "$1"; then
 179         ac_cv_sys_mem_debug=$1
 180     fi
 181
 182     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 183         [ac_cv_sys_mem_debug=no])
 184     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 185 ])
 186
 187 AC_ARG_ENABLE(mem_debug, AC_HELP_STRING([--enable-mem-debug],
 188               [Enable memory debugging.]), AC_MEM_DEBUG([$enableval]),
 189               AC_MEM_DEBUG)
 190
 191 AM_CONDITIONAL(MEM_DEBUG, test "x${ac_cv_sys_mem_debug}" != "xno")
 192
 193 AC_ARG_ENABLE(pinentry, AC_HELP_STRING([--disable-pinentry],
 194               [Disable pinentry(1) support (not pwmd).]), WITH_PINENTRY=no,
 195               WITH_PINENTRY=yes)
 196
 197 if test "x$WITH_PINENTRY" != "xno"; then
 198     AC_CHECK_HEADERS([locale.h])
 199     AC_DEFINE(WITH_PINENTRY, 1, [Define if you want local pinentry(1) support.])
 200 fi
 201
 202 AM_CONDITIONAL([WITH_PINENTRY], [test "x$WITH_PINENTRY" = "xyes"])
 203 pinentry="/usr/bin/pinentry"
 204
 205 AC_ARG_WITH(pinentry, AC_HELP_STRING([--with-pinentry=PATH],
 206               [Default location of the pinentry binary (/usr/bin/pinentry)]),
 207               pinentry="$withval")
 208
 209 AC_SUBST(pinentry)
 210 AC_DEFINE_UNQUOTED(PINENTRY_PATH, ["$pinentry"],
 211                    [Default location of the pinentry binary.])
 212
 213 # Cracklib support (requires pinentry support).
 214 AC_ARG_ENABLE(quality, AC_HELP_STRING([--enable-quality],
 215               [Enable password quality checking with cracklib.]),
 216               WITH_QUALITY=$enableval, WITH_QUALITY=no)
 217 if test "x$WITH_QUALITY" = "xyes"; then
 218     if test "x$WITH_PINENTRY" != "xyes"; then
 219         AC_MSG_ERROR([--enable-quality needs --enable-pinentry])
 220     fi
 221
 222     AC_CHECK_HEADER([crack.h],, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 223     AC_CHECK_LIB([crack], FascistCheck,, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 224     AC_DEFINE(WITH_QUALITY, 1, [Define if you want password quality checking.])
 225 fi
 226 AM_CONDITIONAL(WITH_QUALITY, [test "x$WITH_QUALITY" = "xyes"])
 227
 228 crackdict="/var/cache/cracklib/cracklib_dict"
 229 AC_ARG_WITH(crackdict, AC_HELP_STRING([--with-crack-dict=PATH],
 230               [Location of the cracklib dictionary (/var/cache/cracklib/cracklib_dict).]),
 231               crackdict="$withval")
 232 AC_SUBST(crackdict)
 233 AC_DEFINE_UNQUOTED(CRACKLIB_DICT, ["$crackdict"], [The location of the cracklib dictionary.])
 234
 235 AC_CONFIG_FILES([Makefile libpwmd-7.0.pc doc/Makefile doc/doxygen.conf.in \
 236                  doc/pwmc.1 src/Makefile src/libpwmd.h po/Makefile.in])
 237 AC_OUTPUT
 238 echo
 239 echo "Features:"
 240 echo "    Memory debug: ${ac_cv_sys_mem_debug}"
 241 echo "    Pinentry: $WITH_PINENTRY"
 242 echo "    Pinentry location: $pinentry"
 243 echo "    Cracklib: $WITH_QUALITY"
 244 echo "    Cracklib dictionary: $crackdict"
 245 echo "    Ssh support: $WITH_SSH"
 246 echo "    GnuTLS support: $WITH_GNUTLS"
 247 echo "    Interactive pwmc: $WITH_INTERACTIVE"