configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.60)
   3 AC_INIT(libpwmd, 7.3.0-dev, [Ben Kibbey bjk@luxsci.net])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_AUX_DIR(build)
   6 AC_CANONICAL_TARGET
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AC_PROG_MAKE_SET
   9 #AC_DISABLE_SHARED
  10 AC_USE_SYSTEM_EXTENSIONS
  11 AC_PROG_LIBTOOL
  12 AC_CONFIG_SRCDIR([src/libpwmd.c])
  13 AM_CONFIG_HEADER([config.h])
  14 AM_GNU_GETTEXT([external])
  15 AM_GNU_GETTEXT_VERSION([0.16.1])
  16
  17 VER_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
  18 VER_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
  19 VER_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
  20 AC_SUBST(VER_MAJOR)
  21 AC_SUBST(VER_MINOR)
  22 AC_SUBST(VER_PATCH)
  23 VER_MAJOR_HEX=`printf "%02X" $VER_MAJOR`
  24 VER_MINOR_HEX=`printf "%02X" $VER_MINOR`
  25 VER_PATCH_HEX=`printf "%02X" $VER_PATCH`
  26 AC_SUBST(VER_MAJOR_HEX)
  27 AC_SUBST(VER_MINOR_HEX)
  28 AC_SUBST(VER_PATCH_HEX)
  29 VER_STRING="\"$VERSION\""
  30 AC_SUBST(VER_STRING)
  31
  32 case "$target_os" in
  33     darwin*)
  34         LDFLAGS="$LDFLAGS -flat_namespace -L/sw/lib"
  35         CPPFLAGS="$CPPFLAGS -I/sw/include -L/sw/lib"
  36         ;;
  37     linux*)
  38         case "$target_cpu" in
  39             x86_64*)
  40                 LDFLAGS="$LDFLAGS -lrt"
  41                 ;;
  42             *)
  43                 ;;
  44         esac
  45         ;;
  46     *)
  47         ;;
  48 esac
  49
  50 dnl Checks for programs.
  51 AC_PROG_CC_C99
  52
  53 if test "$ac_cv_prog_cc_c99" = "no"; then
  54     AC_MSG_ERROR("Unable to find a C99 compatible compiler.")
  55 fi
  56
  57 dnl Borrowed from libssh2!
  58 dnl ************************************************************
  59 dnl Enable hiding of internal symbols in library to reduce its size and
  60 dnl speed dynamic linking of applications.  This currently is only supported
  61 dnl on gcc >= 4.0 and SunPro C.
  62 dnl
  63 AC_MSG_CHECKING([whether to enable hidden symbols in the library])
  64 AC_ARG_ENABLE(hidden-symbols,
  65 AC_HELP_STRING([--enable-hidden-symbols],[Hide internal symbols in library])
  66 AC_HELP_STRING([--disable-hidden-symbols],[Leave all symbols with default visibility in library]),
  67 [ case "$enableval" in
  68   no)
  69        AC_MSG_RESULT(no)
  70        ;;
  71   *)
  72        AC_MSG_CHECKING([whether $CC supports it])
  73        if test "$GCC" = yes ; then
  74          if $CC --help --verbose 2>&1 | grep fvisibility= > /dev/null ; then
  75            AC_MSG_RESULT(yes)
  76            AC_DEFINE(LIBPWMD_API, [__attribute__ ((visibility ("default")))], [to make a symbol visible])
  77            CFLAGS="$CFLAGS -fvisibility=hidden"
  78          else
  79             AC_MSG_RESULT(no)
  80           fi
  81
  82        else
  83          dnl Test for SunPro cc
  84          if $CC 2>&1 | grep flags >/dev/null && $CC -flags | grep xldscope= >/dev/null ; then
  85            AC_MSG_RESULT(yes)
  86            AC_DEFINE(LIBPWMD_API, [__global], [to make a symbol visible])
  87            CFLAGS="$CFLAGS -xldscope=hidden"
  88          else
  89            AC_MSG_RESULT(no)
  90          fi
  91        fi
  92        ;;
  93   esac ],
  94        AC_MSG_RESULT(no)
  95 )
  96
  97 dnl Checks for header files.
  98 AC_HEADER_STDC
  99 AC_HEADER_SYS_WAIT
 100 AC_CHECK_HEADERS([fcntl.h limits.h stdlib.h string.h unistd.h sys/socket.h \
 101                   getopt.h])
 102
 103 dnl Checks for typedefs, structures, and compiler characteristics.
 104 AC_C_CONST
 105 AC_TYPE_SIZE_T
 106 AC_STRUCT_TM
 107 AC_TYPE_SSIZE_T
 108 AC_TYPE_PID_T
 109
 110 AX_CHECK_COMPILE_FLAG([-D_FORTIFY_SOURCE=2],
 111                       [CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"])
 112 AX_CHECK_COMPILE_FLAG([-fsanitize=undefined],
 113                       [CFLAGS="$CFLAGS -fsanitize=undefined"])
 114 ACX_PTHREAD(, AC_MSG_ERROR([Missing or incomplete pthread installation]))
 115 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 116 LIBS="$PTHREAD_LIBS $LIBS"
 117 PKG_PROG_PKG_CONFIG
 118
 119 AC_ARG_ENABLE(interactive, AC_HELP_STRING([--disable-interactive], [Disable interactive mode in pwmc.]),
 120                 WITH_INTERACTIVE=no, WITH_INTERACTIVE=yes)
 121 AC_MSG_CHECKING([if interactive mode is wanted])
 122 AC_MSG_RESULT($WITH_INTERACTIVE)
 123 if test "x$WITH_INTERACTIVE" = "xyes"; then
 124     VL_LIB_READLINE
 125
 126     if test "x$vl_cv_lib_readline" != "xno"; then
 127         READLINE_LIBS="$vl_cv_lib_readline"
 128         AC_SUBST(READLINE_LIBS)
 129     else
 130         AC_MSG_ERROR([Missing or incomplete readline installation.])
 131         WITH_INTERACTIVE="no"
 132     fi
 133 fi
 134 AM_CONDITIONAL([WITH_READLINE], [test x"$vl_cv_lib_readline" != "x"])
 135
 136 AM_PATH_LIBASSUAN([2.1.0], have_libassuan_2_1_0=yes)
 137 if test x"$have_libassuan_2_1_0" != x"yes";then
 138    AM_PATH_LIBASSUAN([2.0.3],, AC_MSG_ERROR([libassuan 2.0.3 or later required.]))
 139 else
 140    AC_DEFINE(LIBASSUAN_2_1_0, 1, [Define if you have libassuan 2.1.0 or later.])
 141 fi
 142
 143 AM_PATH_GPG_ERROR(,, AC_MSG_ERROR([Missing or incomplete libgpg-error installation.]))
 144
 145 AC_ARG_ENABLE(ssh, AC_HELP_STRING([--enable-ssh], [Enable SSH support.]),
 146                 WITH_SSH=$enableval, WITH_SSH=no)
 147 AC_MSG_CHECKING([if ssh support is wanted])
 148 AC_MSG_RESULT($WITH_SSH)
 149 if test "x$WITH_SSH" = "xyes"; then
 150     AC_MSG_CHECKING([for libssh2 availability])
 151     PKG_CHECK_EXISTS([libssh2], have_libssh2=1)
 152     WITH_SSH=no
 153
 154     if test $have_libssh2; then
 155         PKG_CHECK_MODULES([libssh2], [libssh2 >= 1.2.9])
 156         AC_DEFINE(WITH_SSH, 1, [Define if you want SSH support.])
 157         WITH_SSH=yes
 158     else
 159         AC_MSG_ERROR([Missing or incomplete libssh2 installation.])
 160     fi
 161 fi
 162 AM_CONDITIONAL([WITH_SSH], [test "x$WITH_SSH" = "xyes"])
 163
 164 AC_ARG_ENABLE(gnutls, AC_HELP_STRING([--enable-gnutls],
 165               [Enable GnuTLS client support.]), WITH_GNUTLS=$enableval,
 166               WITH_GNUTLS=no)
 167 AC_MSG_CHECKING([if gnutls support is wanted])
 168 AC_MSG_RESULT($WITH_GNUTLS)
 169 if test "x$WITH_GNUTLS" = "xyes"; then
 170     AC_MSG_CHECKING([for libgnutls availability])
 171     PKG_CHECK_EXISTS(gnutls, have_libgnutls=1, AC_MSG_ERROR([gnutls pkg-config module not found]))
 172     WITH_GNUTLS=no
 173
 174     if test $have_libgnutls; then
 175         PKG_CHECK_MODULES([GNUTLS], [gnutls])
 176         AC_DEFINE(WITH_GNUTLS, 1, [Define if you want GnuTLS support.])
 177         WITH_GNUTLS=yes
 178     else
 179         AC_MSG_ERROR([Missing or incomplete gnutls installation.])
 180     fi
 181 fi
 182 AM_CONDITIONAL(WITH_GNUTLS, [test "x$WITH_GNUTLS" = "xyes"])
 183
 184 # Default pwmd socket.
 185 AC_ARG_WITH(pwmd_socket, AC_HELP_STRING([--with-pwmd-socket=PATH],
 186               [Default pwmd socket (~/.pwmd/socket)]),
 187               pwmd_socket="$withval", pwmd_socket=)
 188 if test x"$pwmd_socket" != "x"; then
 189    AC_DEFINE_UNQUOTED(DEFAULT_PWMD_SOCKET, ["$pwmd_socket"],
 190                       [Default pwmd socket (~/.pwmd/socket).])
 191 else
 192    pwmd_socket="~/.pwmd/socket"
 193 fi
 194 AC_SUBST(pwmd_socket)
 195
 196 dnl Checks for library functions.
 197 AC_FUNC_MALLOC
 198 AC_FUNC_REALLOC
 199 AC_FUNC_STRFTIME
 200 AC_FUNC_SELECT_ARGTYPES
 201 AC_CHECK_FUNCS([memmove select socket strdup strerror setlocale getcwd \
 202                 memset stpcpy strchr strrchr strtok_r getopt_long getpwuid_r])
 203 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
 204
 205 AC_DEFUN([AC_MEM_DEBUG],
 206 [
 207     if test "$1"; then
 208         ac_cv_sys_mem_debug=$1
 209     fi
 210
 211     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 212         [ac_cv_sys_mem_debug=no])
 213     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 214 ])
 215
 216 AC_ARG_ENABLE(mem_debug, AC_HELP_STRING([--enable-mem-debug],
 217               [Enable memory debugging.]), AC_MEM_DEBUG([$enableval]),
 218               AC_MEM_DEBUG)
 219
 220 AM_CONDITIONAL(MEM_DEBUG, test "x${ac_cv_sys_mem_debug}" != "xno")
 221
 222 AC_ARG_ENABLE(pinentry, AC_HELP_STRING([--disable-pinentry],
 223               [Disable pinentry(1) support (not pwmd).]), WITH_PINENTRY=no,
 224               WITH_PINENTRY=yes)
 225
 226 if test "x$WITH_PINENTRY" != "xno"; then
 227     AC_CHECK_HEADERS([locale.h])
 228     AC_DEFINE(WITH_PINENTRY, 1, [Define if you want local pinentry(1) support.])
 229 fi
 230
 231 AM_CONDITIONAL([WITH_PINENTRY], [test "x$WITH_PINENTRY" = "xyes"])
 232 pinentry="/usr/bin/pinentry"
 233
 234 AC_ARG_WITH(pinentry, AC_HELP_STRING([--with-pinentry=PATH],
 235               [Default location of the pinentry binary (/usr/bin/pinentry)]),
 236               pinentry="$withval")
 237
 238 AC_SUBST(pinentry)
 239 AC_DEFINE_UNQUOTED(PINENTRY_PATH, ["$pinentry"],
 240                    [Default location of the pinentry binary.])
 241
 242 # Cracklib support (requires pinentry support).
 243 AC_ARG_ENABLE(quality, AC_HELP_STRING([--enable-quality],
 244               [Enable password quality checking with cracklib.]),
 245               WITH_QUALITY=$enableval, WITH_QUALITY=no)
 246 if test "x$WITH_QUALITY" = "xyes"; then
 247     if test "x$WITH_PINENTRY" != "xyes"; then
 248         AC_MSG_ERROR([--enable-quality needs --enable-pinentry])
 249     fi
 250
 251     AC_CHECK_HEADER([crack.h],, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 252     AC_CHECK_LIB([crack], FascistCheck,, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 253     AC_DEFINE(WITH_QUALITY, 1, [Define if you want password quality checking.])
 254 fi
 255 AM_CONDITIONAL(WITH_QUALITY, [test "x$WITH_QUALITY" = "xyes"])
 256
 257 crackdict="/var/cache/cracklib/cracklib_dict"
 258 AC_ARG_WITH(crackdict, AC_HELP_STRING([--with-crack-dict=PATH],
 259               [Location of the cracklib dictionary (/var/cache/cracklib/cracklib_dict).]),
 260               crackdict="$withval")
 261 AC_SUBST(crackdict)
 262 AC_DEFINE_UNQUOTED(CRACKLIB_DICT, ["$crackdict"], [The location of the cracklib dictionary.])
 263
 264 dnl Disable optimizing of memset(). GCC and CLang (and others?) accept
 265 dnl multiple optimization flags and use the last one specified. The
 266 dnl non-optimized memset() may still use any CPU features found in the
 267 dnl user specified CFLAGS (-mtune) and libc.
 268 CFLAGS_ORIG="$CFLAGS"
 269 CFLAGS_MEMZERO="$CFLAGS -O0"
 270 CFLAGS=
 271 AC_SUBST(CFLAGS_ORIG)
 272 AC_SUBST(CFLAGS_MEMZERO)
 273
 274 AC_CONFIG_FILES([Makefile libpwmd-7.0.pc doc/Makefile doc/doxygen.conf.in \
 275                  doc/pwmc.1 src/Makefile src/libpwmd.h po/Makefile.in])
 276 AC_OUTPUT
 277 echo
 278 echo "Features:"
 279 echo "    Interactive pwmc: $WITH_INTERACTIVE"
 280 echo "    Ssh: $WITH_SSH"
 281 echo "    GnuTLS: $WITH_GNUTLS"
 282 echo "    Local pinentry: $WITH_PINENTRY"
 283 echo "    Pinentry location: $pinentry"
 284
 285 if test x"$pwmd_socket" != "x"; then
 286 echo "    Default pwmd socket: $pwmd_socket"
 287 else
 288 echo "    Default pwmd socket: ~/.pwmd/socket"
 289 fi
 290
 291 echo "    Local passphrase quality checking: $WITH_QUALITY"
 292 echo "    Crack dictionary: $crackdict"
 293 echo "    Memory debug: ${ac_cv_sys_mem_debug}"