configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.59)
   3 AC_INIT(libpwmd, 5.0.8, [Ben Kibbey bjk@luxsci.net])
   4 AC_CONFIG_AUX_DIR(build)
   5 AC_CANONICAL_TARGET
   6 AM_INIT_AUTOMAKE([foreign])
   7 AC_PROG_MAKE_SET
   8 #AC_DISABLE_SHARED
   9 AC_PROG_LIBTOOL
  10 AC_CONFIG_SRCDIR([libpwmd.c])
  11 AM_CONFIG_HEADER([config.h])
  12 AM_GNU_GETTEXT([external])
  13 AM_GNU_GETTEXT_VERSION([0.16.1])
  14
  15 VER_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`"
  16 VER_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`"
  17 VER_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`"
  18 VER_COMPAT=0
  19 AC_SUBST(VER_MAJOR)
  20 AC_SUBST(VER_MINOR)
  21 AC_SUBST(VER_PATCH)
  22 AC_SUBST(VER_COMPAT)
  23
  24 case "$target_os" in
  25     darwin*)
  26         LDFLAGS="$LDFLAGS -flat_namespace -L/sw/lib"
  27         CPPFLAGS="$CPPFLAGS -I/sw/include -L/sw/lib"
  28         ;;
  29     *)
  30         ;;
  31 esac
  32
  33 CFLAGS="$CFLAGS -D_GNU_SOURCE"
  34
  35 dnl Checks for programs.
  36 AC_PROG_CC
  37
  38 dnl Checks for header files.
  39 AC_HEADER_STDC
  40 AC_HEADER_SYS_WAIT
  41 AC_CHECK_HEADERS([fcntl.h limits.h stdlib.h string.h unistd.h sys/socket.h \
  42                   assuan.h])
  43
  44 dnl Checks for typedefs, structures, and compiler characteristics.
  45 AC_C_CONST
  46 AC_TYPE_SIZE_T
  47 AC_STRUCT_TM
  48 AC_TYPE_SSIZE_T
  49 AC_TYPE_PID_T
  50
  51 AM_PATH_LIBASSUAN(1.0.5,, AC_MSG_ERROR([Missing or incomplete libassuan installation.]))
  52 AM_PATH_GPG_ERROR(,, AC_MSG_ERROR([Missing or incomplete libgpg-error installation.]))
  53 AC_CHECK_PTH(, yes, yes, no, have_libpth=yes, have_libpth=no)
  54 AM_CONDITIONAL([WITH_LIBPTH], [test "x$have_libpth" = "xyes"])
  55
  56 if test "x$have_libpth" = "xyes"; then
  57     AM_PATH_LIBASSUAN_PTH(1.0.5,, AC_MSG_ERROR([libassuan-pth not found]))
  58 fi
  59
  60 AC_ARG_ENABLE(tcp, AC_HELP_STRING([--disable-tcp],
  61               [Disable TCP (GnuTLS) support.]), WITH_TCP=no,
  62               WITH_TCP=$enableval)
  63
  64 if test "x$WITH_TCP" != "xno"; then
  65     AM_PATH_LIBGNUTLS(, AC_DEFINE(HAVE_LIBGNUTLS, 1,
  66                       [Define if you want TCP (GnuTLS) support.]),
  67                       AC_MSG_ERROR([Missing or incomplete libgnutls installation.]))
  68     AC_CHECK_LIB(event, evdns_resolve_ipv4, ,
  69                  AC_MSG_ERROR([Missing or incomplete libevent installation.]))
  70     LIBEVENT_LIBS="-levent"
  71     AC_SUBST(LIBEVENT_LIBS)
  72 fi
  73
  74 dnl Checks for library functions.
  75 AC_FUNC_MALLOC
  76 AC_FUNC_REALLOC
  77 AC_FUNC_STRFTIME
  78 AC_FUNC_SELECT_ARGTYPES
  79 AC_CHECK_FUNCS([memmove select socket strdup strerror setlocale getcwd \
  80                 memset stpcpy strchr strrchr strtok_r])
  81
  82 AC_DEFUN([AC_MEM_DEBUG],
  83 [
  84     if test "$1"; then
  85         ac_cv_sys_mem_debug=$1
  86     fi
  87
  88     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
  89         [ac_cv_sys_mem_debug=no])
  90     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
  91 ])
  92
  93 AC_ARG_ENABLE(mem_debug, AC_HELP_STRING([--enable-mem-debug],
  94               [Enable memory debugging.]), AC_MEM_DEBUG([$enableval]),
  95               AC_MEM_DEBUG)
  96
  97 AM_CONDITIONAL(MEM_DEBUG, test "x${ac_cv_sys_mem_debug}" != "xno")
  98
  99 AC_ARG_ENABLE(pinentry, AC_HELP_STRING([--disable-pinentry],
 100               [Disable local pinentry(1) support.]), WITH_PINENTRY=no,
 101               WITH_PINENTRY=$enableval)
 102
 103 if test "x$WITH_PINENTRY" != "xno"; then
 104     AC_CHECK_HEADERS([locale.h])
 105     AC_DEFINE(WITH_PINENTRY, 1, [Define if you want local pinentry(1) support.])
 106 fi
 107
 108 pinentry="/usr/bin/pinentry"
 109
 110 AC_ARG_WITH(pinentry, AC_HELP_STRING([--with-pinentry=PATH],
 111               [Default location of the pinentry binary (/usr/bin/pinentry)]),
 112               pinentry="$withval")
 113
 114 AC_SUBST(pinentry)
 115 AC_DEFINE_UNQUOTED(PINENTRY_PATH, ["$pinentry"],
 116                    [Default location of the pinentry binary.])
 117
 118 AC_CONFIG_FILES([Makefile libpwmd.h libpwmd.pc libpwmd-pth.pc libpwmd.3 \
 119                  pwmc.1 po/Makefile.in])
 120 AC_OUTPUT